SoundTransform

Pakket	flash.media
Klasse	public final class SoundTransform
Overerving	SoundTransform Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

De klasse SoundTransform bevat eigenschappen voor volume en pannen.

Bekijk de voorbeelden

Verwante API-elementen

flash.display.SimpleButton.soundTransform
flash.display.Sprite.soundTransform
flash.media.Microphone.soundTransform
flash.media.SoundChannel.soundTransform
flash.media.SoundMixer.soundTransform
flash.net.NetStream.soundTransform

Openbare eigenschappen

Overerfde openbare eigenschappen verbergen

Overerfde openbare eigenschappen weergeven

	Eigenschap		Gedefinieerd door
		constructor : Object Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie.	Object
		leftToLeft : Number Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de linkerinvoer via de linkerluidspreker moet worden afgespeeld.	SoundTransform
		leftToRight : Number Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de linkerinvoer via de rechterluidspreker moet worden afgespeeld.	SoundTransform
		pan : Number Het pannen van geluid van links naar rechts, van -1 (volledig naar links) tot en met 1 (volledig naar rechts).	SoundTransform
		rightToLeft : Number Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de rechterinvoer via de linkerluidspreker moet worden afgespeeld.	SoundTransform
		rightToRight : Number Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de rechterinvoer via de rechterluidspreker moet worden afgespeeld.	SoundTransform
		volume : Number Het volume, van 0 (stil) tot en met 1 (hoogste volume).	SoundTransform

Openbare methoden

Overerfde openbare methoden verbergen

Overerfde openbare methoden weergeven

	Methode		Gedefinieerd door
		SoundTransform(vol:Number = 1, panning:Number = 0) Maakt een object SoundTransform.	SoundTransform
		hasOwnProperty(name:String):Boolean Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd.	Object
		isPrototypeOf(theClass:Object):Boolean Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven.	Object
		propertyIsEnumerable(name:String):Boolean Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in.	Object
		toLocaleString():String Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.	Object
		toString():String Retourneert een tekenreeksrepresentatie van het opgegeven object.	Object
		valueOf():Object Retourneert de primitieve waarde van het opgegeven object.	Object

Eigenschapdetails

leftToLeft

eigenschap

leftToLeft:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de linkerinvoer via de linkerluidspreker moet worden afgespeeld.

Implementatie
public function get leftToLeft():Number
public function set leftToLeft(value:Number):void

leftToRight

eigenschap

leftToRight:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de linkerinvoer via de rechterluidspreker moet worden afgespeeld.

Implementatie
public function get leftToRight():Number
public function set leftToRight(value:Number):void

pan

eigenschap

pan:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Het pannen van geluid van links naar rechts, van -1 (volledig naar links) tot en met 1 (volledig naar rechts). De waarde 0 staat voor geen panning (in het midden tussen links en rechts).

Implementatie
public function get pan():Number
public function set pan(value:Number):void

rightToLeft

eigenschap

rightToLeft:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de rechterinvoer via de linkerluidspreker moet worden afgespeeld.

Implementatie
public function get rightToLeft():Number
public function set rightToLeft(value:Number):void

rightToRight

eigenschap

rightToRight:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Een waarde, van 0 (niets) tot en met 1 (alles), die aangeeft hoeveel van de rechterinvoer via de rechterluidspreker moet worden afgespeeld.

Implementatie
public function get rightToRight():Number
public function set rightToRight(value:Number):void

volume

eigenschap

volume:Number

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Het volume, van 0 (stil) tot en met 1 (hoogste volume).

Implementatie
public function get volume():Number
public function set volume(value:Number):void

Constructordetails

()

Constructor

public function SoundTransform(vol:Number = 1, panning:Number = 0)

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Maakt een object SoundTransform.

Parameters

	`vol:Number` (default = `1`) — Het volume, van 0 (stil) tot en met 1 (hoogste volume).

	`panning:Number` (default = `0`) — Het pannen van geluid van links naar rechts, van -1 (volledig naar links) tot en met 1 (volledig naar rechts). De waarde 0 staat voor geen panning (midden).

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld wordt het geluid alleen afgespeeld via het rechterkanaal en is het volume ingesteld op 50 procent.

Het geluid wordt in de constructor geladen en toegewezen aan een geluidskanaal (channel). Er wordt ook een SoundTransform-object (transform) gemaakt. Het eerste argument stelt het volume in op 50 procent (het bereik is 0,0 tot en met 1,0). Het tweede argument stelt het pannen in. In dit voorbeeld is pannen ingesteld op 1,0. Dat wil zeggen dat het geluid alleen uit de rechterluidspreker komt. Deze instellingen zijn pas van kracht wanneer het SoundTransform-object transform wordt toegewezen aan de eigenschap soundTransform van het geluidskanaal.

Opmerking: Er is nog weinig foutafhandeling voor dit voorbeeld gedefinieerd.

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundTransform;
    import flash.events.IOErrorEvent;

    public class SoundTransform_constructorExample extends Sprite
    {
        public function SoundTransform_constructorExample() {
            var mySound:Sound = new Sound();
            var url:URLRequest = new URLRequest("mySound.mp3");
            var channel:SoundChannel;
            var transform:SoundTransform = new SoundTransform(0.5, 1.0);

            mySound.load(url);    
            channel = mySound.play();
            channel.soundTransform = transform;

            mySound.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
        }

        private function errorHandler(errorEvent:IOErrorEvent):void {
            trace("The sound could not be loaded: " + errorEvent.text);
        }
    }
}

Voorbeelden Hoe dit voorbeeld te gebruiken

SoundTransformExample.as

In het volgende voorbeeld wordt een MP3-bestanden geladen en afgespeeld. Als u de muis of een ander invoerapparaat over het werkgebied verplaatst wanneer het MP3-bestand wordt afgespeeld, veranderen de instellingen voor volume en pannen. Wanneer u dit voorbeeld wilt uitvoeren, plaatst u een bestand genaamd MySound.mp3 in dezelfde map als het SWF-bestand.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundTransform;
    import flash.net.URLRequest;
    import flash.utils.Timer;

    public class SoundTransformExample extends Sprite {
        private var url:String = "MySound.mp3";
        private var soundFactory:Sound;
        private var channel:SoundChannel;
        private var positionTimer:Timer;

        public function SoundTransformExample() {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            var request:URLRequest = new URLRequest(url);
            soundFactory = new Sound();
            soundFactory.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            soundFactory.load(request);
            channel = soundFactory.play();
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function ioErrorHandler(event:Event):void {
            trace("ioErrorHandler: " + event);
        }

        private function setPan(pan:Number):void {
            trace("setPan: " + pan.toFixed(2));
            var transform:SoundTransform = channel.soundTransform;
            transform.pan = pan;
            channel.soundTransform = transform;
        }

        private function setVolume(volume:Number):void {
            trace("setVolume: " + volume.toFixed(2));
            var transform:SoundTransform = channel.soundTransform;
            transform.volume = volume;
            channel.soundTransform = transform;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            var halfStage:uint = Math.floor(stage.stageWidth / 2);
            var xPos:uint = event.stageX;
            var yPos:uint = event.stageY;
            var value:Number;
            var pan:Number;

            if (xPos > halfStage) {
                value = xPos / halfStage;
                pan = value - 1;
            } else if (xPos < halfStage) {
                value = (xPos - halfStage) / halfStage;
                pan = value;
            } else {
                pan = 0;
            }

            var volume:Number = 1 - (yPos / stage.stageHeight);

            setVolume(volume);
            setPan(pan);
            
        }
    }
}

Juridische kennisgeving | Online privacybeleid

SoundTransform - AS3

Pakkettenx

Taalelementen

Bijlagen

Pakket flash.media

leftToLeft

leftToRight

pan

rightToLeft

rightToRight

volume

SoundTransform