AccessibilityImplementation  - AS3

Geeft een foutcode aan. Fouten worden out-of-band aangegeven in plaats van in geretourneerde waarden. Als u een fout wilt aangeven, stelt u de eigenschap errno in op een van de foutcodes die worden beschreven in de bijlage AccessibilityImplementation-constanten. Op die manier wordt de geretourneerde waarde genegeerd. De eigenschap errno van de AccessibilityImplementation wordt altijd door de speler gewist (ingesteld op nul) voordat een AccessibilityImplementation-methode wordt aangeroepen.

Verwante API-elementen

Wordt gebruikt om een componenttoegankelijkheidssectie te maken. Als een component wordt vrijgegeven zonder een ActionScript-toegankelijkheidsimplementatie, raadt Adobe u aan een componenttoegankelijkheidssectie toe te voegen. Dankzij deze sectie behandelt Flash Player de component, voor toegankelijkheidsdoeleinden, als eenvoudige afbeelding en wordt dus niet de interne structuur van knoppen, tekstvelden enzovoort binnen de component getoond.

Als u een componenttoegankelijkheidssectie wilt maken, maakt u een subklasse van de relevante AccImpl-klasse, waarbij u de stub-eigenschap met de waarde true overschrijft.

Verwante API-elementen

Statische constructor. Instantieer AccessibilityImplementation niet rechtstreeks door de bijbehorende constructor aan te roepen. Maak in plaats daarvan nieuwe toegankelijkheidsimplementaties door de klasse mx.accessibility.AccImpl voor elke nieuwe component uit te breiden.

Verwante API-elementen

Een IAccessible-methode die de standaardhandeling uitvoert van de component die deze AccessibilityImplementation vertegenwoordigt of van een van de onderliggende elementen.

Implementeer deze methode alleen als de AccessibilityImplementation een gebruikersinterface-element vertegenwoordigt waarvoor een standaardhandeling is opgenomen in het MSAA-model.

Als u accDoDefaultAction() alleen voor de AccessibilityImplementation zelf of alleen voor de onderliggende elementen implementeert, moet u in sommige gevallen aangeven dat er geen standaardhandeling is voor de childID die is doorgegeven. Dit doet u door de eigenschap errno in te stellen op E_MEMBERNOTFOUND.

Parameters

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

MSAA-methode voor het retourneren van een DisplayObject of Rectangle waarmee het selectiekader van een onderliggend element in de AccessibilityImplementation wordt opgegeven.

Deze methode wordt nooit aangeroepen als de childID nul is. Implementeer deze methode niet als in uw AccessibilityImplementation nooit onderliggende elementen worden opgenomen. Als uw AccessibilityImplementation wel onderliggende elementen kan bevatten, is deze methode verplicht.

Meestal kunt u aan de vereisten van deze methode voldoen door een object te retourneren dat het onderliggende element zelf vertegenwoordigt. Het onderliggende element moet dan wel een DisplayObject zijn. Als dit het geval is, kunt u het DisplayObject retourneren dat overeenkomt met de instantienaam voor het relevante visuele object in de weergavelijst.

Als een onderliggend element niet in aanmerking komt voor de hierboven beschreven techniek, kunt u het selectiekader zelf berekenen en een Rectangle retourneren met de volgende eigenschappen: x, y, width en height. Met de leden x en y geeft u de linkerbovenhoek van het selectiekader op; met de leden width en height geeft u de grootte van het selectiekader op. Geef deze vier leden op in pixels in het werkgebied, en relatief ten opzichte van de oorsprong van de component die de AccessibilityImplementation vertegenwoordigt. De eigenschappen x en y kunnen negatieve waarden hebben, aangezien de oorsprong van een DisplayObject niet altijd in de linkerbovenhoek ligt.

Als het onderliggende element dat is opgegeven door childID niet zichtbaar is (get_accState zou voor dit element dus een waarde met STATE_SYSTEM_INVISIBLE retourneren), kunt u null van accLocation retourneren. U kunt ook een Rectangle retourneren die de coördinaten van het onderliggende element weergeeft als het wel zichtbaar was geweest.

Parameters

Meer informatie

Verwante API-elementen

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

IAccessible-methode voor het wijzigen van de selectie in de component die deze AccessibilityImplementation vertegenwoordigt.

De parameter childID is nooit nul. Deze methode wordt altijd voor een onderliggend element gebruikt en niet voor de algehele component; Flash Player verzorgt de selectie van de algehele component.

De parameter selFlag is een bitveld dat uit een of meer constanten voor selectiemarkering bestaat. Hiermee kan een MSAA-client aangeven hoe het item waarnaar wordt verwezen door de childID moet worden geselecteerd of focus krijgt. Hierna volgen beschrijvingen van de constanten voor selectiemarkering en hun betekenis voor de toegankelijkheidsimplementatie. Het komt er in de praktijk op neer dat de meeste implementaties van deze methode in toegankelijkheidsimplementaties die overerven van de klasse mx.accessibility.ListBaseAccImpl in Flex de constante selFlag negeren. In plaats daarvan baseren ze zich voor meervoudige selectie op het toetsenbordselectiegedrag van de component.

De parameter selFlag kan wel of niet de markering SELFLAG_TAKEFOCUS bevatten. Als deze markering aanwezig is, moet u de onderliggende focus instellen op de opgegeven childID en, tenzij SELFLAG_EXTENDSELECTION ook aanwezig is, het betreffende onderliggende element het selectieanker maken. In het andere geval moeten de onderliggende focus en het selectieanker ongewijzigd blijven, ondanks het feit dat aanvullende, hieronder beschreven markeringen de selectie kunnen wijzigen.

Het argument selFlag bevat altijd een van de volgende vier markeringen. Deze geven aan welke selectiewijziging gewenst is:

• SELFLAG_TAKESELECTION: wis de bestaande selectie (indien aanwezig) en stel de selectie in op de opgegeven childID.

• SELFLAG_EXTENDSELECTION: bereken het bereik van onderliggende elementen tussen en inclusief het selectieanker en de opgegeven childID. Als SELFLAG_ADDSELECTION aanwezig is: voeg al deze onderliggende elementen aan de selectie toe. Als SELFLAG_REMOVESELECTION aanwezig is: verwijder al deze onderliggende elementen uit de selectie. Als noch SELFLAG_ADDSELECTION noch SELFLAG_REMOVESELECTION aanwezig is, moeten al deze onderliggende elementen de selectiestatus van het selectieanker krijgen. Als het selectieanker is geselecteerd: voeg deze onderliggende elementen aan de selectie toe. Als het selectieanker niet is geselecteerd: verwijder deze onderliggende elementen uit de selectie.

• SELFLAG_ADDSELECTION (zonder SELFLAG_EXTENDSELECTION): voeg de opgegeven childID aan de selectie toe.

• SELFLAG_REMOVESELECTION (zonder SELFLAG_EXTENDSELECTION): verwijder de opgegeven childID uit de selectie.

Voor een component waarvoor meervoudige selectie niet mogelijk is, zijn de enige geldige selFlag-parameterwaarden SELFLAG_TAKEFOCUS en SELFLAG_TAKESELECTION. U kunt er in theorie ook voor kiezen SELFLAG_REMOVESELECTION te ondersteunen voor een component zonder meervoudige selectie. De gebruiker zou dan een null-selectie kunnen afdwingen. De meeste componenten zonder meervoudige selectie werken echter niet op deze manier. Bovendien wordt in MSAA-clients mogelijk aan dit type bewerking voorbij gegaan.

Als u markeringen tegenkomt die ongeldig lijken, stelt u errno in op E_INVALIDARG.

Wanneer accSelect wordt aangeroepen, zorgt Flash Player ervoor dat het hostfocus krijgt (de vensterfocus van de bijbehorende containertoepassing) en dat uw component focus krijgt binnen Flash Player.

Parameters

Meer informatie

Verwante API-elementen

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

MSAA-methode voor het retourneren van de standaardhandeling van de component die deze AccessibilityImplementation vertegenwoordigt of van een van de onderliggende elementen.

Implementeer deze methode alleen als de AccessibilityImplementation een gebruikersinterface-element vertegenwoordigt waarvoor een standaardhandeling is opgenomen in het MSAA-model; retourneer de exacte tekenreeks die het MSAA-model opgeeft. De tekenreeks van de standaardhandeling voor een Button-component is bijvoorbeeld "Press".

Als u get_accDefaultAction alleen voor de AccessibilityImplementation zelf of alleen voor de onderliggende elementen implementeert, moet u in sommige gevallen aangeven dat er geen standaardhandeling is voor de childID die is doorgegeven. Dit doet u door null te retourneren.

Parameters

Meer informatie

Verwante API-elementen

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

MSAA-methode voor het retourneren van de id van een geheel getal zonder teken van het onderliggende element (indien aanwezig) dat een onderliggende focus in de component bevat. Als geen enkel onderliggend element een onderliggende focus heeft, retourneert de methode nul.

Meer informatie

Verwante API-elementen

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

MSAA-methode voor het retourneren van de naam voor de component die deze AccessibilityImplementation vertegenwoordigt of voor een van de onderliggende elementen.

Als het de AccessibilityImplementation zelf betreft (childID == 0) en deze methode niet is geïmplementeerd of geen waarde retourneert, gebruikt Flash Player de eigenschapswaarde AccessibilityProperties.name (indien aanwezig).

Voor AccessibilityImplementations die onderliggende elementen kunnen bevatten, moet deze methode worden geïmplementeerd, en een tekenreekswaarde retourneren als childID niet nul is.

Afhankelijk van het type gebruikersinterface-element hebben namen in MSAA een van de volgende twee betekenissen: een door de schrijver toegewezen naam of de tekstinhoud van het element. Meestal valt een AccessibilityImplementation zelf in de eerste categorie. De bijbehorende name-eigenschap is een door de schrijver toegewezen naam. Onderliggende elementen vallen altijd in de tweede categorie. Hun namen duiden hun tekstinhoud aan.

Als de eigenschap name van een AccessibilityImplementation een door de schrijver toegewezen naam aanduidt, zijn er twee manieren waarop componenten namen van schrijvers kunnen verkrijgen. Bij de eerste manier gaat het om namen in de component zelf; een CheckBox-component kan bijvoorbeeld een tekstlabel bevatten dat als naam dient. Bij de tweede manier - een fallback van de eerste - gaat het om namen die zijn opgegeven in de gebruikersinterface en die terechtkomen in AccessibilityProperties.name. Dankzij deze fallbackoptie kunnen gebruikers namen op dezelfde manier opgeven als voor elke andere Sprite of MovieClip.

Er blijven nu drie mogelijkheden over voor de AccessibilityImplementation zelf (childID == zero):

• Door schrijver toegewezen naam binnen component. De methode get_accName moet worden geïmplementeerd en een tekenreekswaarde retourneren met de naam van de AccessibilityImplementation als childID nul is. Als childID nul is maar de AccessibilityImplementation geen naam heeft, moet get_accName een lege tekenreeks retourneren om te voorkomen dat de speler terugvalt op de eigenschap AccessibilityProperties.name.

• Door schrijver toegewezen naam vanuit UI. Als de AccessibilityImplementation onderliggende elementen kan bevatten, moet de methode get_accName worden geïmplementeerd. Deze mag echter geen waarde retourneren als childID nul is. Implementeer get_accName niet als de AccessibilityImplementation geen onderliggende elementen kan bevatten.

• Naam die inhoud aanduidt. De methode get_accName moet worden geïmplementeerd en een relevante tekenreekswaarde retourneren als childID nul is. Als childID nul is maar de AccessibilityImplementation geen inhoud heeft, moet get_accName een lege tekenreeks retourneren om te voorkomen dat de speler terugvalt op de eigenschap AccessibilityProperties.name.

Voor onderliggende elementen (als de AccessibilityImplementation deze kan bevatten), geldt altijd het derde geval. De methode get_accName moet worden geïmplementeerd en een relevante tekenreekswaarde retourneren als childID niet nul is.

Parameters

Meer informatie

Verwante API-elementen

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

MSAA-methode voor het retourneren van de systeemrol voor de component die deze AccessibilityImplementation vertegenwoordigt of voor een van de onderliggende elementen. Systeemrollen zijn vooraf gedefinieerd voor alle componenten in MSAA.

Parameters

Meer informatie

Verwante API-elementen

MSAA-methode voor het retourneren van een array die de id’s bevat van alle onderliggende elementen die zijn geselecteerd. De geretourneerde array kan nul, één of meer id's bevatten, alle gehele getallen zonder teken.

Meer informatie

Verwante API-elementen

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

IAccessible-methode voor het retourneren van de huidige runtimestatus van de component die deze AccessibilityImplementation vertegenwoordigt of van een van de onderliggende elementen.

Deze methode moet een combinatie van nul, één of meer vooraf gedefinieerde objectstatusconstanten voor componenten in MSAA retourneren. Als meer dan één status van toepassing is, moeten de statusconstanten worden gecombineerd in een bitveld met |, de bitsgewijze operator OR.

Om aan te geven dat geen van de statusconstanten op dit moment van toepassing is, moet deze methode nul retourneren.

Als het goed is, hoeft u de statussen STATE_SYSTEM_FOCUSABLE en STATE_SYSTEM_FOCUSED niet te volgen of rapporteren. Flash Player verwerkt deze statussen automatisch.

Parameters

Meer informatie

Verwante API-elementen

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

MSAA-methode voor het retourneren van de runtimewaarde van de component die deze AccessibilityImplementation vertegenwoordigt of van een van de onderliggende elementen.

Implementeer deze methode alleen als de AccessibilityImplementation een gebruikersinterface-element vertegenwoordigt waarvoor een waarde is opgenomen in het MSAA-model. Houd er rekening mee dat sommige gebruikersinterface-elementen die een 'waarde' hebben, deze waarde op verschillende manieren kunnen tonen, zoals get_accName (tekst bijvoorbeeld), get_accState (selectievakjes bijvoorbeeld) of get_accSelection (keuzelijsten bijvoorbeeld).

Als u get_accValue alleen voor de AccessibilityImplementation zelf of alleen voor de onderliggende elementen implementeert, moet u in sommige gevallen aangeven dat er geen concept van waarde is voor de childID die is doorgegeven. Dit doet u door null te retourneren.

Parameters

Meer informatie

Verwante API-elementen

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

Retourneert een array die de id’s van gehele getallen zonder teken van alle onderliggende elementen in de AccessibilityImplementation bevat.

De lengte van de array kan nul zijn. De id's in de array moeten in dezelfde logische volgorde worden weergegeven als de onderliggende elementen die ze vertegenwoordigen. Als uw AccessibilityImplementation onderliggende elementen kan bevatten, is deze methode verplicht. Als dat niet het geval is, implementeert u deze methode niet.

Zorg er bij het toewijzen van id's aan onderliggende elementen voor dat deze voor elke instantie van uw AccessibilityImplementation uniek zijn. Id's van onderliggende elementen hoeven niet opeenvolgend te zijn en hun volgorde hoeft niet overeen te komen met de logische volgorde van de onderliggende elementen. Zorg ervoor dat u id's voor onderliggende elementen niet opnieuw gebruikt; als een onderliggend element wordt verwijderd, mag de bijbehorende id tijdens de levensduur van de betreffende AccessibilityImplementation-instantie niet nog een keer worden gebruikt. Vanwege implementatiekeuzes in de Flash-spelercode kan ongewenst gedrag optreden als u meer dan een miljoen id's voor onderliggende elementen gebruikt.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Retourneert true of false om aan te geven of een tekstobject waarvoor een selectiekader is opgegeven met x, y, width en height als label moet worden beschouwd voor de component die deze AccessibilityImplementation vertegenwoordigt.

De x-coördinaat en de y-coördinaat zijn relatief ten opzichte van de linkerbovenhoek van de component waarop de AccessibilityImplementation van toepassing is en kunnen negatief zijn. Alle coördinaten worden opgegeven in pixels in het werkgebied.

Met deze methode worden toegankelijke componenten meegenomen als in Flash Player wordt gezocht naar relaties in automatische labeling, waarmee de naam van een object kan worden opgehaald uit tekst buiten het object. Deze methode is opgenomen omdat de criteria voor het herkennen van labels naar verwachting van component tot component verschillen. Als u deze methode implementeert, kunt u het beste geometrische criteria gebruiken die vergelijkbaar zijn met de criteria die in de spelercode voor knoppen en tekstvelden worden gebruikt. Het gaat hierbij om de volgende criteria:

• Voor knoppen: alle tekst die volledig binnen de knop valt, wordt beschouwd als label.
• Voor tekstvelden: alle tekst dichtbij aan de bovenkant en links uitgelijnd, of dichtbij aan de linkerkant, wordt beschouwd als label.

Als u de component die de AccessibilityImplementation vertegenwoordigt niet wilt opnemen in automatische-labelingrelaties, implementeert u isLabeledBy niet. Dit komt op hetzelfde neer als altijd false retourneren. isLabeledBy mag niet worden geïmplementeerd als de AccessibilityImplementation in de categorie "door schrijver toegewezen naam binnen component" valt die hierboven bij get_accName is beschreven.

Deze methode is niet gebaseerd op een IAccessible-methode; het is een specifieke Flash-methode.

Parameters