DisplayObjectContainer  - AS3

Bepaalt of de onderliggende elementen van het object door de muis of door een gebruikersinvoerapparaat worden ingeschakeld. Als een object wordt ingeschakeld, kan een gebruiker ermee communiceren met behulp van een muis of een gebruikersinvoerapparaat. De standaardwaarde is true.

Deze eigenschap is handig wanneer u een knop maakt met een instantie van de klasse Sprite (in plaats van de klasse SimpleButton). Wanneer u een instantie Sprite gebruikt om een knop te maken, kunt u het uiterlijk van de knop aanpassen met de methode addChild() en zo aanvullende instanties Sprites toevoegen. Dit kan leiden tot onverwacht gedrag bij muisgebeurtenissen aangezien de instanties Sprite die u toevoegt als onderliggende objecten het doelobject van een muisgebeurtenis kunnen worden, terwijl u verwacht dat de bovenliggende instantie het doelobject is. Wanneer u er zeker van wilt zijn dat de bovenliggende instantie fungeert als doelobject voor muisgebeurtenissen, stelt u de eigenschap mouseChildren van de bovenliggende instantie in op false.

Bij het instellen van deze eigenschap wordt geen gebeurtenis verzonden. U moet de methode addEventListener() gebruiken om interactieve functionaliteit toe te voegen.

Verwante API-elementen

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Retourneert het aantal onderliggende objecten van dit object.

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Bepaalt of de onderliggende objecten van het object tabnavigatie hebben. Schakelt tabnavigatie voor de onderliggende objecten van het object in of uit. De standaardwaarde is true.

Opmerking: Gebruik de tabChildren-eigenschap niet met Flex. Gebruik in plaats daarvan gebruikt u de mx.core.UIComponent.hasFocusableChildren-eigenschap.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Retourneert een object TextSnapshot voor deze instantie DisplayObjectContainer.

Verwante API-elementen

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

Wanneer de constructor new DisplayObjectContainer() wordt aangeroepen, wordt de uitzondering ArgumentError gegenereerd. U kunt echter constructors aanroepen voor de volgende subklassen van DisplayObjectContainer:

• new Loader()
• new Sprite()
• new MovieClip()

Voegt een onderliggende instantie DisplayObject toe aan deze instantie DisplayObjectContainer. Het onderliggende object wordt toegevoegd voor (boven) alle andere onderliggende objecten van deze instantie DisplayObjectContainer. (Wanneer u een onderliggend object wilt toevoegen aan een specifieke indexpositie, gebruikt u de methode addChildAt().)

Wanneer u een onderliggend object toevoegt dat al een ander weergaveobjectcontainer als bovenliggend object heeft, wordt het object verwijderd uit de lijst met onderliggende objecten van de andere weergaveobjectcontainer.

Opmerking: De opdracht stage.addChild kan problemen veroorzaken met een gepubliceerd SWF-bestand, zoals veiligheidsproblemen en conflicten met andere geladen SWF-bestanden. Er is slechts één werkgebied binnen een Flash-runtime-instantie, ongeacht hoeveel SWF-bestanden u in de runtime laadt. Objecten moeten over het algemeen niet direct aan het werkgebied worden toegevoegd. Het enige object dat zich niet in het werkgebied mag bevinden, is het hoofdobject. Maak een DisplayObjectContainer waarin alle items op de weergavelijst staan. Voeg vervolgens, indien nodig, die DisplayObjectContainer-instantie toe aan het werkgebied.

Parameters

Verwante API-elementen

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Voegt een onderliggende instantie DisplayObject toe aan deze instantie DisplayObjectContainer. Het onderliggende object wordt toegevoegd op de opgegeven indexpositie. Index 0 vertegenwoordigt de achterkant (onderkant) van het weergaveoverzicht voor het object DisplayObjectContainer.

In het volgende voorbeeld worden bijvoorbeeld drie weergaveobjecten, genaamd a, b en c, weergegeven op respectievelijk de indexpositie 0, 2 en 1:

Wanneer u een onderliggend object toevoegt dat al een ander weergaveobjectcontainer als bovenliggend object heeft, wordt het object verwijderd uit de lijst met onderliggende objecten van de andere weergaveobjectcontainer.

Parameters

Verwante API-elementen

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Geeft aan of vanwege beveiligingsbeperkingen weergaveobjecten worden weggelaten uit de lijst die wordt geretourneerd wanneer de methode DisplayObjectContainer.getObjectsUnderPoint() wordt aangeroepen met het opgegeven punt point. Standaard heeft inhoud van een bepaald domein geen toegang tot objecten van een ander domein, tenzij dit is toegestaan via een aanroep van de methode Security.allowDomain(). Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

De parameter point is de coördinaatruimte van het werkgebied, die kan verschillen van de coördinaatruimte van de weergaveobjectcontainer (tenzij de weergaveobjectcontainer het werkgebied is). U kunt de methoden globalToLocal() en localToGlobal() gebruiken om punten om te zetten tussen deze twee coördinaatruimten.

Parameters

Verwante API-elementen

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Bepaalt of het opgegeven weergaveobject een onderliggend object van de instantie DisplayObjectContainer of de instantie zelf is. Er wordt gezocht in het hele weergaveoverzicht, met inbegrip van de instantie DisplayObjectContainer. Onderliggende objecten van onderliggende objecten enzovoort retourneren elk de waarde true.

Parameters

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Retourneert de onderliggende weergaveobjectinstantie bij de opgegeven index.

Parameters

Verwante API-elementen

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Retourneert de onderliggende weergaveobjectinstantie met de opgegeven naam. Wanneer meer dan één onderliggend weergaveobject de opgegeven naam heeft, retourneert de methode het eerste object in de lijst met onderliggende objecten.

De methode getChildAt() is sneller dan de methode getChildByName(). De methode getChildAt() heeft toegang tot een onderliggend object via een array in de cache, terwijl de methode getChildByName() een gekoppelde lijst moet doorlopen om toegang te krijgen tot een onderliggend object.

Parameters

Verwante API-elementen

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Retourneert de indexpositie van een onderliggende (child) instantie DisplayObject.

Parameters

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Retourneert een array met objecten die zich onder het opgegeven punt bevinden en onderliggende objecten van deze instantie DisplayObjectContainer zijn (of onderliggende objecten van onderliggende objecten van die instantie). Eventuele onderliggende objecten die om beveiligingsredenen niet toegankelijk zijn, worden weggelaten uit de geretourneerde array. Wanneer u wilt bepalen of deze beveiligingsbeperking van invloed is op de geretourneerde array, roept u de methode areInaccessibleObjectsUnderPoint() aan.

De parameter point is de coördinaatruimte van het werkgebied, die kan verschillen van de coördinaatruimte van de weergaveobjectcontainer (tenzij de weergaveobjectcontainer het werkgebied is). U kunt de methoden globalToLocal() en localToGlobal() gebruiken om punten om te zetten tussen deze twee coördinaatruimten.

Parameters

Verwante API-elementen

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Verwijdert de opgegeven onderliggende instantie DisplayObject uit de lijst met onderliggende objecten van de instantie DisplayObjectContainer. De eigenschap parent van het verwijderde onderliggende object wordt ingesteld op null en het object wordt opgeschoond wanneer er geen andere referenties naar het object bestaan. De indexposities van eventuele weergaveobjecten boven het onderliggende object in de DisplayObjectContainer worden met 1 verlaagd.

De opschoonfunctie wijst ongebruikte geheugenruimte opnieuw toe. Wanneer niet meer actief wordt verwezen naar een variabele of object of wanneer de variabele of het object nergens meer is opgeslagen, wordt de geheugenruimte die de variabele of het object innam leeggemaakt wanneer er geen andere referenties naar bestaan.

Parameters

 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

Verwijdert een onderliggend DisplayObject uit de opgegeven indexpositie in de lijst met onderliggende objecten van de DisplayObjectContainer. De eigenschap parent van het verwijderde onderliggende object wordt ingesteld op null en het object wordt opgeschoond wanneer er geen andere referenties naar het object bestaan. De indexposities van eventuele weergaveobjecten boven het onderliggende object in de DisplayObjectContainer worden met 1 verlaagd.

De opschoonfunctie wijst ongebruikte geheugenruimte opnieuw toe. Wanneer niet meer actief wordt verwezen naar een variabele of object of wanneer de variabele of het object nergens meer is opgeslagen, wordt de geheugenruimte die de variabele of het object innam leeggemaakt wanneer er geen andere referenties naar bestaan.

Parameters

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Verwijdert alle DisplayObject-instanties childuit de lijst met onderliggende objecten van de instantie DisplayObjectContainer. De eigenschap parent van de verwijderde onderliggende objecten wordt ingesteld op null en de objecten worden opgeschoond wanneer er geen andere referenties naar de onderliggende objecten bestaan.

De opschoonfunctie wijst ongebruikte geheugenruimte opnieuw toe. Wanneer niet meer actief wordt verwezen naar een variabele of object of wanneer de variabele of het object nergens meer is opgeslagen, wordt de geheugenruimte die de variabele of het object innam leeggemaakt wanneer er geen andere referenties naar bestaan.

Parameters

Wijzigt de positie van een bestaand onderliggend object in de weergaveobjectcontainer. Dit is van invloed op de laagvolgorde van onderliggende objecten. In het volgende voorbeeld worden bijvoorbeeld drie weergaveobjecten, genaamd a, b en c, weergegeven op respectievelijk de indexpositie 0, 1 en 2:

Wanneer u de methode setChildIndex() gebruikt en een indexpositie opgeeft die al in gebruik is, veranderen alleen de posities tussen de voormalige en de nieuwe positie van het weergaveobject. Alle andere posities blijven dezelfde. Als een onderliggend item wordt verplaatst naar een index die LAGER ligt dan de huidige index, zullen de indexverwijzingen van alle onderliggende items daartussenin met 1 TOENEMEN. Als een onderliggend item wordt verplaatst naar een index die HOGER ligt dan de huidige index, zullen de indexverwijzingen van alle onderliggende items daartussenin met 1 AFNEMEN. Wanneer de weergaveobjectcontainer in het vorige voorbeeld bijvoorbeeld container heet, kunt u de positie van de weergaveobjecten genaamd a en b omwisselen door de volgende code aan te roepen:

container.setChildIndex(container.getChildAt(1), 0);

Deze code resulteert in de volgende rangschikking van objecten:

Parameters

Verwante API-elementen

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Stopt recursief de tijdlijnuitvoering van alle filmclips die beginnen bij dit object.

De onderliggende weergaveobjecten die behoren tot een sandbox waartoe de uitvoeringscode geen toegang heeft, worden genegeerd.

Opmerking: Het streamen van media die wordt beheerd via een NetStream-object, wordt niet gestopt.

Wisselt de z-volgorde (van voor naar achter) van de twee opgegeven onderliggende objecten om. Alle andere onderliggende objecten in de weergaveobjectcontainer behouden hun indexpositie.

Parameters

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Wisselt de z-volgorde (van voor naar achter) van de onderliggende objecten op de twee opgegeven indexposities in de lijst met onderliggende objecten om. Alle andere onderliggende objecten in de weergaveobjectcontainer behouden hun indexpositie.

Parameters

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. De constructor roept de methode configureAssets() aan.
2. De methode configureAssets() maakt Sprite-objecten child en lastChild.
3. Een for-lus maakt de vijf oranje vierkanten en plaatst ze een voor een.
4. Telkens wanneer een object CustomSprite wordt gemaakt, roept de constructor ervan de methode draw() van het object CustomSprite aan die een vierkant van 50 bij 50 pixels maakt door de methoden beginFill(), drawRect() en endFill() van de klasse Graphics aan te roepen. De methode addChild() voegt elk vierkant toe aan het weergaveoverzicht.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}