File  - AS3

De map met de geïnstalleerde bestanden van de toepassing.

De eigenschap url voor dit object gebruikt het URL-schema app (niet het URL-schema file). Dat betekent dat de url-tekenreeks wordt opgegeven met "app:" aan het begin (niet "file:"). Als u een File-object maakt dat gerelateerd is aan de map File.applicationDirectory (met de methode resolvePath()), gebruikt de eigenschap url van het File-object ook het URL-schema app.

Opmerking: u kunt geen gegevens schrijven naar bestanden of mappen die een pad hebben dat gebruikmaakt van het URL-schema app:. Het is ook niet mogelijk om bestanden of mappen te verwijderen of te maken die een pad hebben dat gebruikmaakt van het URL-schema app:. Uit veiligheidsoogpunt is het wijzigen van inhoud in de toepassingsmap geen goede werkwijze. Daarom wordt dit op sommige platforms geblokkeerd door het besturingssysteem. Als u toepassingsspecifieke gegevens wilt opslaan, kunt u ook de opslagmap van de toepassing gebruiken (File.applicationStorageDirectory). Als u wilt dat inhoud in de toepassingsopslagmap toegang kan verkrijgen tot voor de toepassing unieke functionaliteit (AIR API's), kunt u die functionaliteit beschikbaar maken via een sandbox-bridge.

De eigenschap applicationDirectory biedt een manier voor het verwijzen naar de toepassingsmap die op verschillende platforms werkt. Als u een File-object instelt om te verwijzen naar de toepassingsmapmet de eigenschap nativePath of url, werkt dat alleen op het platform waarvoor dat pad geldig is.

Op het Android-systeem is de eigenschap nativePath van een File-object dat naar de toepassingsmap wijst, een lege tekenreeks. Als u toegang wilt krijgen tot de toepassingsbestanden, moet u de eigenschap urlgebruiken.

Verwante API-elementen

De privé-opslagmap van de toepassing.

Elke AIR-toepassing heeft een unieke, persistente toepassingsopslagmap, die wordt gemaakt wanneer u voor het eerst toegang krijgt tot File.applicationStorageDirectory. Deze map is uniek voor elke toepassing en gebruiker. Deze map is een handige plek om specifieke gegevens van de toepassing of gebruiker in op te slaan.

Wanneer u een AIR-toepassing verwijdert is het afhankelijk van het platform of de toepassingsopslagmap en de bijbehorende bestanden al dan niet worden verwijderd.

De eigenschap url voor dit object gebruikt het URL-schema app-storage (niet het URL-schema file). Dat betekent dat de url-tekenreeks wordt opgegeven met "app-storage:" aan het begin (niet "file:"). Als u een object File maakt dat gerelateerd is aan de map File.applicationStoreDirectory (met de methode resolvePath()), gebruikt de url van het object ook het URL-schema app-storage (zoals in het voorbeeld).

De eigenschap applicationStorageDirectory biedt een manier voor het verwijzen naar de opslagmap van de toepassing die op verschillende platforms werkt. Als u een File-object instelt om te verwijzen naar de opslagmap van de toepassing met de eigenschap nativePath of url, werkt dat alleen op het platform waarvoor dat pad geldig is.

Opmerking (alleen Mac OS): Om te voldoen aan de Mac App Store-vereisten, is de fysieke locatie van deze directory gewijzigd tussen AIR 3.2 en AIR 3.3:

• 3.2-naamruimte en lager: ~/Library/Preferences/appid/Local Store/
• 3.3-naamruimte en hoger: path/Library/Application Support/appid/Local Store/, waarbij path ofwel ~/Library/Containers/bundle-id/Data is (bij een sandbox-omgeving), of ~ (buiten een sandbox-omgeving)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

De cachemap van de toepassing.

De eigenschap cacheDirectory biedt een manier om te verwijzen naar de cachemap. Uw toepassing moet de cachemap gebruiken om bestanden op te slaan die zijn gedownload vanaf een server of die op een andere manier opnieuw kunnen worden gegenereerd. Voorbeelden van bestanden die u in de cachemap moet plaatsen, omvatten databasecachebestanden en downloadbare inhoud, zoals de inhoud die wordt gebruikt door tijdschrift-, krant- en kaarttoepassingen.

Als u een File-object instelt om te verwijzen naar de cachemap met behulp van de eigenschap nativePath of url, zal dit alleen werken op platforms waarvoor dat pad geldig is.

Als een besturingssysteem een cachemap niet ondersteunt, is cacheDirectory null

De bureaubladmap van de gebruiker.

De eigenschap desktopDirectory biedt een manier voor het verwijzen naar de bureaubladmap die op verschillende platforms werkt. Als u een File-object instelt om te verwijzen naar de bureaubladmap met de eigenschap nativePath of url, werkt dat alleen op het platform waarvoor dat pad geldig is.

Als het besturingssysteem geen ondersteuning biedt voor een bureaubladmap, wordt in plaats daarvan een geschikte map in het bestandssysteem gebruikt.

AIR for TV-apparaten werken niet met bureaubladmappen voor gebruikers. Daarom verwijst de eigenschapdesktopDirectory naar dezelfde maplocatie als de eigenschap File.userDirectory. De gebruikersmap is uniek voor de toepassing.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

De documentenmap van de gebruiker.

Onder Windows is dit de map Mijn documenten (bijvoorbeeld C:\Documents and Settings\gebruikersnaam\Mijn documenten). Onder Mac OS is /Users/gebruikersnaam/Documenten de standaardlocatie. Onder Linux is /home/gebruikersnaam/Documents de standaardlocatie (op een Engelstalig systeem) en de eigenschap gebruikt de instelling xdg-user-dirs.

De eigenschap documentsDirectory biedt een manier voor het verwijzen naar de documentenmap die op verschillende platforms werkt. Als u een File-object instelt om te verwijzen naar de documentenmap met de eigenschap nativePath of url, werkt dat alleen op het platform waarvoor dat pad geldig is.

Als het besturingssysteem geen ondersteuning biedt voor een documentmap, wordt in plaats daarvan een geschikte map in het bestandssysteem gebruikt.

AIR for TV-apparaten werken niet met documentmappen voor gebruikers. Daarom verwijst de eigenschapdocumentsDirectory naar dezelfde maplocatie als de eigenschap File.userDirectory. De gebruikersmap is uniek voor de toepassing.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Geeft aan of het referentiebestand of -map gedownload (van het internet) is of niet.

Deze eigenschap heeft alleen betekenis bij besturingssystemen waarop bestanden kunnen worden gemarkeerd als gedownload:

• Windows XP service pack 2 en later en op Windows Vista
• Mac OS 10.5 en later

Bij systemen waarbij dit niet mogelijk is, zoals Linux, heeft deze eigenschap geen betekenis (en wordt deze ingesteld op false).

Verwante API-elementen

Geeft aan of het bestand of het pad waarnaar wordt verwezen, bestaat. De waarde is true als het File-object verwijst naar een bestaand bestand of een bestaande map, en false in andere gevallen.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Een Icon-object met de pictogrammen die voor het bestand zijn gedefinieerd. Een object Icon is een array van BitmapData-objecten die de verschillende staten van de pictogrammen weergeven. Onder Linux bevat het object Icon geen pictogrammen. Op het Android-systeem is de waarde van de eigenschap icon gelijk aan null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Geeft aan of naar een map wordt verwezen. De waarde is true als het bestandsobject verwijst naar een map; false in andere gevallen.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Geeft aan of het bestand of de map waarnaar wordt verwezen, "verborgen" is. De waarde is true als het bestand of de map waarnaar wordt verwezen verborgen is, en false in andere gevallen.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Geeft aan of de map waarnaar wordt verwezen een pakket is.

De waarde is true als het de map waarnaar wordt verwezen een pakket is, en false in andere gevallen. Met de klasse File kunnen pakketten niet rechtstreeks worden gemaakt.

• Onder Mac OS kunnen mappen worden aangewezen als pakketten; deze zullen in de Finder worden weergegeven als één bestand in plaats van als een map. Deze eigenschap is ingesteld op true als de map waarnaar wordt verwezen een pakket is, en false als het bestand geen map is, niet bestaat of geen pakket is.
• Op andere besturingssystemen is deze eigenschap altijd ingesteld op false.

Geeft aan of de verwijzing een symbolische koppeling is.

De waarde is true als het File-object een symbolische koppeling is, en false in andere gevallen. Met de klasse File kunnen symbolische koppelingen niet rechtstreeks worden gemaakt.

Met symbolische koppelingen kan een bestand naar een ander bestand of een map op de schijf verwijzen. Symbolische koppelingen zijn vergelijkbaar met, maar niet hetzelfde als aliassen onder Mac OS en snelkoppelingen onder Windows. Een alias of een snelkoppeling wordt altijd als een bestand gerapporteerd (niet als een map), en het lezen of schrijven naar een alias of snelkoppeling heeft nooit gevolgen voor het oorspronkelijke bestand of de oorspronkelijke map waarnaar deze verwijst. Een symbolische koppeling gedraagt zich echter gewoonlijk zoals het bestand of de map waarnaar deze verwijst. Deze kan als bestand of als map worden gerapporteerd en het lezen van of schrijven naar een symbolische koppeling heeft gevolgen voor de map of het bestand waarnaar deze verwijst, niet voor de symbolische koppeling zelf. Als u een symbolische koppeling verwijdert, wordt echter de koppeling verwijdert en niet het doel van de koppeling.

Mac^® OS^®, Linux en Windows^® Vista^® ondersteunen symbolische koppelingen. Verder is onder Windows de eigenschap isSymbolicLink voor een object File dat verwijst naar een junction point (wordt gebruikt in het NTFS-bestandssysteem) ingesteld op true.

De tekenreeks voor regeleinde die door het besturingssysteem van de host wordt gebruikt.

Onder Mac OS en Linux is dit het regeldoorvoerteken (tekencode 0x0A hexadecimaal). Onder Windows is dit het Enter-teken (tekencode 0x0D hexadecimaal), gevolgd door het regeldoorvoerteken (tekencode 0x0A hexadecimaal).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Het volledige pad in de notatie van het besturingssysteem van de host. Onder Mac OS en Linux wordt de forward slash (/) gebruikt als padscheidingsteken. In Windows is het echter mogelijk om de eigenschap nativePath in te stellen met de forward slash (/) of de backslash (\) als padscheidingsteken; AIR vervangt forward slashes automatisch door de backslash (\).

Bedenk voordat u code schrijft om de eigenschap nativePath rechtstreeks in te stellen, of daardoor platformspecifieke code ontstaat. Een eigen pad zoals "C:\\Documents and Settings\\bob\\Desktop" is bijvoorbeeld alleen geldig in Windows. U kunt veel beter de volgende statische eigenschappen gebruiken, die algemeen gebruikte mappen vertegenwoordigen en die geldig zijn op alle platforms:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

U kunt de methode resolvePath() gebruiken om een pad te krijgen dat relatief is ten opzichte van deze mappen.

Sommige Flex-API's, zoals de eigenschap source van de SWFLoader-klasse maken gebruik van een URL (de eigenschap url van een File-object) en niet van een native pad (de eigenschap nativePath).

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

De map met het bestand of de map waarnaar wordt verwezen door dit object File.

Als het bestand of de map niet bestaat, resulteert de eigenschap parent nog steeds in het File-object dat wijst naar de bovenliggende map, zelfs als die map niet bestaat.

Deze eigenschap is identiek aan de resulterende waarde voor resolvePath("..") behalve dat de bovenliggende map van een hoofdmap null is.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Hiermee bepaalt u of de toepassing al dan niet toegangsrecht heeft tot het bestandssysteem.

Verwante API-elementen

Geeft aan of de runtime al dan niet voorkomt dat er een back-up wordt gemaakt van dit File-object in de cloud.

Als deze eigenschap is ingesteld op true, wordt hier niet automatisch een back-up van gemaakt in de cloud op platforms die deze service bieden. De standaardwaarde van deze eigenschap is false.

Het scheidingsteken voor padcomponenten van het besturingssysteem van de host.

In Mac OS en Linux is dit de schuine streep (/). Onder Windows is het de backslash (\).

Opmerking: Wanneer u de backslash gebruikt in een letterlijke tekenreeks, moet u niet vergeten het teken tweemaal te typen (zie "map\\bestand.ext"). Elk paar backslashes in een letterlijke tekenreeks staat voor één backslash in de tekenreeks.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

De beschikbare ruimte op deze bestandslocatie in bytes.

Als het File-object verwijst naar een map, geeft spaceAvailable de ruimte aan in de map die door bestanden kan worden gebruikt. Als het File-object verwijst naar een bestand, geeft spaceAvailable de ruimte aan waarin het bestand kan groeien. Als de bestandslocatie niet bestaat, wordt spaceAvailable ingesteld op 0. Als het File-object verwijst naar een symbolische koppeling, geeft spaceAvailable de ruimte aan die beschikbaar is op de locatie waarnaar de symbolische koppeling wijst.

Meestal is de beschikbare ruimte voor een map of bestand gelijk aan de beschikbare ruimte op het volume waarop de map of het bestand zich bevindt. Bij de beschikbare ruimte kan echter ook rekening worden gehouden met quota voor accounts en beperkingen voor mappen.

Als u een bestand of map toevoegt aan een volume, is hiervoor meestal meer ruimte nodig dan de daadwerkelijke grootte van het bestand of de grootte van de inhoud van de map. Zo is er bijvoorbeeld ruimte nodig om indexgegevens op te slaan. Het is ook mogelijk dat de vereiste schijfsectoren extra ruimte vragen. Daarnaast verandert de hoeveelheid beschikbare ruimte dynamisch. U kunt dus niet alle vermelde ruimte gebruiken voor het opslaan van bestanden.

De standaardcodering die door het besturingssysteem van de host wordt gebruikt.

Mogelijke waarden zijn onder andere "windows-1252" "shift-jis", "cn-gb", "iso-8859-1". Zie Ondersteunde tekensets voor een complete lijst.

U kunt deze waarde gebruiken in de methode readMultiByte() en writeMultiByte() van de klasse FileStream.

Verwante API-elementen

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

De URL voor dit bestandspad.

Als dit een verwijzing is naar een pad in de toepassingsopslagmap, is het URL-schema "app-storage"; als het een verwijzing is naar een pad in de toepassingsmap, is het URL-schema "app"; anders is het schema "file".

U kunt spatietekens gebruiken (in plaats van "%20") wanneer u een waarde toewijst aan de eigenschap url. AIR codeert de tekenreeksen automatisch (bijvoorbeeld door spaties om te zetten in "%20").

Verwante API-elementen

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

De map van de gebruiker.

Onder Windows is dit de bovenliggende map van de map Mijn documenten (bijvoorbeeld C:\Documents and Settings\gebruikersnaam). Onder Mac OS is dit /Users/gebruikersnaam. Onder Linux is dit /home/gebruikersnaam.

De eigenschap userDirectory biedt een manier voor het verwijzen naar de gebruikersmap die op verschillende platforms werkt. Als u de eigenschap nativePath of url van een File-object rechtstreeks instelt, werkt dat alleen op het platform waarvoor dat pad geldig is.

Als het besturingssysteem geen ondersteuning biedt voor een gebruikersmap, wordt in plaats daarvan een geschikte map in het bestandssysteem gebruikt.

Op AIR for TV-apparaten verwijst de eigenschap userDirectory naar een gebruikersmap die uniek is voor de toepassing.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

De constructorfunctie voor de klasse File.

Als u een path-argument doorgeeft, verwijst het object File naar het opgegeven pad en worden de eigenschap nativePath en url op dat pad ingesteld.

Hoewel u een path-argument kunt doorgeven om een bestandspad op te geven, dient u te overwegen of dit platformspecifieke code oplevert. Een eigen pad zoals "C:\\Documents and Settings\\bob\\Desktop" of een URL zoals "file:///C:/Documents%20and%20Settings/bob/Desktop" is bijvoorbeeld alleen geldig in Windows. U kunt veel beter de volgende statische eigenschappen gebruiken, die algemeen gebruikte mappen vertegenwoordigen en die geldig zijn op alle platforms:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Vervolgens kunt u de methode resolvePath() gebruiken om een pad te krijgen dat relatief is ten opzichte van deze mappen. Met de volgende code wordt bijvoorbeeld een File-object ingesteld om te verwijzen naar het bestand settings.xml in de opslagmap van de toepassing:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Let op: als u een URL-tekenreeks in de parameter path doorgeeft, wordt de URL gedecodeerd om het bestandspad te herleiden. Met de instructie new File("file:///c:/test/demo%20file%201%2e0.txt") wordt een object File gemaakt met 'c:\test\demo file 1.0.txt' als native pad. (Een URL gebruikt een van de schemavoorvoegsels file:, app: of app-storage:.) Als de geldige URL-voorvoegsels worden weggelaten, wordt de padtekenreeks als native pad beschouwd en vindt er geen decodering plaats. U moet rekening houden met dit gedrag wanneer u paden valideert die zijn afgeleid van bronnen die mogelijk niet vertrouwd kunnen worden. Als u de invoertekenreeks gewoon valideert, kan het zijn dat door decodering van de URL een aanvaller uw validatiecontroles kan omzeilen. Valideer altijd het definitieve pad van het geïnstantieerde object File:

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Verwante API-elementen

Hiermee wordt een dialoogvenster geopend waarin de gebruiker een map kan selecteren. Wanneer de gebruiker de map selecteert, wordt de gebeurtenis select verzonden. De eigenschap target van de gebeurtenis select is het object File dat naar de geselecteerde map verwijst.

Het dialoogvenster waarin u een directory kunt kiezen wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Opmerking:Android-apparaten bieden geen ondersteuning voor browseForDirectory(). Het File-object verzendt direct een cancel-gebeurtenis.

Parameters

Verwante API-elementen

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Hiermee wordt het dialoogvenster Bestand openen weergegeven, waarin de gebruiker een bestand kan selecteren om te openen.

Wanneer de gebruiker het bestand selecteert, wordt de gebeurtenis select verzonden. De eigenschap target van de gebeurtenis select is het object File dat naar het geselecteerde bestand verwijst.

Het dialoogvenster Bestand openen wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Opmerking: bij Android-apparaten kan de dialoogvenstertitel van het bestand niet wordt ingesteld. De parameter title wordt genegeerd.

Parameters

Verwante API-elementen

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Hiermee wordt het dialoogvenster Bestand openen weergegeven, waarin de gebruiker een of meer bestanden kan selecteren om te openen.

Wanneer de gebruiker de bestanden selecteert, wordt de gebeurtenis selectMultiple verzonden. De eigenschap target van de gebeurtenis select is dit object File. In tegenstelling tot browseForOpen(), wordt dit File-object met de methode browseForOpenMultiple() niet bijgewerkt om naar een van de gekozen bestanden te verwijzen. De resulterende selectMultiple-gebeurtenis bevat een array met de gekozen bestanden.

Het dialoogvenster Bestand openen wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Opmerking: bij Android-apparaten kan de dialoogvenstertitel van het bestand niet wordt ingesteld. De parameter title wordt genegeerd.

Parameters

Verwante API-elementen

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Hiermee wordt het dialoogvenster Bestand opslaan weergegeven, waarin de gebruiker een bestemming voor het bestand kan selecteren.

Wanneer de gebruiker het bestand selecteert, wordt de gebeurtenis select verzonden. De eigenschap target van de gebeurtenis select is het object File dat naar de geselecteerde opslagbestemming verwijst.

Het dialoogvenster Bestand opslaan wordt niet altijd weergegeven vóór vensters die het eigendom zijn van een ander venster (vensters waarvan de eigenschap owner een waarde heeft die niet gelijk is aan null). Als u problemen wilt voorkomen met de volgorde waarin vensters worden weergegeven, moet u vensters met een eigenaar verbergen voordat u deze methode aanroept.

Opmerking: bij Android-apparaten kan de dialoogvenstertitel van het bestand niet wordt ingesteld. De parameter title wordt genegeerd.

Parameters

Verwante API-elementen

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Hiermee wordt een asynchrone bewerking in behandeling geannuleerd.

Autoriseert het bestandspad.

Als het object File naar een bestaand bestand of een bestaande map verwijst, wordt het pad zodanig aangepast dat het overeenkomt met het hoofdlettergebruik van de werkelijke bestands- of mapnaam. Als het object File een symbolische koppeling is, wordt hiermee het pad zodanig aangepast dat het overeenkomt met het bestand of de map waarnaar de koppeling verwijst, ongeacht of het bestand of de map daadwerkelijk bestaat. Wanneer in hoofdlettergevoelige bestandssystemen (zoals Linux) meerdere bestanden bestaan met namen die alleen verschillen in hoofdlettergebruik, wordt met de methode canonicalize() het pad aangepast aan het eerste bestand dat wordt gevonden (in een volgorde die door het bestandssysteem is bepaald).

Daarnaast worden korte bestandsnamen in Windows naar lange bestandsnamen geconverteerd met de methode canonicalization.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Retourneert een kopie van dit object File. Gebeurtenisregistraties worden niet gekopieerd.

Opmerking: Met deze methode wordt het bestand zelf niet gekopieerd. Er wordt alleen een kopie gemaakt van de instantie van het object File ActionScript . Als u een bestand wilt kopiëren, gebruikt u de methode copyTo().

Kopieert het bestand of de map op de locatie die door dit File-object is opgegeven naar de locatie die door de parameter newLocation is opgegeven. Tijdens het kopieerproces worden zo nodig bovenliggende mappen gemaakt (indien mogelijk). Als bestanden worden overschreven met gebruik van copyTo(), worden de bestandskenmerken ook overschreven.

Parameters

Verwante API-elementen

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Begint het bestand of de map te kopiëren op de locatie die door dit object File is opgegeven naar de locatie die door de bestemmingsparameter is opgegeven.

Tot slot wordt de gebeurtenis complete (gelukt) of ioError (mislukt) verzonden. Tijdens het kopieerproces worden zo nodig bovenliggende mappen gemaakt (indien mogelijk).

Parameters

Verwante API-elementen

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Maakt de opgegeven map en eventueel noodzakelijke bovenliggende mappen. Als de map al bestaat, wordt er geen actie uitgevoerd.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Resulteert in een verwijzing naar een nieuwe tijdelijke map. Dit is een nieuwe map in het pad naar de tijdelijke map van het systeem.

Met deze methode kunt u een nieuwe, unieke map aanwijzen, zonder dat u een query hoeft uit te voeren om te controleren of de map nieuw en uniek is.

Verwijder de tijdelijke directory eventueel handmatig voordat u de toepassing sluit, omdat dit op sommige apparaten niet automatisch gebeurt.

Verwante API-elementen

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Resulteert in een verwijzing naar een nieuw tijdelijk bestand. Dit is een nieuw bestand in het pad naar de tijdelijke map van het systeem.

Met deze methode kunt u een nieuw, uniek bestand aanwijzen, zonder dat u een query hoeft uit te voeren om te controleren of het bestand nieuw en uniek is.

Verwijder het tijdelijke bestand eventueel handmatig voordat u de toepassing sluit, omdat dit niet automatisch gebeurt.

Verwante API-elementen

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Hiermee wordt de map verwijderd. Als dit bestand een symbolische koppeling naar een map is, wordt de koppeling, en niet de map, verwijderd.

Parameters

Verwante API-elementen

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Hiermee wordt de map asynchroon verwijderd. Als dit bestand een symbolische koppeling naar een map is, wordt de koppeling, en niet de map, verwijderd.

Parameters

Verwante API-elementen

Hiermee wordt het bestand verwijderd. Als dit bestand een symbolische koppeling is, wordt de koppeling, en niet het doelbestand, verwijderd.

Verwante API-elementen

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Hiermee wordt het bestand asynchroon verwijderd. Als dit bestand een symbolische koppeling is, wordt de koppeling, en niet het doelbestand, verwijderd.

Verwante API-elementen

Geeft een array met bestandsobjecten die overeenkomen met bestanden en mappen in de map die staat voor dit object File. De methode verkent de inhoud van submappen niet.

Verwante API-elementen

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Haalt asynchroon een array van objecten File op die overeenkomen met de inhoud van de map die staat voor dit object File.

Verwante API-elementen

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Hiermee wordt het relatieve pad tussen twee bestandspaden gevonden.

Het relatieve pad is de lijst met componenten die aan deze verwijzing kunnen worden toegevoegd (omgezet) om de tweede (parameter)verwijzing te vinden. Het relatieve pad wordt gegeven met het scheidingsteken "/".

Relatieve paden kunnen eventueel ".." verwijzingen bevatten, maar deze paden komen niet voorbij opvallende volumegrenzen.

Parameters

Resulteert in een array met File-objecten, waarin de hoofdmappen van het bestandssysteem worden vermeld.

Onder Windows is dit bijvoorbeeld een lijst volumes,. zoals het station C: en het station D:. Een leeg station, bijvoorbeeld een cd- of dvd-station waarin geen schijf is geplaatst, wordt niet in deze array opgenomen. In Mac OS en Linux geeft deze methode altijd als resultaat de unieke hoofdmap van de computer (de map "/").

Op bepaalde bestandssystemen, zoals het Android-bestandssysteem, kan de hoofdmap niet kan worden gelezen. In dat geval komen de eigenschappen van het geretourneerde File-object niet altijd overeen met de werkelijke waarde. Op het Android-systeem wordt bijvoorbeeld de waarde 0 gerapporteerd door de eigenschap spaceAvailable.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Verplaatst het bestand of de map op de locatie die door dit object File is opgegeven naar de locatie die door de bestemmingsparameter is opgegeven.

Als u een bestand een andere naam wilt geven, stelt u de bestemmingsparameter zo in dat deze naar een pad verwijst dat zich in de bestandsmap bevindt, maar met een andere bestandsnaam.

Tijdens het verplaatsen worden zo nodig bovenliggende mappen gemaakt (indien mogelijk).

Parameters

Verwante API-elementen

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Begint het bestand of de map op de locatie die door dit object File is opgegeven te verplaatsen naar de locatie die door de parameter newLocation is opgegeven.

Als u een bestand een andere naam wilt geven, stelt u de bestemmingsparameter zo in dat deze naar een pad verwijst dat zich in de bestandsmap bevindt, maar met een andere bestandsnaam.

Tijdens het verplaatsen worden zo nodig bovenliggende mappen gemaakt (indien mogelijk).

Parameters

Verwante API-elementen

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Verplaatst een bestand of map naar de prullenbak.

Opmerking: als een besturingssysteem geen ondersteuning biedt voor het concept van een prullenbak waarbij bestanden kunnen worden hersteld, worden de bestanden direct verwijderd.

Verwante API-elementen

Verplaatst een bestand of map asynchroon naar de prullenbak.

Opmerking: als een besturingssysteem geen ondersteuning biedt voor het concept van een prullenbak waarbij bestanden kunnen worden hersteld, worden de bestanden direct verwijderd.

Verwante API-elementen

Hiermee wordt het bestand geopend in de toepassing die in het besturingssysteem geregistreerd staat om dit bestandstype te openen.

AIR voorkomt dat u bepaalde bestanden opent met de methode File.openWithDefaultApplication(). Bij Windows-systemen voorkomt AIR dat u bepaalde bestandstypen kunt openen (bestanden met specifieke extensies die hieronder worden weergegeven). Op Mac OS en Linux voorkomt AIR dat u bestanden opent die in bepaalde toepassingen worden gestart. Deze toepassingen staan hieronder vermeld. Als u een van deze bestanden opent met de methode openWithDefaultApplication(), treedt een uitzonderingsfout op. Deze beperking geldt niet voor AIR-toepassingen die zijn geïnstalleerd met een native installatieprogramma (toepassingen die zijn uitgebreid met het bureaubladprofiel); deze toepassingen kunnen elk bestandstype openen.

Documenten in de toepassingsmap kunnen niet worden geopend.

De onderstaande tabellen bevatten bestandsextenties die niet mogen worden gebruikt op Windows en extensies van equivalente toepassingen op Mac OS en Linux:

Verwante API-elementen

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Hiermee wordt toestemming gevraagd voor toegang tot het bestandssysteem.

Hiermee wordt een nieuw object File gemaakt met een pad dat gerelateerd is aan het pad van dit object File, gebaseerd op de parameter path (een tekenreeks).

U kunt een relatief pad of absoluut gebruiken voor de parameter path.

Als u een relatief pad opgeeft, wordt de parameter path toegevoegd aan het einde van het pad van het File-object. Als u ".." gebruikt in de parameter path, kan dit resulteren in een pad dat niet onder het File-object ligt. De resulterende verwijzing verwijst niet noodzakelijk naar een daadwerkelijke locatie in het bestandssysteem.

Als u een absolute bestandsverwijzing opgeeft, retourneert deze methode het File-object dat wijst naar het pad. De absolute bestandsverwijzing moet een geldige, eigen padsyntaxis hebben van het besturingssysteem van de gebruiker, bijvoorbeeld "C:\\test" in geval van Windows. Gebruik geen URL, bijvoorbeeld "file:///c:/test", voor de parameter path.

Alle resulterende paden worden als volgt genormaliseerd:

• Alle "." elementen worden genegeerd.
• Alle ".." elementen gebruiken de bovenliggende invoer.
• Geen enkele ".." verwijzing die de hoofdmap van het bestandssysteem of de toepassings-resistente hoofdopslag bereikt, geeft dit knooppunt door; het wordt genegeerd.

Gebruik altijd de forward slash (/) als padscheidingsteken. Bij Windows kunt u eventueel ook de backslash (\) gebruiken, maar dit wordt niet aanbevolen. Als u de backslash gebruikt, kunnen de toepassingen mogelijk niet worden uitgevoerd op andere platforms.

Bestandsnamen en mapnamen zijn hoofdlettergevoelig in Linux.

Parameters

Wordt verzonden wanneer een asynchrone bewerking in behandeling wordt geannuleerd.

Deze gebeurtenis heeft de volgende eigenschappen:

Wordt verzonden wanneer een asynchrone bewerking voltooid is.

Deze gebeurtenis heeft de volgende eigenschappen:

Wordt verzonden wanneer een mappenlijst beschikbaar is als gevolg van a een oproep aan de methode getDirectoryListingAsync().

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer tijdens een asynchrone bestandsbewerking een fout optreedt.

Deze gebeurtenis heeft de volgende eigenschappen:

Wordt verzonden wanneer de toepassing toegang tot het bestandssysteem vraagt. Controleer de waarde van de eigenschap status om te bepalen of de toestemming is verleend of geweigerd

Verwante API-elementen

Wordt verzonden wanneer een beveiligingsbeperking door een bewerking wordt overtreden.

Deze gebeurtenis heeft de volgende eigenschappen:

Wordt verzonden wanneer de gebruiker in een browservenster een bestand of een map selecteert.

Deze gebeurtenis heeft de volgende eigenschappen:

Wordt verzonden wanneer de gebruiker bestanden selecteert in het dialoogvenster dat wordt geopend door een aanroep van de methode browseForOpenMultiple().

Verwante API-elementen