URLRequestMethod - Bron voor Adobe ActionScript® 3 (AS3 ) API

Pakket	flash.net
Klasse	public final class URLRequestMethod
Overerving	URLRequestMethod Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

De klasse URLRequestMethod biedt waarden die opgeven of het object URLRequest de methode POST of de methode GET moet gebruiken bij het verzenden van gegevens naar een server.

Bekijk de voorbeelden

Verwante API-elementen

URLRequest
URLVariables

Openbare eigenschappen

Overerfde openbare eigenschappen verbergen

Overerfde openbare eigenschappen weergeven

	Eigenschap		Gedefinieerd door
		constructor : Object Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie.	Object

Openbare methoden

Overerfde openbare methoden verbergen

Overerfde openbare methoden weergeven

	Methode		Gedefinieerd door
		hasOwnProperty(name:String):Boolean Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd.	Object
		isPrototypeOf(theClass:Object):Boolean Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven.	Object
		propertyIsEnumerable(name:String):Boolean Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in.	Object
		toLocaleString():String Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.	Object
		toString():String Retourneert een tekenreeksrepresentatie van het opgegeven object.	Object
		valueOf():Object Retourneert de primitieve waarde van het opgegeven object.	Object

Openbare constanten

	Constante		Gedefinieerd door
		DELETE : String = "DELETE" [statisch] Geeft op dat het URLRequest-object een DELETE is.	URLRequestMethod
		GET : String = "GET" [statisch] Geeft op dat het object URLRequest een GET is.	URLRequestMethod
		HEAD : String = "HEAD" [statisch] Geeft op dat het URLRequest-object een HEAD is.	URLRequestMethod
		OPTIONS : String = "OPTIONS" [statisch] Geeft aan dat het URLRequest-object OPTIONS is.	URLRequestMethod
		POST : String = "POST" [statisch] Geeft aan dat het URLRequest-object POST is.	URLRequestMethod
		PUT : String = "PUT" [statisch] Geeft aan dat het URLRequest-object PUT is.	URLRequestMethod

Constantedetails

DELETE

Constante

public static const DELETE:String = "DELETE"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0

Geeft op dat het URLRequest-object een DELETE is.

GET

Constante

public static const GET:String = "GET"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Geeft op dat het object URLRequest een GET is.

HEAD

Constante

public static const HEAD:String = "HEAD"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0

Geeft op dat het URLRequest-object een HEAD is.

OPTIONS

Constante

public static const OPTIONS:String = "OPTIONS"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0

Geeft aan dat het URLRequest-object OPTIONS is.

POST

Constante

public static const POST:String = "POST"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9, Flash Lite 4

Geeft aan dat het URLRequest-object POST is.

Opmerking: Wanneer voor inhoud die wordt uitgevoerd in Adobe AIR de functie navigateToURL() wordt gebruikt, behandelt de runtime een URLRequest dat de methode POST gebruikt (een methode waarvan de eigenschap method is ingesteld op URLRequestMethod.POST ) alsof de methode GET wordt gebruikt.

PUT

Constante

public static const PUT:String = "PUT"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0

Geeft aan dat het URLRequest-object PUT is.

Voorbeelden Hoe dit voorbeeld te gebruiken

URLRequestMethodExample.as

In het volgende voorbeeld worden de gegevens uit een lokaal tekstbestand geladen en weergegeven. Tevens wordt informatie over gebeurtenisafhandeling getraceerd.

Opmerking: wanneer u dit voorbeeld wilt uitvoeren, plaatst u een bestand met de naam example.txt in dezelfde map als het SWF-bestand. Dit bestand moet een eenvoudig tekstbestand met enkele woorden of regels tekst zijn.

De voorbeeldcode doet het volgende:

De constructorfunctie maakt een instantie URLLoader genaamd loader.
Het object loader wordt aan de methode configureListeners() doorgegeven, die listeners toevoegt voor elk van de ondersteunde gebeurtenissen URLLoader.
Er wordt een instantie URLRequest genaamd request gemaakt die de naam opgeeft van het bestand dat moet worden geladen.
De eigenschap method van de aanvraag wordt op URLRequestMethod.POST ingesteld.
Het object request wordt vervolgens aan loader.load() doorgegeven, waarna het tekstbestand wordt geladen.
Nadat URLLoader het tekstbestand heeft geladen, wordt de gebeurtenis Event.COMPLETE geactiveerd die de methode completeHandler() activeert. De methode completeHandler() traceert eenvoudig de eigenschap data, de inhoud van het tekstbestand.



package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestMethodExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestMethodExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("example.txt");
            
            request.method = URLRequestMethod.POST;
            loader.load(request);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}

Juridische kennisgeving | Online privacybeleid

URLRequestMethod - AS3

Klassen x

DELETE

GET

HEAD

OPTIONS

POST

PUT