CapsStyle - Bron voor Adobe ActionScript® 3 (AS3 ) API

Pakket	flash.display
Klasse	public final class CapsStyle
Overerving	CapsStyle Object

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

De klasse CapsStyle is een opsomming van constante waarden die aangeven welke stijl voor lijnuiteinden moet worden gebruikt bij het tekenen van lijnen. De constanten kunnen worden gebruikt als waarden voor de parameter caps van de methode flash.display.Graphics.lineStyle(). U kunt de volgende drie soorten lijnuiteinden instellen:

De drie typen uiteinde: NONE, ROUND en SQUARE.

Bekijk de voorbeelden

Verwante API-elementen

flash.display.Graphics.lineStyle()

Openbare eigenschappen

Overerfde openbare eigenschappen verbergen

Overerfde openbare eigenschappen weergeven

	Eigenschap		Gedefinieerd door
		constructor : Object Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie.	Object

Openbare methoden

Overerfde openbare methoden verbergen

Overerfde openbare methoden weergeven

	Methode		Gedefinieerd door
		hasOwnProperty(name:String):Boolean Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd.	Object
		isPrototypeOf(theClass:Object):Boolean Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven.	Object
		propertyIsEnumerable(name:String):Boolean Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in.	Object
		toLocaleString():String Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.	Object
		toString():String Retourneert een tekenreeksrepresentatie van het opgegeven object.	Object
		valueOf():Object Retourneert de primitieve waarde van het opgegeven object.	Object

Openbare constanten

	Constante		Gedefinieerd door
		NONE : String = "none" [statisch] Wordt gebruikt om geen uiteinden op te geven in de parameter caps van de methode flash.display.Graphics.lineStyle().	CapsStyle
		ROUND : String = "round" [statisch] Wordt gebruikt om ronde uiteinden op te geven in de parameter caps van de methode flash.display.Graphics.lineStyle().	CapsStyle
		SQUARE : String = "square" [statisch] Wordt gebruikt om vierkante uiteinden op te geven in de parameter caps van de methode flash.display.Graphics.lineStyle().	CapsStyle

Constantedetails

NONE

Constante

public static const NONE:String = "none"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

Wordt gebruikt om geen uiteinden op te geven in de parameter caps van de methode flash.display.Graphics.lineStyle().

ROUND

Constante

public static const ROUND:String = "round"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

Wordt gebruikt om ronde uiteinden op te geven in de parameter caps van de methode flash.display.Graphics.lineStyle().

SQUARE

Constante

public static const SQUARE:String = "square"

Taalversie:

ActionScript 3.0

Runtimeversies:

AIR 1.0, Flash Player 9

Wordt gebruikt om vierkante uiteinden op te geven in de parameter caps van de methode flash.display.Graphics.lineStyle().

Voorbeelden Hoe dit voorbeeld te gebruiken

CapsStyleExample.as

In het volgende voorbeeld wordt de klasse CapsStyleExample gebruikt om drie parallelle lijnen te tekenen, elk met een ander lijnuiteinde.

De eigenschappen van elke lijn zijn als volgt ingesteld:
- De lengte is ingesteld op 80 pixels.
- De randkleur is ingesteld op oranje.
- De randdikte is ingesteld op 30 pixels.
- De markeerkleur is ingesteld op grijs.
- De markeerdikte is ingesteld op 0 pixels.
- De alpha is ingesteld op 1, waardoor deze effen is.
- Pixelhinting is ingesteld op false (streken worden niet aangevuld tot volledige pixels).
- De modus voor de lijnschaal is ingesteld op normaal, waarbij de dikte wordt geschaald.
- De verbindingsstijl voor de uiteinden van de rand is ingesteld op MITER.
- De afknotlimiet is ingesteld op 1, wat betekent dat het verstek dicht bij de lijn wordt afgesneden.
De klasseconstructor maakt drie verticale lijnen, die beginnen bij x = 0, y = 0, door driemaal de methode drawLine() aan te roepen met drie verschillende uiteindestijlen (geen, afgerond en vierkant). Elk van de drie aanroepen van de methode drawLine() gebruikt de uiteindestijl en de eerder vermelde eigenschappen om een verticale lijn en de bijbehorende lijnmarkering te tekenen. De aanroepen maken eerst een nieuw Shape-object child en gebruiken vervolgens methoden van de klasse Graphics om de lijnstijl in te stellen en de lijnen en markeringen te tekenen. Elke instantie van child wordt toegevoegd aan het weergaveoverzicht en in het werkgebied getekend.
De verbonden lijnsegmenten worden opnieuw getekend met de methode refreshLayout() op y = 80 pixels en te beginnen op x = 80 pixels, met een afstand van 25 pixels tussen de lijnsegmenten.

package {
    import flash.display.CapsStyle;
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.JointStyle;
    import flash.display.LineScaleMode;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class CapsStyleExample extends Sprite {
        private var lineLength:uint            = 80;
        private var borderColor:uint           = 0xFFCC00;
        private var borderSize:uint            = 30;
        private var highlightColor:uint        = 0x666666;
        private var highlightSize:uint         = 0;
        private var gutter:uint                = 25;
        private var borderAlpha:uint           = 1;
        private var borderPixelHinting:Boolean = false;
        private var borderScaleMode:String     = LineScaleMode.NORMAL;
        private var borderJointStyle:String    = JointStyle.MITER;
        private var borderMiterLimit:uint      = 1;

        public function CapsStyleExample() {
            drawLine(CapsStyle.NONE);
            drawLine(CapsStyle.ROUND);
            drawLine(CapsStyle.SQUARE);
            refreshLayout();
        }

        private function drawLine(capsStyle:String):void {
            var child:Shape = new Shape();
            child.graphics.lineStyle(borderSize,
                                     borderColor,
                                     borderAlpha,
                                     borderPixelHinting,
                                     borderScaleMode,
                                     capsStyle,
                                     borderJointStyle,
                                     borderMiterLimit);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);
            child.graphics.endFill();

            child.graphics.moveTo(0, 0);
            child.graphics.lineStyle(highlightSize, highlightColor);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(0, lineLength);

            addChild(child);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = lineLength;
            lastChild.y = lineLength;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = lineLength;
                lastChild = child;
            }
        }
    }
}

Juridische kennisgeving | Online privacybeleid

CapsStyle - AS3

Klassen x

NONE

ROUND

SQUARE