HTMLHost

Paket	flash.html
Sınıf	public class HTMLHost
Miras Alma	HTMLHost Object

Çalışma Zamanı Sürümleri:

AIR 1.0

Bir HTMLHost nesnesi, HTMLLoader nesnesinin, çeşitli özellikleri ayarlayarak veya HTML sayfasının window nesnesinin çeşitli yöntemlerini çağırarak kontrol edilebilen kullanıcı arabirimi öğelerine yönelik davranışlarını tanımlar. Bu yöntemler ve özellikler:

window.blur()
window.focus()
window.moveBy()
window.moveTo()
window.location
window.close()
window.open()
window.resizeBy()
window.resizeTo()
window.status
window.document.title

HTMLHost sınıfındaki yöntemler bu window ayarlarının her birindeki değişikleri işlemek için yöntemler sunar. Bu sınıfı kullanmak için, HTMLHost sınıfını uzatan ve davranışları ayarlamak istediğiniz yöntemleri geçersiz kılan yeni bir sınıf (bir alt sınıf) oluşturun. HTMLHost sınıfının yöntemleri, JavaScript özelliklerini ve yöntemlerini şu şekilde işler:

JavaScript özelliği veya yöntemi	HTMLHost yöntemi
`window.blur()`	`windowBlur()`
`window.focus()`	`windowFocus`
`window.location`	`updateLocation`
`window.close()`	`windowClose`
`window.open()`	`createWindow`
`window.status`	`updateStatus`
`window.document.title`	`updateTitle`

window.moveBy(), window.moveTo(), window.resizeBy() ve window.resizeTo() yöntemlerindeki değişikliklere yanıt vermek için, HTMLHost öğesinin alt sınıfındaki set windowRect() yöntemini geçersiz kılın.

Her HTMLHost nesnesi en fazla bir HTMLLoader nesnesiyle ilişkilendirilebilir. HTMLLoader nesnesinin htmlHost özelliğine bir HTMLHost örneği atandığında bu ilişki kurulur. HTMLLoader nesnesinin htmlHost özelliğine null değerinin atanması veya HTMLHost nesnesinin, başka bir HTMLLoader nesnesinin htmlHost özelliği olarak atanması, HTMLHost öğesini ilk HTMLLoader nesnesinden kaldırır.

Örnekleri görüntüle

İlgili API Öğeleri

HTMLLoader
HTMLWindowCreateOptions

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object
		htmlLoader : flash.html:HTMLLoader [salt okunur] Bu HostControl nesnesinin geçerli olduğu HTMLLoader nesnesi.	HTMLHost
		windowRect : Rectangle HTMLLoader nesnesindeki JavaScript kodu, window.moveBy(), window.moveTo(), window.resizeBy() veya window.resizeTo() yöntemini çağırdığında değişen özellik.	HTMLHost

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		HTMLHost(defaultBehaviors:Boolean = true) Bir HTMLHost nesnesi oluşturur.	HTMLHost
		createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader HTMLLoader nesnesindeki JavaScript kodu, window.open() yöntemini çağırdığında çağrılan işlev.	HTMLHost
		hasOwnProperty(name:String):Boolean Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.	Object
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		propertyIsEnumerable(name:String):Boolean Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String Belirtilen nesnenin dize olarak temsil edilen halini döndürür.	Object
		updateLocation(locationURL:String):void HTMLLoader nesnesindeki JavaScript kodu, window.location özelliğini ayarladığında çağrılan işlev.	HTMLHost
		updateStatus(status:String):void HTMLLoader nesnesindeki JavaScript kodu, window.location status özelliğini ayarladığında çağrılan işlev.	HTMLHost
		updateTitle(title:String):void HTMLLoader nesnesindeki JavaScript kodu, window.document.title özelliğini ayarladığında veya DOM üzerinden ya da yeni bir sayfa yüklendiği için title öğesi değiştiğinde çağrılan işlev.	HTMLHost
		valueOf():Object Belirtilen nesnenin temel değerini döndürür.	Object
		windowBlur():void HTMLLoader nesnesindeki JavaScript kodu, window.blur() yöntemini çağırdığında çağrılan işlev.	HTMLHost
		windowClose():void HTMLLoader nesnesindeki JavaScript kodu, window.close() yöntemini çağırdığında çağrılan işlev.	HTMLHost
		windowFocus():void HTMLLoader nesnesindeki JavaScript kodu, window.focus() yöntemini çağırdığında çağrılan işlev.	HTMLHost

Özellik Ayrıntısı

htmlLoader

özellik

htmlLoader:flash.html:HTMLLoader [salt okunur]

Çalışma Zamanı Sürümleri:

AIR 1.0

Bu HostControl nesnesinin geçerli olduğu HTMLLoader nesnesi. O HTMLLoader nesnesinin htmlHost özelliği, bu HostControl nesnesine ayarlanır.

Uygulama
public function get htmlLoader():flash.html:HTMLLoader

İlgili API Öğeleri

HTMLLoader.htmlHost

windowRect

özellik

windowRect:Rectangle

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu window.moveBy(), window.moveTo(), window.resizeBy() veya window.resizeTo() yöntemini çağırdığında değişen özellik.

HTMLHost öğesinin alt sınıfında, yeni pencere sınırlarını istediğiniz gibi işlemek için set windowRect() yöntemini geçersiz kılın.

Uygulama
public function get windowRect():Rectangle
public function set windowRect(value:Rectangle):void

Yapıcı Ayrıntı

()

Yapıcı

public function HTMLHost(defaultBehaviors:Boolean = true)

Çalışma Zamanı Sürümleri:

AIR 1.0

Bir HTMLHost nesnesi oluşturur.

Parametreler

defaultBehaviors:Boolean (default = true) — Kök özelliği davranışlarının, varsayılan olarak sağlanıp sağlanmayacağını gösterir.

Yöntem Ayrıntısı

createWindow

()

yöntem

public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu, window.open() yöntemini çağırdığında çağrılan işlev.

Varsayılan olarak, bir HTMLLoader öğesindeki HTML sayfasında bulunan window.open() öğesine yapılan bir JavaScript çağrısı çalışma zamanı içinde yeni bir NativeWindow nesnesi açmaz. HTMLHost sınıfının alt sınıfında bulunan createWindow geçersiz kılmasında yeni bir NativeWindow nesnesi oluşturarak yeni bir NativeWindow nesnesi açabilirsiniz.

Parametreler

windowCreateOptions:flash.html:HTMLWindowCreateOptions — window.open() öğesine yapılan çağrıya features parametresi şeklinde iletilen dizedeki özellikleri içeren bir nesne.

Döndürür

flash.html:HTMLLoader — Yeni bir HTML sayfası içeren bir HTMLLoader nesnesi. Genellikle, bu yöntemle yeni bir HTMLLoader nesnesi oluşturursunuz. Bu nesneyi, yeni bir NativeWindow nesnesinin sahne alanına ekleyin ve ardından geri döndürün.

updateLocation

()

yöntem

public function updateLocation(locationURL:String):void

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu, window.location özelliğini ayarladığında çağrılan işlev.

Parametreler

locationURL:String — HTMLLoader nesnesinin window özelliğinde bulunan location özelliğinin ayarlandığı değer.

updateStatus

()

yöntem

public function updateStatus(status:String):void

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu, window.status özelliğini ayarladığında çağrılan işlev.

Parametreler

status:String — HTMLLoader nesnesinin window özelliğinde bulunan status özelliğinin ayarlandığı değer.

updateTitle

()

yöntem

public function updateTitle(title:String):void

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu, window.document.title özelliğini ayarladığında veya DOM üzerinden ya da yeni bir sayfa yüklendiği için title öğesi değiştiğinde çağrılan işlev.

Parametreler

title:String — HTMLLoader nesnesinin window.document.title özelliğinin ayarlandığı değer.

windowBlur

()

yöntem

public function windowBlur():void

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu, window.blur() yöntemini çağırdığında çağrılan işlev.

windowClose

()

yöntem

public function windowClose():void

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu, window.close() yöntemini çağırdığında çağrılan işlev.

Varsayılan olarak, HTMLLoader nesnesinin HTML sayfasında bulunan window.close() öğesine yapılan bir JavaScript çağrısı, HTMLLoader nesnesini içeren pencereleri kapatır.

windowFocus

()

yöntem

public function windowFocus():void

Çalışma Zamanı Sürümleri:

AIR 1.0

HTMLLoader nesnesindeki JavaScript kodu, window.focus() yöntemini çağırdığında çağrılan işlev.

Örnekler Bu örnek nasıl kullanılır?

HTMLHost.1.as

Aşağıdaki kod, HTMLHost öğesinin bir alt sınıfı olan CustomHost sınıfını tanımlar. CustomHost sınıfı, HTMLLoader sayfasındaki JavaScript çeşitli özellikleri ayarladığında veya window nesnesinin çeşitli yöntemlerini çağırdığında yapılan işlemleri tanımlamak için HTMLHost sınıfında miras alınan yöntemleri geçersiz kılar:

package
{
    import flash.html.HTMLHost;
    import flash.html.HTMLLoader;
    import flash.display.NativeWindow;
    import flash.display.NativeWindowInitOptions;
    import flash.display.StageScaleMode;
    import flash.geom.Rectangle;
    import flash.text.TextField;

    public class CustomHost extends HTMLHost
    {
        import flash.html.*;
        public var statusField:TextField;
        public function CustomHost(defaultBehaviors:Boolean=true)
        {
            super(defaultBehaviors);
        }
        override public function windowClose():void
        {
            htmlLoader.stage.window.close();
        }
        override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
        {
            var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
            var window:NativeWindow = new NativeWindow(initOptions);
            window.visible = true;
            var htmlLoader2:HTMLLoader = new HTMLLoader();
            htmlLoader2.width = window.width;
            htmlLoader2.height = window.height;
            window.stage.scaleMode = StageScaleMode.NO_SCALE;
            window.stage.addChild(htmlLoader2);
            return htmlLoader2;
        }
        override public function updateLocation(locationURL:String):void
        {
            trace(locationURL);
        }        
        override public function set windowRect(value:Rectangle):void
        {
            htmlLoader.stage.nativeWindow.bounds = value;
        }
        override public function updateStatus(status:String):void
        {
            statusField.text = status;
        }        
        override public function updateTitle(title:String):void
        {
            htmlLoader.stage.nativeWindow.title = title + "- Example Application";
        }
        override public function windowBlur():void
        {
            htmlLoader.alpha = 0.5;
        }
        override public function windowFocus():void
        {
            htmlLoader.alpha = 1;
        }
    }
}

Sahneye bir HTMLLoader nesnesi ve statusBar adlı bir TextField nesnesi ekleyen aşağıdaki sınıfı oluşturun. HTMLLoader nesnesi, htmlHost özelliği olarak bir CustomHost nesnesi tanımlar:

package
 {
     import flash.display.Sprite;
 
     public class SimpleHTMLBox extends Sprite
     {
         import flash.html.HTMLHost;
         import flash.html.HTMLLoader;
         import flash.text.TextField;
         import flash.net.URLRequest;
         import CustomHost;
         private var host:CustomHost;
         private var statusField:TextField;
         private var html:HTMLLoader;
         
         public function SimpleHTMLBox()
         {
             html = new HTMLLoader();
             var url:String = "Test.html";
             var urlReq:URLRequest = new URLRequest(url); 
             html.load(urlReq);
             
             host = new CustomHost();
             html.htmlHost = host;
             statusField = new TextField();
             host.statusField = statusField;
             
             configureUI();
         }
         private function configureUI():void
         {
             html.width = 400;
             html.height = 200;
             statusField.width = 400;
             statusField.height = 24;
             statusField.border = true;
             statusField.y = 200;
             
             addChild(html);
             addChild(statusField);                
         }
         
     }
 }

Ana pencerenin sahnesine bu sınıf tarafından tanımlanan bir nesne ekleyen bir AIR uygulaması oluşturun.

Uygulama kaynaklar dizininde (uygulama açıklayıcı dosyasını içeren dizin) Test.html adlı bir HTML sayfası oluşturun ve bu sayfaya aşağıdaki içeriği ekleyin:

<html>
     <head>
         <title>Test</title>
     </head>
     <body>
         <a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
         <br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
         <br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
         <br/><a href="#" onclick="window.close()">window.close()</a>
         <br/><a href="#" onclick="window.blur()">window.blur()</a>
         <br/><a href="#" onclick="window.focus()">window.focus()</a>
         <br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
     </body>
 </html>

Uygulamayı test ettiğinizde, CustomHost sınıfı HTML sayfasındaki kullanıcı arabirimi ilişkili JavaScript ayarlarını işler.

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

HTMLHost - AS3

Sınıflar x

htmlLoader

windowRect

HTMLHost

createWindow

updateLocation

updateStatus

updateTitle

windowBlur

windowClose

windowFocus