FileReference  - AS3

De aanmaakdatum van het bestand op de lokale schijf. Wanneer het object niet is gevuld, retourneert een aanroep om de waarde van deze eigenschap op te halen de waarde null.

Opmerking: Als een besturingssysteem geen creationDate heeft als eigenschap, is CreationDate in dergelijke gevallen gelijk aan lastModifiedDate.

Verwante API-elementen

Het Macintosh-makerstype van het bestand, dat alleen wordt gebruikt in Mac OS-versies ouder dan Mac OS X. In Windows of Linux is deze eigenschap null. Wanneer het object FileReference niet is gevuld, retourneert een aanroep om de waarde van deze eigenschap op te halen de waarde null.

Verwante API-elementen

Het object ByteArray bevat de gegevens van het geladen bestand na een geslaagde aanroep van de methode load().

Verwante API-elementen

De bestandsnaamextensie.

De bestandsextensie is het deel van de naam dat volgt op (niet inclusief) de laatste punt ('.'). Als de bestandsnaam geen punt bevat, is de extensie null.

Opmerking: Gebruik de eigenschap extension om het bestandstype te bepalen. Gebruik daarvoor niet de eigenschap creator of type. U mag de eigenschappen creator en type eigenlijk als verouderd beschouwen. Ze zijn van toepassing op oudere versies van Mac OS.

De datum waarop het bestand op de lokale schijf het laatst is gewijzigd. Wanneer het object FileReference niet is gevuld, retourneert een aanroep om de waarde van deze eigenschap op te halen de waarde null.

Verwante API-elementen

De naam van het bestand op de lokale schijf. Als het FileReference-object niet is gevuld (door een geldige aanroep naar FileReference.download() of FileReference.browse()), genereert Flash Player een fout wanneer u de waarde van deze eigenschap probeert te verkrijgen.

Alle eigenschappen van een object FileReference worden gevuld door de methode browse() aan te roepen. In tegenstelling tot andere FileReference-eigenschappen wordt bij het aanroepen van de methode download() de eigenschap name gevuld wanneer de gebeurtenis select wordt verzonden.

Verwante API-elementen

Hiermee bepaalt u of de toepassing al dan niet toegangsrecht heeft tot het bestandssysteem.

Verwante API-elementen

De grootte van het bestand op de lokale schijf in bytes.

Opmerking: In de eerste versie van ActionScript 3.0 was de eigenschap size gedefinieerd als een uint-object, dat bestandsgrootten ondersteunde tot circa 4 GB. Het is nu geïmplementeerd als een Number-object zodat grotere bestanden kunnen worden ondersteund.

Verwante API-elementen

Het bestandstype.

In Windows of Linux is deze eigenschap de bestandsextensie. Op de Macintosh is deze eigenschap het bestandstype van vier tekens, dat alleen wordt gebruikt in Mac OS-versies die ouder zijn dan Mac OS X. Wanneer het FileReference-object niet is gevuld, retourneert een aanroep om de waarde van deze eigenschap op te halen de waarde null.

Voor Windows, Linux en Mac OS X is het de bestandsextensie - het deel van de eigenschap name dat volgt na de laatste punt (.) - het bestandstype aan.

Verwante API-elementen

Maakt een nieuw object FileReference. Wanneer het object FileReference is gevuld, vertegenwoordigt het een bestand op de lokale schijf van de gebruiker.

Verwante API-elementen

Geeft een bladerdialoogvenster weer waarin de gebruiker een bestand kan selecteren om te uploaden. Het dialoogvenster behoort tot het besturingssysteem van de gebruiker. De gebruiker kan een bestand op de lokale computer selecteren, maar ook op andere systemen, bijvoorbeeld via een UNC-pad onder Windows.

Opmerking: de File-klasse van Adobe AIR bevat toegangsmethoden voor specifieke dialoogvensters voor de selectie van systeembestanden. Deze methoden zijn: File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() en File.browseForSave().

Wanneer u deze methode aanroept en de gebruiker een bestand selecteert, worden de eigenschappen van dit object FileReference met de eigenschappen van dat bestand gevuld. Telkens wanneer de methode FileReference.browse() wordt aangeroepen, worden de eigenschappen van het object FileReference teruggezet naar het bestand dat door de gebruiker in het dialoogvenster is geselecteerd. Er kan slechts een enkele sessie browse() ofdownload() tegelijk worden uitgevoerd (omdat slechts een enkel dialoogvenster tegelijk kan worden weergegeven).

Met de parameter typeFilter kunt u bepalen welke bestanden in het dialoogvenster worden weergegeven.

In Flash Player 10 en Flash Player 9 Update 5 kunt u deze methode alleen gebruiken in reactie op een gebruikersgebeurtenis (bijvoorbeeld in een gebeurtenishandler voor een muisklik of een toetsaanslag). Als u deze methode op een ander moment aanroept, wordt een uitzondering gegenereerd in Flash Player.

Als u publiceert naar Flash Player 10, kan er altijd maar één van de volgende bewerkingen actief zijn omdat er nieuwe functionaliteit is toegevoegd aan Flash Player: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Als niet aan deze voorwaarde wordt voldaan, genereert Flash Player een runtime-fout (code 2174). Gebruik FileReference.cancel() om een actieve bewerking te stoppen. Deze beperking geldt alleen voor Flash Player 10. Deze beperking ten aanzien van gelijktijdige beperkingen geldt dus niet voor eerdere versies van Flash Player.

Het Adobe AIR-dialoogvenster waarin u kunt bladeren door bestanden wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Parameters

Verwante API-elementen

Annuleert een actieve upload of download op dit object FileReference. Met het aanroepen van deze methode wordt niet de gebeurtenis cancel verzonden. Dat gebeurt alleen wanneer de gebruiker de bewerking annuleert door het dialoogvenster voor uploaden of downloaden te sluiten.

Opent een dialoogvenster waarin de gebruiker een bestand van een externe server kan downloaden. Hoewel voor Flash Player geen beperkingen gelden op de grootte van bestanden die u kunt uploaden en downloaden, biedt de speler officieel ondersteuning voor het uploaden of downloaden van maximaal 100 MB.

Met de methode download() wordt eerst een dialoogvenster van het besturingssysteem geopend, waarin de gebruiker wordt gevraagd een bestandsnaam in te voeren en een locatie op de lokale computer te selecteren om het bestand op te slaan. Wanneer de gebruiker een locatie selecteert en het downloaden bevestigt (door bijvoorbeeld op Opslaan te klikken), begint het downloaden vanaf de externe server. Listeners ontvangen gebeurtenissen die de voortgang, het voltooien of mislukken van het downloaden aangeven. Wanneer u de status van het dialoogvenster en het downloaden wilt controleren na het aanroepen van download(), moet de code luisteren naar gebeurtenissen zoals cancel, open, progress en complete.

De functies FileReference.upload() en FileReference.download() zijn niet-blokkerend. Deze functies worden geretourneerd nadat ze zijn aangeroepen, voordat de bestandsoverdracht is voltooid. Wanneer het object FileReference buiten bereik treedt, wordt bovendien elke upload of download die voor dat object nog niet is voltooid, geannuleerd. Zorg ervoor dat het object FileReference binnen bereik blijft gedurende de tijd dat het uploaden of downloaden zal duren.

Wanneer het bestand is gedownload, worden de eigenschappen van het object FileReference gevuld met de eigenschappen van het lokale bestand. De gebeurtenis complete wordt verzonden wanneer het downloaden is gelukt.

Er kan slechts een enkele sessie browse() ofdownload() tegelijk worden uitgevoerd (omdat slechts een enkel dialoogvenster tegelijk kan worden weergegeven).

Deze methode ondersteunt het downloaden van elk bestandstype met HTTP of HTTPS.

U kunt geen verbinding maken met algemeen gereserveerde poorten. Zie "Netwerk-API's beperken" in de Adobe ActionScript 3.0-ontwikkelaarsgids voor een volledige lijst van geblokkeerde poorten.

Opmerking: wanneer uw server verificatie vereist, kunnen alleen SWF-bestanden die in een browser worden uitgevoerd, met andere woorden, die de browserinsteekmodule of ActiveX-besturingselement gebruiken, een dialoogvenster weergeven waarin de gebruiker wordt gevraagd een gebruikersnaam en wachtwoord ter verificatie op te geven (alleen voor downloads). Uploaden met behulp van de insteekmodule of het ActiveX-besturingselement, of uploaden en downloaden met een zelfstandige of externe speler, mislukt.

Houd bij gebruik van deze methode rekening met het beveiligingsmodel van Flash Player:

• Laden is niet toegestaan wanneer het aanroepende SWF-bestand zich in een niet-vertrouwde lokale sandbox bevindt.
• Standaard wordt toegang tussen sandboxen geweigerd. Websites kunnen toegang tot een bron toestaan door een bestand met URL-beleid toe te voegen.
• U kunt voorkomen dat een SWF-bestand deze methode gebruikt door de parameter allowNetworking in te stellen van de tags object en embed op de HTML-pagina die de SWF-inhoud bevat.
• In Flash Player 10 en Flash Player 9 Update 5 kunt u deze methode alleen gebruiken in reactie op een gebruikersgebeurtenis (bijvoorbeeld in een gebeurtenishandler voor een muisklik of een toetsaanslag). Als u deze methode op een ander moment aanroept, wordt een uitzondering gegenereerd in Flash Player.

In Adobe AIR is de inhoud in de beveiligingssandbox van de toepassing (inhoud die met de AIR-toepassing is geïnstalleerd) echter niet beperkt tot deze beveiligingsbeperkingen.

Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

Wanneer u een bestand downloadt met deze methode, wordt het bestand gemarkeerd als gedownload op besturingssystemen met een dergelijke markeringsfunctie:

• Windows XP service pack 2 en later en op Windows Vista
• Mac OS 10.5 en later

Op sommige besturingssystemen, zoals Linux, worden gedownloade bestanden niet gemarkeerd.

Als u publiceert naar Flash Player 10, kan er altijd maar één van de volgende bewerkingen actief zijn omdat er nieuwe functionaliteit is toegevoegd aan Flash Player: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Als niet aan deze voorwaarde wordt voldaan, genereert Flash Player een runtime-fout (code 2174). Gebruik FileReference.cancel() om een actieve bewerking te stoppen. Deze beperking geldt alleen voor Flash Player 10. Deze beperking ten aanzien van gelijktijdige beperkingen geldt dus niet voor eerdere versies van Flash Player.

Het Adobe AIR-dialoogvenster waarin u bestanden kunt downloaden wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Start het laden van een lokaal bestand dat door een gebruiker is geselecteerd. Hoewel voor Flash Player geen beperkingen gelden op de grootte van bestanden die u kunt uploaden, downloaden, laden of opslaan, biedt de speler officieel ondersteuning voor bestanden van maximaal 100 MB. Voor inhoud die in Flash Player wordt uitgevoerd, moet u de methode FileReference.browse() of FileReferenceList.browse() aanroepen voordat u de methode load() aanroept. Inhoud die in AIR wordt uitgevoerd in de toepassingssandbox, kan echter de methode load() van een object File aanroepen zonder eerste de methode browse() aan te roepen. (De klasse File van AIR is een uitbreiding van de klasse FileReference.)

Listeners ontvangen gebeurtenissen waarmee de voortgang of het al dan niet slagen van het laden wordt aangegeven. Hoewel u het object FileReferenceList kunt gebruiken om gebruikers meerdere bestanden te laten selecteren om te laden, moet u de bestanden één voor één laden. Doorloop de array FileReferenceList.fileList van FileReference-objecten om de bestanden één voor één te laden.

Adobe AIR bevat ook de FileStream-klasse, waarmee u meer opties hebt voor het lezen van bestanden.

De functies FileReference.upload(), FileReference.download(), FileReference.load() en FileReference.save() zijn niet-blokkerend. Deze functies worden geretourneerd nadat ze zijn aangeroepen, voordat de bestandsoverdracht is voltooid. Wanneer het FileReference-object buiten bereik treedt, wordt bovendien elke transactie met dat object die nog niet is voltooid, geannuleerd zodra het object buiten bereik is. Zorg ervoor dat het FileReference-object binnen bereik blijft gedurende de tijd dat het uploaden, downloaden, laden of opslaan naar verwachting zal duren.

Als het laden van het bestand is geslaagd, wordt de inhoud opgeslagen als een bytearray in de eigenschap data van het object FileReference.

De volgende beveiligingsoverwegingen zijn van toepassing:

• Laden is niet toegestaan wanneer het aanroepende SWF-bestand zich in een niet-vertrouwde lokale sandbox bevindt.
• Standaard wordt toegang tussen sandboxen geweigerd. Websites kunnen toegang tot een bron toestaan door een bestand met interdomeinbeleid toe te voegen.
• U kunt voorkomen dat een bestand deze methode gebruikt door de parameter allowNetworking in te stellen van de tags object en embed op de HTML-pagina die de SWF-inhoud bevat.

Deze beperkingen zijn echter niet van toepassing op AIR-inhoud in de beveiligingssandbox van de toepassing.

Let erop dat wanneer u naar Flash Player 10 of AIR 1.5 publiceert, slechts een van de volgende bewerkingen tegelijk actief kan zijn: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Als niet aan deze voorwaarde wordt voldaan, genereert de toepassing een runtimefout (code 2174). Gebruik FileReference.cancel() om een actieve bewerking te stoppen. Deze beperking geldt alleen voor Flash Player 10 en AIR 1.5. Deze beperking voor meerdere gelijktijdige bewerkingen geldt niet voor eerdere versies van Flash Player of AIR.

Het Adobe AIR-dialoogvenster waarin u kunt bladeren door bestanden wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Verwante API-elementen

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Hiermee wordt toestemming gevraagd voor toegang tot het bestandssysteem.

Opent een dialoogvenster waarmee de gebruiker een bestand in het lokale bestandssysteem kan opslaan. Hoewel voor Flash Player geen beperkingen gelden op de grootte van bestanden die u kunt uploaden, downloaden, laden of opslaan, biedt de speler officieel ondersteuning voor bestanden van maximaal 100 MB.

Met de methode save() wordt eerst een dialoogvenster van het besturingssysteem geopend, waarin de gebruiker wordt gevraagd een bestandsnaam in te voeren en een locatie op de lokale computer te selecteren om het bestand op te slaan. Wanneer de gebruiker een locatie selecteert en de opslag bevestigt (bijvoorbeeld door op Opslaan te klikken), wordt het opslagproces gestart. Listeners ontvangen gebeurtenissen die de voortgang, het voltooien of mislukken van het opslaan aangeven. Wanneer u de status van het dialoogvenster en het opslaan wilt controleren na het aanroepen van save(), moet uw code luisteren naar gebeurtenissen zoals cancel, open, progress en complete.

Adobe AIR bevat ook de FileStream-klasse, waarmee u meer opties hebt om bestanden lokaal op te slaan.

De functies FileReference.upload(), FileReference.download(), FileReference.load() en FileReference.save() zijn niet-blokkerend. Deze functies worden geretourneerd nadat ze zijn aangeroepen, voordat de bestandsoverdracht is voltooid. Wanneer het FileReference-object buiten bereik treedt, wordt bovendien elke transactie met dat object die nog niet is voltooid, geannuleerd zodra het object buiten bereik is. Zorg ervoor dat het FileReference-object binnen bereik blijft gedurende de tijd dat het uploaden, downloaden, laden of opslaan naar verwachting zal duren.

Wanneer het bestand is opgeslagen, worden de eigenschappen van het object FileReference gevuld met de eigenschappen van het lokale bestand. De gebeurtenis complete wordt verzonden wanneer het opslaan is gelukt.

Er kan slechts een enkele sessie browse() ofsave() tegelijk worden uitgevoerd (omdat slechts een enkel dialoogvenster tegelijk kan worden weergegeven).

In Flash Player kunt u deze methode alleen aanroepen in reactie op een gebruikersgebeurtenis (bijvoorbeeld in een gebeurtenishandler voor een muisklik of een toetsaanslag). Als u deze methode op een ander moment aanroept, wordt een uitzondering gegenereerd in Flash Player. Deze beperking geldt niet voor AIR-inhoud in de toepassingssandbox.

Het Adobe AIR-dialoogvenster waarin u kunt bestanden kunt opslaan wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Parameters

Verwante API-elementen

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Hiermee wordt het uploaden van het bestand naar een externe server gestart. Hoewel voor Flash Player geen beperkingen gelden op de grootte van bestanden die u kunt uploaden en downloaden, biedt de speler officieel ondersteuning voor het uploaden of downloaden van maximaal 100 MB. U moet de methode FileReference.browse() of FileReferenceList.browse() aanroepen voordat u deze methode aanroept.

Voor de Adobe AIR-bestandsklasse, die de FileReference-klasse uitbreidt, kunt u de upload()-methode gebruiken om elk bestand te laden. Voor de FileReference-klasse (in Flash Player) moet de gebruiker eerst een bestand selecteren.

Listeners ontvangen gebeurtenissen die de voortgang, het voltooien of mislukken van de upload weergeven. Hoewel u gebruik kunt maken van het object FileReferenceList om gebruikers meerdere bestanden te laten selecteren om te uploaden, moet u de bestanden een voor een uploaden. Daarvoor doorloopt u de array van FileReferenceList.fileList van objecten FileReference.

De functies FileReference.upload() en FileReference.download() zijn niet-blokkerend. Deze functies worden geretourneerd nadat ze zijn aangeroepen, voordat de bestandsoverdracht is voltooid. Wanneer het object FileReference buiten bereik treedt, wordt bovendien elke upload of download die voor dat object nog niet is voltooid, geannuleerd. Zorg ervoor dat het object FileReference binnen bereik blijft gedurende de tijd dat het uploaden of downloaden zal duren.

Het bestand wordt geüpload naar de URL die in de parameter url wordt doorgegeven. De URL moet een serverscript zijn dat is geconfigureerd om uploads te accepteren. Flash Player uploadt bestanden met behulp van de HTTP-methode POST. Het serverscript dat de upload afhandelt, moet een POST-aanvraag verwachten met de volgende elementen:

• Content-Type van multipart/form-data
• Content-Disposition met standaard een kenmerk name ingesteld op "Filedata" en een kenmerk filename ingesteld op de naam van het oorspronkelijke bestand
• De binaire inhoud van het bestand

U kunt geen verbinding maken met algemeen gereserveerde poorten. Zie "Netwerk-API's beperken" in de Adobe ActionScript 3.0-ontwikkelaarsgids voor een volledige lijst van geblokkeerde poorten.

Een voorbeeld van een POST-aanvraag kunt u vinden bij de beschrijving van de parameter uploadDataFieldName. U kunt parameters POST of GET naar de server verzenden met de methode upload(). Zie de beschrijving van de parameter request.

Wanneer de parameter testUpload gelijk is aan true en wanneer het te uploaden bestand groter is dan ongeveer 10 KB, verzendt Flash Player onder Windows eerst een POST-testupload zonder inhoud voordat het echte bestand wordt geüpload om te controleren of de upload kan slagen. Vervolgens verzendt Flash Player een tweede POST-bewerking met de feitelijke bestandsinhoud. Voor bestanden kleiner dan 10 KB voert Flash Player één POST-upload uit met de feitelijk te uploaden bestandsinhoud. Flash Player onder Macintosh voert geen POST-testuploads uit.

Opmerking: wanneer uw server verificatie vereist, kunnen alleen SWF-bestanden die in een browser worden uitgevoerd, met andere woorden, die de browserinsteekmodule of ActiveX-besturingselement gebruiken, een dialoogvenster weergeven waarin de gebruiker wordt gevraagd een gebruikersnaam en wachtwoord ter verificatie op te geven (alleen voor downloads). Uploaden met behulp van de insteekmodule of het ActiveX-besturingselement, of uploaden en downloaden met een zelfstandige of externe speler, mislukt.

Houd bij gebruik van deze methode rekening met het beveiligingsmodel van Flash Player:

• Laden is niet toegestaan wanneer het aanroepende SWF-bestand zich in een niet-vertrouwde lokale sandbox bevindt.
• Standaard wordt toegang tussen sandboxen geweigerd. Websites kunnen toegang tot een bron toestaan door een bestand met URL-beleid toe te voegen.
• U kunt voorkomen dat een SWF-bestand deze methode gebruikt door de parameter allowNetworking in te stellen van de tags object en embed op de HTML-pagina die de SWF-inhoud bevat.

In Adobe AIR is de inhoud in de application -beveiligingssandbox (inhoud die met de AIR-toepassing is geïnstalleerd), echter niet beperkt tot deze beveiligingsbeperkingen.

Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

Als u publiceert naar Flash Player 10, kan er altijd maar één van de volgende bewerkingen actief zijn omdat er nieuwe functionaliteit is toegevoegd aan Flash Player: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Als niet aan deze voorwaarde wordt voldaan, genereert Flash Player een runtime-fout (code 2174). Gebruik FileReference.cancel() om een actieve bewerking te stoppen. Deze beperking geldt alleen voor Flash Player 10. Deze beperking ten aanzien van gelijktijdige beperkingen geldt dus niet voor eerdere versies van Flash Player.

Parameters

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

Verwante API-elementen

Start het uploaden van een bestand naar een URL zonder enige codering. Terwijl de methode upload() het bestand codeert in een formulier-gegevensenvelop, geeft de methode uploadUnencoded() de bestandsinhoud ongewijzigd door in het hoofdgedeelte van de HTTP-aanvraag. Gebruik de methode uploadUnencoded() als de gegevens die u wilt verzenden reeds zijn gecodeerd in een indeling die de ontvangende server begrijpt. U gebruikt de methode uploadeUnencoded() doorgaans samen met de methode HTTP/WebDAV PUT.

Parameters

Verwante API-elementen

Wordt verzonden wanneer het uploaden en downloaden van een bestand via het bladerdialoogvenster wordt geannuleerd door de gebruiker. Flash Player verzendt deze gebeurtenis niet als de gebruiker het uploaden of downloaden op een andere manier annuleert (door de browser of de toepassing af te sluiten).

Deze gebeurtenis heeft de volgende eigenschappen:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Wordt verzonden wanneer het downloaden is voltooid of wanneer door het uploaden de HTTP-statuscode 200 wordt gegenereerd. Voor een bestandsdownload wordt deze gebeurtenis verzonden nadat Flash Player of Adobe AIR het gehele bestand naar schijf heeft gedownload. Voor een bestandsupload wordt deze gebeurtenis verzonden nadat Flash Player of Adobe AIR de HTTP-statuscode 200 van de ontvangende server heeft ontvangen.

Deze gebeurtenis heeft de volgende eigenschappen:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Verwante API-elementen

Wordt verzonden als een aanroep naar de methode upload() of uploadUnencoded() via HTTP toegang tot gegevens probeert te krijgen, en Adobe AIR de statuscode voor de aanvraag kan detecteren en retourneren.

De constante HTTPStatusEvent.HTTP_RESPONSE_STATUS definieert de waarde van de eigenschap type van een httpResponseStatus-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer een upload mislukt en er een HTTP-statuscode beschikbaar is die de fout beschrijft. De gebeurtenis httpStatus wordt verzonden, gevolgd door een gebeurtenis ioError.

De gebeurtenis httpStatus wordt alleen verzonden bij mislukte uploads. In het geval van inhoud die in Flash Player wordt uitgevoerd, is deze gebeurtenis niet van toepassing op downloadproblemen. Wanneer een download mislukt vanwege een HTTP-fout, wordt de fout gerapporteerd als I/O-fout.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer de upload of download mislukt. Een bestandsoverdracht kan om een van de volgende redenen mislukken:

• Er is een input/output-fout opgetreden terwijl de speler het bestand las, schreef of verzond.
• Het SWF-bestand probeert een bestand te uploaden dat verificatie vereist (bijvoorbeeld een gebruikersnaam en wachtwoord). Tijdens het uploaden bieden Flash Player en Adobe AIR gebruikers niet de mogelijkheid een wachtwoord in te voeren. Wanneer een SWF-bestand een bestand probeert te uploaden naar een server die verificatie vereist, mislukt de upload.
• Het SWF-bestand probeert binnen de zelfstandige of externe speler een bestand te downloaden vanaf een server die verificatie vereist. Tijdens het downloaden bieden de zelfstandige en externe spelers gebruikers niet de mogelijkheid wachtwoorden in te voeren. Wanneer een SWF-bestand in deze spelers een bestand probeert te downloaden naar een server die verificatie vereist, mislukt de download. Het downloaden van een bestand kan alleen slagen in het ActiveX-besturingselement, spelers die als insteekmodule aan de browser zijn toegevoegd en de Adobe AIR runtime.
• De waarde die wordt doorgegeven aan de parameter url in de methode upload(), bevat een ongeldig protocol. Geldige protocollen zijn HTTP en HTTPS.

Belangrijk: alleen toepassingen die in een browser worden uitgevoerd, met andere woorden, die de browserinsteekmodule of het ActiveX-besturingselement gebruiken, en inhoud die in Adobe AIR wordt uitgevoerd, kunnen een dialoogvenster weergeven waarin de gebruiker wordt gevraagd een gebruikersnaam en wachtwoord ter verificatie op te geven (alleen voor downloads). Uploaden met behulp van de insteekmodule of de Flash Player-versie met ActiveX-besturingslement en uploaden en downloaden met de zelfstandige of externe speler mislukt.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer het uploaden of downloaden begint.

Deze gebeurtenis heeft de volgende eigenschappen:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Verwante API-elementen

Wordt verzonden wanneer de toepassing toegang tot het bestandssysteem vraagt. Controleer de waarde van de eigenschap status om te bepalen of de toestemming is verleend of geweigerd

Verwante API-elementen

Wordt periodiek verzonden tijdens het uploaden of downloaden van het bestand. De gebeurtenis progress wordt verzonden terwijl Flash Player bytes verzendt naar een server en wordt periodiek aangeroepen tijdens het verzenden, zelfs wanneer het verzenden uiteindelijk niet slaagt. U kunt vaststellen of het verzenden van bestanden is geslaagd door te luisteren naar de gebeurtenis complete.

In sommige gevallen worden gebeurtenissen progress niet ontvangen. Wanneer bijvoorbeeld het te verzenden bestand bijzonder klein is of wanneer het uploaden of downloaden zeer snel gaat, wordt mogelijk geen gebeurtenis progress verzonden.

Voortgang van bestandsupload kan niet worden bepaald op Macintosh-platforms lager dan OS X 10.3. De gebeurtenis progress wordt tijdens het uploaden aangeroepen, maar de waarde van de eigenschap bytesLoaded van de gebeurtenis is -1. Dit geeft aan dat de voortgang niet kan worden bepaald.

Deze gebeurtenis heeft de volgende eigenschappen:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Verwante API-elementen

Wordt verzonden wanneer een aanroep van de methode FileReference.upload() of FileReference.download() een bestand naar een server probeert te uploaden of een bestand van de server probeert te downloaden dat zich buiten de beveiligingssandbox van de aanroeper bevindt. De waarde van de eigenschap text die een beschrijving geeft van de specifieke fout die optrad, is doorgaans "securitySandboxError". Het aanroepende SWF-bestand heeft mogelijk geprobeerd toegang te verkrijgen tot een SWF-bestand buiten het domein, waarvoor het geen toestemming heeft. U kunt proberen deze fout te verhelpen door een bestand met URL-beleid te gebruiken.

In Adobe AIR zijn deze beveiligingsbeperkingen niet van toepassing op inhoud in de sandbox met toepassingsbeveiliging.

In Adobe AIR zijn deze beveiligingsbeperkingen niet van toepassing op inhoud in de sandbox met toepassingsbeveiliging.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer de gebruiker in het bladerdialoogvenster een bestand selecteert om te uploaden of downloaden. (Dit dialoogvenster wordt geopend bij het aanroepen van de methode FileReference.browse(), FileReferenceList.browse() of FileReference.download().) Wanneer de gebruiker een bestand selecteert en de handeling bevestigt (door bijvoorbeeld op OK te klikken), worden de eigenschappen van het object FileReference gevuld.

In het geval van inhoud die wordt uitgevoerd in Flash Player of buiten de sandbox met toepassingsbeveiliging in de Adobe AIR runtime, is de exacte werking van de select-gebeurtenis afhankelijk van de methode die deze activeert. Wanneer de select-gebeurtenis wordt verzonden na een browse()-aanroep, kan Flash Player of de AIR-toepassing alle eigenschappen van het object FileReference lezen, omdat het door de gebruiker geselecteerde bestand zich op het lokale bestandssysteem bevindt. Wanneer de gebeurtenis select plaatsvindt na het aanroepen van download(), kan Flash Player of de AIR-toepassing alleen de eigenschap name lezen omdat het bestand nog niet naar het lokale bestandssysteem is gedownload op het moment dat de gebeurtenis select wordt verzonden. Wanneer het bestand is gedownload en de gebeurtenis complete is verzonden, kan Flash Player of de AIR-toepassing alle andere eigenschappen van het object FileReference lezen.

Deze gebeurtenis heeft de volgende eigenschappen:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Wordt verzonden nadat gegevens van de server zijn ontvangen nadat het uploaden is voltooid. Deze gebeurtenis wordt niet verzonden wanneer geen gegevens van de server worden geretourneerd.

Deze gebeurtenis heeft de volgende eigenschappen:

Opmerking: om dit voorbeeld te kunnen uitvoeren, wijzigt u de eigenschap uploadURL.url zodanig dat deze naar een feitelijk bestaande URL verwijst en niet naar de fictieve voorbeeld-URL. De URL moet verwijzen naar het bestand yourUploadHandlerScript.cfm in de hoofdwebmap van de opgegeven URL. Afhankelijk van uw configuratie moet u wellicht ook het SWF-bestand compileren met Local Playback Security ingesteld op Access Network Only of moet u beveiligingsinstellingen in Flash Player aanpassen om voor dit bestand netwerktoegang mogelijk te maken.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}