TextBlock  - AS3

Ne görürsen onu alırsın (WYSIWYG) yazdırma doğruluğundan sapılacak olsa da, ekran görünümünü geliştirmek istediğinizi belirtir. Aygıt fontu oluşturma sırasında alt piksel glif konumlandırmasını desteklemeyen, ancak doğrusal olmayan ölçeklemeyi destekleyen platformlar ve fontlar için bu özelliğin true olarak ayarlanması, özellikle küçük punto boyutları için WYSIWYG yazdırma doğruluğundan belirli ölçüde taviz vererek bu metriklerin kullanılmasını sağlar. Doğrusal olmayan font ölçekleme, piksel yapışmasından kaynaklanan düzensiz boşlukları gizlemek için tek tek gliflerin genişliğini seçici olarak ölçekleyerek çalışır.

Alt piksel glif konumlandırmasını desteklemeyen platformlarda bu bayrak yok sayılır.

Bu bayrağın gömülü font oluşturma üzerinde bir etkisi yoktur.

Varsayılan değer true şeklindedir.

İçeriklerinden bağımsız olarak, bloktan oluşturulan tüm satırların taban çizgilerini belirlemek için kullanılan font. Taban çizgileri font ve font boyutuna bağlıdır.

Varsayılan değer null şeklindedir. Taban çizgisi fontu null olduğunda, taban çizgisi font boyutu yok sayılır ve belirli bir satırın taban çizgisi, satırdaki en büyük metnin fontunu ve boyutunu esas alır. Hem baselineFontDescription hem de baselineFontSize öğelerini belirttiğinizde, bunlar içeriklerinden bağımsız olarak metin bloğundaki tüm satırların taban çizgilerini belirler. Bu birleşim daha çok Asya tipografisinde kullanışlıdır.

İlgili API Öğeleri

Bloktan oluşturulan satırların taban çizgilerini hesaplamak için kullanılan font boyutu. Taban çizgileri font ve font boyutuna bağlıdır.

12 varsayılan değerdir. Taban çizgisi fontu null olduğunda, taban çizgisi font boyutu yok sayılır ve belirli bir satırın taban çizgisi, satırdaki en büyük metnin fontunu ve boyutunu esas alır.

İlgili API Öğeleri

Bu bloktan oluşturulan satırlar için hangi taban çizgisinin y=0 konumunda olduğunu belirtir. Bu özelliğin geçerli değerleri TextBaseline sınıfının üyelerinde bulunur.

TextBaseline.ROMAN varsayılan değerdir.

Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:

İlgili API Öğeleri

Metin bloğunun çift yönlü paragraf gömme seviyesini belirtir. Genel olarak, soldan sağa yazılan paragraflar (İngilizce, Japonca vb.) için 0, sağdan sola yazılan paragraflar (Arapça, İbranice vb.) için ise 1 kullanın. 0 veya 1 dışındaki değerlerin kullanımı özel durumlar için ayrılmıştır. Ayrıntılar için bkz. UAX#9, "Unicode Bidirectional Algorithm" (http://www.unicode.org/reports/tr9/).

Varsayılan değer 0'dır.

bidiLevel öğesi değiştirildiğinde, önceden kesilmiş satırların geçerliliği TextLineValidity.INVALID olarak değişir. bidiLevel özelliği değiştirildikten sonra, firstInvalidLine özelliği firstLine özelliğine eşit olur ve TextBlock içindeki tüm satırları yeniden kesmeniz gerekir.

İlgili API Öğeleri

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Metin bloğunun içeriklerini tutar. ContentElement bir taban sınıfı olduğundan, content öğesine, ContentElement alt sınıfının bir örneğini atayın: TextElement, GraphicElement veya GroupElement. TextElement nesnesi bir String içerir, GraphicElement nesnesi bir DisplayObject içerir ve GroupElement öğesi TextElement, GraphicElement veya diğer GroupElement nesnelerinden birini veya birkaçını içeren bir Vector nesnesi içerir. Homojen bir metin paragrafı için TextElement öğesini, grafik için GraphicElement öğesini ve metin ve grafik öğelerinin veya bu öğelerin birçok örneğinin ve diğer GroupElement nesnelerinin birleşimi için GroupElement öğesini kullanın.

Varsayılan değer null şeklindedir.

content özelliği değiştirildiğinde, önceden oluşturulmuş olan tüm satırların geçerliliği TextLineValidity.INVALID olarak değiştirilir. content özelliği değiştirildikten sonra, firstInvalidLine özelliği firstLine özelliğine eşit olur ve TextBlock içindeki tüm satırları yeniden kesmeniz gerekir.

İlgili API Öğeleri

Metin bloğundaki, TextLine.validity öğesinin TextLineValidity.VALID öğesine eşit olmadığı birinci satırı tanımlar.

Varsayılan değer null şeklindedir.

İlgili API Öğeleri

Varsa, TextBlock içindeki birinci TextLine.

Varsayılan değer null şeklindedir.

İlgili API Öğeleri

Varsa, TextBlock içindeki sonuncu TextLine.

Varsayılan değer null şeklindedir.

İlgili API Öğeleri

Metin bloğundaki metin satırlarını bir birim olarak döndürür. Bunun etkili olması için, lineRotation öğesini ayarladıktan sonra createTextLine() yöntemini çağırın. Varsayılan değer TextRotation.ROTATE_0 olur.

Herhangi bir glifin son dönüşü, ElementFormat.textRotation, ContentElement.textRotation ve TextBlock.lineRotation değerlerine bağlıdır.

Asya metni için tipik olarak TextBlock.lineRotation kullanılır. Dikey Japonca metin paragrafı oluşturmak için şunları yapın:

1. TextBlock.lineRotation özelliğini TextRotation.ROTATE_90 olarak ayarlayın.
2. İçeriğin ElementFormat.textRotation özelliğini varsayılan TextRotation.AUTO değerine ayarlayın.

Bu özelliğin değerini ayarlamak için, TextRotation sınıfında tanımlanan şu sabitleri kullanın:

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Metin bloğundaki metnin sekme duraklarını, TabStop nesnelerinin Vector öğeleri şeklinde belirtir.

Varsayılan değer null şeklindedir ve herhangi bir sekme durağının belirtilmediği anlamına gelir. Herhangi bir sekme durağı belirtilmediyse (veya ekleme noktası son belirtilen sekme durağının ötesindeyse) çalışma zamanı varsayılan olarak yarım inçlik sekmeler oluşturur.

tabStops özelliği ayarlandığında, TextBlock öğesi dahili kullanım için Vector öğesinin bir kopyasını oluşturur. Orijinal Vector öğesinin veya içeriklerinin değiştirilmesi, TextBlock öğesini etkilemez. tabStops özelliği sorgulandığında, dahili Vector öğesinin bir kopyası döndürülür. Yine bu döndürülen vektör öğesinin veya içeriklerinin değiştirilmesi, TextBlock öğesini etkilemez.

İlgili API Öğeleri

Satır oluşturma sırasında kullanılacak TextJustifier öğesini belirtir.

Varsayılan değer, oluşturulmuş bir varsayılan TextJustifier nesnesidir.

textJustifier özelliği ayarlandığında, TextBlock öğesi dahili kullanım için nesnenin bir kopyasını oluşturur. Orijinal nesnenin değiştirilmesi, TextBlock öğesini etkilemez. textJustifier özelliği sorgulandığında, dahili nesnenin bir kopyası döndürülür. Yine bu döndürülen nesnenin değiştirilmesi, TextBlock öğesini etkilemez.

İlgili API Öğeleri

createTextLine() işleminin sonucunu belirtir. Bloğun içeriği değiştirildiğinde, önceden kesilmiş satırlar geçersiz kılınır ve bu özellik null değerine sıfırlanır.

Varsayılan değer null şeklindedir.

Bu özelliğin değerleri TextLineCreationResult öğesinde bulunur

İlgili API Öğeleri

Uygulamaya, rastgele verileri metin bloğuyla ilişkilendirme yolu sağlar. Veriler, düzeltme tarihi veya yazarın adı gibi içerikle ilgili bilgiler veya işleme sırasında kullandığınız önbelleğe alınan veriler olabilir.

Bir TextBlock nesnesi oluşturur

İlgili API Öğeleri

Metin bloğunu kendi içeriğinden bir metin satırı oluşturacak şekilde yönlendirir. Bu metin satırı previousLine parametresi tarafından belirtilen noktada başlar ve width parametresi tarafından belirtilen noktada kesilir. Metin satırı, görüntüleme listesine ekleyebileceğiniz bir TextLine öğesidir.

Önceden kesilmiş bir metin bloğu aralığı üzerinden satır kesme, kesme işleminin gerçekleştiği alanın içerisinde ve ötesinde satırların geçerliliğini değiştirebilir. Satırların durumu VALID'den INVALID veya POSSIBLY_INVALID olarak değişebilir. Yeni kesilmiş bir satır daha önceden kesilmiş ve POSSIBLY_INVALID durumuna sahip bir satırla tam olarak hizalanırsa, daha önceden kesilmiş bu satır ve ardından gelen tüm POSSIBLY_INVALID satırları VALID durumuna geri döner. TextLineValidity üyesi olmayan değerlere ayarlanan satırların geçerliliği VALID olarak değişmez ancak INVALID olarak değişebilir. Metin satırlarını yeniden kesmeye nereden başlayacağınızı veya devam edeceğinizi görmek için, metin bloğuna bir değişiklik yaptıktan sonra firstInvalidLine özelliğini kontrol edin.

Metine Unicode Sıfır Genişlik Boşluğu (Unicode Zero Width Space) (ZWSP) karakterini dahil ederek, yapay kelime kesmeleri oluşturabilirsiniz. Bu, doğru satır kesme için sözlük gerektiren Tay dili gibi dillerde fayda sağlayabilir. Flash çalışma zamanı böyle bir sözlük içermez.

Bellek yükünü azaltmak için, istenen tüm satırlar oluşturulduğunda, örneğin, kabın yeniden boyutlandırılması nedeniyle satırların art arda yeniden kesilmesi gerekeceği beklenmediği sürece, kullanıcı releaseLineCreationData() yöntemini çağırarak metin bloğunun, satır kesme ile ilişkili geçici verileri atmasına izin vermelidir.

Parametreler

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

TextBlock öğesinin temel içeriğini bir XML dizesi olarak atar. Bu durum otomatik test işleminde fayda sağlayabilir ve metin, biçimlendirme ve mizanpaj bilgilerini içerir.

Aşağıda, çıktı açıklanmaktadır:

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Her satır çıktısının bir açıklaması için, TextLine.dump() yöntemine bakın.

Not: Çıktının içeriği ve biçimi gelecekte değişebilir. Adobe, bu yöntemin geriye dönük uyumluluğunu garantilemez.

İlgili API Öğeleri

Belirtilen dizindeki karakteri dahil etmeden belirtilen karakter dizininden bir sonraki atom sınırının dizinini bulur. Atom sınırları arasındaki karakterler, TextLine içinde bir atom oluşturmak için birleşir, örn. 'e' ve birleştiren bir ters vurgu işareti.

Parametreler

İlgili API Öğeleri

Belirtilen dizindeki karakteri dahil etmeden belirtilen karakter dizininden bir sonraki kelime sınırının dizinini bulur. Kelime sınırları, karakterlerin Unicode özellikleri esas alınarak belirlenir.

Parametreler

Belirtilen dizindeki karakteri dahil etmeden belirtilen karakter dizinine giden bir önceki atom sınırının dizinini bulur. Atom sınırları arasındaki karakterler, TextLine içinde bir atom oluşturmak için birleşir, örn. 'e' ve birleştiren bir ters vurgu işareti.

Parametreler

İlgili API Öğeleri

Belirtilen dizindeki karakteri dahil etmeden belirtilen karakter dizininden bir önceki kelime sınırının dizinini bulur. Kelime sınırları, karakterlerin Unicode özellikleri esas alınarak belirlenir.

Parametreler

charIndex parametresi tarafından belirtilmiş karakteri içeren TextLine öğesini döndürür.

Parametreler

Metin bloğunu kendi içeriğinden bir metin satırı oluşturacak şekilde varolan bir metin satırını kullanması için yönlendirir. Bu metin satırı previousLine parametresi tarafından belirtilen noktada başlar ve width parametresi tarafından belirtilen noktada kesilir. Metin satırı, görüntüleme listesine ekleyebileceğiniz bir TextLine öğesidir. Varolan metin satırı yeniden kullanılarak, düşük nesne oluşturma nedeniyle performans düşer.

Yeniden oluşturulan textLine hangi metin bloğundaysa oradan bırakılır. Ek olarak, DisplayObjectContainer, InteractiveObject ve DisplayObject öğelerinden miras alınan özellikler dahil olmak üzere, tüm özellikler varsayılan değerlerine sıfırlanır. Son olarak, grafik öğeler ve diğer dekorasyonlar dahil sıradaki tüm alt öğeler ve tüm olay dinleyicileri kaldırılır. Performansın iyileştirilmesi için, bu tümüyle sıfırlanma durumunun tek istisnası, satırın kendisinin üst öğesinden kaldırılmamasıdır.

Önceden kesilmiş bir metin bloğu aralığı üzerinden satır kesme, kesme işleminin gerçekleştiği alanın içerisinde ve ötesinde satırların geçerliliğini değiştirebilir. Satırların durumu VALID'den INVALID veya POSSIBLY_INVALID olarak değişebilir. Yeni kesilmiş bir satır daha önceden kesilmiş ve POSSIBLY_INVALID durumuna sahip bir satırla tam olarak hizalanırsa, daha önceden kesilmiş bu satır ve ardından gelen tüm POSSIBLY_INVALID satırları VALID durumuna geri döner. TextLineValidity üyesi olmayan değerlere ayarlanan satırların geçerliliği VALID olarak değişmez ancak INVALID olarak değişebilir. Metin satırlarını yeniden kesmeye nereden başlayacağınızı veya devam edeceğinizi görmek için, metin bloğuna bir değişiklik yaptıktan sonra firstInvalidLine özelliğini kontrol edin.

Metine Unicode Sıfır Genişlik Boşluğu (Unicode Zero Width Space) (ZWSP) karakterini dahil ederek, yapay kelime kesmeleri oluşturabilirsiniz. Bu, doğru satır kesme için sözlük gerektiren Tay dili gibi dillerde fayda sağlayabilir. Flash çalışma zamanı böyle bir sözlük içermez.

Bellek yükünü azaltmak için, istenen tüm satırlar oluşturulduğunda, örneğin, kabın yeniden boyutlandırılması nedeniyle satırların art arda yeniden kesilmesi gerekeceği beklenmediği sürece, kullanıcı releaseLineCreationData() yöntemini çağırarak metin bloğunun, satır kesme ile ilişkili geçici verileri atmasına izin vermelidir.

Parametreler

İlgili API Öğeleri

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Metin bloğuna, metin satırı oluşturmayla ilişkili tüm geçici verileri yayınlamasını bildirir. Bir uygulamanın ayak izini en aza indirgemek için, bir metin bloğundan metin oluşturma işiniz bittiğinde releaseLineCreationData() yöntemini çağırın. Ancak, satırları yeniden kesme performansını en üst düzeye çıkarmak için (örneğin, kap yeniden boyutlandırıldığında) releaseLineCreationData() yöntemi çağrılmamalıdır. Bellek ve performans dengesini sağlamak uygulamaya kalmıştır.

Değişmesi beklenmeyen metin için önerilen işlem: bir metin bloğu başlatma, istenen çıktıyı oluşturmak için gerekli sıklıkta createTextLine() yöntemini çağırma ve sonra releaseLineCreationData() yöntemini çağırma.

İlgili API Öğeleri

Metin satırları aralığını, TextBlock tarafından tutulan satır listesinden kaldırır. Bu, başka bir başvuru yoksa, satırlarda çöp toplama işlemi yapılmasını sağlar.

Kaldırılan satırların textBlock, nextLine ve previousLine üyelerini null değerine ayarlar. TextBlock içindeki kaldırılan satırların ve kaldırılan satırlardan sonra gelen tüm satırların validity öğesini TextLineValidity.INVALID değerine ayarlar.

Parametreler

İlgili API Öğeleri