GlowFilter  - AS3

De alpha-transparantiewaarde voor de kleur. Geldige waarden zijn 0 tot en met 1. De waarde .25 stelt bijvoorbeeld een transparantiewaarde in van 25%. De standaardwaarde is 1.

De mate van horizontale vervaging. Geldige waarden zijn 0 tot en met 255 (drijvende komma). De standaardwaarde is 6. Waarden die een macht van 2 zijn (zoals 2, 4, 8, 16 en 32), zijn geoptimaliseerd om sneller te renderen dan andere waarden.

De mate van verticale vervaging. Geldige waarden zijn 0 tot en met 255 (drijvende komma). De standaardwaarde is 6. Waarden die een macht van 2 zijn (zoals 2, 4, 8, 16 en 32), zijn geoptimaliseerd om sneller te renderen dan andere waarden.

De kleur van de gloed. Geldige waarden hebben de hexadecimale notatie 0x RRGGBB. De standaardwaarde is 0xFF0000.

Geeft op of de gloed een binnengloed is. De waarde true geeft een binnengloed aan. De standaardwaarde is false, een buitengloed (een gloed rondom de buitenranden van het object).

Geeft op of het object een uitneemeffect heeft. De waarde true zorgt ervoor dat het object transparant wordt gevuld en de achtergrondkleur van het document zichtbaar wordt gemaakt. De standaardwaarde is false (niet uitnemen).

Het aantal keren dat het filter moet worden toegepast. De standaardwaarde is BitmapFilterQuality.LOW. Hiermee wordt het filter eenmaal toegepast. De waarde BitmapFilterQuality.MEDIUM past het filter tweemaal toe, terwijl het met de waarde BitmapFilterQuality.HIGH driemaal wordt toegepast. Filters met lagere waarden worden sneller gerenderd.

Voor de meeste toepassingen is een waarde van laag, normaal of hoog voor quality voldoende. Hoewel u aanvullende numerieke waarden tot en met 15 kunt gebruiken om verschillende effecten te verkrijgen, worden hogere waarden langzamer gerenderd. In plaats van de waarde van quality te verhogen, krijgt u vaak een vergelijkbaar effect met snellere rendering door de waarden van blurX en blurY te verhogen.

Verwante API-elementen

De sterkte van de afdruk of de spreiding. Hoe hoger de waarde, hoe meer kleur er wordt afgedrukt en hoe sterker het contrast tussen de gloed en de achtergrond wordt. Geldige waarden zijn 0 tot en met 255. De standaardwaarde is 2.

Initialiseert een nieuwe instantie GlowFilter met de opgegeven parameters.

Verwante API-elementen

Retourneert een kopie van dit filterobject.

1. Importeer de vereiste klassen.
2. Declareer drie eigenschappen die in de methode draw worden gebruikt, die de methoden van de klasse Graphics gebruikt, waar met behulp van de eigenschap graphics van Sprite toegang toe wordt gekregen om een oranje vierkant te tekenen.
3. Maak de constructorfunctie, die het volgende doet:
   • Roept de functie draw aan om een rechthoek te maken.
   • Maakt het BitmapFilter-object glowFilter en wijst dit object toe aan de retourwaarden van de functie getBitmapFilter().
   • Wijst de array met de waarden van het glowFilter-object toe aan de eigenschap filters van het hoofdweergaveobject. In dit geval worden de eigenschappen van het gloedfilter overgenomen door alle onderliggende weergaveobjecten van het hoofdweergaveobject. Als gevolg hiervan worden de eigenschappen van het gloedfilter weergegeven door de rechthoek die door de functie draw() is gemaakt.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.GlowFilter;

    public class GlowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function GlowFilterExample() {
        //draw the rectangle using the draw() function below
            draw();
            
        //assign the values from getBitmapFilter function below
        //to a BitmapFilter object "glowFilter"
            var glowFilter:BitmapFilter = getBitmapFilter();
            
        //populate the filters property of the root display object with the array of values
        //from the glowFilter object.
            filters = [ glowFilter ];
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x33CCFF;
            var alpha:Number = 0.8;
            var blurX:Number = 35;
            var blurY:Number = 35;
            var strength:Number = 2;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;

            return new GlowFilter(color,
                                  alpha,
                                  blurX,
                                  blurY,
                                  strength,
                                  quality,
                                  inner,
                                  knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}