Sound  - AS3

Retourneert het momenteel beschikbare aantal bytes in dit object Sound. Deze eigenschap is meestal alleen nuttig voor extern geladen bestanden.

Retourneert het totale aantal bytes in dit object Sound.

Biedt toegang tot de metagegevens die onderdeel zijn van een MP3-bestand.

MP3-geluidsbestanden kunnen ID3-tags bevatten die metagegevens over het bestand bieden. Wanneer een MP3-bestand dat u met de methode Sound.load() laadt ID3-tags bevat, kunt u deze eigenschappen controleren. Alleen ID3-tags die de tekenset UTF-8 gebruiken, worden ondersteund.

Flash Player 9 en later en AIR ondersteunen ID3 2.0-tags, met name 2.3 en 2.4. In de volgende tabellen vindt u de standaardtags van ID3 2.0 en het type inhoud dat de tags vertegenwoordigen. De eigenschap Sound.id3 biedt toegang tot deze tags via my_sound.id3.COMM, my_sound.id3.TIME, enzovoort. In de eerste tabel worden de tags beschreven die toegankelijk zijn via de naam van de ID3 2.0-eigenschap of de ActionScript-eigenschap. In de tweede tabel worden ID3-tags beschreven die worden ondersteund, maar waarvoor geen eigenschappen zijn gedefinieerd in ActionScript.

In de volgende tabel worden ID3-tags beschreven die worden ondersteund, maar waarvoor geen eigenschappen zijn gedefinieerd in de klasse Sound. U hebt toegang tot deze tags door het aanroepen van mySound.id3.TFLT, mySound.id3.TIME, enzovoort. Opmerking: geen van deze labels wordt in Flash Lite 4 ondersteund.

Houd rekening met het beveiligingsmodel van Flash Player wanneer u deze eigenschap gebruikt:

• De eigenschap id3 van een object Sound is altijd toegestaan voor SWF-bestanden in dezelfde beveiligingssandbox als het geluidsbestand. Voor bestanden in andere sandboxen zijn beveiligingscontroles beschikbaar.
• Wanneer u het geluid laadt met de methode load() van de klasse Sound, kunt u een parameter context opgeven (een object SoundLoaderContext). Als u de eigenschap checkPolicyFile van het object SoundLoaderContext instelt op true, controleert Flash Player of er een bestand met URL-beleid aanwezig is op de server waarvan het geluid wordt geladen. Als een beleidsbestand bestaat dat toegang van het domein met het ladende SWF-bestand toestaat, krijgt het bestand toegang tot de eigenschap id3 van het object Sound; anders wordt de toegang geweigerd.

In Adobe AIR is de inhoud in de application -beveiligingssandbox (inhoud die met de AIR-toepassing is geïnstalleerd), echter niet beperkt tot deze beveiligingsbeperkingen.

Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.net.URLRequest;
    import flash.media.ID3Info;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;

    public class Sound_id3Example extends Sprite {
        private var snd:Sound = new Sound();       
        private var myTextField:TextField = new TextField();

        public function Sound_id3Example() {
            snd.addEventListener(Event.ID3, id3Handler);
            snd.load(new URLRequest("mySound.mp3"));
        }
    
        private function id3Handler(event:Event):void {
            var id3:ID3Info = snd.id3;

            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.border = true;

            myTextField.appendText("Received ID3 Info: \n");
              
            for (var propName:String in id3) {
                myTextField.appendText(propName + " = " + id3[propName] + "\n");
            }
 
            myTextField.appendText("\n" + "Artist: " + id3.artist + "\n");
            myTextField.appendText("Song name: " + id3.songName + "\n");
            myTextField.appendText("Album: " + id3.album + "\n\n"); 
 
            this.addChild(myTextField);
        }
    }
}

Retourneert de bufferstatus van externe MP3-bestanden. Wanneer de waarde true is, wordt het afspelen onderbroken terwijl het object wacht op meer gegevens.

Geeft aan of de eigenschap Sound.url is afgebroken. Als de waarde isURLInaccessible true is, is de waarde Sound.url alleen het domein van de laatste URL waaruit het geluid is geladen. Bijvoorbeeld: de eigenschap wordt afgebroken als het geluid wordt geladen vanuit http://www.adobe.com/assets/hello.mp3; de eigenschap Sound.url heeft de waarde http://www.adobe.com. De waarde isURLInaccessible is alleen true als aan alle volgende voorwaarden is voldaan:

• Er was sprake van een HTTP-omleiding bij het laden van het geluidsbestand.
• Het SWF-bestand dat Sound.load() aanroept, is afkomstig uit een ander domein dan de laatste URL van het geluidsbestand.
• Het SWF-bestand dat Sound.load() aanroept, heeft geen toestemming het geluidsbestand te openen. Toestemming het geluidsbestand te openen verleent u op dezelfde manier als toestemming voor de eigenschap Sound.id3: maak een beleidsbestand en gebruik de eigenschap SoundLoaderContext.checkPolicyFile.

Opmerking: de eigenschap isURLInaccessible is toegevoegd voor Flash Player 10.1 en AIR 2.0. Deze eigenschap is echter beschikbaar voor SWF-bestanden van alle versies als deze door de Flash-runtime wordt ondersteund. Bij het gebruik van bepaald ontwerpgereedschap in 'strikte modus' treedt dus een compilatiefout op. U kunt de fout omzeilen door de indirecte syntaxis mySound["isURLInaccessible"] te gebruiken of de strikte modus uit te schakelen. Als u Flash Professional CS5 of Flex SDK 4.1 gebruikt, kunt u deze API voor runtimes die zijn uitgebracht vóór Flash Player 10.1 en AIR 2, gebruiken en compileren.

Voor toepassingsinhoud in AIR is de waarde van deze eigenschap altijd false.

Verwante API-elementen

De lengte van het huidige geluid, in milliseconden

De URL vanwaar dit geluid werd geladen. Deze eigenschap is alleen van toepassing op objecten Sound die zijn geladen met de methode Sound.load(). Voor objecten Sound die zijn gekoppeld aan een geluidselement uit de bibliotheek van een SWF-bestand heeft de eigenschap url de waarde null.

Wanneer u Sound.load() voor het eerst aanroept, heeft de eigenschap url in eerste instantie de waarde null omdat de uiteindelijke URL nog niet bekend is. De eigenschap url heeft een andere waarde dan null zodra een gebeurtenis open vanuit het object Sound wordt verzonden.

De eigenschap url bevat de uiteindelijke, absolute URL waarvan het geluid is geladen. De waarde van url is doorgaans gelijk aan de waarde die aan de parameter stream vanSound.load() wordt doorgegeven. Als u echter een relatieve URL aan Sound.load() hebt doorgegeven, vertegenwoordigt de waarde van de eigenschap url de absolute URL. Wanneer het oorspronkelijke URL-aanvraag wordt omgeleid door een HTTP-server, weerspiegelt de waarde van de eigenschap url de uiteindelijke URL waarvan het geluidsbestand daadwerkelijk is gedownload. Deze manier om een absolute, uiteindelijke URL te melden komt overeen met de werking van LoaderInfo.url.

In sommige gevallen is de waarde van de eigenschap url afgebroken; zie de eigenschap isURLInaccessible voor meer informatie.

Verwante API-elementen

Maakt een nieuw object Sound. Wanneer u een geldig object URLRequest aan de constructor Sound doorgeeft, roept de constructor automatisch de functie load() aan voor het object Sound. Wanneer u geen geldig object URLRequest doorgeeft aan de constructor Sound, moet u de functieload() voor het object Sound zelf aanroepen, anders wordt de stream niet geladen.

Zodra load() voor een object Sound is aangeroepen, kunt u later geen ander geluidsbestand in dat object Sound laden. Wanneer u een ander geluidsbestand wilt laden, moet u een nieuw object Sound laden.

Sluit de stream, waardoor het downloaden van gegevens wordt gestopt. Er kunnen geen gegevens uit de stream worden gelezen nadat de methode close() is aangeroepen.

 
package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;    
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;

    public class Sound_closeExample extends Sprite {
        private var snd:Sound = new Sound();
        private var button:TextField = new TextField();
        private var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
        
        public function Sound_closeExample() {
            button.x = 10;
            button.y = 10;
            button.text = "START";
            button.border = true;
            button.background = true;
            button.selectable = false;
            button.autoSize = TextFieldAutoSize.LEFT;

            button.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(button);
        }

        private function clickHandler(e:MouseEvent):void {

            if(button.text == "START") {

                snd.load(req);
                snd.play();        

                snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);

                button.text = "STOP";
            }
            else if(button.text == "STOP") {
                    
                try {
                    snd.close();
                    button.text = "Wait for loaded stream to finish.";
                }
                catch (error:IOError) {
                    button.text = "Couldn't close stream " + error.message;    
                }
            }
        }
        
        private function errorHandler(event:IOErrorEvent):void {
                button.text = "Couldn't load the file " + event.text;
        }
    }
}

Haal onbewerkte geluidsgegevens op uit een Sound-object.

Deze methode is bedoeld voor als u werkt met dynamisch gegenereerde audio, met een functie die u toewijst aan de gebeurtenis sampleData voor een ander Sound-object. U kunt deze methode dus gebruiken om geluidsgegevens te extraheren uit een Sound-object. Vervolgens kunt u de gegevens wegschrijven naar de bytearray die door een ander Sound-object wordt gebruikt om dynamische audio te streamen.

De geluidsgegevens worden in de doelbytearray geplaatst, vanaf de huidige positie van de bytearray. De audiogegevens worden altijd weergegeven als 44100 Hz Stereo. Het voorbeeldtype is een 32-bits waarde met zwevende komma, die kan worden geconverteerd naar een getal met NByteArray.readFloat().

Parameters

Verwante API-elementen

var sourceSnd:Sound = new Sound();
var outputSnd:Sound = new Sound();
var urlReq:URLRequest = new URLRequest("test.mp3");

sourceSnd.load(urlReq);
sourceSnd.addEventListener(Event.COMPLETE, loaded);

function loaded(event:Event):void
{
    outputSnd.addEventListener(SampleDataEvent.SAMPLE_DATA, processSound);
    outputSnd.play();
}

function processSound(event:SampleDataEvent):void
{
    var bytes:ByteArray = new ByteArray();
    sourceSnd.extract(bytes, 4096);
    event.data.writeBytes(upOctave(bytes));
}

function upOctave(bytes:ByteArray):ByteArray
{
    var returnBytes:ByteArray = new ByteArray();
    bytes.position = 0;
    while(bytes.bytesAvailable > 0)
    {
        returnBytes.writeFloat(bytes.readFloat());
        returnBytes.writeFloat(bytes.readFloat());
        if (bytes.bytesAvailable > 0)
        {
            bytes.position += 8;
        }
    }
    return returnBytes;
}

Initieert het laden van een extern MP3-bestand via de opgegeven URL. Wanneer u een geldig object URLRequest aan de constructor Sound doorgeeft, roept de constructor Sound.load() aan. U hoeft Sound.load() alleen zelf aan te roepen wanneer u geen geldig object URLRequest aan de constructor Sound doorgeeft of wanneer u een waarde null doorgeeft.

Zodra load() voor een object Sound is aangeroepen, kunt u later geen ander geluidsbestand in dat object Sound laden. Wanneer u een ander geluidsbestand wilt laden, moet u een nieuw object Sound laden.

Houd rekening met het volgende beveiligingsmodel wanneer u deze methode gebruikt:

• Het aanroepen van Sound.load() is niet toegestaan wanneer het aanroepende bestand zich in de sandbox Lokaal-met-bestandssysteem bevindt en het geluid zich in een netwerksandbox bevindt.
• Toegang vanaf de sandbox Lokaal-vertrouwd of Lokaal-met-netwerk is alleen mogelijk met toestemming van een website via een bestand met URL-beleid.
• U kunt geen verbinding maken met algemeen gereserveerde poorten. Zie "Netwerk-API's beperken" in de Adobe ActionScript 3.0-ontwikkelaarsgids voor een volledige lijst van geblokkeerde poorten.
• U kunt voorkomen dat een SWF-bestand deze methode gebruikt door de parameter allowNetworking in te stellen van de tags object en embed op de HTML-pagina die de SWF-inhoud bevat.

Als u in Flash Player 10 en hoger een multipart-inhoudstype gebruikt (bijvoorbeeld 'multipart/form-data') dat een upload bevat (aangegeven met de parameter 'bestandsnaam' in een header 'content-disposition' binnen de POST-body), gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads:

• De POST-bewerking moet worden uitgevoerd in reactie op een door de gebruiker geïnitieerde actie, zoals het klikken met de muis of het indrukken van een toets.
• Als bij de POST-bewerking verschillende domeinen betrokken zijn (het doel van de POST-bewerking bevindt zich niet op dezelfde server als het SWF-bestand dat de POST-aanvraag verstuurt), moet de doelserver een URL-beleidsbestand leveren dat interdomeintoegang toestaat.

In het geval van een multipart-inhoudstype is het ook essentieel dat de syntaxis juist is (in overeenstemming met de norm RFC2046). Als de syntaxis ongeldig lijkt te zijn, gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads.

In Adobe AIR, wordt de inhoud in de beveiligingssandbox application (inhoud die met de AIR-toepassing is geïnstalleerd) niet door deze beveiligingsbeperkingen gelimiteerd.

Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

Parameters

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
    
    public class Sound_loadExample extends Sprite {
        private var snd:Sound = new Sound();
        private var statusTextField:TextField  = new TextField();

        public function Sound_loadExample(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;
            var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
            snd.load(req);
            
            snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
 
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                     
            this.addChild(statusTextField);
        }
    
        private function progressHandler(event:ProgressEvent):void {
            var loadTime:Number = event.bytesLoaded / event.bytesTotal;
            var LoadPercent:uint = Math.round(100 * loadTime);
              
            statusTextField.text = "Sound file's size in bytes: " + event.bytesTotal + "\n" 
                                 + "Bytes being loaded: " + event.bytesLoaded + "\n" 
                                 + "Percentage of sound file that is loaded " + LoadPercent + "%.\n";
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

laad MP3-geluidsgegevens van een ByteArray-object naar een Sound-object. De gegevens worden gelezen vanaf de huidige ByteArray-positie en bij voltooiing wordt de ByteArray-positie aan het einde van de opgegeven bytelengte verlaten. Als de MP3-geluidsgegevens ID3-gegevens bevatten, worden er ID3-gebeurtenissen verzonden tijdens deze functieaanroep. Deze functie heeft een uitzondering tot gevolg als het ByteArray-object niet voldoende gegevens bevat.

Parameters

Laad PCM 32-bits geluidsgegevens met zwevende-kommawaarde van een ByteArray-object in een Sound-object. De gegevens worden vanaf de huidige ByteArray-positie gelezen en de ByteArray-positie aan het einde van de opgegeven samplelengte, vermenigvuldigd met 1 kanaal of 2 kanalen als de stereomarkering is ingesteld, wordt bij voltooiing verlaten.

Vanaf Flash Player 11.8 kan slechts een beperkte hoeveelheid audiogegevens worden doorgegeven aan deze functie. Voor SWF-versies >= 21 genereert deze functie een uitzondering als de hoeveelheid audiogegevens die in deze functie wordt doorgegeven meer dan 1800 seconden is. Dat wil zeggen dat de samples/sampleRate kleiner dan of gelijk aan 1800 moet zijn. Voor SWF-versies < 21 treedt er een stille runtimefout op wanneer de hoeveelheid audiogegevens die wordt doorgegeven, meer is dan 12.000 seconden. Dit is alleen voor achterwaartse compatibiliteit.

Deze functie genereert een uitzondering als het ByteArray-object onvoldoende gegevens bevat.

Parameters

Genereert een nieuw object SoundChannel om het geluid af te spelen. Deze methode retourneert een object SoundChannel dat u gebruikt om het geluid te stoppen en het volume te controleren. (Wanneer u volume, pannen en balans wilt regelen, gebruikt u het object SoundTransform dat aan het geluidskanaal is toegewezen.)

Parameters

Verwante API-elementen

 
package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;
    import flash.media.Sound;;
    import flash.net.URLRequest;
    import flash.media.SoundChannel;
    import flash.events.ProgressEvent;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample1 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel = new SoundChannel();
        private var infoTextField:TextField = new TextField();
    
        public function Sound_playExample1() {

            var req:URLRequest = new URLRequest("MySound.mp3");
            
            infoTextField.autoSize = TextFieldAutoSize.LEFT;
            infoTextField.text = "Please wait for the file to be loaded.\n" 
                                + "Then select from the bar to decide where the file should start.";
            
            snd.load(req);               
            channel = snd.play();

            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(Event.COMPLETE, completeHandler);


            this.addChild(infoTextField);
        }

        private function completeHandler(event:Event):void {                
            infoTextField.text = "File is ready.";

            var bar:Sprite = new Sprite();

            bar.graphics.lineStyle(5, 0xFF0000);
            bar.graphics.moveTo(100, 100);
            bar.graphics.lineTo(200, 100);

            bar.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(bar);
        }
    
        private function clickHandler(event:MouseEvent):void {
            
                var position:uint = event.localX;
                var percent:uint = Math.round(position) - 100;   
                var cue:uint = (percent / 100) * snd.length;

                channel.stop();
                channel = snd.play(cue);    
        }

        private function errorHandler(errorEvent:IOErrorEvent):void {
            infoTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.media.Sound;
    import flash.net.URLRequest;

    public class Sound_playExample2 extends Sprite {
        private var button:Sprite = new Sprite(); 
        private var snd:Sound = new Sound();
            
        public function Sound_playExample2() {

            var req:URLRequest = new URLRequest("click.mp3");
            snd.load(req);               
     
            button.graphics.beginFill(0x00FF00);
            button.graphics.drawRect(10, 10, 50, 30);
            button.graphics.endFill();
     
            button.addEventListener(MouseEvent.CLICK, clickHandler);
            button.addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
     
            this.addChild(button);
        }

        private function clickHandler(event:MouseEvent):void {
            snd.play();            
        }

        private function doubleClickHandler(event:MouseEvent):void {
            snd.play(0, 2);        
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample3 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel;
        private var statusTextField:TextField  = new TextField();

        public function Sound_playExample3(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;

           var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
                snd.load(req);
            
                channel = snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
                    
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
                    
            this.addChild(statusTextField);
        }
    
        private function enterFrameHandler(event:Event):void {    
            var loadTime:Number = snd.bytesLoaded / snd.bytesTotal;
            var loadPercent:uint = Math.round(100 * loadTime);
            var estimatedLength:int = Math.ceil(snd.length / (loadTime));
            var playbackPercent:uint = Math.round(100 * (channel.position / estimatedLength));
      
            statusTextField.text = "Sound file's size is " + snd.bytesTotal + " bytes.\n" 
                                   + "Bytes being loaded: " + snd.bytesLoaded + "\n" 
                                   + "Percentage of sound file that is loaded " + loadPercent + "%.\n"
                                   + "Sound playback is " + playbackPercent + "% complete.";     
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }

        private function soundCompleteHandler(event:Event):void {
            statusTextField.text = "The sound has finished playing.";
            removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }
    }
}

Wordt verzonden nadat gegevens zijn geladen.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden door een object Sound wanneer ID3-gegevens beschikbaar zijn voor een MP3-geluid.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer een invoer-/uitvoerfout optreedt die ertoe leidt dat een laadbewerking mislukt.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer een laadbewerking begint.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer gegevens worden ontvangen tijdens een laadbewerking.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer het runtime-programma om nieuwe geluidsgegevens vraagt.

Deze gebeurtenis heeft de volgende eigenschappen:

var mySound:Sound = new Sound();
function sineWaveGenerator(event:SampleDataEvent):void {
    for ( var c:int=0; c<8192; c++ ) {
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
    }
}

mySound.addEventListener(SampleDataEvent.SAMPLE_DATA,sineWaveGenerator);
mySound.play();

Verwante API-elementen