Object  - AS3

Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru. Bir nesne, bir sınıf örneğiyse, constructor özelliği o sınıf nesnesinin bir başvurusunu tutar. Yapıcı işleviyle bir nesne oluşturulursa, constructor özelliği, yapıcı işlevinin bir başvurusunu tutar. Yapıcı işlevini, bir sınıfın constructor yöntemiyle karıştırmayın. Yapıcı işlevi, nesne oluşturmak için kullanılan bir Function nesnesidir ve sınıfları tanımlamada class anahtar kelimesi kullanılmasına alternatiftir.

Bir sınıfı tanımlamak için class anahtar kelimesini kullanırsanız, sınıf nesnesinin bir başvurusunu tutan constructor adında bir özellik sınıfın prototip nesnesine atanır. Sınıfın bir örneği, bu özelliği prototip nesnesinden miras alır. Örneğin, şu kod yeni bir A sınıfı ve myA adında bir sınıf örneği oluşturur:

     dynamic class A {}
     trace(A.prototype.constructor);      // [class A]
     trace(A.prototype.constructor == A); // true
     var myA:A = new A();
     trace(myA.constructor == A);         // true

İleri düzey kullanıcılar, nesne oluşturmaya yönelik bir şablon olarak kullanılabilen Function nesnesi tanımlamak için class anahtar kelimesi yerine function anahtar kelimesini kullanmayı seçebilir. Nesne oluşturmak için bu tür bir işlevi new operatörüyle birlikte kullanabildiğiniz için, bu işleve yapıcı işlevi denir. Bir yapıcı işlevi oluşturmak için function anahtar kelimesini kullanırsanız, bunun prototip nesnesine, yapıcı işlevinin bir başvurusunu tutan constructor adında bir özellik atanır. Daha sonra bir nesne oluşturmak için yapıcı işlevini kullanırsanız, nesne, yapıcı işlevinin prototip nesnesinden constructor özelliğini miras alır. Örneğin, şu kod yeni bir f yapıcı işlevi ve myF adında bir nesne oluşturur:

     function f() {}
     trace(f.prototype.constructor);      // function Function() {}
     trace(f.prototype.constructor == f); // true
     var myF = new f();
     trace(myF.constructor == f);         // true

Not: constructor özelliği yazılabilir, başka bir deyişle, kullanıcı kodu bir atama deyimiyle değerini değiştirebilir. constructor özelliğinin değerinin değiştirilmesi önerilmez, ancak constructor özelliğinin değerine bağlı olan bir kod yazarsanız, değerin sıfırlanmamasını sağlamanız gerekir. Yalnızca prototip nesnesi (örneğin, className.prototype.constructor) üzerinden özelliğe erişildiğinde değer değiştirilebilir.

constructor özelliğine erişir ve katı modda derleme yaparsanız, constructor özelliği bir çalışma zamanı varlığı olan prototip nesnesine bağlı olduğundan derleme zamanında bir hata alırsınız. Standart mod kullanırsanız veya sınıf açıklaması "dinamik" olursa, kod bir hata üretmeden çalıştırılır.

İlgili API Öğeleri

Bir sınıf veya işlev nesnesinin prototip nesnesine bir başvuru. prototype özelliği otomatik olarak oluşturulur ve oluşturduğunuz herhangi bir sınıf veya işlev nesnesine eklenir. Bu özellik, oluşturduğunuz sınıf veya işleve özel olduğundan statiktir. Örneğin, bir sınıf oluşturursanız, prototype özelliğinin değeri sınıfın tüm örnekleri tarafından paylaşılır ve yalnızca bir sınıf özelliği olarak erişilebilir. Sınıfınızın örnekleri doğrudan prototype özelliğine erişemez.

Bir sınıfın prototip nesnesi, bir sınıfın tüm örneklerinde durumu paylaşmaya yönelik bir mekanizma sağlayan özel bir sınıf örneğidir. Çalışma zamanında sınıf örneğinde bir özellik bulunmadığında, sınıf prototip nesnesi olan temsilcide bu özelliğin olup olmadığı kontrol edilir. Prototip nesnesi bu özelliği içermiyorsa, işlem, Flash çalışma zamanı bu özelliği buluncaya kadar, prototip nesnesinin temsilcisinin hiyerarşide art arda daha yüksek seviyeleri kontrol etmesiyle işlem devam eder.

Not: ActionScript 3.0'da, prototip mirası birincil miras mekanizması değildir. Sınıf tanımlarında sabit özelliklerin mirasını yönlendiren sınıf mirası, ActionScript 3.0'daki birincil miras mekanizmasıdır.

Bir Object nesnesi oluşturur ve nesnenin constructor özelliğinde nesnenin constructor yöntemine giden bir başvuruyu saklar.

Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir. Hedef nesne, name parametresiyle belirtilen dizeyle eşlenen bir özelliğe sahipse, bu yöntem true, sahip değilse false döndürür. Şu özellik türleri, bu yöntemin bir sınıf örneği olan nesneler (sınıf nesnelerinin tersi) için true döndürmesine neden olur:

• Sabit örnek özellikleri—statik olmayan nesne sınıfının tanımladığı değişkenler, sabitler veya yöntemler.
• Miras alınan sabit örnek özellikleri—nesne sınıfının miras aldığı değişkenler, sabitler veya yöntemler.
• Dinamik özellikler—başlatıldıktan sonra nesneye eklenen özellikler (sınıf tanımı dışında). Dinamik özellikler eklemek için, nesneyi tanımlayan sınıfın dynamic anahtar kelimesi ile bildirilmesi gerekir.

Şu özellik türleri, bu yöntemin bir sınıf örneği olan nesneler için false döndürmesine neden olur:

• Statik özellikler—bir nesneyi tanımlayan sınıfta veya nesnenin alt sınıflarından herhangi birinde statik anahtar kelimeyle tanımlanan değişkenler, sabitler ya da yöntemler;
• Prototip özellikler—nesnenin prototip zincirinin bir parçası olan prototip nesnesinde tanımlanmış özellikler. ActionScript 3.0'da prototip zinciri, sınıf mirası için kullanılmaz ancak alternatif bir miras şekli olarak var olur. Örneğin, Array sınıfı örneği, Array sınıfının prototip zincirinin bir parçası olan Object.prototype öğesinde bulunduğundan, valueOf() yöntemine erişebilir. Array örneğinde valueOf() öğesini kullanabilseniz de, bu örneğin hasOwnProperty("valueOf") dönüş değeri false olur.

ActionScript 3.0'ın, sınıf tanımlarının doğrudan temsili olan sınıf nesneleri vardır. hasOwnProperty() yöntemi sınıf nesnelerinde çağrıldığında, ancak bir özellik o sınıf nesnesinde tanımlanmış statik bir özellikse, true döndürür. Örneğin, CustomArray adında bir Array alt sınıfı oluşturur ve foo adında CustomArray içinde statik bir özellik tanımlarsanız, CustomArray.hasOwnProperty("foo") çağrısı true döndürür. Ancak Array sınıfında tanımlı DESCENDING statik özelliği için CustomArray.hasOwnProperty("DESCENDING") çağrısı false döndürür.

Not: Object sınıfı yöntemleri, Object prototipinde dinamik olarak oluşturulur. Bir Object alt sınıfında bu yöntemi yeniden tanımlamak için override anahtar kelimesini kullanmayın. Örneğin, bir Object alt sınıfı, taban sınıfının geçersiz kılmasını kullanmak yerine function hasOwnProperty():Boolean öğesini uygular.

Parametreler

Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir. Nesne, theClass parametresinin belirttiği nesnenin prototip zincirindeyse, bu yöntem true döndürür. Hedef nesne, theClass nesnesinin prototip zincirinde yoksa ve theClass parametresi de bir nesne değilse, bu yöntem false döndürür.

Not: Object sınıfı yöntemleri, Object prototipinde dinamik olarak oluşturulur. Bir Object alt sınıfında bu yöntemi yeniden tanımlamak için override anahtar kelimesini kullanmayın. Örneğin, bir Object alt sınıfı, taban sınıfının geçersiz kılmasını kullanmak yerine function isPrototypeOf():Boolean öğesini uygular.

Parametreler

Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir. true ise bu durumda özellik vardır ve for..in döngüsünde numaralandırılmış olabilir. Bu yöntem hedef nesnenin prototip zincirini kontrol etmediğinden, bu özellik hedef nesnede var olmalıdır.

Oluşturduğunuz özellikler numaralandırılabilir ancak yerleşik özellikler genellikle numaralandırılamaz.

Not: Object sınıfı yöntemleri, Object prototipinde dinamik olarak oluşturulur. Bir Object alt sınıfında bu yöntemi yeniden tanımlamak için override anahtar kelimesini kullanmayın. Örneğin, bir Object alt sınıfı, taban sınıfının geçersiz kılmasını kullanmak yerine function propertyIsEnumerable():Boolean öğesini uygular.

Parametreler

Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar. Bu yöntem hedef nesnenin prototip zincirini kontrol etmediğinden, bu özellik hedef nesnede var olmalıdır.

Parametreler

İlgili API Öğeleri

Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.

Bu yöntemin varsayılan uygulaması, yerel ayara özel biçimlendirme gerçekleştirmez ve toString() ile aynı dizeyi döndürür. Alt sınıflar, gerektiğinde kendi yerel ayarlarına göre uygulamasını sağlamalıdır.

Not: Object sınıfı yöntemleri, Object prototipinde dinamik olarak oluşturulur. Bir Object alt sınıfında bu yöntemi yeniden tanımlamak için override anahtar kelimesini kullanmayın. Örneğin, Object sınıfının bir alt sınıfı, temel sınıfın geçersiz kılınmasını kullanmak yerine, function toLocaleString():String öğesini uygular.

İlgili API Öğeleri

Belirtilen nesnenin dize olarak temsil edilen halini döndürür.

Not: Object sınıfı yöntemleri, Object prototipinde dinamik olarak oluşturulur. Bir Object alt sınıfında bu yöntemi yeniden tanımlamak için override anahtar kelimesini kullanmayın. Örneğin, Object sınıfının bir alt sınıfı, temel sınıfın geçersiz kılınmasını kullanmak yerine, function toString():String uygular.

Belirtilen nesnenin temel değerini döndürür. Bu nesnenin temel bir değeri yoksa, nesnenin kendisi döndürülür.

Not: Object sınıfı yöntemleri, Object prototipinde dinamik olarak oluşturulur. Bir Object alt sınıfında bu yöntemi yeniden tanımlamak için override anahtar kelimesini kullanmayın. Örneğin, bir Object alt sınıfı, taban sınıfının geçersiz kılmasını kullanmak yerine function valueOf():Object öğesini uygular.

İlgili API Öğeleri

Bu örnek, firstInitObj ve secondInitObj değer nesnelerini oluşturur. Circle özel sınıfı, değer nesnesini kabul eder ve bunun eşlenen dahili özelliklerini değer nesnesinde tanımlanan özelliklere ayarlarken bu özel sınıfın döngüsünde ilerler.

package {
    import flash.display.Sprite;

    public class ObjectExample extends Sprite {
        public function ObjectExample() {
            var firstInitObj:Object = new Object();
            firstInitObj.bgColor = 0xFF0000;
            firstInitObj.radius = 25;
            firstInitObj.xCenter = 25;
            firstInitObj.yCenter = 25;
                        
            var firstCircle:Circle = new Circle(firstInitObj);
            addChild(firstCircle);
            firstCircle.x = 50;
            firstCircle.y = 50;

            var secondInitObj:Object = {bgColor:0xCCCCCC, radius:50, xCenter:50, yCenter:50};

            var secondCircle:Circle = new Circle(secondInitObj);            
            addChild(secondCircle);
            secondCircle.x = 100;
            secondCircle.y = 100;
        }
        
    }
}

import flash.display.Shape;
    
class Circle extends Shape {
    public var bgColor:Number = 0xFFFFFF;
    public var radius:Number = 0;
    public var xCenter:Number = 0;
    public var yCenter:Number = 0;
        
    public function Circle(initObj:Object) {
        for(var i:String in initObj) {
            this[i] = initObj[i];
        }
        draw();
    }
        
    public function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawCircle(xCenter, yCenter, radius);
        graphics.endFill();
    }
}