| Pakket | flash.html |
| Klasse | public class HTMLHost |
| Overerving | HTMLHost  Object |
| Runtimeversies: | AIR 1.0 |
vensterobject van de HTML-pagina aan te roepen. Deze methoden en eigenschappen zijn de volgende:
-
window.blur() -
window.focus() -
window.moveBy() -
window.moveTo() -
window.location -
window.close() -
window.open() -
window.resizeBy() -
window.resizeTo() -
window.status -
window.document.title
De methoden in de klasse HTMLHost bieden manieren waarop wijzigingen in elk van deze vensterinstellingen moeten worden afgehandeld. Als u deze klasse wilt gebruiken, maakt u een nieuwe klasse (een subklasse) die de klasse HTMLHost uitbreidt en de methoden waarvoor u gedrag wilt definiëren overschrijft. De methoden van de klasse HTMLHost handelen JavaScript-eigenschappen en -methoden als volgt af:
| JavaScript-eigenschap of -methode | Methode HTMLHost |
|---|---|
window.blur()
|
windowBlur()
|
window.focus()
|
windowFocus
|
window.location
|
updateLocation
|
window.close()
|
windowClose
|
window.open()
|
createWindow
|
window.status
|
updateStatus
|
window.document.title
|
updateTitle
|
Als u wilt reageren op wijzigingen in de methoden window.moveBy(), window.moveTo(), window.resizeBy() en window.resizeTo(), overschrijft u de methode set windowRect() in de subklasse HTMLHost.
Elk HTMLHost-object kan aan hoogstens één HTMLLoader-object worden gekoppeld. Door een HTMLHost-instantie toe te kennen aan de eigenschap htmlHost van het HTMLLoader-object, wordt deze relatie tot stand gebracht. Door null toe te kennen aan de eigenschap htmlHost van het HTMLLoader-object of door het HTMLHost-object in te stellen als de eigenschap htmlHost van een ander HTMLLoader-object, verwijdert u de HTMLHost uit het eerste HTMLLoader-object.
Verwante API-elementen
Overerfde openbare eigenschappen verbergen
Overerfde openbare eigenschappen weergeven| Eigenschap | Gedefinieerd door | ||
|---|---|---|---|
 | constructor : Object
Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie. | Object | |
| htmlLoader : flash.html:HTMLLoader [alleen-lezen]
Het HTMLLoader-object waarop dit HostControl-object van toepassing is. | HTMLHost | ||
| windowRect : Rectangle
De eigenschap die wordt gewijzigd wanneer JavaScript-code in het object HTMLLoader de methode window.moveBy(), window.moveTo(), window.resizeBy() of window.resizeTo() aanroept. | HTMLHost | ||
| Methode | Gedefinieerd door | ||
|---|---|---|---|
Maakt een HTMLHost-object. | HTMLHost | ||
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.open() aanroept. | HTMLHost | ||
|
Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd. | Object | |
|
Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven. | Object | |
|
Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd. | Object | |
|
Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in. | Object | |
|
Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies. | Object | |
|
Retourneert een tekenreeksrepresentatie van het opgegeven object. | Object | |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.location aanroept. | HTMLHost | ||
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.status aanroept. | HTMLHost | ||
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de eigenschap window.document.title instelt of wanneer het element titel wordt gewijzigd. Dit kan via de DOM of omdat er een nieuwe pagina wordt geladen. | HTMLHost | ||
|
Retourneert de primitieve waarde van het opgegeven object. | Object | |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.blur() aanroept. | HTMLHost | ||
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.close() aanroept. | HTMLHost | ||
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.focus() aanroept. | HTMLHost | ||
htmlLoader | eigenschap |
htmlLoader:flash.html:HTMLLoader [alleen-lezen] | Runtimeversies: | AIR 1.0 |
Het HTMLLoader-object waarop dit HostControl-object van toepassing is. De eigenschap htmlHost van dat HTMLLoader-object wordt ingesteld op dit HostControl-object.
Implementatie
public function get htmlLoader():flash.html:HTMLLoaderVerwante API-elementen
windowRect | eigenschap |
windowRect:Rectangle| Runtimeversies: | AIR 1.0 |
De eigenschap die wordt gewijzigd wanneer JavaScript-code in het object HTMLLoader de methode window.moveBy(), window.moveTo(), window.resizeBy() of window.resizeTo() aanroept.
Overschrijf in de subklasse van HTMLHost de methode set windowRect() om de nieuwe vensterbegrenzingen af te handelen zoals dat nodig is.
Implementatie
public function get windowRect():Rectangle public function set windowRect(value:Rectangle):void HTMLHost | () | Constructor |
createWindow | () | methode |
public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader| Runtimeversies: | AIR 1.0 |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.open() aanroept.
Standaard wordt met een JavaScript-aanroep naar window.open() op de HTML-pagina van een HTMLLoader geen nieuw NativeWindow-object in de runtime geopend. U kunt een nieuw NativeWindow-object in de runtime openen door een nieuw NativeWindow-object in de methodeoverschrijving createWindow te maken in de subklasse van de klasse HTMLHost.
Parameters
windowCreateOptions:flash.html:HTMLWindowCreateOptions — Een object dat eigenschappen bevat in de tekenreeks die als de parameter features van de aanroep naar window.open() is doorgegeven.
|
flash.html:HTMLLoader — Een HTMLLoader-object dat de nieuwe HTML-pagina bevat. Gewoonlijk maakt u in deze methode een nieuw HTMLLoader-object, voegt u het toe aan het werkgebied van een nieuw NativeWindow-object, en retourneert u het.
|
updateLocation | () | methode |
public function updateLocation(locationURL:String):void| Runtimeversies: | AIR 1.0 |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.location aanroept.
Parameters
locationURL:String — De waarde waarop de eigenschap location van de eigenschap window van het HTMLLoader-object wordt ingesteld.
|
updateStatus | () | methode |
public function updateStatus(status:String):void| Runtimeversies: | AIR 1.0 |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.status aanroept.
Parameters
status:String — De waarde waarop de eigenschap status van de eigenschap window van het HTMLLoader-object wordt ingesteld.
|
updateTitle | () | methode |
public function updateTitle(title:String):void| Runtimeversies: | AIR 1.0 |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de eigenschap window.document.title instelt of wanneer het element titelwordt gewijzigd. Dit kan via de DOM of omdat er een nieuwe pagina wordt geladen.
Parameters
title:String — De waarde waarop de eigenschap window.document.title van het HTMLLoader-object wordt ingesteld.
|
windowBlur | () | methode |
public function windowBlur():void| Runtimeversies: | AIR 1.0 |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.blur() aanroept.
windowClose | () | methode |
public function windowClose():void| Runtimeversies: | AIR 1.0 |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.close() aanroept.
Standaard wordt met een JavaScript-aanroep van window.close() in de HTML-pagina van een HTMLLoader-object het venster met het HTMLLoader-object gesloten.
windowFocus | () | methode |
public function windowFocus():void| Runtimeversies: | AIR 1.0 |
De functie die wordt aangeroepen wanneer JavaScript-code in het HTMLLoader-object de methode window.focus() aanroept.
window-object aanroept:
package
{
import flash.html.HTMLHost;
import flash.html.HTMLLoader;
import flash.display.NativeWindow;
import flash.display.NativeWindowInitOptions;
import flash.display.StageScaleMode;
import flash.geom.Rectangle;
import flash.text.TextField;
public class CustomHost extends HTMLHost
{
import flash.html.*;
public var statusField:TextField;
public function CustomHost(defaultBehaviors:Boolean=true)
{
super(defaultBehaviors);
}
override public function windowClose():void
{
htmlLoader.stage.window.close();
}
override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
{
var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
var window:NativeWindow = new NativeWindow(initOptions);
window.visible = true;
var htmlLoader2:HTMLLoader = new HTMLLoader();
htmlLoader2.width = window.width;
htmlLoader2.height = window.height;
window.stage.scaleMode = StageScaleMode.NO_SCALE;
window.stage.addChild(htmlLoader2);
return htmlLoader2;
}
override public function updateLocation(locationURL:String):void
{
trace(locationURL);
}
override public function set windowRect(value:Rectangle):void
{
htmlLoader.stage.nativeWindow.bounds = value;
}
override public function updateStatus(status:String):void
{
statusField.text = status;
}
override public function updateTitle(title:String):void
{
htmlLoader.stage.nativeWindow.title = title + "- Example Application";
}
override public function windowBlur():void
{
htmlLoader.alpha = 0.5;
}
override public function windowFocus():void
{
htmlLoader.alpha = 1;
}
}
}
statusBar. Het HTMLLoader-object definieert een CustomHost-object als zijn eigenschap htmlHost:
package
{
import flash.display.Sprite;
public class SimpleHTMLBox extends Sprite
{
import flash.html.HTMLHost;
import flash.html.HTMLLoader;
import flash.text.TextField;
import flash.net.URLRequest;
import CustomHost;
private var host:CustomHost;
private var statusField:TextField;
private var html:HTMLLoader;
public function SimpleHTMLBox()
{
html = new HTMLLoader();
var url:String = "Test.html";
var urlReq:URLRequest = new URLRequest(url);
html.load(urlReq);
host = new CustomHost();
html.htmlHost = host;
statusField = new TextField();
host.statusField = statusField;
configureUI();
}
private function configureUI():void
{
html.width = 400;
html.height = 200;
statusField.width = 400;
statusField.height = 24;
statusField.border = true;
statusField.y = 200;
addChild(html);
addChild(statusField);
}
}
}Bouw een AIR-toepassing die een object dat met deze klasse is gedefinieerd, toevoegt aan het werkgebied van het hoofdvenster.
Maak een HTML-pagina met de naam Test.html in de map met toepassingsbronnen (de map die het descriptorbestand van de toepassing bevat), en geef die pagina de volgende inhoud:
<html>
<head>
<title>Test</title>
</head>
<body>
<a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
<br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
<br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
<br/><a href="#" onclick="window.close()">window.close()</a>
<br/><a href="#" onclick="window.blur()">window.blur()</a>
<br/><a href="#" onclick="window.focus()">window.focus()</a>
<br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
</body>
</html>Wanneer u de toepassing test, handelt de klasse CustomHost de JavaScript-instellingen met betrekking tot de gebruikersinterface op de HTML-pagina af.
Wed Jun 13 2018, 11:42 AM Z