MovieClip  - AS3

Hiermee wordt het nummer van het frame waarin de afspeelkop zich bevindt op de tijdlijn van de instantie MovieClip opgegeven. Wanneer de filmclip meerdere scènes heeft, is deze waarde het framenummer in de huidige scène.

mc1.gotoAndStop(mc1.currentFrame + 5);

De label van het huidige frame in de tijdlijn van de MovieClip-instantie. Als het huidige frame geen label heeft, is currentLabel null.

De huidige label waarin de afspeelkop zich op de tijdlijn van de instantie MovieClip bevindt. Wanneer het huidige frame geen label heeft, wordt currentLabel ingesteld op de naam van het vorige frame dat een label bevat. Wanneer het huidige frame en vorige frames geen label bevatten, retourneert currentLabel null.

trace(mc1.currentLabel);

Retourneert een array van objecten FrameLabel vanuit de huidige scène. Wanneer de instantie MovieClip geen scènes gebruikt, bevat de array alle framelabels van de gehele MovieClip-instantie.

Verwante API-elementen

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

De huidige scène waarin de afspeelkop zich op de tijdlijn van de instantie MovieClip bevindt.

Verwante API-elementen

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Een Booleaanse waarde die aangeeft of een filmclip is ingeschakeld. De standaardwaarde van enabled is true. Wanneer enabled op false is ingesteld, worden de frames Over, Down en Up van de filmclip uitgeschakeld. De filmclip blijft gebeurtenissen ontvangen (zoals mouseDown, mouseUp, keyDown en keyUp).

De eigenschap enabled is alleen van toepassing op de knopachtige eigenschappen van een filmclip. U kunt de eigenschap enabled altijd wijzigen. De gewijzigde filmclip wordt in dat geval onmiddellijk in- of uitgeschakeld. Wanneer enabled op false is ingesteld, wordt het object niet in de automatische tabvolgorde opgenomen.

mc1.enabled = false;

Het aantal frames dat vanuit een gestreamd SWF-bestand is geladen. U kunt de eigenschap framesLoaded gebruiken om te bepalen of de inhoud van een bepaald frame, en alle frames daarvoor, wordt geladen en lokaal beschikbaar is in de browser. Daarnaast kunt u deze eigenschap gebruiken voor het controleren van downloads van grote SWF-bestanden. U kunt bijvoorbeeld voor gebruikers een bericht weergeven dat het SWF-bestand wordt geladen, totdat een opgegeven frame in het bestand is geladen.

Wanneer de filmclip meerdere scènes bevat, retourneert de eigenschap framesLoaded het aantal frames dat voor alle scènes in de filmclip is geladen.

Verwante API-elementen

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Een Booleaanse waarde die aangeeft of een filmclip momenteel wordt afgespeeld.

Een array van objecten Scene, elk met de naam, het aantal frames en de framelabels voor een scène in de instantie MovieClip.

Verwante API-elementen

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

Het totaal aantal frames in de instantie MovieClip.

Wanneer de filmclip meerdere frames bevat, retourneert de eigenschap totalFrames het totaal aantal frames in alle scènes in de filmclip.

 trace(mc1.totalFrames);

Hiermee wordt aangegeven of andere weergaveobjecten die objecten SimpleButton of MovieClip zijn, releasegebeurtenissen van de muis of van gebruikersinvoer kunnen ontvangen. Met de eigenschap trackAsMenu kunt u menu's maken. U kunt de eigenschap trackAsMenu voor elk object SimpleButton of MovieClip instellen. De standaardwaarde van de eigenschap trackAsMenu is false.

U kunt de eigenschap trackAsMenu altijd wijzigen; de aangepaste filmclip gebruikt direct het nieuwe gedrag.

 mc1.trackAsMenu = true;

Maakt een nieuwe instantie MovieClip. Nadat de MovieClip is gemaakt, roept u de methode addChild() of addChildAt() aan van een weergaveobjectcontainer in het werkgebied.

Speelt het SWF-bestand vanaf het opgegeven frame af. Dit gebeurt nadat alle resterende handelingen in het frame zijn uitgevoerd. Wanneer u zowel een scène als een frame wilt opgeven, geeft u een waarde op voor de parameter scene.

Parameters

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Verplaatst de afspeelkop naar het opgegeven frame van de filmclip en stopt deze daar. Dit gebeurt nadat alle resterende handelingen in het frame zijn uitgevoerd. Geef een parameter scene op om naast een frame ook een scène op te geven.

Parameters

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Verplaatst de afspeelkop naar het volgende frame en stopt deze. Dit gebeurt nadat alle resterende handelingen in het frame zijn uitgevoerd.

Verwante API-elementen

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Hiermee wordt de afspeelkop naar de volgende scène van de instantie MovieClip verplaatst. Dit gebeurt nadat alle resterende handelingen in het frame zijn uitgevoerd.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Verplaatst de afspeelkop in de tijdlijn van de filmclip.

Verwante API-elementen

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Verplaatst de afspeelkop naar het vorige frame en stopt deze. Dit gebeurt nadat alle resterende handelingen in het frame zijn uitgevoerd.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Hiermee wordt de afspeelkop naar de vorige scène van de instantie MovieClip verplaatst. Dit gebeurt nadat alle resterende handelingen in het frame zijn uitgevoerd.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Stopt de afspeelkop in de filmclip.

1. De constructorfunctie definieert een tekstveld dat wordt gebruikt om waarden weer te geven van eigenschappen van het object MovieClipExample (dat MovieClip uitbreidt).
2. De geretourneerde waarde van de methode getPropertiesString() wordt gebruikt als tekst voor het tekstveld outputText. De methode getPropertiesString() retourneert een tekenreeks die wordt gevuld met waarden van de volgende eigenschappen van de filmclip: currentFrame, currentLabel, currentScene, framesLoaded, totalFrames en trackAsMenu.
3. De twee regels code in de constructorfunctie passen de eigenschappen width en height van het tekstveld outputText aan.
4. De laatste regel van de constructorfunctie voegt het tekstveld outputText toe aan het weergaveoverzicht.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}