NumericStepper  - AS3 Flash

Hiermee wordt een waarde opgehaald of ingesteld die aangeeft of de component gebruikersinteractie kan accepteren. De waarde true geeft aan dat de component gebruikersinteractie accepteert; de waarde false geeft aan dat dit niet het geval is.

Wanneer u de eigenschap enabled instelt op false, wordt de kleur van de container gedimd en wordt de gebruikersinvoer geblokkeerd (niet in het geval van de componenten Label en ProgressBar).

De standaardwaarde is true.

Hiermee wordt de modus van de invoermethode-editor (IME) opgehaald of ingesteld. De IME maakt mogelijk dat gebruikers met een QWERTY-toetsenbord tekens uit Chinese, Japanse of Koreaanse tekensets kunnen invoeren.

Flash stelt de IME op de opgegeven modus in wanneer de component de focus krijgt, en herstelt de oorspronkelijke instelling als de component de focus niet meer heeft.

De klasse flash.system.IMEConversionMode definieert constanten voor de geldige waarden voor deze eigenschap. Stel deze eigenschap in op null als u het gebruik van de IME met de component wilt voorkomen.

Hiermee wordt de maximale waarde in een reeks van numerieke waarden opgehaald of ingesteld.

De standaardwaarde is 10.

Hiermee wordt de minimale waarde in een reeks van numerieke waarden opgehaald of ingesteld.

De standaardwaarde is 0.

Hiermee wordt de volgende waarde in een reeks van waarden opgehaald.

Hiermee wordt de vorige waarde in een reeks van waarden opgehaald.

Hiermee wordt een getal (niet gelijk aan nul) opgehaald dat de stapgrootte tussen waarden beschrijft. De eigenschap value is een veelvoud van dit getal na aftrek van het minimum. De component NumericStepper rondt de waarde af op de dichtstbijzijnde stapgrootte.

De standaardwaarde is 1.

Hiermee wordt een verwijzing opgehaald naar de component TextInput die de component NumericStepper bevat. Gebruik deze eigenschap om de onderliggende TextInput-component te benaderen en te manipuleren. Met deze eigenschap kunt u bijvoorbeeld de huidige selectie in het tekstvak wijzigen of de tekens beperken die in het tekstvak worden geaccepteerd.

Hiermee wordt de huidige waarde van de component NumericStepper opgehaald of ingesteld.

De standaardwaarde is 1.

Hiermee wordt een nieuwe componentinstantie NumericStepper gemaakt.

Hiermee wordt de focusindicator van deze component weergegeven of verborgen.

De klasse UIComponent implementeert deze methode door het maken en positioneren van een instantie van de klasse die wordt bepaald door de stijl focusSkin.

Parameters

Hiermee wordt de standaardstijlkaart voor de huidige component opgehaald. Op de stijlkaart vindt u het type dat voor de component geschikt is, afhankelijk van de stijl die de component gebruikt. De stijl disabledTextFormat bevat bijvoorbeeld de waarde null of een object TextFormat. U kunt deze stijlen gebruiken en setStyle() aanroepen voor de huidige component. De volgende code overschrijft de standaardstijl disabledTextFormat voor de opgegeven component:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Verwante API-elementen

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Hiermee wordt de focus op de componentinstantie ingesteld.

Wordt verzonden wanneer de gebruiker de waarde van de component NumericStepper wijzigt.

Opmerking: deze gebeurtenis wordt niet verzonden als ActionScript wordt gebruikt om de waarde te wijzigen.

Deze gebeurtenis heeft de volgende eigenschappen:

1. Voeg de component NumericStepper toe aan uw bibliotheek.
2. Sla deze code op als NumericStepperExample.as in dezelfde map als de FLA.
3. Stel de DocumentClass in de FLA in op NumericStepperExample.

package 
{
    import flash.display.Sprite
    import flash.text.TextField;
    import flash.events.Event;
    import fl.controls.NumericStepper;
    
    public class NumericStepperExample extends Sprite
    {
        private var ns1:NumericStepper;
        private var ns2:NumericStepper;
        private var tf1:TextField;
        private var tf2:TextField;
        private var rowHeight1:Number = 10;
        private var rowHeight2:Number = 50;
        
        public function NumericStepperExample() {        
            setupSteppers();
            setupTextFields();
        }
        private function setupTextFields():void {
            tf1 = new TextField();
            tf1.text = "This stepper increments by 1 between 0 and 5. Disables if it reaches 0.";
            tf1.autoSize = "left";
            tf1.x = 100;
            tf1.y = rowHeight1;
            addChild(tf1);
            
            tf2 = new TextField();
            tf2.text = "This stepper increments by 0.01 between 0 and 20. Disables if it reaches 0.";
            tf2.autoSize = "left";
            tf2.x = 100;
            tf2.y = rowHeight2;
            addChild(tf2);
        }
        private function setupSteppers():void {    
            ns1 = new NumericStepper();
            ns1.stepSize = 1;
            ns1.maximum = 5;
            ns1.minimum = 0;
            ns1.addEventListener(Event.CHANGE,changeOccurred);
            ns1.move(10,rowHeight1);
            addChild(ns1);

            ns2 = new NumericStepper();
            ns2.stepSize = 0.01;
            ns2.maximum = 20;
            ns2.minimum = 0;
            ns2.value = 10;
            ns2.addEventListener(Event.CHANGE,changeOccurred);
            ns2.move(10,rowHeight2);
            addChild(ns2);
        }
        private function changeOccurred(e:Event):void {
            var nsTarget:NumericStepper = e.target as NumericStepper;
            if(nsTarget.value == 0) nsTarget.enabled = false;
        }
    }
}