SimpleButton  - AS3

Hiermee wordt een weergaveobject opgegeven dat wordt gebruikt als het visuele object voor de toestand Omlaag van de knop, de toestand van de knop wanneer de gebruiker het object hitTestState selecteert.

Verwante API-elementen

Een Booleaanse waarde waarmee wordt opgegeven of een knop is ingeschakeld. Wanneer een knop is uitgeschakeld (de eigenschap enabled is ingesteld op false), is de knop zichtbaar maar kan er niet op worden geklikt. De standaardwaarde is true. Deze eigenschap is handig wanneer u een deel van de navigatie wilt uitschakelen. U kunt bijvoorbeeld een knop op de weergegeven pagina uitschakelen zodat er niet op kan worden geklikt en de pagina niet opnieuw kan worden geladen.

Opmerking: als u klikken met de muis op een knop wilt voorkomen, stelt u zowel de eigenschap enabled als de eigenschap mouseEnabled in op false.

Hiermee wordt een weergaveobject opgegeven dat wordt gebruikt als het testobject voor raakdetectie van de knop. Stel voor een basisknop de eigenschap hitTestState in op hetzelfde weergaveobject als de eigenschap overState. Als u de eigenschap hitTestState niet instelt, is de SimpleButton inactief; deze reageert niet op gebruikersinvoergebeurtenissen.

Verwante API-elementen

Geeft een weergaveobject op dat wordt gebruikt als het visuele object voor de toestand Boven van de knop, de toestand van de knop wanneer de cursor zich boven de knop bevindt.

Verwante API-elementen

Het object SoundTransform dat is toegewezen aan deze knop. Het object SoundTransform bevat eigenschappen waarmee het volume, panning en de toewijzing van de linker- en rechterluidspreker worden ingesteld. Dit object SoundTransform is van toepassing op alle toestanden van de knop. Dit object SoundTransform heeft alleen effect op ingesloten geluiden.

Verwante API-elementen

Hiermee wordt aangegeven of andere weergaveobjecten die objecten SimpleButton of MovieClip zijn, releasegebeurtenissen van gebruikersinvoer kunnen ontvangen. Met de eigenschap trackAsMenu kunt u menu's maken. U kunt de eigenschap trackAsMenu voor elk object SimpleButton of MovieClip instellen. Wanneer de eigenschap trackAsMenu niet bestaat, is het standaardgedrag false.

U kunt de eigenschap trackAsMenu altijd wijzigen; de aangepaste knop neemt meteen het nieuwe gedrag aan.

Geeft een weergaveobject op dat wordt gebruikt als het visuele object voor de toestand Omhoog van de knop, de toestand van de knop wanneer de cursor zich niet boven de knop bevindt.

Verwante API-elementen

Een Booleaanse waarde die, wanneer ingesteld op true, aangeeft of de handje-cursor wordt weergegeven wanneer de cursor over een knop beweegt. Als deze eigenschap op false is ingesteld, wordt in plaats daarvan de pijlaanwijzer weergegeven. De standaardwaarde is true.

U kunt de eigenschap useHandCursor altijd wijzigen; de aangepaste knop gebruikt direct het nieuwe cursorgedrag.

Hiermee wordt een nieuwe instantie SimpleButton gemaakt. U kunt een of alle weergaveobjecten die verschillende knoptoestanden vertegenwoordigen, in de constructor instellen als parameter.

1. In de constructor SimpleButtonExample() wordt een nieuw object CustomSimpleButton van het type SimpleButton gemaakt met de naam button, wat de constructormethode CustomSimpleButton aanroept. Het object button wordt aan het weergaveoverzicht toegevoegd. De kleur en de grootte van de knop worden in de volgende stappen bepaald.
2. In de klasse CustomSimpleButton worden instantie-eigenschappen gedeclareerd die later worden gebruikt om de grootte en de achtergrondkleur van button te beheren, op basis van de knoptoestand (oranje in de normale toestand, donkergeel in de toestand Boven, en lichtblauw in de toestand Omlaag). In alle toestanden van button is de grootte van het vierkant ingesteld op 80 pixels met de eigenschap size.
3. De constructorfunctie voor de klasse CustomSimpleButton stelt de eigenschappen downState, overState, upState, hitTestState en useHandCursor in met vier instanties van de klasse ButtonDisplayState.
4. In de klasse ButtonDisplayState stelt de constructor de waarde van de grootte en de achtergrondkleur van het vierkant in en roept de methode draw() aan.
5. De methode draw() tekent het vierkant opnieuw met de grootte en de achtergrondkleur die is ingesteld in de constructor op basis van de knoptoestand.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}