Loader  - AS3

Bevat het hoofdweergaveobject van het SWF-bestand of afbeeldingsbestand (JPG, PNG of GIF) dat is geladen met de methoden load() of loadBytes().

Verwante API-elementen

Retourneert een object LoaderInfo dat overeenkomt met het object dat wordt geladen. Objecten LoaderInfo worden tussen het object Loader en het geladen inhoudsobject gedeeld. Het object LoaderInfo geeft informatie over de laadvoortgang en statistieken over het geladen bestand.

Gebeurtenissen met betrekking tot de laadbewerking worden verzonden door het object LoaderInfo waarnaar de eigenschap contentLoaderInfo van het object Loader verwijst. De eigenschap contentLoaderInfo wordt, zelfs voordat de inhoud is geladen, op een geldig object LoaderInfo ingesteld, zodat u gebeurtenislisteners aan het object kunt toevoegen voor de laadbewerking.

Gebruik de Loader.uncaughtErrorEvents-eigenschap, en niet de Loader.contentLoaderInfo.uncaughtErrorEvents-eigenschap, om niet-afgevangen fouten op te sporen die in een geladen SWF plaatsvinden.

Verwante API-elementen

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

Een object dat een uncaughtError-gebeurtenis verstuurt, wanneer er in de SWF een niet-afgehandelde fout plaatsvindt die door dit Loader-object wordt geladen. Er vindt een niet-afgevangen fout plaats wanneer er een fout optreedt buiten een Poging..catch blokkeert of wanneer er een ErrorEvent-object naar niet-geregistreerde listeners wordt verstuurd.

Let op: de uncaughtErrorEvents-eigenschap van een Loader-object verstuurt alleen eraan gekoppelde gebeurtenissen, geen gebeurtenissen die het rechtstreeks verstuurt. Het verstuurt nooit een uncaughtErrorEvent in de doelfase. Deze verstuurt de gebeurtenis alleen in de fasen opnemen en terugkoppelen. Om een niet-afgevangen fout in de huidige SWF (de SWF waarin het Loader-object wordt gedefinieerd) gebruikt u in plaats daarvan de LoaderInfo.uncaughtErrorEvents-eigenschap.

Als de door het Loader-object geladen inhoud een SWF-bestand in AVM1 (ActionScript 2) is, resulteren niet-afgevangen fouten in het SWF-bestand in AVM1 niet in een uncaughtError-gebeurtenis.

Verwante API-elementen

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

Maakt een object Loader dat u kunt gebruiken om bestanden te laden, zoals SWF-, JPEG-, GIF- of PNG-bestanden. Roep de methode load() aan om het element als een onderliggend item van de instantie Loader te laden. Vervolgens kunt u het object Loader aan het weergaveoverzicht toevoegen (bijvoorbeeld met de methode addChild() van een instantie DisplayObjectContainer). Het element wordt tijdens het laden in het werkgebied weergegeven.

U kunt een instantie Loader ook buiten het weergaveoverzicht gebruiken (zonder dat u het aan de weergaveobjectcontainer in het weergaveoverzicht toevoegt). In deze modus kunt u de instantie Loader gebruiken om een SWF-bestand te laden dat aanvullende modules van een toepassing bevat.

Wanneer u wilt detecteren wanneer een SWF-bestand klaar is met laden, kunt u de gebeurtenissen van het object LoaderInfo gebruiken die aan de eigenschap contentLoaderInfo van het object Loader zijn gekoppeld. Op dat punt kan de code in het SWF-modulebestand worden uitgevoerd om de module te starten. In de modus buiten het weergaveoverzicht kan een instantie Loader ook worden gebruikt om een SWF-bestand te laden dat componenten of media-elementen bevat. U kunt de gebeurtenismeldingen van het object LoaderInfo gebruiken om te detecteren wanneer de componenten klaar zijn met laden. De toepassing kan de componenten en media-elementen in de bibliotheek van het SWF-bestand dan gebruiken door de ActionScript 3.0-klassen te instantiëren die deze componenten en elementen vertegenwoordigen.

Wanneer u de status van een object Loader wilt bepalen, controleert u de volgende gebeurtenissen die het object LoaderInfo aan de eigenschap contentLoaderInfo van het object Loader heeft gekoppeld.

• De gebeurtenis open wordt verzonden wanneer het laden wordt gestart.
• De gebeurtenis ioError of securityError wordt verzonden wanneer het bestand niet kan worden geladen of wanneer tijdens het laadproces een fout is opgetreden.
• De gebeurtenis progress wordt continu geactiveerd tijdens het laden van het bestand.
• De gebeurtenis complete wordt verzonden wanneer een bestand volledig is gedownload, maar voordat de methoden en eigenschappen van de geladen filmclip beschikbaar zijn.
• De gebeurtenis init wordt verzonden nadat de eigenschappen en methoden van het geladen SWF-bestand toegankelijk zijn, zodat u kunt beginnen met het manipuleren van het geladen SWF-bestand. Deze gebeurtenis wordt verzonden vóór de handler complete. De gebeurtenis init kan in streaming SWF-bestanden aanzienlijk eerder plaatsvinden dan de gebeurtenis complete. Voor de meeste toepassingen gebruikt u de handler init.

Opmerkingen (alleen iOS): In AIR-toepassingen op iOS kunt u een SWF-bestand dat ActionScript bevat, alleen laden vanaf het toepassingspakket. Deze beperking omvat alle ActionScript, zoals elementen met klassenamen die zijn geëxporteerd voor ActionScript. Als u een SWF-bestand wilt laden, moet u het SWF-bestand laden met hetzelfde toepassingsdomein als het bovenliggende SWF-bestand.

Vóór AIR 3.6 kunnen alleen SWF-bestanden die geen ActionScript-bytecode bevatten, worden geladen, ongeacht of ze werden geladen vanaf het toepassingspakket of via een netwerk. Als alternatief voor het gebruik van een extern SWF-bestand met ActionScript kunt u een SWC-bibliotheek maken en deze koppelen aan uw SWF-hoofdbestand.

Deze beperkingen zijn niet van toepassing wanneer een toepassing wordt uitgevoerd in de iOS-simulator (ipa-test-interpreter-simulator of ipa-debug-interpreter-simulator) of interpretermodus (ipa-test-interpreter of ipa-debug-interpreter).

Verwante API-elementen

Annuleert een bewerking met de methode load() die momenteel wordt uitgevoerd voor de instantie Loader.

Verwante API-elementen

Laadt een SWF-bestand, JPEG-bestand, progressief JPEG-bestand, GIF-bestand zonder animatie of PNG-bestand in een object dat een onderliggend item is van dit object Loader. Wanneer u een GIF-bestand met animatie laadt, wordt alleen het eerste frame weergegeven. Aangezien het object Loader slechts één onderliggend item kan bevatten, wordt bij het verzenden van een volgende aanvraag load() de vorige aanvraag beëindigd (indien in behandeling) en wordt een nieuwe laadbewerking gestart.

Opmerking: In AIR 1.5 en Flash Player 10 is de maximale grootte voor een geladen afbeelding 8,191 pixels breed of hoog en mag het totale aantal pixels niet groter zijn dan 16,777,215 pixels. (Als een geladen afbeelding 8,191 pixels breed is, kan deze daarom slechts 2048 pixels hoog zijn.) In Flash Player 9 en lager en AIR 1.1 en lager is de maximale hoogte 2880 pixels en de maximale breedte 2880 pixels.

Een in een object Loader geladen SWF-bestand of afbeelding overerft de eigenschappen van positie, rotatie en schaal van de bovenliggende weergaveobjecten van het object Loader.

Gebruik de methode unload() om films of afbeeldingen te verwijderen die met deze methode zijn geladen of om een laadbewerking te annuleren.

U kunt voorkomen dat een SWF-bestand deze methode gebruikt door de parameter allowNetworking in te stellen van de tags object en embed op de HTML-pagina die de SWF-inhoud bevat.

iOS-opmerkingen

In AIR-toepassingen op iOS kunt u een SWF-bestand dat ActionScript bevat, alleen laden vanaf het toepassingspakket. Deze beperking omvat alle ActionScript, zoals elementen met klassenamen die zijn geëxporteerd voor ActionScript. Als u een SWF-bestand wilt laden, moet u het SWF-bestand laden met hetzelfde toepassingsdomein als het bovenliggende SWF-bestand, zoals weergegeven in het volgende voorbeeld:

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

Bovendien kunt u op iOS geen SWF-bestand laden dat ActionScript ByteCode (ABC) bevat, het vervolgens verwijderen en daarna opnieuw laden. Als u dit doet, genereert de runtime de fout 3764.

Vóór AIR 3.6 kunnen alleen SWF-bestanden die geen ActionScript-bytecode bevatten, worden geladen, ongeacht of ze werden geladen vanaf het toepassingspakket of via een netwerk. Als alternatief voor het gebruik van een extern SWF-bestand met ActionScript kunt u een SWC-bibliotheek maken en deze koppelen aan uw SWF-hoofdbestand.

Deze beperkingen zijn niet van toepassing wanneer een toepassing wordt uitgevoerd in de iOS-simulator (ipa-test-interpreter-simulator of ipa-debug-interpreter-simulator) of interpretermodus (ipa-test-interpreter of ipa-debug-interpreter).

Loader-beveiliging

Als u deze methode gebruikt, kunt u overwegen het beveiligingsmodel van Flash Player te gebruiken. Dit model wordt beschreven in het gedeelte over de klasse Loader.

Als u in Flash Player 10 en hoger een multipart-inhoudstype gebruikt (bijvoorbeeld 'multipart/form-data') dat een upload bevat (aangegeven met de parameter 'bestandsnaam' in een header 'content-disposition' binnen de POST-body), gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads:

• De POST-bewerking moet worden uitgevoerd in reactie op een door de gebruiker geïnitieerde actie, zoals het klikken met de muis of het indrukken van een toets.
• Als bij de POST-bewerking verschillende domeinen betrokken zijn (het doel van de POST-bewerking bevindt zich niet op dezelfde server als het SWF-bestand dat de POST-aanvraag verstuurt), moet de doelserver een URL-beleidsbestand leveren dat interdomeintoegang toestaat.

In het geval van een multipart-inhoudstype is het ook essentieel dat de syntaxis juist is (in overeenstemming met de norm RFC2046). Als de syntaxis ongeldig lijkt te zijn, gelden voor de POST-bewerking de beveiligingsregels die van toepassing zijn op uploads.

Lees voor meer informatie over beveiliging het onderwerp Security in het Flash Player Developer Center.

Parameters

Verwante API-elementen

Wordt geladen van binaire gegevens die in een ByteArray-object zijn opgeslagen.

De methode loadBytes() is asynchroon. U moet op de gebeurtenis "init" wachten voordat u de eigenschappen van een geladen object opent.

Als u deze methode gebruikt, kunt u overwegen het beveiligingsmodel van Flash Player te gebruiken. Dit model wordt beschreven in het gedeelte over de klasse Loader.

Opmerking (alleen iOS): In AIR-toepassingen op iOS kunt u een SWF-bestand dat ActionScript bevat, alleen laden vanaf het toepassingspakket. Deze beperking omvat alle ActionScript, zoals elementen met klassenamen die zijn geëxporteerd voor ActionScript. Als u een SWF-bestand wilt laden, moet u het SWF-bestand laden met hetzelfde toepassingsdomein als het bovenliggende SWF-bestand.

Vóór AIR 3.6 wordt iOS niet beïnvloed bij het aanroepen van deze methode.

Parameters

Verwante API-elementen

Laadt een IFilePromise-instantie.

De methode loadFilePromise neemt een IFilePromise-object en laadt de binaire gegevens. Als de gegevens bestaan uit een progressieve stream, zoals een video, moet u wachten op 'init' of progress-gebeurtenissen voordat u toegang krijgt tot de eigenschappen van het geladen object. U kunt ook wachten op de hele gebeurtenis. Zo weet u zeker dat de gegevens volledig zijn geladen.

Als u deze methode gebruikt, kunt u overwegen het beveiligingsmodel van Flash Player te gebruiken. Dit model wordt beschreven in het gedeelte over de klasse Loader.

Parameters

Verwante API-elementen

Hiermee wordt een onderliggend item van dit object Loader verwijderd dat met de methode load() is geladen. De eigenschap van het gekoppelde object LoaderInfo wordt teruggezet op null. Het onderliggende item wordt niet noodzakelijkerwijs verwijderd, omdat andere objecten mogelijk verwijzingen ernaar bevatten; het is echter geen onderliggend item meer van het object Loader.

Als u de unload()-methode aanroept, wordt de contentLoaderInfo-eigenschap van het Loader-object ingesteld op null. Eventuele visuele elementen die met het SWF-bestand werden geladen, worden verwijderd en uit het geheugen gewist. ActionScript-klassedefinities in het geladen SWF-bestand blijven in het geheugen en de code in hetzelfde toepassingsdomein als het geladen SWF-bestand heeft toegang tot instanties van deze klassen en kan nieuwe instanties maken.

Opmerking (alleen iOS): Vóór AIR 3.6 heeft deze methode geen effect op iOS.

Voordat u een onderliggend SWF-bestand verwijdert, kunt u het best streams in de objecten van het onderliggende SWF-bestand expliciet sluiten, zoals objecten LocalConnection, NetConnection, NetStream en Sound. Anders kan het geluid in het onderliggende SWF-bestand blijven afspelen, ook al is het onderliggende SWF-bestand verwijderd. Wanneer u streams in het onderliggende SWF-bestand wilt sluiten, voegt u een gebeurtenislistener aan het onderliggende item toe dat naar de gebeurtenis unload luistert. Wanneer het bovenliggende item Loader.unload() aanroept, wordt de gebeurtenis unload naar het onderliggende item verzonden. De volgende code laat zien hoe u dit kunt doen:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Verwante API-elementen

Probeert het laden van de inhoud van een onderliggend SWF-bestand ongedaan te maken en stopt de uitvoering van opdrachten van geladen SWF-bestanden. Deze methode probeert het laden van SWF-bestand ongedaan te maken die zijn geladen met Loader.load() of Loader.loadBytes() door de verwijzingen naar objecten van het type EventDispatcher, NetConnection, Timer, Sound of Video van het onderliggende SWF-bestand te verwijderen. Dit heeft de volgende gevolgen voor het onderliggende SWF-bestand en de weergavelijst van het onderliggende SWF-bestand:

• Geluid wordt gestopt.
• Gebeurtenislisteners van de werkruimte worden verwijderd.
• Listeners voor de gebeurtenissen enterFrame, frameConstructed, exitFrame, activate en deactivate worden verwijderd.
• Timers worden gestopt.
• Camera- en Microphone-instanties worden ontkoppeld.
• Filmclips worden gestopt.

Als u de unloadAndStop()-methode aanroept, wordt de contentLoaderInfo-eigenschap van het Loader-object ingesteld op null. Eventuele visuele elementen die met het SWF-bestand werden geladen, worden verwijderd en uit het geheugen gewist. ActionScript-klassedefinities in het geladen SWF-bestand blijven in het geheugen en de code in hetzelfde toepassingsdomein als het geladen SWF-bestand heeft toegang tot instanties van deze klassen en kan nieuwe instanties maken.

Opmerking (alleen iOS): Vóór AIR 3.6 heeft deze methode geen effect op iOS.

Parameters

Verwante API-elementen

1. De eigenschap url, de locatie en naam van het afbeeldingsbestand, wordt gemaakt.
2. In de constructor LoaderExample wordt een nieuw object met de naam loader gemaakt, die vervolgens aan de methodeconfigureListeners() wordt doorgegeven. Dit wordt beschreven in stap 3.
3. De constructor maakt een nieuwe instantie van het URLRequest-object request waarbij url wordt doorgegeven zodat de bestandsnaam en -locatie bekend zijn.
4. Het object request wordt doorgegeven aan de methode load() van het object loader(), waarmee de afbeelding in het weergaveoverzicht wordt geladen.
5. Een gebeurtenislistener clickHandler wordt geregistreerd voor de gebeurtenis click op de lader. Nadat u met de muis hebt geklikt, wordt de geladen afbeelding verwijderd.
6. De methode configureListeners() voegt met de volgende methoden zeven gebeurtenislisteners toe:
   • De methode completeHandler() wordt uitgevoerd wanneer het laden van de afbeelding is voltooid.
   • De methode httpStatusHandler() wordt uitgevoerd als de afbeelding niet lokaal wordt geladen en alleen wanneer de netwerkaanvraag beschikbaar is gemaakt en de Flash Player deze kan detecteren.
   • De methode initHandler() wordt voor de methodecompleteHandler() en na de methodeprogressHandler() uitgevoerd. In het algemeen is de gebeurtenis init nuttiger wanneer u SWF-bestanden laadt.
   • De methode ioErrorHandler() wordt uitgevoerd wanneer het afbeeldingsbestand niet beschikbaar of niet toegankelijk is.
   • De methode openHandler() wordt uitgevoerd wanneer het afbeeldingsbestand voor het eerst wordt geopend.
   • De methode progressHandler() wordt uitgevoerd wanneer het afbeeldingsbestand met laden begint en nog een keer wanneer de afbeelding klaar is met laden.
   • De methode unLoadHandler() wordt uitgevoerd wanneer de afbeelding wordt verwijderd met de methode unload() wanneer de gebruiker op de afbeelding klikt.

Hierbij gelden de volgende vereisten:

• U kunt dit voorbeeld alleen uitvoeren wanneer het bestand Image.gif zich in dezelfde map bevindt als het gecompileerde SWF-bestand. Gebruik een afbeelding die een gebied bevat dat binnen de afmetingen van het hoofd-SFW-bestand past.
• Hoewel in dit voorbeeld alle gebeurtenissen wordt gebruikt die voor het object LoaderInfo beschikbaar zijn, is in de meeste gevallen alleen een subset nodig, Met name wanneer u alleen een afbeeldingsbestand laadt, is de gebeurtenis complete (en misschien de gebeurtenis ioError) voldoende bij het laden van een lokale afbeelding.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}