TextFormat  - AS3

Geeft de uitlijning van de tekst aan. Geldige waarden zijn TextFormatAlign-constanten.

De standaardwaarde is TextFormatAlign.LEFT.

Verwante API-elementen

Geeft de blokinspringing in pixels aan. Blokinspringing wordt toegepast op een heel tekstblok, dat wil zeggen op alle regels van de tekst. Bij normale inspringing (TextFormat.indent) wordt daarentegen alleen de eerste regel van elke alinea ingesprongen. Wanneer deze eigenschap null is, is geen blokinspringing voor het object TextFormat opgegeven (blokinspringing is 0).

Geeft aan of de tekst vet is. De standaardwaarde is null, hetgeen betekent dat geen vet lettertype wordt gebruikt. Wanneer de waarde true is, is de tekst vet.

Geeft aan dat de tekst onderdeel is van een lijst met opsommingstekens. In een lijst met opsommingstekens is elke alinea met tekst ingesprongen. Links van de eerste regel van elke alinea wordt een opsommingsteken weergegeven. De standaardwaarde is null, hetgeen betekent dat geen lijst met opsommingstekens wordt gebruikt.

Geeft de kleur van de tekst aan. Een getal bestaande uit drie 8-bits RGB-componenten, 0xFF0000 is bijvoorbeeld rood en 0x00FF00 is groen. De standaardwaarde is null, hetgeen betekent dat in Flash Player de kleur zwart wordt gebruikt (0x000000).

De naam van het lettertype voor tekst in deze tekstopmaak, als tekenreeks. De standaardwaarde is null, hetgeen betekent dat in Flash Player het lettertype Times New Roman wordt gebruikt voor de tekst.

Geeft de inspringing vanaf de linkermarge tot aan het eerste teken van de alinea aan. De standaardwaarde is null, hetgeen betekent dat geen inspringing wordt gebruikt.

Verwante API-elementen

Geeft aan of tekst in deze tekstopmaak cursief is. De standaardwaarde is null, hetgeen betekent dat geen cursief lettertype wordt gebruikt.

Een booleaanse waarde die aangeeft of spatiëring is ingeschakeld (true) of uitgeschakeld (false). Met tekenspatiëring worden de pixels tussen bepaalde tekens aangepast om de leesbaarheid te verbeteren. Tekenspatiëring moet alleen worden gebruikt wanneer dit nodig is, bijvoorbeeld in kopteksten met grote lettertypen. Tekenspatiëring wordt alleen ondersteund voor ingesloten lettertypen.

Bepaalde lettertypen, zoals Verdana en Courier New, ondersteunen tekenspatiëring niet.

De standaardwaarde is null, hetgeen betekent dat geen tekenspatiëring wordt gebruikt.

Een geheel getal dat de hoeveelheid verticale ruimte in pixels (regelafstand genoemd) tussen regels vertegenwoordigt. De standaardwaarde is null, hetgeen betekent dat de gebruikte regelafstand 0 is.

De linkermarge van de alinea, in pixels. De standaardwaarde is null, hetgeen betekent dat de linkermarge 0 pixels is.

Een getal dat de hoeveelheid ruimte vertegenwoordigt die uniform tussen tekens wordt verdeeld. De waarde duidt op het aantal pixels dat na elk teken wordt toegevoegd. De standaardwaarde is null, hetgeen betekent dat een tekenspatiëring van 0 pixels wordt gebruikt. U kunt decimale waarden gebruiken, zoals 1,75.

De rechtermarge van de alinea, in pixels. De standaardwaarde is null, hetgeen betekent dat de rechtermarge 0 pixels is.

De grootte in pixels van tekst met deze tekstopmaak. De standaardwaarde is null, wat betekent dat er een puntgrootte van 12 wordt gebruikt.

Geeft aangepaste tabstops als een array van niet-negatieve gehele getallen op. Elke tabstop wordt opgegeven in pixels. Wanneer geen aangepaste tabstops worden opgegeven (null), is de standaardtabstop 4 (gemiddelde tekenbreedte).

Geeft het doelvenster voor weergave van de hyperlink aan. Wanneer het doelvenster een lege tekenreeks is, wordt de tekst weergegeven in het standaarddoelvenster _self. U kunt een aangepaste naam kiezen of een van de volgende vier namen gebruiken: De optie _self geeft het huidige frame aan in het huidige venster, _blank geeft een nieuw venster aan, _parent geeft het bovenliggende frame aan en _top geeft het frame aan op het hoogste niveau in het huidige venster. Wanneer de eigenschap TextFormat.url een lege tekenreeks of null is, kunt u deze eigenschap wel ophalen of instellen, maar zal de eigenschap geen effect hebben.

Verwante API-elementen

Geeft aan of de tekst met deze tekstopmaak is onderstreept (true) of niet (false). Deze onderstreping is vergelijkbaar met de onderstreping die wordt verkregen met de tag <U>, maar bij deze laatste code is geen sprake van werkelijke onderstreping, aangezien uitlopers niet goed worden overgeslagen. De standaardwaarde is null, hetgeen betekent dat geen onderstreping wordt gebruikt.

Geeft de doel-URL voor de tekst in deze tekstopmaak aan. Wanneer de eigenschap url een lege tekenreeks is, heeft de tekst geen hyperlink. De standaardwaarde is null, hetgeen aangeeft dat de tekst geen hyperlink heeft.

Opmerking: de hyperlink werkt alleen wanneer de tekst met de toegewezen tekstopmaak is ingesteld met de eigenschap htmlText.

Verwante API-elementen

Maakt een object TextFormat met de opgegeven eigenschappen. Vervolgens kunt u de eigenschappen van het object TextFormat wijzigen om de opmaak van tekstvelden te wijzigen.

Elke gewenste parameter kan op null worden ingesteld om aan te geven dat deze niet is gedefinieerd. Alle parameters zijn optioneel; weggelaten parameters worden beschouwd als null.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. Een eigenschap label van het type TextField wordt gemaakt.
2. De klasseconstructor roept de functie configureLabel() aan.
3. De methode configureLabel() maakt eerst een nieuw object TextField en wijst dit toe aan de eigenschap label. Vervolgens worden de parameters ervan als volgt ingesteld:
   • Het tekstveld links wordt uitgevuld
   • De opvulkleur voor de achtergrond wordt ingeschakeld
   • De rand wordt ingeschakeld.
4. De methode configureLabel() maakt de lokale variabele format en wijst deze toe aan een nieuwe instantie TextFormat met de volgende parameterinstellingen:
   • Font type = Verdana
   • Font Color = solid red
   • Font size = 10
   • Font underline = true.
5. De eigenschap defaultTextFormat van het label wordt op format ingesteld en de instantie label wordt toegevoegd aan het weergaveoverzicht, waarin eerst een tekstveld zonder tekst wordt weergegeven (als een klein vak met een witte achtergrond) in het werkgebied.
6. Ten slotte (weer in de constructor) wordt de tekst van het label ingesteld om 'Hello World and welcome to the show' op de coördinaten x = 0, y = 0 weer te geven door het aanroepen van setLabel().

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}