Clipboard  - AS3

Een array van tekenreeksen die de namen van alle beschikbare gegevensindelingen in dit object Clipboard bevat.

Tekenreeksconstanten voor de namen van de standaardgegevensindelingen worden in de klasse ClipboardFormats gedefinieerd. U mag ook andere, in de toepassing gedefinieerde tekenreeksen als indelingsnamen gebruiken om gegevens als een object over te brengen.

Verwante API-elementen

 var availableFormats:Array = Clipboard.generalClipboard.formats;

Het klembord van het besturingssysteem.

Alle gegevens die op het systeemklembord zijn geplakt zijn voor andere toepassingen beschikbaar. Dit kan ook onveilige code op afstand zijn die in een webbrowser wordt uitgevoerd.

Opmerking: In Flash Player 10-toepassingen is een plakbewerking vanaf het klembord alleen mogelijk na een gebruikersgebeurtenis (zoals het indrukken van de sneltoets voor de opdracht Plakken of het kiezen met de muis van de opdracht Plakken in een contextmenu). Clipboard.getData() retourneert de inhoud van het klembord alleen als het InteractiveObject een plakgebeurtenis heeft ontvangen en daarop reageert. Het aanroepen van Clipboard.getData() in andere gevallen werkt niet. Dezelfde beperking geldt in AIR voor inhoud buiten de toepassingssandbox.

Het object generalClipboard wordt automatisch gecreëerd. U kunt geen andere instantie van een Clipboard aan deze eigenschap toewijzen. Gebruik in plaats daarvan de methoden getData() en setData() om gegevens naar het bestaande object te lezen en te schrijven.

Wis altijd het klembord voordat u nieuwe gegevens schrijft om er zeker van te zijn dat oude gegevens in alle indelingen worden gewist.

Het object generalClipboard kan niet worden doorgegeven aan de AIR NativeDragManager. Maak een nieuw Clipboard-object voor native knip- en plakbewerkingen in een AIR-toepassing.

 import flash.desktop.ClipboardFormats;
 
 var copy:String = "A string to copy to the system clipboard.";
 Clipboard.generalClipboard.clear();
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, copy);

 import flash.desktop.ClipboardFormats;
 
 var pasteData:String  = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Geeft aan of de klembordindeling van de bestandspromise wordt ondersteund op het clientsysteem.

Creëert een leeg object Clipboard.

Maak Clipboard-object voor de gegevens van een native beweging voor slepen en neerzetten in Adobe AIR. Clipboard-objecten kunnen voor slechts één beweging voor slepen en neerzetten worden gebruikt. Ze kunnen niet opnieuw worden gebruikt.

Maak geen Clipboard-object voor knip- en plakbewerkingen. Gebruik in plaats hiervan het enkelvoudige object Clipboard.generalClipboard.

Verwante API-elementen

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

Verwijdert alle gegevensrepresentaties uit dit klembordobject.

 Clipboard.generalClipboard.clear();

Wist de gegevensrepresentatie voor de opgegeven indeling.

Parameters

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

Haalt de klembordgegevens op als de gegevens in de opgegeven indeling aanwezig zijn.

Flash Player vereist dat de methode getData() wordt aangeroepen in een paste-gebeurtenishandler. In AIR geldt deze beperking alleen voor inhoud die zich buiten de sandbox met toepassingsbeveiliging bevindt.

De gegevens worden als een nieuw object van het overeenkomstige Flash-gegevenstype geretourneerd als een standaardgegevensindeling wordt benaderd.

De waarde van de parameter transferMode bepaalt of een verwijzing naar het oorspronkelijke object of een anoniem object dat een kopie met serienummering van het oorspronkelijke object bevat wordt geretourneerd als een door de toepassing gedefinieerde indeling wordt benaderd. Wanneer een originalPreferred- of clonePreferred-modus is opgegeven, retourneert Flash Player of AIR de andere versie als de voorkeurversie niet beschikbaar is. Wanneer een originalOnly- of cloneOnly-modus is opgegeven, retourneert Flash Player of AIR null als de gevraagde versie niet beschikbaar is.

Parameters

Verwante API-elementen

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Controleert of in dit object Clipboard gegevens in de opgegeven indeling bestaan.

Gebruik de constanten in de klasseClipboardFormats om te verwijzen naar de standaardindelingsnamen.

Parameters

Verwante API-elementen

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

Voegt een representatie toe van de informatie die in de opgegeven gegevensindeling moet worden overgedragen.

In de toepassingssandbox van Adobe AIR kan setData() op elk moment worden opgeroepen. In andere contexten, kan setData() alleen worden opgeroepen als reactie op gebruiker die door een gebruiker is gegenereerd, zoals een druk op een toets of een muisklik.

Verschillende representaties van dezelfde informatie kunnen als verschillende indelingen aan het klembord worden toegevoegd, waardoor andere componenten of toepassingen beter gebruik kunnen maken van de beschikbare gegevens. Een afbeelding kan bijvoorbeeld worden toegevoegd als bitmapgegevens om door beeldbewerkingstoepassingen te worden gebruikt, als een URL en als gecodeerd PNG-bestand om naar het native bestandssysteem te worden overgedragen.

De gegevensparameter moet het juiste gegevenstype voor de opgegeven indeling zijn:

Namen van aangepaste indelingen kunnen niet beginnen met "air:" of "flash:". Om te vermijden dat er conflicten met de indelingsnamen optreden als u aangepaste indelingen gebruikt, kunt u uw toepassings-id of een pakketnaam als voorvoegsel aan de indeling toevoegen, zoals "com.voorbeeld.applicationName.dataPacket".

Als er overdracht binnen of tussen toepassingen plaatsvindt, bepaalt de parameter serializable of zowel de verwijzing als een kopie beschikbaar zijn, of enkel een verwijzing naar het object beschikbaar is. Stel serializable in op true om zowel de verwijzing en een kopie van het gegevensobject beschikbaar te maken. Stel serializable in op false om alleen de objectverwijzing beschikbaar te maken. Objectverwijzingen zijn alleen geldig binnen de huidige toepassing. Als u serializable instelt op false, betekent dit ook dat de gegevens in die indeling niet beschikbaar zijn voor andere Flash Player- of AIR-toepassingen. Een component kan kiezen om de verwijzing of de kopie van het object op te halen door de juiste klembordoverdrachtmodus in te stellen wanneer de gegevens voor die indeling worden benaderd.

Opmerking: De standaardindelingen worden altijd geconverteerd naar eigen indelingen wanneer gegevens buiten een ondersteunde toepassing worden geplakt of gesleept. Daardoor heeft de waarde van de parameter serializable geen effect op de beschikbaarheid van gegevens in de standaardindelingen voor niet-Flash-toepassingen.

Gebruik in plaats daarvan de methode setDataHandler() om het renderen van de gegevens voor een indeling uit te stellen. Als zowel de methode setData() als setDataHandler() worden gebruikt om een gegevensrepresentatie met dezelfde indelingsnaam toe te voegen, wordt de handlerfunctie nooit aangeroepen.

Opmerking: wanneer u in Mac OS de format-parameter instelt op ClipboardFormats.URL_FORMAT, wordt de URL alleen overgedragen als het een geldige URL is. Anders wordt het klembordobject leeggemaakt (en het aanroepen van getData() levert null op).

Parameters

Verwante API-elementen

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

Voegt een referentie toe aan een handlersfunctie die de over te dragen gegevens produceert.

Gebruik een handlerfunctie om het aanmaken of het renderen van de gegevens uit te stellen totdat de gegevens daadwerkelijk worden benaderd.

De handlerfunctie moet het juiste gegevenstype voor de opgegeven indeling zijn:

De handlerfunctie wordt alleen aangeroepen als de gegevens in de opgegeven indeling worden gelezen. Let op: in sommige gevallen roept het besturingssysteem de functie op voordat er een neerzetactie plaatsvindt. Wanneer u bijvoorbeeld een handlerfunctie gebruikt om gegevens te voorzien voor een bestand dat van een besturingssysteem naar het bestandssysteem is gesleept, roept het besturingssysteem de gegevenshandlerfunctie aan zodra de sleepfunctie de AIR-toepassing verlaat. Dit veroorzaakt normaal gezien een ongewenste pauze wanneer de bestandsgegevens worden gedownload of gemaakt. U kunt voor dit doel in plaats daarvan een URLFilePromise gebruiken.

De onderliggende gegevens kunnen echter veranderen tussen het moment dat de handler is toegevoegd en het moment waarop de gegevens worden gelezen, tenzij in de toepassing stappen zijn ondernomen om de gegevens te beschermen. Het gedrag dat optreedt wanneer gegevens op het klembord, voorgesteld door een handlerfunctie, meer dan eenmaal worden gelezen, wordt niet gegarandeerd. Het is mogelijk dat het klembord de gegevens retourneert die worden geproduceerd door de eerste functieaanroep, of dat de functie opnieuw wordt aangeroepen. U mag niet op een van beide gedragingen vertrouwen.

In de toepassingssandbox van Adobe AIR kan setDataHandler() op elk moment worden opgeroepen. In andere contexten, kan setDataHandler() alleen worden opgeroepen als reactie op gebruiker die door een gebruiker is gegenereerd, zoals een druk op een toets of een muisklik.

Gebruik in plaats daarvan de methode setData() om gegevens rechtstreeks aan dit object Clipboard toe te voegen. Als de methode setData() en de methode setDataHandler() met dezelfde indelingsnaam worden aangeroepen, wordt de handlerfunctie nooit aangeroepen.

Opmerking: wanneer u in Mac OS de format-parameter instelt op ClipboardFormats.URL_FORMAT, wordt de URL alleen overgedragen als de handlerfunctie een geldige URL retourneert. Anders wordt het klembordobject leeggemaakt (en het aanroepen van getData() levert null op).

Parameters

Verwante API-elementen

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. Schrijf de gegevens, in dit geval een tekenreeks, naar Clipboard.generalClipboard.
2. Lees de inhoud van het klembord uit Clipboard.generalClipboard.

Opmerking: wegens beveiligingsbeperkingen voor de toegang tot klembordgegevens, werkt dit voorbeeld niet in Flash Player. In Flash Player kunt u alleen de getData()-methode van het Klembordobject oproepen in een paste -gebeurtenishandler.

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void 
        {
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String
        {
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT))
            {
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } 
            else 
            {
                return null;
            }
        }
        
    }
}