PrintJobOptions  - AS3

Geeft de resolutie aan die voor bitmappen moet worden gebruikt, in pixels per inch. De standaardwaarde is Number.NaN, wat aangeeft dat de native printerresolutie moet worden gebruikt.

De resolutie-instelling geldt voor zowel afdrukken met de bitmapmethode als voor afdrukken met de vectormethode. Voor afdrukken met bitmappen, bepaalt de resolutie hoe de volledige pagina wordt gerasterd. Voor afdrukken met vectors, bepaalt de resolutie hoe specifiek de content, zoals bitmappen en verlopen, gerasterd wordt.

Bepaalt of de inhoud van de afdruktaak als een bitmap of als een vector moet worden afgedrukt. De standaardwaarde is false voor vectorafdrukken.

Wanneer de inhoud die u wilt afdrukken een bitmapafbeelding bevat, stelt u printAsBitmap in op true zodat eventuele alpha-transparantie en kleureffecten worden opgenomen. Wanneer de inhoud die u wilt afdrukken geen bitmapafbeeldingen bevat, moet u de inhoud afdrukken in de vectorindeling. Deze indeling biedt een hogere kwaliteit en is tevens de standaardoptie.

Wanneer u de inhoud als een bitmap wilt afdrukken, gebruikt u de volgende syntaxis:

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);
         

Opmerking: Adobe AIR biedt geen ondersteuning voor vectorafdrukken in Mac OS.

Verwante API-elementen

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

Geeft aan dat de Flash-runtime de meest geschikte afdrukmethode kiest of dat de auteur expliciet zelf selecteert of er moet worden afgedrukt met de vectormethode of met de bitmapmethode.

Stel de eigenschap in op een van de volgende waarden die zijn gedefinieerd in de klasse PrintMethod:

• PrintMethod.AUTO: Geeft aan dat het afdrukken met de vector- of bitmapmethode automatisch wordt ingesteld op basis van de inhoud die moet worden afgedrukt. Afdrukken met een vector wordt gebruikt wanneer de content correct door die methode kan worden gereproduceerd. Als transparantie of bepaalde andere effecten aanwezig zijn, wordt in plaats daarvan afdrukken met een bitmap gebruikt.
• PrintMethod.VECTOR: Geeft aan dat er wordt afgedrukt met de vectormethode. Deze instelling heeft hetzelfde resultaat als het instellen van printAsBitmap op false.
• PrintMethod.BITMAP: Geeft aan dat er wordt afgedrukt met de bitmapmethode. Deze instelling heeft hetzelfde resultaat als het instellen van printAsBitmap op true.

Als u printMethod instelt op een van deze ondersteunde waarden, wordt printAsBitmap genegeerd.

De standaardwaarde is null; de eigenschap printAsBitmap wordt gebruikt.

Verwante API-elementen

Maakt een nieuw object PrintJobOptions. Geef dit object door aan de parameter options van de methode PrintJob.addPage().

Verwante API-elementen