Clipboard  - AS3

Bu Clipboard nesnesinde kullanılabilen veri biçimlerinin adlarını içeren dizelerin bir dizisi.

Standart biçimlerin adlarına yönelik dize sabitleri, ClipboardFormats sınıfında tanımlanmıştır. Uygulama tarafından tanımlanan diğer dizeler, verileri nesne olarak aktarmak için biçim adları olarak da kullanılabilir.

İlgili API Öğeleri

 var availableFormats:Array = Clipboard.generalClipboard.formats;

İşletim sistemi panosu.

Sistem panosuna yapıştırılan tüm veriler, diğer uygulamalarda kullanılabilir. Bu, bir web tarayıcısında çalışan, güvenli olmayan uzak kodu içerebilir.

Not: Flash Player 10 uygulamalarında, panodan yapıştırma işlemi için öncelikle bir kullanıcı olayı (örn. Yapıştır komutu için bir klavye kısayolu veya bağlam menüsündeki Yapıştır komutunun fareyle tıklatılması) gerekir. InteractiveObject paste olayını aldıysa ve bu olayla ilgili harekete geçtiyse, Clipboard.getData() öğesi panonun içeriklerini döndürür. Her durumda Clipboard.getData() öğesinin çağrılması başarısız olur. Aynı sınırlama, AIR'da uygulama sanal alanının dışında bulunan içerik için de geçerlidir.

generalClipboard nesnesi, otomatik olarak oluşturulur. Bu özelliğe başka bir Clipboard örneği atayamazsınız. Bunun yerine, varolan nesneye veri yazmak ve okumak için getData() ve setData() yöntemlerini kullanırsınız.

Tüm biçimlerdeki eski verilerin silindiğinden emin olmak için, üzerine yeni veri yazmadan önce panoyu her zaman temizlemeniz gerekir.

generalClipboard nesnesi AIR NativeDragManager öğesine iletilemez. Bir AIR uygulamasında yerel sürükle ve bırak işlemleri için yeni bir Pano nesnesi oluşturun.

 import flash.desktop.ClipboardFormats;
 
 var copy:String = "A string to copy to the system clipboard.";
 Clipboard.generalClipboard.clear();
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, copy);

 import flash.desktop.ClipboardFormats;
 
 var pasteData:String  = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

İstemci sisteminde dosya izni pano biçiminin desteklenip desteklenmediğini belirtir.

Boş bir Pano nesnesi oluşturur.

Adobe AIR'de bir sürükle ve bırak hareketinin verilerini tutmak için Pano nesneleri oluşturun. Pano nesneleri yalnızca bir sürükle ve bırak hareketi için kullanılabilirler; tekrar kullanılamazlar.

Kopyala ve yapıştır işlemleri için Pano nesnesi oluşturmayın. Bunun yerine tek Clipboard.generalClipboard nesnesini kullanın.

İlgili API Öğeleri

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

Tüm veri sunumlarını bu Clipboard nesnesinden siler.

 Clipboard.generalClipboard.clear();

Belirtilen biçime yönelik veri sunumunu siler.

Parametreler

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

Belirtilen biçimdeki verilerin bulunması durumunda pano verilerini alır.

Flash Player, paste olay işleyicisinde, getData() yönteminin çağrılmasını gerektirir. AIR uygulamasında bu kısıtlama yalnızca uygulama güvenlik sanal alanı dışındaki içerik için geçerlidir.

Bir standart veri biçimine erişildiğinde veri, karşılık gelen Flash veri türünün yeni bir nesnesi olarak döndürülür.

Uygulama tarafından tanımlanan bir biçime erişildiğinde, transferMode parametresinin değeri, orijinal nesneye veya orijinal nesnenin serileştirilmiş bir kopyasını içeren anonim bir nesneye bir başvuru döndürülüp döndürülmeyeceğini belirler. originalPreferred veya clonePreferred modu belirtildiğinde, tercih edilen sürümün bulunmaması durumunda Flash Player veya AIR, alternatif sürümü döndürür. originalOnly veya cloneOnly modu belirtildiğinde, istenen sürümün bulunmaması durumunda Flash Player veya AIR, null değerini döndürür.

Parametreler

İlgili API Öğeleri

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Belirtilen biçimdeki verilerin Clipboard nesnesinde olup olmadığını kontrol eder.

Standart biçim adlarına başvurmak için ClipboardFormats sınıfındaki sabitleri kullanın.

Parametreler

İlgili API Öğeleri

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

Belirtilen veri biçiminde aktarılacak olan bilgilerin bir temsilini ekler.

Adobe AIR uygulamasının uygulama sanal alanında, herhangi bir anda setData() öğesi çağrılabilir. Diğer bağlamlarda, setData() öğesi yalnızca tuş basma veya fare tıklatma gibi kullanıcı tarafından üretilen bir olaya yanıt olarak çağrılabilir.

Aynı bilgilerin farklı sunumları, panoya farklı biçimlerde eklenebilir. Bu da diğer bileşenlerin veya uygulamaların kullanılabilir verilerden yararlanma yeteneğini artırır. Örneğin, bir görüntü, görüntü düzenleme uygulamaları tarafından kullanılmak üzere bitmap verisi olarak ve yerli dosya sistemine aktarım için kodlanmış PNG dosyası olarak eklenebilir.

Veri parametresi, belirtilen biçim için uygun veri türü olmalıdır:

Özel biçim adları "air:" veya "flash:" ile başlayamaz. Özel biçim kullanırken adlandırma çakışmalarını önlemek için, uygulama kimliğinizi veya paket adınızı "com.example.applicationName.dataPacket" gibi bir biçime önek olarak kullanabilirsiniz.

Uygulamalar içinde veya arasında aktarma yaparken serializable parametresi, hem bir başvurunun hem de kopyanın kullanılabilir olup olmadığını veya yalnızca bir nesneye yapılan bir başvurunun kullanılabilir olup olmadığını belirler. Veri nesnesinin hem başvurusunu hem de kopyasını kullanılabilir hale getirmek için serializable öğesini true olarak ayarlayın. Yalnızca nesne başvurusunu kullanılabilir hale getirmek için serializable öğesini false olarak ayarlayın. Nesne başvuruları yalnızca geçerli uygulamada geçerlidir, dolayısıyla serializable öğesini false olarak ayarlamak, aynı zamanda o biçimdeki verilerin diğer Flash Player veya AIR uygulamalarında kullanılabilir olmayacağı anlamına gelir. Bir bileşen, o biçime ait verilere erişirken uygun pano aktarım modunu ayarlayarak nesnenin başvurusunu veya kopyasını almayı seçebilir.

Not: Veriler, desteklenen bir uygulamanın dışına yapıştırıldığında veya sürüklendiğinde standart biçimler her zaman yerel biçimlere dönüştürülür, böylece serializable parametresinin değeri, standart biçimlerdeki verilerin Flash temelli olmayan uygulamalar için kullanılabilirliğini etkilemez.

Bir biçimin verilerinin oluşturulmasını ertelemek için, bunun yerine setDataHandler() yöntemini kullanın. setData() ve setDataHandler() yöntemleri, aynı biçim adına sahip bir veri sunumu eklemek için kullanılır, böylece işleyici işlevi asla çağrılmaz.

Not: Mac OS'de, format parametresini ClipboardFormats.URL_FORMAT olarak ayarladığınızda, URL yalnızca geçerli bir URL olduğunda aktarılır. Aksi takdirde, Clipboard nesnesi boşaltılır (ve getData() öğesinin çağrılması null değerini döndürür).

Parametreler

İlgili API Öğeleri

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

İşleyici işlevine, aktarılacak verileri üreten bir başvuru ekler.

Gerçekten erişilene kadar verinin yaratılmasını veya oluşturulmasını ertelemek için bir işleyici işlevini kullanın.

İşleyici işlevi, belirtilen biçim için uygun veri türünü geri döndürmelidir:

İşleyici işlevi yalnızca belirtilen biçimdeki veriler okunduğunda çağrılır. Bazı durumlarda, işletim sistemi, bırakma gerçekleşmeden önce işlevi çağırır. Örneğin, bir AIR uygulamasında dosya sistemine sürüklenen bir dosya için veri sağlamak üzere bir işleyici işlevi kullandığınızda, işletim sistemi, sürükleme hareketi AIR uygulamasından çıkar çıkmaz veri işleyici işlevini çağırır—genellikle bu, dosya verileri indirilirken veya oluşturulurken istenmeyen bir duraklamaya yol açar. Onun yerine bu amaçla bir URLFilePromise kullanabilirsiniz.

Temel verilerin, uygulamanızın verileri korumak için gereken adımları izlememesi durumunda işleyicinin eklendiği zamanla verilerin okunduğu zaman arasında değişebileceğini unutmayın. Bir işleyici işlevi tarafından temsil edilen pano üzerindeki veriler, birden fazla kez okunduğunda gerçekleşen davranış konusunda garanti verilmez. Pano, ilk işlev çağrısı tarafından üretilen verileri döndürebilir veya işlevi tekrar çağırabilir. Bu iki davranıştan herhangi birine güvenmeyin.

Adobe AIR uygulamasının uygulama sanal alanında, herhangi bir anda setDataHandler() öğesi çağrılabilir. Diğer bağlamlarda, setDataHandler() öğesi yalnızca tuş basma veya fare tıklatma gibi kullanıcı tarafından üretilen bir olaya yanıt olarak çağrılabilir.

Verileri doğrudan bu Clipboard nesnesine eklemek için bunun yerine setData() yöntemini kullanın. setData() ve setDataHandler() yöntemleri aynı biçim adıyla çağrılırsa, işleyici işlevi asla çağrılmaz.

Not: Mac OS'de, format parametresini ClipboardFormats.URL_FORMAT olarak ayarladığınızda, URL yalnızca işleyici işlevi geçerli bir URL döndürdüğünde aktarılır. Aksi takdirde, Clipboard nesnesi boşaltılır (ve getData() öğesinin çağrılması null değerini döndürür).

Parametreler

İlgili API Öğeleri

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. Verileri, bu durumda bir dizeyi Clipboard.generalClipboard öğesine yazın.
2. Pano içeriğini Clipboard.generalClipboard öğesinden okuyun.

Not: Pano verilerine erişmeyle ilgili güvenlik kısıtlamaları nedeniyle, bu örnek Flash Player'da çalışmaz. Flash Player'da yalnızca bir paste olay işleyicisinde Clipboard nesnesinin getData() yöntemini çağırabilirsiniz.

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void 
        {
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String
        {
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT))
            {
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } 
            else 
            {
                return null;
            }
        }
        
    }
}