Label  - AS3 Flash

Hiermee wordt een tekenreeks opgehaald of ingesteld die aangeeft hoe de grootte en uitlijning van een label worden ingesteld om overeen te komen met de waarde van de eigenschap text. De volgende waarden zijn geldig:

• TextFieldAutoSize.NONE: De grootte en uitlijning van een label worden niet aangepast aan de tekst.
• TextFieldAutoSize.LEFT: de grootten van de rechterzijde en onderzijde van het label worden aangepast aan de tekst. De grootten van de linkerzijde en bovenzijde worden niet aangepast.
• TextFieldAutoSize.CENTER: de grootten van de linkerzijde en rechterzijde van het label worden aangepast aan de tekst. Het horizontale midden van het label blijft verankerd op de oorspronkelijke horizontale middenpositie.
• TextFieldAutoSize.RIGHT: de grootten van de linkerzijde en onderzijde van het label worden aangepast aan de tekst. De grootten van de rechterzijde en bovenzijde worden niet aangepast.

De standaardwaarde is TextFieldAutoSize.NONE.

Verwante API-elementen

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of extra witruimte zoals spaties en regeleinden in een component Label met HTML-tekst moet worden verwijderd. De waarde true geeft aan dat witruimte moet worden verwijderd, de waarde false geeft aan dat deze blijft staan.

De eigenschap condenseWhite heeft uitsluitend invloed op tekst die is ingesteld met de eigenschap htmlText, niet met de eigenschap text. Wanneer u tekst instelt met de eigenschap text, wordt de eigenschap condenseWhite genegeerd.

Wanneer u de eigenschap condenseWhite op true instelt, moet u standaard HTML-opdrachten, zoals <br> and <p>, gebruiken om regeleinden op te nemen in het tekstveld.

De standaardwaarde is false.

Verwante API-elementen

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Hiermee wordt de hoogte van de component, in pixels, opgehaald of ingesteld.

Het instellen van deze eigenschap heeft het verzenden van een gebeurtenis resize tot gevolg. Zie de gebeurtenis resize voor gedetailleerde informatie over wanneer deze gebeurtenis wordt verzonden.

Wanneer de eigenschap scaleY van de component niet 1,0 is, zal de hoogte van de component, die wordt verkregen via de interne coördinaten ervan, niet overeenkomen met de hoogtewaarde van de coördinaten van het bovenliggende element. Een component die 100 pixels hoog is en een scaleY van 2 heeft, heeft bijvoorbeeld een waarde van 100 pixels in het bovenliggende element, maar slaat intern een waarde op die een hoogte opgeeft van 50 pixels.

Verwante API-elementen

Hiermee wordt de tekst opgehaald of ingesteld die door de component Label moet worden weergegeven, inclusief HTML-opmaak die de stijlen van die tekst uitdrukt. In deze eigenschap kunt u HTML-tekst opgeven door de subset van HTML-tags te gebruiken die wordt ondersteund door het object TextField.

Wanneer de standaardwaarde van de eigenschap text in Eigenschapcontrole wordt gewijzigd, heeft deze gewijzigde waarde voorrang op elke waarde in het eigenschapveld htmlText in Eigenschapcontrole. Als u de eigenschap htmlText in Eigenschapcontrole wilt gebruiken, moet het eigenschapveld text de waarde Label bevatten, zoals wordt getoond. Wanneer u codeert met ActionScript, hoeft u de waarde van de eigenschap text niet in te stellen, de standaardwaarde is Label.

De standaardwaarde is "".

Verwante API-elementen

Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de tekst kan worden geselecteerd. De waarde true geeft aan dat deze kan worden geselecteerd. De waarde false geeft aan dat dit niet mogelijk is.

Tekst die kan worden geselecteerd, kan door de gebruiker uit de component Label worden gekopieerd.

De standaardwaarde is false.

Hiermee wordt de onbewerkte tekst opgehaald of ingesteld die moet worden weergegeven in de component Label.

Tekens die HTML-markeringen voorstellen, hebben geen speciale betekenis in de tekenreeks en worden weergegeven wanneer ze worden ingevoerd.

Gebruik de eigenschap htmlText om tekst weer te geven die HTML-tags bevat. De HTML vervangt tekst die u instelt met de eigenschap htmlText en de eigenschap text retourneert een onopgemaakte tekstversie van de HTML-tekst, waaruit de HTML-tags zijn verwijderd.

Wanneer de eigenschap text in Eigenschapcontrole een andere waarde krijgt dan de standaardwaarde, heeft deze voorrang op de eigenschap htmlText in Eigenschapcontrole.

De standaardwaarde is "Label".

Verwante API-elementen

Een verwijzing naar het interne tekstveld van de component Label.

Hiermee wordt de breedte van de component, in pixels, opgehaald of ingesteld.

Het instellen van deze eigenschap heeft het verzenden van een gebeurtenis resize tot gevolg. Zie de gebeurtenis resize voor gedetailleerde informatie over wanneer deze gebeurtenis wordt verzonden.

Wanneer de eigenschap scaleX van de component niet 1,0 is, zal de breedte van de component, die wordt verkregen via de interne coördinaten ervan, niet overeenkomen met de breedtewaarde van de coördinaten van het bovenliggende element. Een component die 100 pixels breed is en een scaleX van 2 heeft, heeft bijvoorbeeld een waarde van 100 pixels in het bovenliggende element, maar slaat intern een waarde op die een breedte opgeeft van 50 pixels.

Verwante API-elementen

Hiermee wordt een waarde ingesteld of opgehaald die aangeeft of het tekstveld tekstomloop ondersteund. De waarde true geeft aan dat het mogelijk is, de waarde false geeft aan dat het niet mogelijk is.

De standaardwaarde is false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Hiermee wordt een nieuwe componentinstantie Label gemaakt.

Hiermee wordt de standaardstijlkaart voor de huidige component opgehaald. Op de stijlkaart vindt u het type dat voor de component geschikt is, afhankelijk van de stijl die de component gebruikt. De stijl disabledTextFormat bevat bijvoorbeeld de waarde null of een object TextFormat. U kunt deze stijlen gebruiken en setStyle() aanroepen voor de huidige component. De volgende code overschrijft de standaardstijl disabledTextFormat voor de opgegeven component:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Verwante API-elementen

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Wordt verzonden nadat de breedte of hoogte van de component is gewijzigd.

Opmerking: deze gebeurtenis treedt niet op wanneer u ActionScript-code gebruikt om de labeltekst te wijzigen.

Deze gebeurtenis heeft de volgende eigenschappen:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Voeg de componenten Label en Button toe aan uw bibliotheek.
2. Sla deze code op als LabelExample.as in dezelfde map als de FLA.
3. Stel de DocumentClass in de FLA in op LabelExample.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}