SoundMixer  - AS3

Geeft de audioweergavemodus aan van alle Sound-objecten. Op mobiele apparaten worden hiermee prioriteiten op het gebied van geluid en standaardinstellingen ingesteld aan de hand van de taal van de platformen. In desktop- en tv-omgevingen bestaat er geen functioneel verschil tussen de verschillende modi voor het afspelen van audio.

De geldige waarden voor deze eigenschap zijn gedefinieerd in de AudioPlaybackMode-klasse.

Opmerking: als op iOS één toepassing is ingesteld op audioPlaybackMode=AudioPlaybackMode.VOICE, kunnen andere toepassingen deze niet wijzigen in AudioPlaybackMode.MEDIA.

Maak minimaal gebruik van de modus AudioPlaybackMode.VOICE en schakel zo snel mogelijk terug naar de modus AudioPlaybackMode.MEDIA nadat de voice-aanroep is beëindigd. Op deze manier kunnen ook andere toepassingen worden afgespeeld in de media-modus.

Wanneer u de audioweergavemodus op iOS wijzigt, worden native apps die muziek afspelen, kort gepauzeerd.

De standaardwaarde is AudioPlaybackMode.MEDIA.

Verwante API-elementen

Het aantal seconden dat nodig is voor het in een buffer voorladen van een ingesloten streaming geluid voordat het geluid begint met streamen. De gegevens in een geladen geluid, inclusief de buffertijd, zijn niet toegankelijk voor een SWF-bestand in een ander domein, tenzij u een bestand met interdomeinbeleid implementeert. Zie de beschrijving van de klasse Sound voor meer informatie over beveiliging en geluid. De gegevens in een geladen geluid, inclusief de buffertijd, zijn niet toegankelijk voor code in een bestand dat zich in een ander domein bevindt, tenzij u een bestand met interdomeinbeleid implementeert. In de toepassingssandbox in een AIR-toepassing heeft de code echter toegang tot de gegevens in geluidsbestanden uit om het even welke bron. Zie de beschrijving van de klasse Sound voor meer informatie over beveiliging en geluid.

De eigenschap SoundMixer.bufferTime beïnvloedt alleen de buffertijd voor ingesloten streaming geluiden in een SWF-bestand en staat los van dynamisch gemaakte objecten Sound (dat wil zeggen, objecten Sound die zijn gemaakt in ActionScript). De waarde van SoundMixer.bufferTime kan de buffertijd die is opgegeven in het object SoundLoaderContext dat is doorgegeven aan de methode Sound.load() niet overschrijven of de standaardwaarde ervan instellen.

Verwante API-elementen

Het object SoundTransform waarmee algemene geluidseigenschappen worden beheerd. Het object SoundTransform bevat eigenschappen waarmee het volume, panning en de toewijzing van de linker- en rechterluidspreker worden ingesteld. Het object SoundTransform dat in deze eigenschap wordt gebruikt, biedt de uiteindelijke geluidsinstellingen die worden toegepast op alle geluiden nadat eventuele afzonderlijke geluidsinstellingen zijn toegepast.

Verwante API-elementen

Schakelt de speakerphone in en uit wanneer de spraakmodus van het apparaat is geactiveerd. Standaard gebruiken smartphones de oortelefoon voor audio-uitvoer wanneer SoundMixer.audioPlaybackMode is ingesteld op AudioPlaybackMode.VOICE. Met de eigenschap useSpeakerphoneForVoice kunt u de standaarduitvoer overschrijven, zodat u een speakerphoneknop kunt implementeren in een telefoontoepassing. Deze eigenschap heeft alleen effect in de modus AudioPlaybackMode.VOICE. In desktop- en tv-omgevingen heeft deze eigenschap geen effect.

Opmerking: als op iOS uw toepassing is ingesteld op audioPlaybackMode=VOICE en een andere toepassing ook wordt afgespeeld in de voice-modus, kunt u useSpeakerphoneForVoice=true niet instellen.

Opmerking: op Android dient u android.permission.MODIFY_AUDIO_SETTINGS in te stellen in het descriptorbestand van de AIR-toepassing, anders heeft het wijzigen van deze waarde geen effect. Dit is bovendien een globale instelling voor het apparaat. Andere toepassingen die op het apparaat worden uitgevoerd, kunnen de onderliggende apparaatinstelling op elk gewenst moment wijzigen.

De standaardwaarde is false.

Verwante API-elementen

Bepaalt of geluiden niet toegankelijk zijn vanwege beveiligingsbeperkingen. Een geluid dat wordt geladen van een ander domein dan dat van de inhoud die deze methode aanroept, is bijvoorbeeld niet toegankelijk wanneer de server met het geluid geen URL-beleidsbestand bevat dat toegang verleent aan het domein van dat domein. Het geluid kan wel worden geladen en afgespeeld, maar bewerkingen op laag niveau, zoals ID3-metagegevens voor het geluid opvragen, kunnen niet worden uitgevoerd voor niet-toegankelijke geluiden.

Voor AIR-toepassingsinhoud in de beveiligingssandbox van de toepassing retourneert deze methode altijd false. Alle geluiden, inclusief de geluiden die uit andere domeinen werden geladen, zijn toegankelijk voor inhoud in de beveiligingssandbox van de toepassing.

Verwante API-elementen

Maakt een momentopname van de huidige geluidsgolf en plaatst deze in het opgegeven object ByteArray. De waarden worden opgemaakt als genormaliseerde waarden met drijvende komma in het bereik -1,0 tot en met 1,0. Het object ByteArray dat aan de parameter outputArray is doorgegeven, wordt door de nieuwe waarden overschreven. De grootte van het gemaakte object ByteArray is vastgesteld op 512 waarden met drijvende komma, waarbij de eerste 256 waarden het linkerkanaal vertegenwoordigen en de tweede 256 waarden het rechterkanaal.

Opmerking: deze methode is onderworpen aan lokale beperkingen voor bestandsbeveiliging en aan beperkingen voor laden tussen domeinen. Wanneer u werkt met lokale bestanden of geluiden die worden geladen van een server in een ander domein dan de aanroepende inhoud, moet u sandboxbeperkingen mogelijk afhandelen via een bestand voor interdomeinbeleid. Zie de beschrijving van de klasse Sound voor meer informatie. Daarnaast kan deze methode niet worden gebruikt om gegevens te extraheren uit RTMP-streams, zelfs wanneer de methode wordt aangeroepen door inhoud in hetzelfde domein als de RTMP-server.

Deze methode wordt ondersteund via RTMP in Flash Player 9.0.115.0 en hoger en in Adobe AIR. U kunt toegang tot streams op Flash Media Server beheren in een serverscript. Raadpleeg de eigenschappen Client.audioSampleAccess en Client.videoSampleAccess in de Server-Side ActionScript Language Reference for Adobe Flash Media Server voor meer informatie.

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Stopt alle geluiden die momenteel worden afgespeeld.

>In Flash Professional stopt deze methode de afspeelkop niet. Het afspelen van geluiden die voor streaming zijn ingesteld, wordt hervat terwijl de afspeelkop wordt bewogen over de frames waarin de geluiden zich bevinden.

Houd rekening met het volgende beveiligingsmodel wanneer u deze eigenschap gebruikt:

• Door het aanroepen van de methode soundMixer.stopAll() worden standaard alleen geluiden gestopt in dezelfde beveiligingssandbox als het object dat de methode aanroept. Geluiden waarvan het afspelen niet is gestart vanuit dezelfde sandbox als het aanroepende object, worden niet gestopt.
• Wanneer u het geluid laadt met de methode load() van de klasse Sound, kunt u een parameter context opgeven (een object SoundLoaderContext). Flash Player of Adobe AIR controleert of er een bestand met interdomeinbeleid aanwezig is op de server waarvan het geluid wordt geladen als u de eigenschap checkPolicyFile van het object SoundLoaderContext instelt op true. Wanneer de server een bestand met interdomeinbeleid bevat en het bestand het domein van de aanroepende inhoud toestaat, kan het bestand het geladen geluid stoppen met de methode SoundMixer.stopAll(); anders is dit niet mogelijk.

In Adobe AIR is de inhoud in de application -beveiligingssandbox (inhoud die met de AIR-toepassing is geïnstalleerd), echter niet beperkt tot deze beveiligingsbeperkingen.

Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}