URLRequest  - AS3

Bepaalt of verificatie-aanvragen voor deze aanvraag moeten worden afgehandeld (true) of niet (false). Als de waarde false is, wordt een HTTP-fout geretourneerd door een verificatieaanvraag.

De ondersteunde verificatiemethoden zijn:

• Windows—HTTP Basic/Digest, Geïntegreerde Windows-verificatie (inclusief NTLM en Kerberos), SSL Certificate Authentication.
• Mac—HTTP Basic/Digest, NTLM, SSL Certificate Authentication.

Opmerking:de methoden FileReference.upload(), FileReference.download() en HTMLLoader.load() bieden geen ondersteuning voor de eigenschap URLRequest.authenticate.

De standaardwaarde is true.

Verwante API-elementen

Bepaalt of geslaagde resultaatgegevens voor deze aanvraag in de cache moeten worden opgeslagen. Als de waarde true is, gebruikt de AIR-toepassing de HTTP-cache van het besturingssysteem.

Opmerking: de methode HTMLLoader.load() biedt geen ondersteuning voor de eigenschap URLRequest.cacheResponse.

De standaardwaarde is true.

Verwante API-elementen

Het inhoudstype MIME van de inhoud in de eigenschap data.

De standaardwaarde is application/x-www-form-urlencoded.

Opmerking: de methoden FileReference.upload(), FileReference.download() en HTMLLoader.load() bieden geen ondersteuning voor de eigenschap URLRequest.contentType.

Wanneer een POST-aanvraag wordt verzonden, moeten de waarden van de eigenschappen contentType en data corresponderen. De waarde van de eigenschap contentType vertelt servers hoe deze de waarde van de eigenschap data moeten interpreteren.

• Als de waarde van de eigenschap data een URLVariables-object is, moet de waarde van contentType application/x-www-form-urlencoded zijn.
• Als de waarde van de eigenschap data van een ander type is, moet de waarde van contentType het type aangeven van de POST-gegevens die worden verzonden (dus de binaire- of tekenreeksgegevens in de waarde van de eigenschap data).
• Voor FileReference.upload() wordt het inhoudstype van de aanvraag automatisch ingesteld op multipart/form-data en wordt de eigenschap contentType genegeerd.

Als u in Flash Player 10 en hoger een multipart-inhoudstype gebruikt (bijvoorbeeld 'multipart/form-data') dat een upload bevat (aangegeven met de parameter 'bestandsnaam' in een header 'content-disposition' binnen de POST-body), gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads:

• De POST-bewerking moet worden uitgevoerd in reactie op een door de gebruiker geïnitieerde actie, zoals het klikken met de muis of het indrukken van een toets.
• Als bij de POST-bewerking verschillende domeinen betrokken zijn (het doel van de POST-bewerking bevindt zich niet op dezelfde server als het SWF-bestand dat de POST-aanvraag verstuurt), moet de doelserver een URL-beleidsbestand leveren dat interdomeintoegang toestaat.

In het geval van een multipart-inhoudstype is het ook essentieel dat de syntaxis juist is (in overeenstemming met de norm RFC2046). Als de syntaxis ongeldig lijkt te zijn, gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads.

Verwante API-elementen

Een object dat gegevens bevat die met de URL-aanvraag moeten worden verzenden.

Deze eigenschap wordt gebruikt in combinatie met de eigenschap method. Wanneer de waarde van method GET is, wordt met de syntaxis van de HTTP-querytekenreeks de waarde van data toegevoegd aan de waarde van URLRequest.url. Wanneer de waarde method POST is (of een willekeurige andere waarde dan GET), wordt de waarde van data doorgegeven in de hoofdtekst van de HTTP-aanvraag.

De URLRequest API biedt ondersteuning voor binaire POST en voor URL gecodeerde variabelen, alsook voor tekenreeksen. Het gegevensobject kan ByteArray-, URLVariables- of String-object zijn.

De manier waarop de gegevens worden gebruikt, hangt af van het type object dat wordt gebruikt:

• Wanneer het object een object ByteArray is, worden de binaire gegevens van het object ByteArray gebruikt als POST-gegevens. Voor GET worden gegevens van het type ByteArray niet ondersteund. Ook worden gegevens van het type ByteArray niet ondersteund voor FileReference.upload() en FileReference.download().
• Wanneer het object een object URLVariables is en de methode is POST, worden de variabelen gecodeerd met de indeling x-www-form-urlencoded en wordt de resulterende tekenreeks gebruikt als POST-gegevens. Een uitzondering is een aanroep van FileReference.upload(), waarin de variabelen worden verzonden als afzonderlijke velden in een multipart/form-data-post.
• Wanneer het object een object URLVariables is en de methode is GET, definieert het object URLVariables variabelen die moeten worden verzonden met het object URLRequest.
• Anders wordt het object omgezet in een tekenreeks en wordt de tekenreeks gebruikt als de POST- of GET-gegevens.

Deze gegevens worden pas verzonden wanneer een methode, zoals navigateToURL() of FileReference.upload(), het object URLRequest gebruikt.

Opmerking: de waarde van contentType moet overeenkomen met het type van de gegevens in de eigenschap data. Zie de opmerking bij de beschrijving van de eigenschap contentType.

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Een tekenreeks die het getekende Adobe-platformonderdeel identificeert dat moet worden opgeslagen in (of moet worden opgehaald uit) de Flash Player-cache. Een component van het Adobe-platform is een ondertekend bestand (een SWZ-bestand) dat SWF-inhoud bevat die blijvend aanwezig is in de cache van de computer van een gebruiker. Alle SWZ-bestanden zijn ondertekend door Adobe. Een controlesamenvatting komt overeen met een enkel, in de cache opgeslagen bestand. Als u het bestand op welke wijze dan ook verandert, wordt de controlesamenvatting op onvoorspelbare wijze veranderd. Door een controlesamenvatting te gebruiken, kunt u het in de cache opgeslagen bestand binnen meerdere domeinen verifiëren. Twee bestanden met dezelfde controlesamenvatting zijn hetzelfde bestand, en twee bestanden met verschillende controlesamenvattingen , zijn niet hetzelfde bestand. Een bestand kan (praktisch gezien) worden gemaakt om een controlesamenvatting te vervalsen en zich voor te doen als een andere controlesamenvatting.

De controlesamenvatting is gebaseerd op een SHA-256-algoritme voor de controlesamenvatting van berichten (64 tekens lang in hexadecimale notatie).

De Flex SDK bevat bijvoorbeeld een SWZ-bestand voor het Flex-framework (evenals de digest-tekenreeks voor dat SWZ-bestand). U kunt SWZ-bestand posten op uw webserver en laden in uw SWF-bestand (met de methode load() van een URLLoader-object). Als het overeenkomende SWZ-bestand al aanwezig is in de cache van de computer van de eindgebruiker, gebruikt de toepassing dit SWZ-bestand. (Een SWZ-bestand komt overeen als de digest van het bestand identiek is met de digest van het SWF-bestand dat u opgeeft.) Als dit niet het geval is, downloadt de toepassing het SWZ-bestand van de opgegeven URL.

U hoeft de parameter digest alleen in te stellen in een URLRequest-object dat wordt gebruikt in een aanroep van de methode URLLoader.load() om een SWZ-bestand te laden. Als u de eigenschap digest van een URLRequest-object instelt voor gebruik met andere methoden, wordt er een IOError-uitzondering gegenereerd.

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

Bepaalt of omleidingen moeten worden gevolgd (true) of niet (false).

Opmerking:de methoden FileReference.upload(), FileReference.download() en HTMLLoader.load() bieden geen ondersteuning voor de eigenschap URLRequest.followRedirects.

De standaardwaarde is true.

Verwante API-elementen

Geeft de niet-actieve time-outwaarde aan (in milliseconden) voor deze aanvraag.

De niet-actieve time-out is de tijdsduur dat de client wacht op een antwoord van de server, nadat er verbinding is gemaakt, voordat de aanvraag wordt afgebroken.

Opmerking: de methode HTMLLoader.load() biedt geen ondersteuning voor de eigenschap URLRequest.idleTimeout De HTMLLoader-klasse bepaalt zelf zijn idleTimeout-eigenschap.

De standaardwaarde is initialized from the URLRequestDefaults.idleTimeout property.

Verwante API-elementen

Bepaalt of de HTTP-protocolstack cookies voor deze aanvraag moet beheren. Als de waarde true is, worden cookies toegevoegd aan de aanvraag en worden cookies in het antwoord onthouden. Als de waarde false is, worden geen cookies aan de aanvraag toegevoegd en worden antwoordcookies niet onthouden. Gebruikers kunnen cookies echter wel zelf beheren door de header rechtstreeks te manipuleren. Opmerking: Op Windows-systemen kunt u niet handmatig cookies toevoegen aan een URL-verzoek wanneer de waarde van manageCookies is ingesteld op true. Bij andere besturingssystemen kunt u wel cookies toevoegen aan een verzoek, onafhankelijk of de waarde van manageCookies is ingesteld optrue of false. Indien toegestaan, kunt u cookies handmatig aan een verzoek toevoegen door een URLRequestHeader-object met de gegevens van de cookie toe te voegen aan de array requestHeaders.

Op Mac OS worden cookies gedeeld met Safari. Ga als volgt te werk om cookies te wissen op Mac OS:

1. Open Safari.
2. Kies Safari > Preferences (Voorkeuren) en klik op het Security panel (deelvenster Beveiliging).
3. Klik op de knop Show Cookies (Cookies tonen).
4. Klik op de knop Remove All (Alles verwijderen).

Ga als volgt te werk om cookies te wissen op Windows:

1. Ga naar het Configuratiescherm, open Internet-opties en klik op het tabblad Algemeen.
2. Klik op de knop Cookies verwijderen.

De standaardwaarde is true.

Verwante API-elementen

Regelt de methode voor het verzenden van HTTP-formulieren.

Voor SWF-inhoud die wordt uitgevoerd in Flash Player (in de browser) geldt dat deze eigenschap beperkt is tot GET- of POST-bewerkingen. Geldige waarden zijn URLRequestMethod.GET of URLRequestMethod.POST.

Voor inhoud die in Adobe AIR wordt uitgevoerd, kunt u elke willekeurige stringwaarde gebruiken als de inhoud zich in de beveiligingssandbox van de toepassing bevindt. Anders kunt u alleen GET- of POST-bewerkingen gebruiken, net als bij inhoud die in Flash Player wordt uitgevoerd.

Wanneer voor inhoud die wordt uitgevoerd in Adobe AIR de functie navigateToURL() wordt gebruikt, behandelt de runtime een URLRequest dat de methode POST gebruikt (een methode waarvan de eigenschap method is ingesteld op URLRequestMethod.POST ), alsof de methode GET wordt gebruikt.

Opmerking: als inhoud wordt uitgevoerd in Flash Player en het gerefereerde formulier geen hoofdinhoud heeft, gebruikt Flash Player automatisch een GET-bewerking, zelfs als de methode is ingesteld op URLRequestMethod.POST. Daarom is het raadzaam om altijd een dummy hoofdtekst in te sluiten zodat altijd de juiste methode wordt gebruikt.

De standaardwaarde is URLRequestMethod.GET.

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

De array van HTTP-aanvraagheaders die aan de HTTP-aanvraag moet worden toegevoegd. De array bestaat uit objecten URLRequestHeader. Elk object in de array moet een object URLRequestHeader zijn dat de tekenreeksen naam en waarde bevat, als volgt:

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

Flash Player en de AIR-runtime leggen bepaalde beperkingen op ten aanzien van requestheaders. Raadpleeg de beschrijving van de klasse URLRequestHeader voor meer informatie.

Niet alle methoden die URLRequest-parameters accepteren ondersteunen de eigenschap requestHeaders. Raadpleeg de documentatie voor de methode die u wilt aanroepen. De methoden FileReference.upload() en FileReference.download() onderstenen de eigenschap URLRequest.requestHeaders bijvoorbeeld niet.

Vanwege beperkingen van de browser worden aangepaste HTTP-requestheaders alleen ondersteund voor POST-aanvragen, niet voor GET-aanvragen.

Verwante API-elementen

De URL die moet worden aangevraagd.

Zorg ervoor dat u eventuele tekens codeert die in de URL-specificatie (zie http://www.faqs.org/rfcs/rfc1738.html) worden beschreven als onveilig, of die in het URL-schema van het URLRequest-object zijn gereserveerd (als ze worden gebruikt voor een ander doel dan waarvoor ze zijn bedoeld). Gebruik bijvoorbeeld "%25" voor het procentteken (%) en "%23" voor het hekje (#), zoals in "http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25".

Standaard moet de URL zich in hetzelfde domein bevinden als het aanroepende bestand, tenzij de inhoud wordt uitgevoerd in de beveiligingssandbox van de toepassing Adobe AIR. Als u gegevens van een ander domein moet laden, plaatst u een bestand met URL-beleid op de server die als host voor de gegevens fungeert. Zie de beschrijving van de klasse URLRequest voor meer informatie.

Voor inhoud die in Adobe AIR wordt uitgevoerd, kunnen bestanden in de beveiligingssandbox van de toepassing (bestanden die met de toepassing AIR zijn geïnstalleerd) met een van de volgende URL-schema's toegang krijgen tot URL's:

• http en https
• file
• app-storage
• app

Opmerking: IPv6 (Internet Protocol versie 6) wordt ondersteund in AIR en in Flash Player 9.0.115.0 en hoger. IPv6 is een versie van Internet Protocol die 128-bits adressen ondersteunt (een verbetering ten opzichte van het eerdere IPv4-protocol dat alleen 32-bits adressen ondersteunt). Mogelijk moet u IPv6 activeren op uw netwerkinterfaces. Raadpleeg de Help van het besturingssysteem dat als host fungeert van de gegevens voor meer informatie. Wanneer IPv6 wordt ondersteund door het hostsysteem, kunt u numerieke letterlijke IPv6-adressen opgeven in URL's tussen haakjes ([]), bijvoorbeeld.

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

Bepaalt of de lokale cache moet worden geraadpleegd voordat deze URLRequest gegevens ophaalt.

Opmerking: de methode HTMLLoader.load() biedt geen ondersteuning voor de eigenschap URLRequest.useCache.

De standaardwaarde is true.

Verwante API-elementen

Bepaalt de userAgent-tekenreeks die inde HTTP-aanvraag moet worden gebruikt.

De standaardwaarde is dezelfde userAgent-tekenreeks die wordt gebruikt door Flash Player en deze is verschillend voor Macintosh, Linux en Windows.

Opmerking: Deze eigenschap heeft geen invloed op de userAgent-tekenreeks als het URLRequest-object wordt gebruikt met de methode load() van een HTMLLoader-object. Als u de userAgent-tekenreeks wilt instellen voor een HTMLLoader-object, stelt u de eigenschap userAgent van het HTMLLoader-object in of stelt u de statische eigenschap URLRequestDefaults.userAgent in.

Verwante API-elementen

Maakt een object URLRequest. Wanneer System.useCodePage true is, wordt de aanvraag gecodeerd met de systeemcodepagina en niet met Unicode. Wanneer System.useCodePage false is, wordt de aanvraag gecodeerd met Unicode en niet met de systeemcodepagina.

Verwante API-elementen

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

Hiermee wordt toegestaan dat een omgeleide URL van een bron-URLRequest wordt toegepast als vervanging voor een bepaald gedeelte van de URL in een nieuwe URLRequest. Nadat de oorspronkelijke aanvraag is omgeleid, kunnen nieuwe aanvragen rechtstreeks worden verzonden naar de omgeleide serverlocatie.

Nadat de oorspronkelijke URLRequest is voltooid en de waarde van HTTPStatusEvent.redirected is ingesteld op true, kan deze methode met de oorspronkelijke aanvraag worden aangeroepen als sourceRequest. Standaard wordt het domein van de omgeleide URL gebruikt in plaats van het domein in de URL van deze URLRequest. URLRequest.url moet worden ingesteld voordat u deze methode aanroept. De methode moet worden aangeroepen voordat deze URLRequest wordt geladen. Als de parameter wholeURL is ingesteld op true, kan de volledige URL (minus de bestandsnaam) van de bron-URLRequest desgewenst worden vervangen door de volledige URL (minus de uiteindelijke bestandsnaam) in deze URLRequest. De aanroepende functie kan eventueel ook een tekenreeks of een reguliere expressie aanleveren in de parameter pattern. Als dit patroon wordt gevonden, wordt het vervangen door de tekenreeks van de parameter replace. Deze zoek- en vervangactie wordt uitgevoerd nadat de URL is vervangen.

Parameters

Verwante API-elementen

Wanneer u dit voorbeeld wilt uitvoeren, plaatst u een bestand met de naam XMLFile.xml in dezelfde map als het SWF-bestand.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}