CameraRoll  - AS3

Hiermee bepaalt u of de toepassing de toegang tot de camerarol is verleend.

Verwante API-elementen

Of de CameraRoll.addBitmapData()-methode ondersteund wordt. De functie wordt momenteel alleen ondersteund in AIR-toepassingen op mobiele apparaten.

Meldt of de methode CameraRoll.browseForImage() wordt ondersteund. De functie wordt momenteel alleen ondersteund in AIR-toepassingen op mobiele apparaten.

Maakt een CameraRoll-object.

Er wordt slechts één mediabibliotheek ondersteund door ActionScript. Alle CameraRoll-objecten worden op dezelfde locatie voor afbeeldingen opgeslagen.

Hiermee wordt een afbeelding toegevoegd aan de camerarol van het apparaat.

Om tijdens de runtime te controleren of uw toepassing de methode CameraRoll.addBitmapData() ondersteunt, controleert u de eigenschap CameraRoll.supportsAddBitmapData.

Parameters

Opent een dialoogvenster waarin de gebruiker een bestaande afbeelding kan selecteren in de camerarol van het apparaat.

Wanneer de gebruiker een afbeelding selecteert, verzendt deze CameraRoll-instantie een select-gebeurtenis dat een MediaEvent-object bevat. Met de eigenschap data van het MediaEvent-object kunt u de afbeelding laden. De eigenschap data is een MediaPromise-object, dat u kunt laden via de methode loadFilePromise() van de Loader-klasse. Het MediaPromise-object bevat op bepaalde platformen (Blackberry Tablet OS) een geldig bestandsobject, maar op andere platformen niet (iOS en Android). Wanneer u de methode loadFilePromise() gebruikt, wordt de afbeelding naar behoren geladen op alle platformen. Voor toegang tot de onbewerkte gegevens van het mediaobject kunt u de gegevensbron die is verschaft door de mediapromise openen en de gegevens lezen met de methoden van de IDataInput-interface.

Om tijdens de runtime te controleren of uw toepassing de methode CameraRoll.browseForImage() ondersteunt, controleert u de eigenschap CameraRoll.supportsBrowseForImage.

Op iOS (maar alleen op de iPad) kunt u een specifieke grootte aanvragen voor het dialoogvenster met de afbeeldingenbrowser. U kunt ook een gedeelte van het scherm opgeven dat niet mag worden bedekt door dit dialoogvenster. Dit verzoek werkt alleen op de iPad, omdat op dit apparaat niet het hele scherm in beslag wordt genomen door de afbeeldingenbrowser.

U kunt grootte- en positieopties voor de afbeeldingenbrowser (voor de iPad) aanvragen door een CameraRollBrowseOptions-object door te geven aan browseForImage(). Zonder parameters wordt het dialoogvenster met deze methode linksboven in het scherm geplaatst en worden de standaardinstellingen van het systeem voor de grootte gebruikt.

Parameters

Meer informatie

Verwante API-elementen

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

Hiermee wordt toestemming gevraagd voor toegang tot de systeemmediabibliotheek of 'camerarol'.

Verzonden wanneer een gebruiker een bladerbewerking naar afbeeldingen annuleert zonder een afbeelding te selecteren.

Deze gebeurtenis heeft de volgende eigenschappen:

Meldt dat een addBitmapData()-bewerking met succes is uitgevoerd.

Deze gebeurtenis heeft de volgende eigenschappen:

De error-gebeurtenis wordt verzonden wanneer een fout optreedt.

De volgende oorzaken komen voor:

• Een afbeeldingsbrowser kan niet worden geopend.
• Er wordt al een afbeeldingsbrowser gebruikt.
• De AIR-toepassing probeert te bladeren naar een afbeelding terwijl de toepassing op de achtergrond wordt uitgevoerd.
• Een afbeelding kan niet worden toegevoegd aan de mediabibliotheek.
• Er wordt een methode aangeroepen die niet op het apparaat wordt ondersteund.
• De AIR-toepassing probeert om een externe afbeelding zonder internetverbinding te laden.

Deze gebeurtenis heeft de volgende eigenschappen:

Wordt verzonden wanneer de toepassing toegang tot de camerarol vraagt. Controleer de waarde van de eigenschap status om te bepalen of de toestemming is verleend of geweigerd

Verwante API-elementen

Verzonden wanneer een gebruiker een afbeelding selecteert uit de mediabibliotheek van het apparaat.

Via het MediaEvent-object dat voor deze gebeurtenis is verzonden, hebt u toegang tot de gekozen media.

Definieert de waarde van de eigenschap type van een MediaEvent-gebeurtenisobject. Deze gebeurtenis heeft de volgende eigenschappen: