StorageVolume

Pakket	flash.filesystem
Klasse	public class StorageVolume
Overerving	StorageVolume Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

Een StorageVolume-object bevat eigenschappen die een massa-opslagvolume definiëren. Deze klasse word op twee manieren gebruikt:

De eigenschap storageVolume van een StorageVolumeChangeEvent-object is een StorageVolume-object. Dit object staat voor het opslagvolume dat is gemonteerd of gedemonteerd.
De methode StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() retourneert een vector met StorageVolume-objecten. Elk van deze StorageVolume-objecten staat voor een gemonteerd opslagvolume.

Bekijk de voorbeelden

Verwante API-elementen

flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume

Openbare eigenschappen

Overerfde openbare eigenschappen verbergen

Overerfde openbare eigenschappen weergeven

	Eigenschap		Gedefinieerd door
		constructor : Object Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie.	Object
		drive : String [alleen-lezen] De stationsletter van het volume in Windows.	StorageVolume
		fileSystemType : String [alleen-lezen] Het type bestandssysteem op het opslagvolume (zoals FAT, NTFS, HFS of UFS).	StorageVolume
		isRemovable : Boolean [alleen-lezen] Geeft aan of het besturingssysteem het opslagvolume beschouwt als verwijderbaar (true) of niet (false).	StorageVolume
		isWritable : Boolean [alleen-lezen] Geeft aan of een volume beschrijfbaar is (True) of niet (False).	StorageVolume
		name : String [alleen-lezen] De naam van het volume.	StorageVolume
		rootDirectory : File [alleen-lezen] Een bestandsobject dat overeenkomt met de hoofdmap van het volume.	StorageVolume

Openbare methoden

Overerfde openbare methoden verbergen

Overerfde openbare methoden weergeven

	Methode		Gedefinieerd door
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) De constructorfunctie.	StorageVolume
		hasOwnProperty(name:String):Boolean Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd.	Object
		isPrototypeOf(theClass:Object):Boolean Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven.	Object
		propertyIsEnumerable(name:String):Boolean Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in.	Object
		toLocaleString():String Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.	Object
		toString():String Retourneert een tekenreeksrepresentatie van het opgegeven object.	Object
		valueOf():Object Retourneert de primitieve waarde van het opgegeven object.	Object

Eigenschapdetails

drive

eigenschap

drive:String [alleen-lezen]

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

De stationsletter van het volume in Windows. Bij andere platforms is deze eigenschap ingesteld op null.

Implementatie
public function get drive():String

fileSystemType

eigenschap

fileSystemType:String [alleen-lezen]

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

Het type bestandssysteem op het opslagvolume (zoals FAT, NTFS, HFS of UFS).

Implementatie
public function get fileSystemType():String

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

De volgende code geeft het native pad voor de hoofdmap en het type bestandssysteem van elk gemonteerd opslagvolume:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

eigenschap

isRemovable:Boolean [alleen-lezen]

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

Geeft aan of het besturingssysteem het opslagvolume beschouwt als verwijderbaar (true) of niet (false).

In de volgende tabel vindt u de StorageVolume.isRemovable-waarde-eigenschap voor verschillende typen apparaten:

Soort apparaat	Mac OS	Windows	Linux
CD/DVD (vast)	true	true	true
USB-flashstation	true	true	true
USB-vaste schijf	false	false	true
FireWire-vaste schijf	false	false	true
Gedeeld volume	true	false	- ¹
Netwerkstation	false	false	false
Geheugenkaartlezer (leeg)	- ²	false	- ²
Geheugenkaartlezer (met SD/CF-kaart)	true	true	true

¹ Linux heeft geen concept van een gedeeld volume.

² In Windows wordt een lege kaartlezer weergegeven als een niet-verwijderbaar apparaat. In Mac OS en Linux, worden lege kaartlezers niet weergegeven als opslagvolumes.

Implementatie
public function get isRemovable():Boolean

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

De volgende code maakt een lijst met niet-verwijderbare opslagvolumes, gevolgd door een lijst met verwijderbare opslagvolumes:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

eigenschap

isWritable:Boolean [alleen-lezen]

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

Geeft aan of een volume beschrijfbaar is (True) of niet (False).

Opmerking: als u de hoeveelheid beschikbare ruimte van een volume wilt weten, roept u de eigenschap rootDirectory.spaceAvailble van het StorageVolume-object aan.

Implementatie
public function get isWritable():Boolean

Verwante API-elementen

flash.fileSystem.File.spaceAvailable

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

De volgende code maakt een lijst met schrijfbare opslagvolumes en de beschikbare ruimte:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

eigenschap

name:String [alleen-lezen]

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

De naam van het volume. Als er geen naam is, wordt deze eigenschap ingesteld op null.

Implementatie
public function get name():String

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

De volgende code geeft het native pad voor de hoofdmap en de naam van het bestandssysteem (indien aanwezig) voor elk gemonteerd opslagvolume.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

eigenschap

rootDirectory:File [alleen-lezen]

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

Een bestandsobject dat overeenkomt met de hoofdmap van het volume.

Implementatie
public function get rootDirectory():File

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

De volgende code bevat het native pad voor de hoofdmap of elk gemonteerd opslagvolume:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

Constructordetails

()

Constructor

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 2

De constructorfunctie. Over het algemeen roept u deze constructorfunctie niet rechtstreeks aan (om nieuwe StorageVolume-objecten te maken). In plaats daarvan verwijst u StorageVolume-objecten door toegang te krijgen tot de eigenschap storageVolume van een StorageVolumeChangeEvent-object of door StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() aan te roepen.

Parameters

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

Voorbeelden Hoe dit voorbeeld te gebruiken

StorageVolumeExample.as

De volgende code geeft een overzicht van de eigenschappen van elk gemonteerd opslagvolume:

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

De volgende code geeft een overzicht van de eigenschappen van elk opslagvolume dat wordt gemonteerd of gedemonteerd: Merk op dat de eigenschap storageVolume van StorageVolumeChangeEvent alleen wordt ingesteld voor de gebeurtenis storageVolumeMount. De waarde is null voor de gebeurtenisstorageVolumeUnmount:

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

Juridische kennisgeving | Online privacybeleid

StorageVolume - AS3

Klassen x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume