WorkerDomain  - AS3

De WorkerDomain-instantie waarin de code momenteel wordt uitgevoerd. Dit is het enige WorkerDomain in de toepassing.

Geeft aan of de huidige context van de runtime ondersteuning biedt voor gelijktijdige uitvoering van de WorkerDomain- en Worker-objectcode.

Als gelijktijdige uitvoering beschikbaar is, wordt deze eigenschap ingesteld op true.

Maakt een nieuwe Worker-instantie op basis van de bytes in een SWF-bestand.

Elke worker is gemaakt op basis van een geïsoleerde SWF-toepassing en wordt ook als zodanig uitgevoerd. Als u een Worker-instantie wilt maken, moet u de bytes van het SWF-bestand ophalen als ByteArray-instantie en doorgeven aan deze methode. Er zijn drie manieren om de bytes van een SWF-bestand op te halen:

• Gebruik de [Embed]-metatag om het SWF-bestand als een ByteArray in te sluiten in de toepassing:

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Laad een extern SWF-bestand met behulp van URLLoader:

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Gebruik een enkel SWF-bestand voor zowel de 'primordial worker' als voor de worker op de achtergrond.

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

Als u een Worker-object maakt met behulp van createWorker(), wordt de worker niet automatisch uitgevoerd. Als u de code van de worker wilt uitvoeren, moet u de methode start() van het Worker-object aanroepen.

Workers zijn handig omdat het risico op een tragere framesnelheid doordat de hoofdthread voor rendering wordt geblokkeerd door andere code, wordt verkleind. Workers vereisen echter ook extra systeemgeheugen en CPU-gebruik, en dat gaat soms ten koste van de algehele prestaties van de toepassing. Aangezien elke worker een eigen instantie van de runtime-VM gebruikt, kan zelfs een eenvoudige worker leiden tot een aanzienlijke overhead. Wanneer u workers gebruikt, moet u uw code dan ook testen op alle doelplatforms om te voorkomen dat het systeem niet te zwaar wordt belast. Adobe raadt aan dat u niet meer dan een of twee workers op de achtergrond gebruikt in een typisch scenario.

Parameters

Biedt toegang tot de set met workers in het WorkerDomain die gelijktijdig worden uitgevoerd (de state-eigenschap van de Worker-instantie is WorkerState.RUNNING).