Matrix  - AS3

De waarde die invloed heeft op de plaatsing van de pixels langs de x-as wanneer een afbeelding wordt geschaald of gedraaid.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.a);  // 1

myMatrix.a = 2;
trace(myMatrix.a);  // 2

De waarde die invloed heeft op de plaatsing van de pixels langs de y-as wanneer een afbeelding wordt gedraaid of geschaald.

import flash.geom.Matrix;
 
var myMatrix:Matrix = new Matrix();
trace(myMatrix.b);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.b = Math.tan(radians);
trace(myMatrix.b);  // 0.5773502691896257

De waarde die invloed heeft op de plaatsing van de pixels langs de x-as wanneer een afbeelding wordt gedraaid of geschaald.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.c);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.c = Math.tan(radians);
trace(myMatrix.c);  // 0.5773502691896257

De waarde die invloed heeft op de plaatsing van de pixels langs de y-as wanneer een afbeelding wordt geschaald of gedraaid.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.d);  // 1

myMatrix.d = 2;
trace(myMatrix.d);  // 2

De afstand waarmee elk punt langs de x-as moet worden getransleerd.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.tx);  // 0

myMatrix.tx = 50;  // 50
trace(myMatrix.tx);

De afstand waarmee elk punt langs de y-as moet worden getransleerd.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.ty);  // 0

myMatrix.ty = 50;
trace(myMatrix.ty);  // 50

Maakt een nieuw object Matrix met de opgegeven parameters. In matrixnotatie worden deze eigenschappen als volgt geordend:

Wanneer u geen parameter aan de nieuwe constructor new Matrix() aanbiedt, maakt deze een identiteitsmatrix met de volgende waarden:

a = 1

b = 0

c = 0

d = 1

tx = 0

ty = 0

In matrixnotatie ziet de identiteitsmatrix er als volgt uit:

import flash.geom.Matrix;

var matrix_1:Matrix = new Matrix();
trace(matrix_1);  // (a=1, b=0, c=0, d=1, tx=0, ty=0)

var matrix_2:Matrix = new Matrix(1, 2, 3, 4, 5, 6);
trace(matrix_2);  // (a=1, b=2, c=3, d=4, tx=5, ty=6)

Retourneert een nieuw object Matrix dat een kloon van deze matrix is, met een exacte kopie van het object dat de matrix bevat.

Hiermee wordt de matrix met de huidige matrix samengevoegd, zodat de geometrische effecten van de twee matrices worden gecombineerd. In wiskundige termen is het samenvoegen van twee matrices hetzelfde als twee matrices via een matrixvermenigvuldiging combineren.

Wanneer de matrix m1 bijvoorbeeld een object met factor vier schaalt en matrix m2 een object met 1,5707963267949 radialen roteert (Math.PI/2), transformeert m1.concat(m2) m1 in een matrix die een object met factor vier schaalt en het object met Math.PI/2 radialen roteert.

Deze methode vervangt de bronmatrix met de samengevoegde matrix. Wanneer u twee matrices wilt samenvoegen zonder beide bronmatrices te wijzigen, kunt u eerst de bronmatrix kopiëren met de methode clone(), zoals in de voorbeeldsectie voor de klassen wordt getoond.

Parameters

Hiermee wordt een Vector3D-object naar een specifieke kolom van het aanroepende Matrix3D-object gekopieerd.

Parameters

Hiermee wordt een specifieke kolom van het aanroepende Matrix-object naar het Vector3D-object gekopieerd. Het w-element van het Vector3D-object wordt niet gewijzigd.

Parameters

Hiermee worden alle matrixgegevens van het Point-bronobject naar het aanroepende Matrix-object gekopieerd.

Parameters

Hiermee wordt een Vector3D-object naar een specifieke rij van het aanroepende Matrix-object gekopieerd.

Parameters

Hiermee wordt een specifieke rij van het aanroepende Matrix-object naar het Vector3D-object gekopieerd. Het w-element van het Vector3D-object wordt niet gewijzigd.

Parameters

Omvat parameters voor schalen, roteren en transleren. Bij toepassing op een matrix worden de waarden van de matrix gebaseerd op die parameters.

Via de methode createBox() kunt u dezelfde matrix verkrijgen als wanneer u achtereenvolgens de methoden identity(), rotate(), scale() en translate() zou toepassen. mat1.createBox(2,2, Math.PI/4, 100, 100) heeft bijvoorbeeld hetzelfde effect als de volgende code:

     import flash.geom.Matrix;
     
     var mat1:Matrix = new Matrix();
     mat1.identity();
     mat1.rotate(Math.PI/4);
     mat1.scale(2,2);
     mat1.translate(10,20);
     

Parameters

Verwante API-elementen

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_createBox extends Sprite
    {
        public function Matrix_createBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createBox(1, 2, Math.PI/4, 50, 100);
             trace(myMatrix.toString());  
             // (a=0.7071067811865476, b=1.414213562373095, c=-0.7071067811865475, 
             //  d=1.4142135623730951, tx=50, ty=100)
             
             var rectangleShape:Shape = createRectangle(20, 80, 0xFF0000);   
             addChild(rectangleShape);
              
             var rectangleTrans:Transform = new Transform(rectangleShape);
             rectangleTrans.matrix = myMatrix;
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Maakt de specifieke matrixstijl gemaakt die door de methoden beginGradientFill() en lineGradientStyle() van de klasse Graphics wordt verwacht. Breedte en hoogte worden geschaald tot een scaleX / scaleY-paar en de waarden tx / ty worden met de helft van de breedte en hoogte verschoven.

Bekijk bijvoorbeeld een verloop met de volgende kenmerken:

• GradientType.LINEAR
• Twee kleuren, groen en blauw, met de array ratios ingesteld op [0, 255]
• SpreadMethod.PAD
• InterpolationMethod.LINEAR_RGB

De volgende afbeeldingen tonen verlopen waarin de matrix is gedefinieerd met de methode createGradientBox() met verschillende parameterinstellingen:

createGradientBox()-instellingen	Resulterend verloop
width = 25; height = 25; rotation = 0; tx = 0; ty = 0;
width = 25; height = 25; rotation = 0; tx = 25; ty = 0;
width = 50; height = 50; rotation = 0; tx = 0; ty = 0;
width = 50; height = 50; rotation = Math.PI / 4; // 45 degrees tx = 0; ty = 0;

Parameters

Verwante API-elementen

package
{
    import flash.display.GradientType;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    
    public class Matrix_createGradientBox extends Sprite
    {
        public function Matrix_createGradientBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());          // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createGradientBox(200, 200, 0, 50, 50);
             trace(myMatrix.toString());          // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)
             
             var colors:Array = [0xFF0000, 0x0000FF];
             var alphas:Array = [100, 100];
             var ratios:Array = [0, 0xFF];
             
             this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
             this.graphics.drawRect(0, 0, 300, 200);
        }
    }
}

Wanneer een punt is opgegeven in de coördinaatruimte voorafgaand aan transformatie, worden de coördinaten van dat punt geretourneerd nadat de transformatie is uitgevoerd. In tegenstelling tot de standaardtransformatie die met de methode transformPoint() wordt toegepast, wordt bij de transformatie met de methode deltaTransformPoint() geen rekening gehouden met de translatieparameters tx en ty.

Parameters

Stelt elke matrixeigenschap in op een waarde die een nultransformatie tot gevolg heeft. Een object dat is getransformeerd door een identiteitsmatrix is identiek aan het origineel.

Nadat de methode identity() is aangeroepen, heeft de resulterende matrix de volgende eigenschappen: a =1, b =0, c =0, d =1, tx =0 en ty =0.

In matrixnotatie ziet de identiteitsmatrix er als volgt uit:

Voert de tegenovergestelde transformatie van de oorspronkelijke matrix uit. U kunt een omgekeerde matrix op een object toepassen om de uitgevoerde transformatie tijdens het toepassen van de oorspronkelijke matrix ongedaan te maken.

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_invert extends Sprite
    {
        public function Matrix_invert()
        {
            var rect0:Shape = createRectangle(20, 80, 0xFF0000);   
            var rect1:Shape = createRectangle(20, 80, 0x00FF00);   
            var rect2:Shape = createRectangle(20, 80, 0x0000FF);
            var rect3:Shape = createRectangle(20, 80, 0x000000);
            
            var trans0:Transform = new Transform(rect0);
            var trans1:Transform = new Transform(rect1);
            var trans2:Transform = new Transform(rect2);
            var trans3:Transform = new Transform(rect3);
             
            var doubleScaleMatrix:Matrix = new Matrix(2, 0, 0, 2, 0, 0);
            trans0.matrix = doubleScaleMatrix;
            trace(doubleScaleMatrix.toString());  // (a=2, b=0, c=0, d=2, tx=0, ty=0)
             
            var noScaleMatrix:Matrix = new Matrix(1, 0, 0, 1, 0, 0);
            trans1.matrix = noScaleMatrix;
            rect1.x = 50;
            trace(noScaleMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
            var halfScaleMatrix:Matrix = doubleScaleMatrix.clone();
            halfScaleMatrix.invert();
            trans2.matrix = halfScaleMatrix;
            rect2.x = 100;
            trace(halfScaleMatrix.toString());  // (a=0.5, b=0, c=0, d=0.5, tx=0, ty=0)
             
            var originalAndInverseMatrix:Matrix = doubleScaleMatrix.clone();
            originalAndInverseMatrix.concat(halfScaleMatrix);
            trans3.matrix = originalAndInverseMatrix;
            rect3.x = 150;
            trace(originalAndInverseMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)            
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Past een rotatietransformatie op het object Matrix toe.

De methode rotate() wijzigt de eigenschappen a, b, c en d van het object Matrix. In matrixnotatie is dit hetzelfde als het samenvoegen van de huidige matrix met het volgende:

Parameters

Past een schaaltransformatie op de matrix toe. De x-as wordt vermenigvuldigd door sx en de y-as wordt vermenigvuldigd door sy.

De methode scale() wijzigt de eigenschappen a en d van het object Matrix. In matrixnotatie is dit hetzelfde als het samenvoegen van de huidige matrix met de volgende matrix:

Parameters

Hiermee worden de leden van Matrix op de opgegeven waarden ingesteld.

Parameters

Retourneert een tekstwaarde die de eigenschappen van het object Matrix opsomt.

Hiermee wordt het resultaat geretourneerd van het toepassen van de geometrische transformatie die door het object Matrix wordt vertegenwoordigd, op het opgegeven punt.

Parameters

Zet de matrix om langs de x- en y-as, zoals opgegeven door de parameters dx en dy.

Parameters

1. De toepassing maakt een nieuw Matrix-object myMatrix en gebruikt de methode trace() om de standaardeigenschapwaarden voor het object myMatrix als uitvoer te geven.
2. De toepassing roept createGradientBox() aan met de parameters width en height ingesteld op 200 pixels, geen rotatie, en de afstand om te transleren langs de x- en y-as ingesteld op 50 pixels.
3. De toepassing drukt het object myMatrix opnieuw af om de wijziging te laten zien na de aanroep van createGradientBox().
4. De toepassing stelt drie variabelen in om het vullen van het verloopvak te besturen:
   • colors: stelt de verloopkleuren in tussen effen rood en effen blauw.
   • alphas: stelt de dekking in op dekkend.
   • ratios: stelt de distributie van de kleuren gelijk voor zowel rood als blauw.
5. De toepassing roept de grafische methode beginGradientFill() aan, die werkt op het object myMatrix en het roept de methode lineTo() aan, wat resulteert in een verlopend gevuld vak.

package {
    import flash.geom.Matrix;
    import flash.display.Sprite;
    import flash.display.GradientType;

    public class MatrixExample extends Sprite {

        public function MatrixExample() {
            var myMatrix:Matrix = new Matrix();
            trace(myMatrix.toString());    // (a=1, b=0, c=0, d=1, tx=0, ty=0)

            myMatrix.createGradientBox(200, 200, 0, 50, 50);
            trace(myMatrix.toString());    // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)

            var colors:Array = [0xFF0000, 0x0000FF];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 0xFF];
            graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
            graphics.lineTo(0, 300);
            graphics.lineTo(300, 300);
            graphics.lineTo(300, 0);
            graphics.lineTo(0, 0);
        }
    }
}