UIComponent  - AS3 Flash

Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de component gebruikersinteractie kan accepteren. De waarde true geeft aan dat de component gebruikersinteractie accepteert; de waarde false geeft aan dat dit niet het geval is.

Wanneer u de eigenschap enabled instelt op false, wordt de kleur van de container gedimd en wordt de gebruikersinvoer geblokkeerd (niet in het geval van de componenten Label en ProgressBar).

De standaardwaarde is true.

Hiermee wordt een Booleaanse waarde opgehaald of ingesteld die aangeeft of de component focus kan krijgen nadat de gebruiker erop heeft geklikt. De waarde true geeft aan dat focus kan worden ontvangen; de waarde false geeft aan dat dit niet het geval is.

Indien deze eigenschap false is, wordt de focus overgedragen naar het eerste bovenliggende element waarvan de eigenschap mouseFocusEnabled is ingesteld op true.

De standaardwaarde is true.

Verwante API-elementen

Hiermee wordt de FocusManager opgehaald of ingesteld die de focus voor deze component en de andere items op hetzelfde niveau bepaalt. Elke pop-upcomponent behoudt de eigen focuslus en FocusManager-instantie. Gebruik deze eigenschap om toegang te krijgen tot de juiste FocusManager voor deze component.

Hiermee wordt de hoogte van de component, in pixels, opgehaald of ingesteld.

Het instellen van deze eigenschap heeft het verzenden van een gebeurtenis resize tot gevolg. Zie de gebeurtenis resize voor gedetailleerde informatie over wanneer deze gebeurtenis wordt verzonden.

Wanneer de eigenschap scaleY van de component niet 1,0 is, zal de hoogte van de component, die wordt verkregen via de interne coördinaten ervan, niet overeenkomen met de hoogtewaarde van de coördinaten van het bovenliggende element. Een component die 100 pixels hoog is en een scaleY van 2 heeft, heeft bijvoorbeeld een waarde van 100 pixels in het bovenliggende element, maar slaat intern een waarde op die een hoogte opgeeft van 50 pixels.

Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de component focus kan krijgen nadat de gebruiker erop heeft geklikt. De waarde true geeft aan dat focus kan worden ontvangen; de waarde false geeft aan dat dit niet het geval is.

Indien deze eigenschap false is, wordt de focus overgedragen naar het eerste bovenliggende element waarvan de eigenschap mouseFocusEnabled is ingesteld op true.

De standaardwaarde is true.

Verwante API-elementen

Hiermee wordt de huidige breedte van de component met een schaalfactor vermenigvuldigd.

Verwante API-elementen

Hiermee wordt de huidige hoogte van de component met een schaalfactor vermenigvuldigd.

Verwante API-elementen

Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de huidige componentinstantie zichtbaar is. De waarde true geeft aan dat de huidige component zichtbaar is; de waarde false geeft aan dat dit niet het geval is.

Wanneer deze eigenschap is ingesteld op true, verzendt het object een gebeurtenis show. Wanneer deze eigenschap is ingesteld op false, verzendt het object een gebeurtenis hide. In geen van beide gevallen genereren de onderliggende elementen van het object de gebeurtenissen show of hide, tenzij het object een specifieke implementatie schrijft om dat wel te doen.

De standaardwaarde is true.

Verwante API-elementen

Hiermee wordt de breedte van de component, in pixels, opgehaald of ingesteld.

Het instellen van deze eigenschap heeft het verzenden van een gebeurtenis resize tot gevolg. Zie de gebeurtenis resize voor gedetailleerde informatie over wanneer deze gebeurtenis wordt verzonden.

Wanneer de eigenschap scaleX van de component niet 1,0 is, zal de breedte van de component, die wordt verkregen via de interne coördinaten ervan, niet overeenkomen met de breedtewaarde van de coördinaten van het bovenliggende element. Een component die 100 pixels breed is en een scaleX van 2 heeft, heeft bijvoorbeeld een waarde van 100 pixels in het bovenliggende element, maar slaat intern een waarde op die een breedte opgeeft van 50 pixels.

Verwante API-elementen

Hiermee wordt de x-coördinaat opgehaald of ingesteld die de positie van de component langs de x-as binnen de bovenliggende container vertegenwoordigt. Deze waarde wordt in pixels uitgedrukt en vanaf links berekend.

Het instellen van deze eigenschap heeft het verzenden van de gebeurtenis ComponentEvent.MOVE tot gevolg.

De standaardwaarde is 0.

Verwante API-elementen

Hiermee wordt de y-coördinaat opgehaald of ingesteld die de positie van de component langs de y-as binnen de bovenliggende container vertegenwoordigt. Deze waarde wordt in pixels uitgedrukt en vanaf boven berekend.

Het instellen van deze eigenschap heeft het verzenden van de gebeurtenis move tot gevolg.

Verwante API-elementen

Hiermee wordt een nieuwe componentinstantie UIComponent gemaakt.

Hiermee wordt een stijleigenschap van deze componentinstantie verwijderd.

Hierdoor retourneert de methode getStyle() niet noodzakelijkerwijs de waarde undefined.

Parameters

Verwante API-elementen

Hiermee wordt de focusindicator van deze component weergegeven of verborgen.

De klasse UIComponent implementeert deze methode door het maken en positioneren van een instantie van de klasse die wordt bepaald door de stijl focusSkin.

Parameters

Hiermee wordt een directe tekenhandeling gestart zonder dat alles ongeldig wordt gemaakt, zoals met invalidateNow.

Hiermee wordt het object opgehaald dat momenteel focus heeft.

Deze methode retourneert niet noodzakelijkerwijs de component die focus heeft. Hiermee wordt mogelijk de interne subcomponent geretourneerd van de component die focus heeft. Gebruik de eigenschap focusManager.focus om de component die focus heeft op te halen.

Hiermee wordt een stijleigenschap opgehaald die in de stijlopzoekketen van de component is ingesteld.

Het type dat door deze methode wordt geretourneerd, hangt af van de stijleigenschap die de methode ophaalt. Mogelijke typen zijn onder andere Booleaans, tekenreeks, getal, int, een uint voor een RGB-kleur, een klasse voor een skin, of een object.

Wanneer u deze methode aanroept om een bepaalde stijleigenschap op te halen, zal deze van een bekend type zijn dat u kunt opslaan in een variabele van hetzelfde type. Typecasting is niet nodig. Gebruik in plaats hiervan een eenvoudige toewijzingsinstructie zoals deze:

var backgroundColor:uint = getStyle("backgroundColor");

Wanneer de stijleigenschap niet is ingesteld in de stijlopzoekketen, retourneert deze methode de waarde undefined. undefined is een speciale waarde die niet hetzelfde is als false, "", NaN, 0 of null. Een geldige stijlwaarde is nooit undefined. U kunt de statische methode StyleManager.isValidStyleValue() gebruiken om te testen of een waarde is ingesteld.

Parameters

Verwante API-elementen

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Hiermee wordt de standaardstijlkaart voor de huidige component opgehaald. Op de stijlkaart vindt u het type dat voor de component geschikt is, afhankelijk van de stijl die de component gebruikt. De stijl disabledTextFormat bevat bijvoorbeeld de waarde null of een object TextFormat. U kunt deze stijlen gebruiken en setStyle() aanroepen voor de huidige component. De volgende code overschrijft de standaardstijl disabledTextFormat voor de opgegeven component:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Verwante API-elementen

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Retourneert de opgegeven stijl voor een component, waarbij rekening wordt gehouden met alle stijlen die op algemeen niveau, componentniveau en instantieniveau zijn ingesteld.

Als voor een component bijvoorbeeld een stijl op algemeen niveau is ingesteld op myStyle en u getStyle("myStyle") aanroept voor een instantie zonder instantie-instelling, wordt null geretourneerd. Als u getStyleValue("myStyle") aanroept, wordt "myStyle" geretourneerd, omdat deze stijl actief is op het algemene niveau.

Parameters

Hiermee wordt een eigenschap als ongeldig gemarkeerd en wordt de component bij het volgende frame opnieuw getekend, tenzij anders wordt aangegeven.

Parameters

Hiermee worden de stijlen van meerdere klassen in één object samengevoegd. Wanneer een stijl in verschillende objecten is gedefinieerd, wordt de eerst gevonden stijl in een van die objecten gebruikt.

Parameters

Hiermee wordt de component naar de opgegeven positie binnen het bovenliggende item verplaatst. Dit heeft hetzelfde effect als het wijzigen van de locatie van de component door de eigenschappen x en y ervan in te stellen. Het aanroepen van deze methode zorgt dat de gebeurtenis ComponentEvent.MOVE wordt verzonden.

Wanneer u in een aangepaste component de methode updateDisplayList() wilt overschrijven, gebruikt u de methode move() in plaats van de eigenschappen x en y in te stellen. Een aanroep van de methode move() zorgt er namelijk voor dat een gebeurtenisobject move wordt verzonden, direct nadat de verplaatsingsbewerking is voltooid. Wanneer u daarentegen de componentlocatie wijzigt door de eigenschappen x en y in te stellen, wordt het gebeurtenisobject verzonden wanneer het scherm de eerstvolgende keer wordt vernieuwd.

Parameters

Verwante API-elementen

Hiermee wordt de focus ingesteld op deze component. De component kan vervolgens de focus aan een subcomponent geven.

Opmerking: alleen de componenten TextInput en TextArea geven een focusindicator weer wanneer deze methode de focus instelt. Alle componenten bevatten een focusindicator wanneer de gebruiker met de Tab-toets naar de component gaat.

Hiermee wordt de grootte van de component op de opgegeven breedte en hoogte ingesteld.

Parameters

Hiermee wordt een stijleigenschap op deze componentinstantie ingesteld. Deze stijl kan een stijl vervangen die globaal is ingesteld.

Het aanroepen van deze methode kan leiden tot verminderde prestaties. Gebruik dit alleen wanneer het nodig is.

Parameters

Verwante API-elementen

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Hiermee worden de eigenschappen en de lay-out van dit object gevalideerd en bijgewerkt, waarbij het object zonodig opnieuw wordt getekend.

Eigenschappen die aanzienlijke berekeningen vereisen, worden normaalgesproken pas verwerkt nadat het script is uitgevoerd. Het instellen van één eigenschap kan namelijk de verwerking van andere eigenschappen vereisen. Wanneer u bijvoorbeeld de eigenschap width instelt, kan het nodig zijn dat de breedten van de onder- of bovenliggende elementen van het object eveneens worden herberekend. En als het script de breedte van het object meer dan een keer herberekent, moeten deze onderling afhankelijke eigenschappen mogelijk ook nogmaals worden herberekend. Gebruik deze methode om dit gedrag handmatig te overschrijven.

Wordt verzonden nadat de zichtbaarheid van de component van zichtbaar in onzichtbaar is gewijzigd.

Deze gebeurtenis heeft de volgende eigenschappen:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Verwante API-elementen

Wordt verzonden nadat de component is verplaatst.

Deze gebeurtenis heeft de volgende eigenschappen:

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Wordt verzonden nadat de grootte van de component is gewijzigd.

Deze gebeurtenis heeft de volgende eigenschappen:

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Wordt verzonden nadat de zichtbaarheid van de component van onzichtbaar in zichtbaar is gewijzigd.

Deze gebeurtenis heeft de volgende eigenschappen:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Verwante API-elementen

Het versienummer van de componenten.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);