URLLoader  - AS3

Geeft het aantal bytes aan dat tot nu toe tijdens de laadbewerking is geladen.

Geeft het totale aantal bytes in de gedownloade gegevens aan. Deze eigenschap bevat 0 terwijl de laadbewerking in voortgang is en wordt gevuld wanneer de bewerking is voltooid. Wanneer de header Content-Length ontbreekt, is de waarde van de eigenschap bytesTotal onbepaald.

De gegevens die via de laadbewerking zijn ontvangen. Deze eigenschap wordt alleen gevuld wanneer de laadbewerking is voltooid. De indeling van de gegevens hangt af van de instelling van de eigenschap dataFormat.

Wanneer de eigenschap dataFormat op URLLoaderDataFormat.TEXT is ingesteld, zijn de ontvangen gegevens een tekenreeks met de tekst van het geladen bestand.

Wanneer de eigenschap dataFormat op URLLoaderDataFormat.BINARY is ingesteld, zijn de ontvangen gegevens een object ByteArray met de onbewerkte binaire gegevens.

Wanneer de eigenschap dataFormat op URLLoaderDataFormat.VARIABLES is ingesteld, zijn de ontvangen gegevens een object URLVariables met de URL-gecodeerde variabelen.

Verwante API-elementen

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

Hiermee wordt bepaald of de gedownloade gegevens zijn ontvangen als tekst (URLLoaderDataFormat.TEXT), als onbewerkte binaire gegevens (URLLoaderDataFormat.BINARY) of als URL-gecodeerde variabelen (URLLoaderDataFormat.VARIABLES).

Wanneer de eigenschap dataFormat de waarde URLLoaderDataFormat.TEXT heeft, zijn de ontvangen gegevens een tekenreeks met de tekst van het geladen bestand.

Wanneer de eigenschap dataFormat de waarde URLLoaderDataFormat.BINARY heeft, zijn de ontvangen gegevens een object ByteArray met de onbewerkte binaire gegevens.

Wanneer de eigenschap dataFormat de waarde URLLoaderDataFormat.VARIABLES heeft, zijn de ontvangen gegevens een object URLVariables met de URL-gecodeerde variabelen.

De standaardwaarde is URLLoaderDataFormat.TEXT.

Verwante API-elementen

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Maakt een object URLLoader.

Verwante API-elementen

Registreert een gebeurtenislistenerobject bij een object EventDispatcher, zodat de listener een melding van een gebeurtenis ontvangt. U kunt gebeurtenislisteners registreren op alle knooppunten in het weergaveoverzicht van een specifiek type gebeurtenis, fase of prioriteit.

Nadat het registreren van een gebeurtenislistener is voltooid, kunt u de prioriteit ervan niet wijzigen door extra aanroepen van addEventListener(). Wanneer u de prioriteit van een listener wilt wijzigen, moet u eerst removeListener() aanroepen. U kunt de listener opnieuw registreren met het nieuwe prioriteitsniveau.

Nadat de listener is geregistreerd, resulteren volgende aanroepen van addEventListener() met een andere waarde voor type of useCapture in het maken van een afzonderlijke listenerregistratie. Wanneer u bijvoorbeeld eerst een listener registreert bij useCapture ingesteld op true, luistert deze alleen tijdens de vastlegfase. Wanneer u addEventListener() opnieuw aanroept met hetzelfde listenerobject maar met useCapture ingesteld op false, hebt u twee afzonderlijke listeners: één die tijdens de vastlegfase luistert en één die tijdens de doel- en terugkoppelfasen luistert.

U kunt geen gebeurtenislistener registeren voor alleen de doel- of terugkoppelfase. Deze fasen worden bij de registratie gekoppeld, omdat terugkoppeling alleen van toepassing is op voorouders van het doelknooppunt.

Wanneer u een gebeurtenislistener niet langer nodig hebt, kunt u deze verwijderen door removeEventListener() aan te roepen; anders kan dit resulteren in geheugenproblemen. Gebeurtenisluisteraars worden niet automatisch uit het geheugen verwijderd, omdat de verzamelaar met ongewenste details de luisteraar niet verwijderd zolang het verzendende object bestaat (behalve als de parameter useWeakReference op true is ingesteld).

Het kopiëren van een instantie EventDispatcher kopieert de daaraan gekoppelde gebeurtenislisteners. (Wanneer uw nieuwe knooppunt een gebeurtenislistener nodig heeft, moet u de listener eraan koppelen na het maken van het knooppunt.) Wanneer u echter een instantie EventDispatcher verplaatst, worden de daaraan gekoppelde listeners mee verplaatst.

Wanneer de gebeurtenislistener wordt geregistreerd op een knooppunt terwijl een gebeurtenis op dit knooppunt wordt verwerkt, wordt de gebeurtenislistener niet geactiveerd tijdens de huidige fase maar kan wel worden geactiveerd in een latere fase in de gebeurtenisstroom, zoals de terugkoppelfase.

Wanneer een gebeurtenislistener wordt verwijderd uit een knooppunt terwijl een gebeurtenis wordt verwerkt op het knooppunt, wordt deze nog steeds geactiveerd door de huidige handelingen. Nadat deze is verwijderd, wordt de gebeurtenislistener niet meer aangeroepen (tenzij deze opnieuw wordt geregistreerd voor toekomstige verwerking).

Parameters

function(evt:Event):void

Sluit de laadbewerking die wordt uitgevoerd. Een eventuele laadbewerking die wordt uitgevoerd, wordt direct beëindigd. Wanneer momenteel geen URL wordt gestreamd, wordt een fout met betrekking tot een ongeldige stream gegenereerd.

Verzendt en laadt gegevens via de opgegeven URL. De gegevens kunnen worden ontvangen als tekst, onbewerkte binaire gegevens of URL-gecodeerde variabelen, afhankelijk van de waarde die u voor de eigenschap dataFormat instelt. De standaardwaarde van de eigenschap dataFormat is tekst. Wanneer u gegevens naar de opgegeven URL wilt verzenden, kunt u de eigenschap data in het object URLRequest instellen.

Opmerking: wanneer een bestand dat wordt geladen niet-ASCII-tekens bevat (zoals in vele niet-Engelse talen), wordt geadviseerd het bestand met UTF-8- of UTF-16-codering op te slaan in plaats van een niet-Unicode-indeling zoals ASCII.

Een SWF-bestand in de sandbox Lokaal-met-bestandssysteem kan geen gegevens laden naar een bron in de netwerksandbox of deze bron van gegevens voorzien.

Standaard moeten het aanroepende SWF-bestand en de URL die u laadt zich in exact hetzelfde domein bevinden. Een SWF-bestand op www.adobe.com kan bijvoorbeeld alleen gegevens laden van bronnen die zelf ook aanwezig zijn op www.adobe.com. Wanneer u gegevens van een ander domein wilt laden, plaatst u een bestand met URL-beleid op de server die als host fungeert voor de gegevens.

U kunt geen verbinding maken met algemeen gereserveerde poorten. Zie "Netwerk-API's beperken" in de Adobe ActionScript 3.0-ontwikkelaarsgids voor een volledige lijst van geblokkeerde poorten.

Als u in Flash Player 10 en hoger een multipart-inhoudstype gebruikt (bijvoorbeeld 'multipart/form-data') dat een upload bevat (aangegeven met de parameter 'bestandsnaam' in een header 'content-disposition' binnen de POST-body), gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads:

• De POST-bewerking moet worden uitgevoerd in reactie op een door de gebruiker geïnitieerde actie, zoals het klikken met de muis of het indrukken van een toets.
• Als bij de POST-bewerking verschillende domeinen betrokken zijn (het doel van de POST-bewerking bevindt zich niet op dezelfde server als het SWF-bestand dat de POST-aanvraag verstuurt), moet de doelserver een URL-beleidsbestand leveren dat interdomeintoegang toestaat.

In het geval van een multipart-inhoudstype is het ook essentieel dat de syntaxis juist is (in overeenstemming met de norm RFC2046). Als de syntaxis ongeldig lijkt te zijn, gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads.

Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

Parameters

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Wordt verzonden nadat alle ontvangen gegevens zijn gedecodeerd en in de gegevenseigenschap van het object URLLoader zijn geplaatst. De ontvangen gegevens zijn toegankelijk nadat deze gebeurtenis is verzonden.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden als een aanroep naar de methode load() via HTTP toegang tot gegevens probeert te krijgen, en Adobe AIR de statuscode voor de aanvraag kan detecteren en retourneren.

De constante HTTPStatusEvent.HTTP_RESPONSE_STATUS definieert de waarde van de eigenschap type van een httpResponseStatus-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden als een aanroep naar URLLoader.load() via HTTP toegang probeert te krijgen tot gegevens. Voor inhoud die in Flash Player wordt uitgevoerd, wordt deze gebeurtenis alleen verzonden als de huidige Flash Player-omgeving de statuscode voor de aanvraag kan detecteren en retourneren. (Sommige browseromgevingen kunnen deze informatie mogelijk niet bieden.) De gebeurtenis httpStatus (indien aanwezig) wordt verzonden voor (en als aanvulling op) een eventuele gebeurtenis complete of error.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer een aanroep naar URLLoader.load() resulteert in een fatale fout die de download beëindigt.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer de downloadbewerking begint na een aanroep van de methode URLLoader.load().

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer gegevens tijdens de downloadbewerking worden ontvangen.

Let op dat in het geval van een object URLLoader de gegevens pas toegankelijk zijn nadat alle gegevens volledig zijn ontvangen. ProgressEvent fungeert daarom slechts als melding van de voortgang van de download. Wanneer u toegang wilt tot de gegevens voordat deze volledig zijn gedownload, gebruikt u het object URLStream.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Wordt verzonden wanneer een aanroep naar URLLoader.load() probeert gegevens te laden van een server buiten de beveiligingssandbox. Wordt ook verzonden wanneer een aanroep van URLLoader.load() probeert een SWZ-bestand te laden en het certificaat ongeldig is of de digest-tekenreeks niet overeenkomt met de component.

Deze gebeurtenis heeft de volgende eigenschappen:

Verwante API-elementen

Opmerking: wanneer u dit voorbeeld wilt uitvoeren, plaatst u een bestand genaamd urlLoaderExample.txt in dezelfde map als het SWF-bestand. Dit bestand moet alleen de volgende tekstregel bevatten: answer=42&question=unknown

De voorbeeldcode doet het volgende:

1. De constructorfunctie maakt een instantie URLLoader genaamd loader en een instantie URLRequest genaamd request die de locatie en de naam bevat van het bestand dat moet worden geladen.
2. Het object loader wordt aan de methode configureListeners() doorgegeven, die listeners toevoegt voor elk van de ondersteunde gebeurtenissen URLLoader.
3. Het object request wordt vervolgens aan loader.load() doorgegeven, waarna het tekstbestand wordt geladen.
4. Nadat URLLoader het tekstbestand heeft geladen, wordt de gebeurtenis Event.COMPLETE geactiveerd die de methode completeHandler() activeert. De methode completeHandler() maakt een object URLVariables van de tekst die uit het bestand is geladen. Het object URLVariables zet URL-gecodeerde naam-waardeparen om in ActionScript-eigenschappen, zodat de geladen gegevens gemakkelijker kunnen worden gebruikt.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}