DisplacementMapFilter  - AS3

Geeft de alpha-transparantiewaarde op die voor verschuivingen buiten de grenzen moet worden gebruikt. Deze wordt als een genormaliseerde waarde van 0,0 tot en met 1,0 opgegeven. De waarde .25 stelt bijvoorbeeld een transparantiewaarde in van 25%. De standaardwaarde is 0. Gebruik deze eigenschap wanneer de eigenschap mode opDisplacementMapFilterMode.COLOR is ingesteld.

Geeft op welke kleur voor verschuivingen buiten de grenzen moet worden gebruikt. De geldige reeks verschuivingen loopt van 0,0 tot en met 1,0. De waarden hebben een hexadecimale indeling. De standaardwaarde van color is 0. Gebruik deze eigenschap wanneer de eigenschap mode opDisplacementMapFilterMode.COLOR is ingesteld.

Beschrijft welk kleurkanaal in de kaartafbeelding moet worden gebruikt om het x-resultaat te verschuiven. Mogelijke waarden zijn de BitmapDataChannel-constanten:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Verwante API-elementen

Beschrijft welk kleurkanaal in de kaartafbeelding moet worden gebruikt om het y-resultaat te verschuiven. Mogelijke waarden zijn de BitmapDataChannel-constanten:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Verwante API-elementen

Een object BitmapData met verschuivingskaartgegevens.

Verwante API-elementen

Een waarde die de verschuiving van de linkerbovenhoek van het doelweergaveobject vanaf de linkerbovenhoek van de kaartafbeelding aangeeft.

Verwante API-elementen

De modus voor het filter. Mogelijke waarden zijn de DisplacementMapFilterMode-constanten:

• DisplacementMapFilterMode.WRAP — Laat de verschuivingswaarde naar de andere kant van de bronafbeelding doorlopen.
• DisplacementMapFilterMode.CLAMP — Klemt de verschuivingswaarde vast aan de rand van de bronafbeelding.
• DisplacementMapFilterMode.IGNORE — Wanneer de verschuivingswaarde buiten bereik valt, wordt de verschuiving genegeerd en wordt de bronpixel gebruikt.
• DisplacementMapFilterMode.COLOR — Wanneer de verschuivingswaarde buiten de afbeelding valt, worden de waarden in de eigenschappen color en alpha vervangen.

Verwante API-elementen

De vermenigvuldiger die moet worden gebruikt om het x-verschuivingsresultaat van de verschuivingskaartberekening te schalen.

De vermenigvuldiger die moet worden gebruikt om het y-verschuivingsresultaat van de verschuivingskaartberekening te schalen.

Initialiseert een instantie DisplacementMapFilter met de opgegeven parameters.

Verwante API-elementen

Retourneert een kopie van dit filterobject.

1. De klasse definieert variabelen voor de achtergrondkleur, voor het tekstveldlabel en voor de grootte en verschuiving die in verschillende functies wordt gebruikt.
2. De constructorfunctie roept de methode draw() aan, die de methoden van de klasse Graphics gebruikt om een vierkant met radiaal verlopende vulling te tekenen. graphics is een eigenschap van het object DisplacementMapFilterExample, dat Sprite uitbreidt.
3. De constructorfunctie roept de methode createLabel() aan, die een tekstveld maakt waarin de waarde van labelText wordt weergegeven, en voegt dit toe aan het weergaveoverzicht.
4. De constructorfunctie roept de methode createFilter() aan, die het volgende doet:
   • Maakt een variabele met de naam filter voor het filterobject.
   • Roept de methode getDisplacementMapFilter() aan en wijst de geretourneerde waarde toe aan de variabele filter.
   • Geeft filter door aan de eigenschapfilters van het object DisplacementFilterExample (de hoofdklasse).
5. De methode getBitmapFilter() maakt een object BitmapData met de naam mapBitmap en wijst er de resultaten van de methode createBitmapData() aan toe. Het object mapBitmap definieert, samen met andere variabelen, een nieuw verschuivingsmapfilter.
6. De methode createBitmapData() maakt een nieuw object BitmapData dat is gebaseerd op de huidige inhoud van het object DisplacementMapFilterExample. Het maakt een nieuwe bitmap op basis van bitmapData en voegt de bitmap toe aan het werkgebied.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}