PrintJob  - AS3

Geeft aan of een afdruktaak op dat moment actief is of niet. Een afdruktaak is actief (de eigenschap heeft de waarde true) als aan een van de volgende voorwaarden wordt voldaan:

• Het dialoogvenster Pagina-instelling of het dialoogvenster Afdrukken wordt weergegeven.
• De methode start() of start2() is aangeroepen en heeft als retourwaarde true, en de methode send() of terminate() is niet aangeroepen.

Als deze eigenschap de waarde true heeft en u roept de methode showPageSetupDialog(), start() of start2() aan, dan wordt er een uitzondering gegenereerd door de runtime.

Verwante API-elementen

Het aantal exemplaren dat door het afdruksysteem wordt afgedrukt van de pagina's die vervolgens aan de afdruktaak zijn toegevoegd. Deze waarde is het aantal exemplaren dat door de gebruiker is ingevoerd in het dialoogvenster Afdrukken van het besturingssysteem. Als het aantal exemplaren niet in het dialoogvenster Afdrukken is weergegeven of als dit dialoogvenster niet aan de gebruiker is getoond, is de waarde 1 (tenzij deze waarde is gewijzigd door toepassingscode).

Het paginanummer van de eerste pagina in het bereik dat door de gebruiker is ingevoerd in het dialoogvenster Afdrukken van het besturingssysteem. Deze eigenschap is nul als de gebruiker heeft aangegeven dat alle pagina's moeten worden afgedrukt, als het paginabereik niet in het dialoogvenster Afdrukken is weergegeven, of als het dialoogvenster Afdrukken niet aan de gebruiker is getoond.

Geeft aan of de momenteel geselecteerde printer met de huidige afdrukinstellingen afdrukken maakt in kleur (true) of met grijswaarden (false).

De waarde is true als er niet kan worden vastgesteld of er in kleur of met grijswaarden wordt afgedrukt.

Geeft aan of de klasse PrintJob op het huidige platform wordt ondersteund (true) of niet (false).

De naam of titel van de afdruktaak. De taaknaam wordt doorgaans door het besturingssysteem gebruikt voor de titel van de taak in de afdrukwachtrij of voor de standaardnaam van de taak als deze naar een bestand wordt afgedrukt.

Als u start() of start2() niet hebt aangeroepen en u geen waarde voor de eigenschap hebt ingesteld, dan heeft deze eigenschap de waarde null.

Stel bij elke afdruktaak die u uitvoert met een instantie van PrintJob, deze eigenschap in voordat u de methode start() of start2() aanroept.

De standaardwaarde is null.

Het paginanummer van de laatste pagina in het bereik dat door de gebruiker is ingevoerd in het dialoogvenster Afdrukken van het besturingssysteem. Deze eigenschap is nul als de gebruiker heeft aangegeven dat alle pagina's moeten worden afgedrukt, als het paginabereik niet in het dialoogvenster Afdrukken is weergegeven, of als het dialoogvenster Afdrukken niet aan de gebruiker is getoond.

De fysieke resolutie van de geselecteerde printer in pixels per inch. De waarde wordt berekend op basis van de huidige afdrukinstellingen die door het besturingssysteem worden doorgegeven.

Als de resolutie niet kan worden vastgesteld, is de waarde een standaardwaarde. De standaardwaarde is 600 ppi op Linux en 360 ppi op Mac OS. In Windows is de printerresolutie altijd beschikbaar en is er dus geen standaardwaarde nodig.

De afdrukstand van afbeeldingen. De geaccepteerde waarden zijn gedefinieerd als constanten in de klasse PrintJobOrientation.

Opmerking: Om de afdrukstand in te stellen in het dialoogvenster Pagina-instelling en het dialoogvenster Afdrukken, moet u in AIR 2 of hoger deze eigenschap instellen voordat u een afdruktaak start. Om de afdrukstand voor een paginabereik in de taak in te stellen, stelt u de eigenschap in terwijl de afdruktaak wordt uitgevoerd (nadat start() of start2() is aangeroepen).

Verwante API-elementen

De hoogte van het grootste gebied dat in het werkelijk bedrukbare gebied van een pagina kan worden gecentreerd, in punten. Door de gebruiker ingestelde marges worden genegeerd. Deze eigenschap is alleen beschikbaar na een aanroep van de methode PrintJob.start().

Opmerking: Deze eigenschap is vervangen in AIR 2 en hoger. Gebruik in plaats hiervan printableArea, dat het bedrukbare gebied meet in fractionele punten en niet-gecentreerde bedrukbare gebieden correct beschrijft.

Verwante API-elementen

De breedte van het grootste gebied dat in het werkelijk bedrukbare gebied van een pagina kan worden gecentreerd, in punten. Door de gebruiker ingestelde marges worden genegeerd. Deze eigenschap is alleen beschikbaar na een aanroep van de methode PrintJob.start().

Opmerking: Deze eigenschap is vervangen in AIR 2 en hoger. Gebruik in plaats hiervan printableArea, dat het bedrukbare gebied meet in fractionele punten en niet-gecentreerde bedrukbare gebieden correct beschrijft.

Verwante API-elementen

De grenzen van de printermedia in punten. Deze waarde gebruikt hetzelfde coördinatensysteem dat wordt gebruikt voor volgende aanroepen naar addPage().

De algemene papierhoogte, in punten. Deze eigenschap is alleen beschikbaar na een aanroep van de methode PrintJob.start().

Opmerking: Deze eigenschap is vervangen in AIR 2 en hoger. Gebruik in plaats hiervan paperArea, dat de papierafmetingen meet in fractionele punten.

Verwante API-elementen

De algemene papierbreedte, in punten. Deze eigenschap is alleen beschikbaar na een aanroep van de methode PrintJob.start().

Opmerking: Deze eigenschap is vervangen in AIR 2 en hoger. Gebruik in plaats hiervan paperArea, dat de papierafmetingen meet in fractionele punten.

Verwante API-elementen

De grenzen van het afdrukbare gebied van de printermedia in punten. Deze waarde gebruikt hetzelfde coördinatensysteem dat wordt gebruikt voor volgende aanroepen naar addPage().

Haalt de printer op of stelt de printer in die voor de huidige afdruktaak moet worden gebruikt. De string die aan de setter is doorgegeven en door de getter is geretourneerd, moet overeenkomen met een van de strings in de Array die door methode printers() wordt geretourneerd. Stel de waarde in op null om aan te geven dat de standaardprinter moet worden gebruikt. Op besturingssystemen waarvoor de standaardprinter niet kan worden vastgesteld heeft deze eigenschap de waarde null.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.printer = "HP_LaserJet_1";
     myPrintJob.start();
     

Door het instellen van de waarde van deze eigenschap, wordt er onmiddellijk geprobeerd de printer te selecteren. Als het selecteren van de printer mislukt, wordt de waarde van deze eigenschap weer ingesteld op de vorige waarde. Nadat u de printerwaarde hebt ingesteld kunt u nagaan of het instellen daadwerkelijk is gelukt door de waarde handmatig te controleren. Op deze manier kunt u vaststellen of de waarde overeenkomt met de door u ingestelde waarde.

De eigenschap printer van een actieve afdruktaak kan niet worden gewijzigd. Het wijzigen van deze eigenschap mislukt als dit gebeurt nadat de methode start() of start2() succesvol is aangeroepen en voordat send() of terminate() is aangeroepen.

Retourneert een lijst met de beschikbare printers als stringnaamwaarden. De lijst wordt niet vooraf berekend, maar wordt gegenereerd wanneer de functie wordt aangeroepen. Als er geen printers beschikbaar zijn of als afdrukken niet door het systeem wordt ondersteund, is de waarde null. Als het systeem wel ondersteuning voor afdrukken biedt maar niet over de functionaliteit beschikt om een lijst met printers te retourneren, is de waarde een vector met één enkel element (de eigenschap length hiervan heeft de waarde 1). In dit geval is het enkele element de daadwerkelijke printernaam of een standaardnaam als de huidige printernaam niet kan worden vastgesteld.

Geeft aan of de Flash-runtimeomgeving ondersteuning biedt voor een afzonderlijk dialoogvenster Pagina-instelling. Als deze eigenschap de waarde true heeft, kunt u de methode showPageSetupDialog() aanroepen om het dialoogvenster Pagina-instelling van het besturingssysteem weer te geven.

Verwante API-elementen

Maakt een PrintJob-object dat u kunt gebruiken om een of meer pagina's af te drukken. Nadat u een object PrintJob hebt gemaakt,moet u (in onderstaande volgorde) de methoden PrintJob.start(), PrintJob.addPage() en vervolgens PrintJob.send() gebruiken om de afdruktaak naar de printer te verzenden.

U kunt bijvoorbeeld de tekst van de tijdelijke aanduiding [params] van de methodeaanroepen myPrintJob.addPage() vervangen door aangepaste parameters, zoals in de volgende code wordt getoond:

 // create PrintJob object
 var myPrintJob:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (myPrintJob.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    myPrintJob.send();
 }
 

In AIR 2 of hoger kunt meerdere PrintJob-instanties maken en gebruiken. Eigenschappen die voor de PrintJob-instantie zijn ingesteld, blijven geldig nadat het afdrukken is voltooid. Hierdoor kunt u een PrintJob-instantie opnieuw gebruiken en de door een gebruiker geselecteerde afdrukvoorkeuren behouden, terwijl er voor andere inhoud in uw toepassing andere afdrukvoorkeuren kunnen worden ingesteld. U kunt voor inhoud in Flash Player en in versies van AIR ouder dan AIR 2 geen tweede PrintJob-object maken als het eerste object nog steeds actief is. Wanneer u een tweede PrintJob-object maakt (door new PrintJob() aan te roepen) terwijl het eerste PrintJob-object nog actief is, wordt het tweede PrintJob-object niet gemaakt. Het is daarom verstandig de waarde myPrintJob te controleren voordat u een tweede PrintJob-object maakt.

Verwante API-elementen

Verzendt het opgegeven Sprite-object als een enkele pagina naar de afdrukspooler. Voordat u deze methode gebruikt, moet u een PrintJob-object maken en vervolgens start() of start2() gebruiken. Nadat u addPage() een of meerdere keren hebt aangeroepen voor een afdruktaak, gebruikt u send() om de gespoolde pagina's naar de printer te versturen. Met andere woorden, nadat u een PrintJob-object hebt gemaakt gebruikt u (in deze volgorde) start() of start2(), addPage() en vervolgens send() om de afdruktaak naar de printer te versturen. U kunt na één aanroep naar start(), addPage() meerdere keren aanroepen om meerdere pagina's in een afdruktaak af te drukken.

Als addPage() een uitzondering in Flash Player veroorzaakt (omdat u bijvoorbeeld start() niet hebt aangeroepen of omdat de gebruiker de afdruktaak heeft geannuleerd), mislukken alle volgende aanroepen naar addPage(). Als eerdere aanroepen naar addPage() echter wel zijn gelukt, verzendt de laatste send()-opdracht de gespoolde pagina's naar de printer.

Als de afdruktaak meer dan 15 seconden nodig heeft om de bewerking addPage() te voltooien, genereert Flash Player een uitzondering voor de volgende aanroep naar addPage().

Als u een waarde voor de parameter printArea doorgeeft, worden de x- en y-coördinaten van de rechthoek printArea in de linkerbovenhoek (coördinaat 0,0) van het afdrukbare gebied van de pagina geplaatst. De alleen-lezen eigenschappen pageHeight en pageWidth geven het afdrukbare gebied aan dat wordt ingesteld door start(). Afdrukken worden uitgelijnd ten opzichte van de linkerbovenhoek van het afdrukbare gebied van de pagina. Als het gebied dat in printArea is gedefinieerd groter is dan het afdrukbare gebied van de pagina, wordt de afdruk daarom afgekapt aan de rechterzijde of aan de onderzijde (of beide) van het gebied dat is gedefinieerd in printArea. Als u in Flash Professional geen waarde voor printArea hebt doorgegeven en het werkgebied is groter dan het afdrukbare gebied, wordt de afdruk op dezelfde manier afgekapt. Als u in Flex of Flash Builder geen waarde voor printArea hebt doorgegeven en het scherm is groter dan het afdrukbare gebied, wordt de afbeelding op dezelfde manier afgekapt.

Wanneer u een object Sprite wilt schalen voordat u het gaat afdrukken, stelt u de eigenschappen (zie flash.display.DisplayObject.scaleX en flash.display.DisplayObject.scaleY) in voordat u deze methode aanroept en zet u de eigenschappen na het afdrukken terug naar de oorspronkelijke waarden. De schaal van een object Sprite is niet gerelateerd aan printArea. Wanneer u een afdrukgebied van 50 x 50 pixels opgeeft, worden er 2500 pixels afgedrukt. Wanneer u het object Sprite hebt geschaald, worden ook 2500 pixels afgedrukt, maar wordt het object met de geschaalde grootte afgedrukt.

De afdrukfunctie van Flash Player biedt ondersteuning voor PostScript- en niet-PostScript-printers. Bij niet-PostScript-printers worden vectoren in bitmaps omgezet.

Parameters

Verwante API-elementen

Stelt het papierformaat in. De geaccepteerde waarden voor de parameter paperSize zijn constanten in de klasse PaperSize. Het aanroepen van deze methode heeft hetzelfde effect op de afdrukinstellingen als wanneer de gebruiker een papierformaat kiest in het dialoogvenster Pagina-instelling of in het dialoogvenster Afdrukken.

U kunt deze methode op elk gewenst moment aanroepen. Roep deze methode aan voordat u begint met een afdruktaak om het standaardpapierformaat in te stellen in het dialoogvenster Pagina-instelling en het dialoogvenster Afdrukken. Roep deze methode aan als er een afdruktaak actief is om het papierformaat in te stellen voor een paginabereik in de taak.

     import flash.printing.PrintJob;
     import flash.printing.PaperSize;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.selectPaperSize(PaperSize.ENV_10);
     

Parameters

Verwante API-elementen

Verstuurt gespoolde aanroepen naar de printer na succesvolle aanroepen naar de methoden start(), start2() en addPage().

Deze methode mislukt als de aanroep naar de methode start() of start2() mislukt of als er een uitzondering wordt gegenereerd bij een aanroep naar de methode addPage(). Om een fout te vermijden, controleert u voordat u deze methode aanroept of de methode start() of start2() true retourneert en vangt u eventuele addPage()-uitzonderingen af. In het volgende voorbeeld wordt gedemonstreerd hoe u op de juiste wijze op fouten kunt controleren voordat u deze methode aanroept:

     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.start()) {
       try {
         myPrintJob.addPage([params]);
       }
       catch(e:Error) {
          // handle error 
       }
     
       myPrintJob.send();
     }
     

Verwante API-elementen

Geeft het dialoogvenster Pagina-instelling van het besturingssysteem weer als de huidige omgeving hiervoor ondersteuning biedt. Gebruik de supportsPageSetupDialog-eigenschap om te bepalen of Pagina-instelling wordt ondersteund.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.supportsPageSetupDialog)
     {
         myPrintJob.showPageSetupDialog();
     }
     

Verwante API-elementen

Hiermee wordt het dialoogvenster Afdrukken van het besturingssysteem weergegeven en wordt er met spoolen begonnen. In het dialoogvenster Afdrukken kan de gebruiker de afdrukinstellingen wijzigen. Wanneer de methode PrintJob.start() lukt (nadat de gebruiker in het dialoogvenster Afdrukken op OK heeft geklikt), worden de volgende eigenschappen gevuld op basis van de afdrukinstellingen die door de gebruiker zijn gekozen:

Opmerking: wanneer de gebruiker in het dialoogvenster Afdrukken op Annuleren klikt, worden de eigenschappen niet gevuld.

Wanneer de gebruiker in het dialoogvenster Afdrukken op OK klikt, wordt een afdruktaak naar het besturingssysteem gespoold. Omdat het besturingssysteem vervolgens informatie over de voortgang van het afdrukken aan de gebruiker toont, moet u PrintJob.addPage() en PrintJob.send() zo spoedig mogelijk aanroepen om de pagina's naar de spooler te verzenden. U kunt de alleen-lezen-eigenschappen voor hoogte, breedte en afdrukstand gebruiken die met deze methode worden gevuld om de lay-out van de afdruk te bepalen.

Voer een test uit om te controleren of deze methode true retourneert (als de gebruiker in het dialoogvenster Afdrukken van het besturingssysteem op OK klikt) voordat er nieuwe aanroepen worden uitgevoerd van PrintJob.addPage() en PrintJob.send():

     var myPrintJob:PrintJob = new PrintJob();
        if(myPrintJob.start()) {
          // addPage() and send() statements here
        }
     

Wanneer een van de volgende intervallen voor de instantie van deze afdruktaak langer duurt dan 15 seconden, retourneert de volgende aanroep van PrintJob.start() false

• PrintJob.start() en de eerste PrintJob.addPage()
• Eén PrintJob.addPage() en de volgende PrintJob.addPage()
• De laatste PrintJob.addPage() en PrintJob.send()

Verwante API-elementen

Hiermee wordt optioneel het dialoogvenster Afdrukken van het besturingssysteem weergegeven, wordt het spoolen gestart en worden eventueel de waarden voor de alleen-lezen-eigenschappen van PrintJob aangepast.

Met de uiOptions-parameter kan de oproeper bepalen welke opties er in het het dialoogvenster Afdrukken worden weergegeven. Zie de PrintUIOptions-klasse. Deze parameter wordt genegeerd als showPrintDialog false is.

Zelfs als showPrintDialog de waarde true heeft, kan het gedrag van deze methode anders zijn dan dat van de methode start(). Op sommige besturingssystemen geeft start() het dialoogvenster Pagina-instelling weer, gevolgd door het dialoogvenster Afdrukken. Bij start2() daarentegen wordt het dialoogvenster Pagina-instelling nooit weergegeven.

In het volgende voorbeeld worden de minimale en maximale pagina-instellingen in het dialoogvenster Afdrukken ingesteld voordat het dialoogvenster aan de gebruiker wordt getoond:

     import flash.printing.PrintJob;
     import flash.printing.PrintUIOptions;
     
     var myPrintJob:PrintJob = new PrintJob();
     var uiOpt:PrintUIOptions = new PrintUIOptions();
     uiOpt.minPage = 1;
     uiOpt.maxPage = 3;
     var accepted:Boolean = myPrintJob.start2(uiOpt);
     

Parameters

Verwante API-elementen

Geeft aan dat de afdruktaak zonder verzenden moet worden beëindigd. Gebruik deze methode wanneer er al een afdruktaak is gestart door een aanroep naar start() of start2(), maar er nog geen pagina's naar de printer moeten worden gestuurd. terminate() wordt doorgaans alleen gebruikt nadat er een fout is opgetreden en er een herstelbewerking moet worden uitgevoerd.

Nadat deze methode is aangeroepen, kan de instantie van PrintJob opnieuw worden gebruikt. Waar mogelijk worden de instellingen voor de afdruktaak behouden, zodat deze in volgende taken opnieuw kunnen worden gebruikt

1. Declareer twee variabelen van het type Sprite met de naam sheet1 en sheet2.
2. Roep init() aan, zodat er een nieuwe instantie Sprite wordt toegewezen aan sheet1 en sheet2 en waarvoor vervolgens createSheet() wordt aangeroepen met andere argumenten.
3. createSheet() doet het volgende:
   1. Het doorgegeven object Sprite wordt gebruikt om een rechthoek te tekenen van 100 pixels breed en 200 pixels hoog, op x = 0 en y = 0, met een lichtgrijze achtergrond en een zwarte rand van één pixel.
   2. Hiermee wordt een nieuw object TextField gemaakt met de naam txt met dezelfde afmetingen als de Sprite. De eigenschap WordWrap wordt ingesteld op true en geeft de eigenschap text voor de tekenreeks door als argument voor createSheet().
   3. Wanneer het doorgegeven argument Object niet nul is, wordt een nieuwe instantie Sprite gemaakt met de naam img die wordt gebruikt om een witte rechthoek te tekenen met de coördinaten en afmetingen van het doorgegeven object. De witte rechthoek wordt aan het weergaveoverzicht van het object sprite toegevoegd door middel van addChild().
   4. Het TextField txt wordt aan het weergaveoverzicht van het object Sprite toegevoegd door middel van addChild().
4. In de constructor wordt vervolgens de geactiveerde afdrukmethode (zonder opmerkingen) aangeroepen. Aangezien deze methoden sterk overeenkomen, wordt printOnePerPage() hieronder beschreven.
5. printOnePerPage() doet het volgende:
   1. Declareert een nieuw object PrintJob met de naam pj en pagesToPrint als een uint.
   2. Opent het afdrukdialoogvenster van het besturingssysteem en wacht tot de gebruiker klikt op OK
   3. Controleert de afdrukstand en als de optie Liggend is geselecteerd, resulteert dat in een fout en wordt het venster gesloten.
   4. Stelt de paginahoogte en -breedte in voor sheet1 en sheet2.
   5. Verzendt sheet1 en sheet2 naar de afdrukspooler met addPage().
   6. Wanneer het aantal pagina's dat moet worden afgedrukt groter is dan 0, worden alle gespoolde pagina's afgedrukt.
6. De methode draw() wordt aangeroepen om de grootte van de twee Sprite-eigenschappen aan het werkgebied aan te passen en sheet2 rechts te plaatsen van sheet1.

Opmerking: de constructor is zodanig ingesteld dat een van de drie afdrukmethoden (één blad per pagina, twee bladen per pagina, of afdrukken op de bovenste helft van de pagina) naar wens kan worden geselecteerd. Dit voorbeeld werkt alleen wanneer twee van de drie afdrukmethoden met codeopmerkingen zijn uitgeschakeld. Het voorbeeld is zodanig opgesteld dat printOnePerPage() wordt aangeroepen.

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}