BevelFilter  - AS3

De hoek van de schuine kant. Geldige waarden zijn 0 tot en met 360°. De standaardwaarde is 45°.

De waarde angle vertegenwoordigt de hoek van de denkbeeldige lichtbron die op het object valt en bepaalt de plaatsing van het effect ten opzichte van het object. Wanneer de eigenschap distance op 0 is ingesteld, wordt het effect niet verschoven ten opzichte van het object en heeft de eigenschap angle daarom geen effect.

De mate van horizontale vervaging in pixels. Geldige waarden zijn 0 tot en met 255 (drijvende komma). De standaardwaarde is 4. Waarden die een macht van 2 zijn (zoals 2, 4, 8, 16 en 32), zijn geoptimaliseerd om sneller te renderen dan andere waarden.

De mate van verticale vervaging in pixels. Geldige waarden zijn 0 tot en met 255 (drijvende komma). De standaardwaarde is 4. Waarden die een macht van 2 zijn (zoals 2, 4, 8, 16 en 32), zijn geoptimaliseerd om sneller te renderen dan andere waarden.

De verschuivingsafstand van de schuine kant. Geldige waarden worden in pixels vermeld (drijvende komma). De standaardwaarde is 4.

De alpha-transparantiewaarde van de markeerkleur. De waarde wordt als een genormaliseerde waarde van 0 tot en met 1 opgegeven. De waarde .25 stelt bijvoorbeeld een transparantiewaarde in van 25%. De standaardwaarde is 1.

De markeerkleur van de schuine kant. Geldige waarden hebben de hexadecimale notatie 0xRRGGBB. De standaardwaarde is 0xFFFFFF.

Past een uitneemeffect toe (true), waardoor het object transparant wordt gevuld en de achtergrondkleur van het document zichtbaar wordt gemaakt. De standaardwaarde is false (niet uitnemen).

Het aantal keren dat het filter moet worden toegepast. De standaardwaarde is BitmapFilterQuality.LOW. Hiermee wordt het filter eenmaal toegepast. De waarde BitmapFilterQuality.MEDIUM past het filter tweemaal toe, terwijl het met de waarde BitmapFilterQuality.HIGH driemaal wordt toegepast. Filters met lagere waarden worden sneller gerenderd.

Voor de meeste toepassingen is een waarde van laag, normaal of hoog voor quality voldoende. Hoewel u aanvullende numerieke waarden tot en met 15 kunt gebruiken om verschillende effecten te verkrijgen, worden hogere waarden langzamer gerenderd. In plaats van de waarde van quality te verhogen, krijgt u vaak een vergelijkbaar effect met snellere rendering door de waarden van blurX en blurY te verhogen.

U kunt de volgende BitmapFilterQuality-constanten gebruiken om waarden van de eigenschap quality op te geven:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

De alpha-transparantiewaarde van de schaduwkleur. Deze waarde wordt als een genormaliseerde waarde van 0 tot en met 1 opgegeven. De waarde .25 stelt bijvoorbeeld een transparantiewaarde in van 25%. De standaardwaarde is 1.

De schaduwkleur van de schuine kant. Geldige waarden hebben de hexadecimale notatie 0xRRGGBB. De standaardwaarde is 0x000000.

De sterkte van de afdruk of de spreiding. Geldige waarden zijn 0 tot en met 255. Hoe hoger de waarde, hoe meer kleur er wordt afgedrukt en hoe sterker het contrast tussen de schuine kant en de achtergrond wordt. De standaardwaarde is 1.

De plaatsing van de schuine kant op het object Schuine kanten worden aan de binnen- en buitenranden geplaatst; een volledige schuine kant wordt op het hele object geplaatst. Geldige waarden zijn BitmapFilterType-constanten:

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

Initialiseert een nieuwe instantie BevelFilter met de opgegeven parameters.

Verwante API-elementen

Retourneert een kopie van dit filterobject.

1. Importeer de vereiste klassen.
2. Declareer drie eigenschappen die in de functie draw() worden gebruikt, die het object tekenen waarop het schuine-kantfilter wordt toegepast.
3. Maak de constructorfunctie BevelFilterExample(), die het volgende doet:
   • Roept de functie draw() aan, die later wordt gedeclareerd.
   • Declareert een variabele filter als een object BitmapFilter en wijst het toe aan de geretourneerde waarde van een aanroep van getBitmapFilter().
   • Maakt een nieuw Array-object myFilters, voegtfilter toe aan de array en wijstmyFilters toe aan de eigenschapfilters van het object BevelFilterExample. Hiermee worden alle filters toegepast die worden gevonden in myFilters, wat in dit geval alleen filter is.
4. Maak de functie getBitmapFilter om eigenschappen te maken en in te stellen voor het filter.
5. Maak de functie draw(). Deze functie gebruikt methoden van de klasse Graphics, waar met behulp van de eigenschap graphics van de klasse Sprite toegang toe wordt verkregen om een vierkant te tekenen.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}