Sprite  - AS3

Geeft de knopmodus van deze sprite op. Wanneer de waarde true is, gedraagt deze sprite zich als een knop. Dit betekent dat de aanwijzer verandert in een handje wanneer de cursor zich op de sprite bevindt en dat de sprite de gebeurtenis click kan ontvangen wanneer op de Enter-toets of de spatiebalk wordt gedrukt terwijl de sprite focus heeft. U kunt voorkomen dat het handje wordt weergegeven door de eigenschap useHandCursor in te stellen op false, in welk geval de aanwijzer wordt weergegeven.

Hoewel u beter de klasse SimpleButton kunt gebruiken om knoppen te maken, kunt u de eigenschap buttonMode gebruiken om een sprite knopachtige functionaliteit te geven. Wanneer u een sprite wilt opnemen in de tabvolgorde, stelt u de eigenschap tabEnabled (die wordt overerfd van de klasse InteractiveObject en standaard is ingesteld op false) in op true. Daarnaast dient u te overwegen of u wilt dat de onderliggende objecten van de sprite gebruikersinvoer hebben. Bij de meeste knoppen wordt geen gebruikersinvoerinteractiviteit ingesteld voor onderliggende objecten aangezien hierdoor de gebeurtenisstroom in de war wordt gestuurd. Wanneer u gebruikersinvoerinteractiviteit wilt uitschakelen voor alle onderliggende objecten, moet u de eigenschap mouseChildren (die is overerfd van de klasse DisplayObjectContainer) instellen op false.

Wanneer u de eigenschap buttonMode gebruikt met de klasse MovieClip (een subklasse van de klasse Sprite), kunt u extra functionaliteit toevoegen aan de knop. Wanneer u frames genaamd _up, _over en _down toevoegt, biedt Flash Player automatische statuswijzigingen. (Deze functionaliteit lijkt op de functionaliteit die in eerdere versies van ActionScript werd geboden voor filmclips die als knoppen werden gebruikt.) Deze automatische statuswijzigingen zijn niet beschikbaar voor sprites, die geen tijdlijn hebben en dus geen frames die u een naam kunt geven.

Verwante API-elementen

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Geeft het weergaveobject op waarover de sprite wordt gesleept of waarop de sprite is neergezet.

Verwante API-elementen

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Geeft het object Graphics op dat bij deze sprite hoort, waarbij vectortekenopdrachten kunnen optreden.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Wijst een andere sprite aan als raakgebied voor een sprite. Wanneer de eigenschap hitArea niet bestaat of de waarde null of undefined heeft, wordt de filmclip zelf als raakgebied gebruikt. De waarde van de eigenschap hitArea kan een verwijzing zijn naar een object Sprite.

U kunt de eigenschap hitArea op elk moment wijzigen. De aangepaste sprite gebruikt direct het nieuwe gedrag voor het raakgebied. De sprite die als raakgebied wordt opgegeven, hoeft niet zichtbaar te zijn. De grafische vorm ervan wordt ook als raakgebied gedetecteerd wanneer de sprite niet zichtbaar is.

Opmerking: u moet de eigenschap mouseEnabled van de sprite die als raakgebied wordt gebruikt instellen op false. Zo niet, dan werkt de spriteknop mogelijk niet omdat de sprite die is toegewezen als raakgebied de gebruikersinvoergebeurtenissen ontvangt in plaats van de spriteknop.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Beheert geluid binnen deze sprite.

Opmerking: deze eigenschap heeft geen invloed op de HTML-inhoud in een HTMLControl-object (in Adobe AIR).

Verwante API-elementen

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

Een Booleaanse waarde die aangeeft of het wijzende handje wordt weergegeven wanneer de cursor wordt bewogen over een sprite waarin de eigenschap buttonMode is ingesteld op true. De standaardwaarde van de eigenschap useHandCursor is true. Wanneer useHandCursor is ingesteld op true, wordt het wijzende handje dat voor knoppen wordt gebruikt, weergegeven wanneer de cursor over een knopsprite beweegt. Wanneer useHandCursor is ingesteld op false, wordt in plaats daarvan de pijlaanwijzer gebruikt.

U kunt de eigenschap useHandCursor op elk moment wijzigen. De aangepaste sprite gebruikt direct het nieuwe uiterlijk voor de aanwijzer.

Opmerking: In Flex of Flash Builder kunt u de eigenschap mouseChildren beter op false instellen als de sprite onderliggende sprites heeft. Wanneer u bijvoorbeeld wilt dat een handje wordt weergegeven boven een Flex-besturingselement <mx:Label>, stelt u de eigenschappen useHandCursor en buttonMode in op true en de eigenschap mouseChildren op false .

Verwante API-elementen

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Maakt een nieuwe instantie Sprite. Nadat u de instantie Sprite hebt gemaakt, roept u de methode DisplayObjectContainer.addChild() of DisplayObjectContainer.addChildAt() aan om de Sprite toe te voegen aan een bovenliggende DisplayObjectContainer.

Hiermee kan de gebruiker de opgegeven sprite slepen. De sprite blijft versleepbaar totdat dit expliciet wordt beëindigd met een aanroep van de methode Sprite.stopDrag() of totdat een andere sprite versleepbaar wordt gemaakt. Er kan slechts één sprite tegelijk versleepbaar zijn.

Driedimensionale weergaveobjecten volgen de cursor en Sprite.startDrag() verplaatst het object binnen het driedimensionale vlak dat wordt gedefinieerd door het weergaveobject. Als het weergaveobject een tweedimensionaal object is en het onderliggende object is van een driedimensionaal object, wordt het tweedimensionale object verplaatst binnen het driedimensionale vlak dat wordt gedefinieerd door het driedimensionale bovenliggende object.

Parameters

Verwante API-elementen

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Hiermee kan de gebruiker de opgegeven sprite naar een apparaat met aanraakbediening slepen. De sprite blijft versleepbaar totdat dit expliciet wordt beëindigd met een aanroep van de methode Sprite.stopTouchDrag() of totdat een andere sprite versleepbaar wordt gemaakt. Er kan slechts één sprite tegelijk versleepbaar zijn.

Driedimensionale weergaveobjecten volgen de cursor en Sprite.startTouchDrag() verplaatst het object binnen het driedimensionale vlak dat wordt gedefinieerd door het weergaveobject. Als het weergaveobject een tweedimensionaal object is en het onderliggende object is van een driedimensionaal object, wordt het tweedimensionale object verplaatst binnen het driedimensionale vlak dat wordt gedefinieerd door het driedimensionale bovenliggende object.

Parameters

Verwante API-elementen

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

Beëindigt de methode startDrag(). Een sprite versleepbaar is gemaakt met de methode startDrag(), blijft versleepbaar totdat de methode stopDrag() wordt toegevoegd of totdat een andere sprite versleepbaar wordt. Er kan slechts één sprite tegelijk versleepbaar zijn.

Verwante API-elementen

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Beëindigt de startTouchDrag()-methode, voor gebruik met apparaten met aanraakbediening. Een sprite versleepbaar is gemaakt met de methode startTouchDrag(), blijft versleepbaar totdat de methode stopTouchDrag() wordt toegevoegd of totdat een andere sprite versleepbaar wordt. Er kan slechts één sprite tegelijk versleepbaar zijn.

Parameters

Verwante API-elementen

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. De eigenschap size (100 x 100 pixels) en de achtergrondkleur (oranje) worden gedeclareerd, zodat deze later kunnen worden gebruikt wanneer het vierkant wordt getekend.
2. Vervolgens maakt de constructor een nieuw onderliggend object Sprite, dat wordt gebruikt dit om twee gebeurtenislisteners en de bijbehorende methoden toe te voegen: mouseDownHandler() en mouseUpHandler().
3. Het onderliggende object Sprite wordt vervolgens doorgegeven aan de methode draw(), die het oranje vierkant tekent.
4. Vervolgens wordt het onderliggende object aan het weergaveoverzicht toegevoegd via een aanroep van de methode addChild().
5. De gebeurtenislisteners werken als volgt:
   • mouseDownHandler(): wanneer de gebruiker op het object Sprite klikt, voegt deze methode een mouseMove-gebeurtenislistener, de methode mouseMoveHandler(), toe die de muisverplaatsingen verwerkt. methode startDrag() aangeroepen, die mogelijk maakt dat het object Sprite wordt versleept.
   • mouseUpHandler(): wanneer de muisknop wordt losgelaten, wordt de gebeurtenislistener mouseMove verwijderd en wordt de methode stopDrag() aangeroepen, die het oranje vierkant op zijn plaats vastzet.
   • mouseMoveHandler: zolang de linkermuisknop wordt ingedrukt, geeft deze methode de speler de opdracht om het oranje vierkant telkens opnieuw te tekenen.

Opmerking: elk van de methoden van de gebeurtenislistener declareert een lokale variabele sprite, waaraan de eigenschap target van de gebeurtenis wordt toegewezen.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}