| Paket | flash.text.engine |
| Sınıf | public final class ElementFormat |
| Miras Alma | ElementFormat  Object |
| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
TextBlock öğesinde bir ContentElement öğesine uygulanana ElementFormat nesnesi, TextBlock öğesini geçersizleştirmez. ContentElement öğesine bir ElementFormat uygulandıktan sonra, locked özelliği true değerine ayarlanır. Kilitlenmiş bir ElementFormat nesnesinin özellikleri değiştirilemez. Bunun yerine, değiştirilip ContentElement öğesine atanabilen, nesnenin kilitlenmemiş bir kopyasını oluşturmak için clone() yöntemini kullanın.
İlgili API Öğeleri
Miras Alınan Genel Özellikleri Gizle
Miras Alınan Genel Özellikleri Göster| Özellik | Tanımlayan: | ||
|---|---|---|---|
| alignmentBaseline : String
Bu biçimdeki öğelerin baskın satır taban çizgilerinin hizalanacağı, kapsayan öğedeki satır taban çizgisini belirtir. | ElementFormat | ||
| alpha : Number
Bu nesne tarafından etkilenen satır öğelerinin saydamlığını belirtir. | ElementFormat | ||
| baselineShift : Number
Öğenin taban çizgisi kaydırmasını piksel cinsinden belirtir. | ElementFormat | ||
| breakOpportunity : String
Bu metne uygulanan satır kesme olanağı. | ElementFormat | ||
| color : uint
Metnin rengini gösterir. | ElementFormat | ||
 | constructor : Object
Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru. | Object | |
| digitCase : String
Bu metin için kullanılan basamak durumu. | ElementFormat | ||
| digitWidth : String
Bu metin için kullanılan basamak genişliği. | ElementFormat | ||
| dominantBaseline : String
Baskın satır taban çizgisi olarak kullanılacak satır taban çizgisinin türünü belirtir. | ElementFormat | ||
| fontDescription : FontDescription
Özellikleri bir fontu tanımlayan nesne. | ElementFormat | ||
| fontSize : Number
Metnin piksel olarak boyutu. | ElementFormat | ||
| kerning : String
Karakter aralığı, okunabilirliği artırmak için belirli karakter çiftleri arasındaki pikselleri ayarlar. | ElementFormat | ||
| ligatureLevel : String
Bu metin için kullanılan birleşik harf düzeyi. | ElementFormat | ||
| locale : String
Metnin yerel ayarı. | ElementFormat | ||
| locked : Boolean
ElementFormat öğesinin kilitlenmiş olup olmadığını belirtir. | ElementFormat | ||
| textRotation : String
Ayrı ayrı gliflere uygulanan döndürme işlemini ayarlar. | ElementFormat | ||
| trackingLeft : Number
Her glifin soluna uygulanan, piksel cinsinden izleme veya elle karakter aralığı. | ElementFormat | ||
| trackingRight : Number
Her glifin sağına uygulanan, piksel cinsinden izleme veya manuel karakter aralığı. | ElementFormat | ||
| typographicCase : String
Bu metin için kullanılan tipografik durum. | ElementFormat | ||
| Yöntem | Tanımlayan: | ||
|---|---|---|---|
ElementFormat(fontDescription:FontDescription = null, fontSize:Number = 12.0, color:uint = 0x000000, alpha:Number = 1.0, textRotation:String = "auto", dominantBaseline:String = "roman", alignmentBaseline:String = "useDominantBaseline", baselineShift:Number = 0.0, kerning:String = "on", trackingRight:Number = 0.0, trackingLeft:Number = 0.0, locale:String = "en", breakOpportunity:String = "auto", digitCase:String = "default", digitWidth:String = "default", ligatureLevel:String = "common", typographicCase:String = "default")
Bir ElementFormat nesnesi oluşturur. | ElementFormat | ||
ElementFormat öğesinin kilitlenmemiş, klonlanmış bir kopyasını oluşturur. | ElementFormat | ||
fontDescription ve fontSize tarafından belirtilen fonta yönelik emBox, üst çizgi konumunu, üst çizgi kalınlığını, alt çizgi konumunu ve alt çizgi kalınlığını açıklayan özelliklere sahip bir FontMetrics nesnesi döndürür.
| ElementFormat | ||
|
Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir. | Object | |
|
Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir. | Object | |
|
Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir. | Object | |
|
Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar. | Object | |
|
Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür. | Object | |
|
Belirtilen nesnenin dize olarak temsil edilen halini döndürür. | Object | |
|
Belirtilen nesnenin temel değerini döndürür. | Object | |
alignmentBaseline | özellik |
alignmentBaseline:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bu biçimdeki öğelerin baskın satır taban çizgilerinin hizalanacağı, kapsayan öğedeki satır taban çizgisini belirtir. Bu özellik için TextBaseline sabitlerini kullanın.
TextBlock.baselineFontDescription ve TextBlock.baselineFontSize öğeleri bu mantığı geçersiz kılacak şekilde ayarlanmadığı sürece, satırdaki en büyük dikey öğe, satır taban çizgilerinin hizalamasını belirler.
Varsayılan değer TextBaseline.USE_DOMINANT_BASELINE şeklindedir.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
TextBaseline.ROMAN | dominantBaseline öğesi, satırın roman taban çizgisiyle hizalanır. |
TextBaseline.ASCENT | dominantBaseline öğesi, satırın artan taban çizgisiyle hizalanır. |
TextBaseline.DESCENT | dominantBaseline öğesi, satırın azalan taban çizgisiyle hizalanır. |
TextBaseline.IDEOGRAPHIC_TOP | dominantBaseline öğesi, satırın ideografik üst taban çizgisiyle hizalanır. |
TextBaseline.IDEOGRAPHIC_CENTER | dominantBaseline öğesi, satırın ideografik orta taban çizgisiyle hizalanır. |
TextBaseline.IDEOGRAPHIC_BOTTOM | dominantBaseline öğesi, satırın ideografik alt taban çizgisiyle hizalanır. |
TextBaseline.USE_DOMINANT_BASELINE | dominantBaseline öğesi, satırın aynı taban çizgisiyle hizalanır. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Grafik öğesinin dominantBaseline öğesinin hizalandığı satırın ayarlama taban çizgisini ayarlar. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Metin öğesinin dominantBaseline öğesinin hizalandığı satırın ayarlama taban çizgisini ayarlar. |
Uygulama
public function get alignmentBaseline():String public function set alignmentBaseline(value:String):voidAtar
ArgumentError — TextBaseline üyesi olmayan herhangi bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
alpha | özellik |
alpha:Number| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bu nesne tarafından etkilenen satır öğelerinin saydamlığını belirtir. Geçerli değerler 0 (tam saydam) ile 1 (tam opak) aralığındadır. alpha özelliği 0 olarak ayarlanmış görüntüleme nesneleri görünmez olsa da etkindir.
Varsayılan değer 1'dir.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Belirtilen alfayı grafik öğesine uygular. DisplayObject veya TextLine grafiğinin kendisinde bulunan herhangi bir alfa kümesiyle çarpımlı olarak birleşir. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Belirtilen alfayı metin öğesine uygular. TextLine öğesinde ayarlı herhangi bir alfa kümesiyle çarpımlı olarak birleşir. |
Uygulama
public function get alpha():Number public function set alpha(value:Number):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
baselineShift | özellik |
baselineShift:Number| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Öğenin taban çizgisi kaydırmasını piksel cinsinden belirtir.
Öğe, bu miktar kadar dominantBaseline öğesinden kaydırılır. Uzaklık değeri, öğe üyelerinin y konumuna eklenir, böylece döndürülmemiş metinde pozitif bir taban çizgisi uzaklığı, öğeyi aşağı taşırken negatif bir taban çizgisi uzaklığı, öğeyi yukarı taşır.
Varsayılan değer 0.0 olup bu, kaydırma olmadığını belirtir.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Grafiği taban çizgisinden uzağa kaydırır. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Metni taban çizgisinden uzağa kaydırır. |
Uygulama
public function get baselineShift():Number public function set baselineShift(value:Number):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
breakOpportunity | özellik |
breakOpportunity:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bu metne uygulanan satır kesme olanağı. Sarma metni birden çok satır halinde kesildiğinde, hangi karakterlerin kesme için kullanılabileceğini belirler. Bu özellik için BreakOpportunity sabitlerini kullanın.
Varsayılan değer BreakOpportunity.AUTO şeklindedir.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
BreakOpportunity.AUTO | Satır kesme olanakları, kelimeler arasındaki kesme gibi standart Unicode karakteri özelliklerini ve kısa çizgileri esas alır. |
BreakOpportunity.ANY | ContentElement nesnesindeki tüm karakterler, satır kesme olanağı olarak değerlendirilir. Bu değer tipik olarak, Romence metin Asya metnine gömüldüğünde kullanılır ve sözcüklerin ortasında oluşan kesmeler için uygundur. |
BreakOpportunity.NONE | Aralıktaki karakterler, satır kesme olanakları olarak değerlendirilmez. |
BreakOpportunity.ALL | Aralıktaki tüm karakterler, satır kesme fırsatları olarak değerlendirilir, başka bir deyişle, her karakterden sonra bir satır kesme oluşur. Yolda metin efektleri oluşturmak için kullanışlıdır. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Gruptaki bitişik metin öğeleri arasında kesme olanağını belirler. Grubun elementFormat öğesi null olursa, bitişik öğelerin ilkinin biçimi kullanılır. |
TextElement | Metin öğesindeki karakterler arasında kesme olanağını belirler. |
Uygulama
public function get breakOpportunity():String public function set breakOpportunity(value:String):voidAtar
ArgumentError — BreakOpportunity öğesinin üyesi olmayan bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
color | özellik |
color:uint| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Metnin rengini gösterir. Üç adet 8 bit RGB bileşeni içeren bir tam sayı; örneğin, 0xFF0000 kırmızı ve 0x00FF00 yeşildir.
Varsayılan değer 0x000000 (siyah) şeklindedir.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Metnin rengini ayarlar. |
Uygulama
public function get color():uint public function set color(value:uint):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
digitCase | özellik |
digitCase:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bu metin için kullanılan basamak durumu. Basamağın büyük/küçük harf durumu, sayısal karakterlerin stilini ve konumunu etkiler. Bu özellik için DigitCase sabitlerini kullanın.
Varsayılan değer DigitCase.DEFAULT şeklindedir.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
DigitCase.DEFAULT | Metne varsayılan basamak büyük/küçük harf durumunu uygular. |
DigitCase.LINING | Metne sıralama basamak büyük/küçük harf durumunu uygular. |
DigitCase.OLD_STYLE | Metne eski stil basamak büyük/küçük harf durumunu uygular. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Öğedeki metin için kullanılan basamak büyük/küçük harf durumunu belirler. |
Uygulama
public function get digitCase():String public function set digitCase(value:String):voidAtar
ArgumentError — DigitCase öğesinin üyesi olmayan herhangi bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
digitWidth | özellik |
digitWidth:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bu metin için kullanılan basamak genişliği. Bu özellik için DigitWidth sabitlerini kullanın.
Varsayılan değer DigitWidth.DEFAULT şeklindedir.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
DigitWidth.DEFAULT | Metne varsayılan basamak genişliğini uygular. |
DigitWidth.PROPORTIONAL | Metne orantılı basamak genişliğini uygular. |
DigitWidth.TABULAR | Metne çizelgeli basamak genişliğini uygular. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Öğedeki metin için kullanılan basamak genişliğini belirler. |
Uygulama
public function get digitWidth():String public function set digitWidth(value:String):voidAtar
ArgumentError — DigitWidth öğesinin üyesi olmayan herhangi bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
dominantBaseline | özellik |
dominantBaseline:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Baskın satır taban çizgisi olarak kullanılacak satır taban çizgisinin türünü belirtir. Baskın satır taban çizgisi, satırdaki öğenin dikey konumunu belirlemek için hizalama satır taban çizgisiyle hizalanır. Bu özellik için TextBaseline sabitlerini kullanın.
Öğenin içeriği, taban çizgilerini belirler. TextElement olması durumunda, font ve nokta boyutu taban çizgilerini belirler. GraphicElement olması durumunda, öğenin yüksekliği taban çizgilerini belirler.
TextBaseline.ROMAN varsayılan değerdir.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
TextBaseline.ROMAN | Öğenin romence taban çizgisi, alignmentBaseline ile hizalanır. |
TextBaseline.ASCENT | Öğenin artan taban çizgisi, alignmentBaseline ile hizalanır. |
TextBaseline.DESCENT | Öğenin azalan taban çizgisi, alignmentBaseline ile hizalanır. |
TextBaseline.IDEOGRAPHIC_TOP | Öğenin ideografik üst taban çizgisi, alignmentBaseline ile hizalanır. |
TextBaseline.IDEOGRAPHIC_CENTER | Öğenin ideografik orta taban çizgisi, alignmentBaseline ile hizalanır. |
TextBaseline.IDEOGRAPHIC_BOTTOM | Öğenin ideografik alt taban çizgisi, alignmentBaseline ile hizalanır. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Grafik öğesinin hangi taban çizgilerinin alignmentBaseline ile hizalanacağını belirler. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Metin öğesinin hangi taban çizgilerinin alignmentBaseline ile hizalanacağını belirler. |
Uygulama
public function get dominantBaseline():String public function set dominantBaseline(value:String):voidAtar
ArgumentError — TextBaseline üyesi olmayan herhangi bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
fontDescription | özellik |
fontDescription:FontDescription| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Özellikleri bir fontu tanımlayan nesne.
Varsayılan değer, varsayılan olarak oluşturulan FontDescription nesnesidir.
fontDescription özelliği ayarlandığında, sağlanan FontDescription nesnesi kilitlenir: locked özelliği true değerine ayarlanır. Kilitlenmiş bir FontDescription değiştirilemez.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Öğedeki metin için kullanılan fontu belirler. |
Uygulama
public function get fontDescription():FontDescription public function set fontDescription(value:FontDescription):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
fontSize | özellik |
fontSize:Number| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Metnin piksel olarak boyutu.
12.0 varsayılan değerdir.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Öğedeki metnin piksel olarak boyutunu belirler. |
Uygulama
public function get fontSize():Number public function set fontSize(value:Number):voidAtar
ArgumentError — Sıfırdan düşük bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
kerning | özellik |
kerning:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Karakter aralığı, okunabilirliği artırmak için belirli karakter çiftleri arasındaki pikselleri ayarlar. Karakter aralığı tabloları olan tüm fontlar için karakter aralığı desteklenir.
Varsayılan değer Kerning.ON şeklindedir.
Bu özelliğin değerlerini ayarlamak için, Kerning sınıfındaki şu sabitleri kullanın:
| Dize değeri | Açıklama |
|---|---|
Kerning.ON | Karakter aralığı etkindir. |
Kerning.OFF | Karakter aralığı devre dışıdır. |
Kerning.AUTO | Uygun olmadığı Asya tipografisi dışında, karakter aralığı etkinleştirilir. Kanji, Hiragana veya Katakana olmadığı takdirde iki karakter arasına karakter aralığı uygulanır. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Gruptaki bitişik metin öğeleri arasına karakter aralığı uygulanıp uygulanmayacağını belirler. Grubun elementFormat öğesi null olursa, bitişik öğelerin ilkinin biçimi kullanılır. |
TextElement | Metin öğesindeki karakterler arasına karakter aralığı uygulanıp uygulanmayacağını belirler. |
Uygulama
public function get kerning():String public function set kerning(value:String):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
ligatureLevel | özellik |
ligatureLevel:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bu metin için kullanılan birleşik harf düzeyi. İki veya daha fazla harf formunun tek bir glif olarak birleşmesiyle birleşik harf oluşur. Birleşik harfler genellikle ortak bileşenleri paylaşan ardışık karakterlerin yerini alır, örn. 'fi', 'fl' veya 'ae' harf çiftleri. Bunlar hem Latince olan hem de Latince olmayan karakter kümeleriyle kullanılır. Bu özellik için LigatureLevel sabitlerini kullanın.
Varsayılan değer LigatureLevel.COMMON şeklindedir.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
LigatureLevel.NONE | Birleşik harf oluşturulmaz. |
LigatureLevel.MINIMUM | En düşük düzeyde birleşik harf oluşturulur. |
LigatureLevel.COMMON | Yaygın birleşik harfler oluşturulur. |
LigatureLevel.UNCOMMON | Yaygın olmayan birleşik harfler oluşturulur. |
LigatureLevel.EXOTIC | Yabancı birleşik harfler oluşturulur. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Gruptaki bitişik metin öğeleri arasındaki birleşik harf düzeyini belirler. Grubun elementFormat öğesi null olursa, bitişik öğelerin ilkinin biçimi kullanılır. |
TextElement | Metin öğesindeki karakterler arasında birleşik harf düzeyini belirler. |
Uygulama
public function get ligatureLevel():String public function set ligatureLevel(value:String):voidAtar
ArgumentError — LigatureLevel öğesinin üyesi olmayan herhangi bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
locale | özellik |
locale:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Metnin yerel ayarı. Büyük/küçük harf dönüşümlerini ve şekillendirmeyi denetler. Standart yerel ayar kimlikleri kullanılır. Örneğin "en", "en_US" ve "en-US" İngilizce iken, "ja" Japonca'dır. Yerel ayar kodlarının bir listesi için bkz. iso639-2 kod listesi.
"en" varsayılan değerdir.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Öğedeki metnin dönüşümlerini be şekillendirmesini belirler. |
Uygulama
public function get locale():String public function set locale(value:String):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
locked | özellik |
locked:Boolean| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5., Flash Lite 4 |
ElementFormat öğesinin kilitlenmiş olup olmadığını belirtir. true olursa, ElementFormat değiştirilemez. ElementFormat nesnesinin kilitlenmemiş bir kopyasını almak için, ElementFormat.clone() öğesini çağırın.
Uygulama
public function get locked():Boolean public function set locked(value:Boolean):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
textRotation | özellik |
textRotation:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Ayrı ayrı gliflere uygulanan döndürme işlemini ayarlar. Bu özellik için TextRotation sınıfında tanımlanan sabitleri kullanın.
Varsayılan değer TextRotation.AUTO şeklindedir.
Herhangi bir glifin son dönüşü, ElementFormat.textRotation, ContentElement.textRotation ve TextBlock.lineRotation öğelerinin toplamıdır.
Genellikle, karakterlerin dikey mizanpajda düzgün şekilde görüntülenmesi için döndürülmesi gerektiği Asya metni için bu özellik uygundur. Bunu gerçekleştirmek için TextRotation.AUTO öğesini, TextBlock.lineRotation = TextRotation.ROTATE_90 ile birlikte kullanın.
Dikey mizanpaj bilgilerini içermeyen fontlarda bu özelliğin ayarlanmasıyla istenmeyen sonuçlar ortaya çıkabilir. Japonca font olan "MS Mincho" gibi vmtx veya VORG tablosu içeren fontlar, bu tablolar doğru mizanpaj için mizanpaj motorlarının gerektirdiği verileri sağladığından, düzgün çalışır. Verdana gibi gerekli bilgileri içermeyen fontlar düzgün çalışmaz.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
TextRotation.ROTATE_0 | Glifler döndürülmez. |
TextRotation.ROTATE_90 | Glifler 90 derece saat yönünde döndürülür. |
TextRotation.ROTATE_180 | Glifler 180 derece döndürülür. |
TextRotation.ROTATE_270 | Glifler 270 derece saat yönünde döndürülür. |
TextRotation.AUTO | Glifin Unicode özellikleriyle belirlendiği şekilde, yalnızca tam genişlikteki ve geniş glifler için 90 derece saatin ters yönünde döndürme işlemini belirtir. Bu değer, yalnızca döndürme gerektiren glifleri döndürmek için Asya Dili metinle tipik olarak kullanılır. Diğer karakterleri etkilemeden dikey bir yönlendirmeye tam genişlikteki ve geniş karakterler döndürmek için bu döndürme işlemi yalnızca dikey metinde uygulanır. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Metin öğesindeki gliflerin dönüşünü belirler. |
Uygulama
public function get textRotation():String public function set textRotation(value:String):voidAtar
ArgumentError — TextRotation üyesi olmayan herhangi bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
trackingLeft | özellik |
trackingLeft:Number| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5., Flash Lite 4 |
Her glifin soluna uygulanan, piksel cinsinden izleme veya manuel karakter aralığı. kerning etkinleştirilirse, fontun karakter aralığı tablosundaki değerlere trackingLeft değeri eklenir. kerning devre dışı bırakılırsa, elle karakter aralığı değeri olarak trackingLeft değeri kullanılır. Hem pozitif hem de negatif değerleri destekler.
Tipik olarak, istenen izleme değeri trackingRight ile trackingLeft arasında bölünür. Aksi takdirde, karma yönlülük metninde iki yönlü sınırın birinde iki izleme vardır, diğerinde ise yoktur.
0.0 varsayılan değerdir.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Grafiğin sol tarafına uygulanacak izlemeyin belirler. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Metin öğesindeki karakterlerin sol tarafına uygulanacak izlemeyi belirler. |
Örnek:
//positive tracking added to kerning
var ef1:ElementFormat = new ElementFormat();
ef1.kerning = flash.text.engine.Kerning.ON;
ef1.trackingLeft = 0.5;
//negative manual kerning
var ef2:ElementFormat = new ElementFormat();
ef2.kerning = flash.text.engine.Kerning.OFF;
ef2.trackingLeft = -1.0;
Uygulama
public function get trackingLeft():Number public function set trackingLeft(value:Number):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
trackingRight | özellik |
trackingRight:Number| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5., Flash Lite 4 |
Her glifin sağına uygulanan, piksel cinsinden izleme veya manuel karakter aralığı. kerning etkinleştirilirse, fontun karakter aralığı tablosundaki değerlere trackingRight değeri eklenir. kerning devre dışı bırakılırsa, elle karakter aralığı değeri olarak trackingRight değeri kullanılır. Hem pozitif hem de negatif değerleri destekler.
Tipik olarak, istenen izleme değeri trackingRight ile trackingLeft arasında bölünür. Aksi takdirde, karma yönlülük metninde iki yönlü sınırın birinde iki izleme vardır, diğerinde ise yoktur.
0.0 varsayılan değerdir.
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Grafiğin sağ tarafına uygulanacak izlemeyi belirler. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Metin öğesindeki karakterlerin sağ tarafına uygulanacak izlemeyi belirler. |
Örnek:
//positive tracking added to kerning
var ef1:ElementFormat = new ElementFormat();
ef1.kerning = flash.text.engine.Kerning.ON;
ef1.trackingRight = 0.5;
//negative manual kerning
var ef2:ElementFormat = new ElementFormat();
ef2.kerning = flash.text.engine.Kerning.OFF;
ef2.trackingRight = -1.0;
Uygulama
public function get trackingRight():Number public function set trackingRight(value:Number):voidAtar
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
typographicCase | özellik |
typographicCase:String| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bu metin için kullanılan tipografik durum. Bu özellik için TypographicCase sınıfında tanımlanan sabitleri kullanın.
Varsayılan değer TypographicCase.DEFAULT şeklindedir.
Bu özelliğin değerlerini ayarlamak için, aşağıdaki dize değerlerini kullanın:
| Dize değeri | Açıklama |
|---|---|
TypographicCase.DEFAULT | Tüm karakterler için normal büyük küçük harflerin kullanıldığını belirtir. |
TypographicCase.TITLE | Büyük harfli karakterlerin çıktıda başlık gliflerini kullandığını belirtir. |
TypographicCase.CAPS | Çıktıdaki büyük harfli karakterler için boşluk ayarlandığını belirtir. |
TypographicCase.SMALL_CAPS | Büyük harfli karakterlerin çıktıda küçük başlık gliflerini kullandığını belirtir. |
TypographicCase.UPPERCASE | Tüm karakterlerin çıktıda büyük harfli glifleri kullandığını belirtir. |
TypographicCase.LOWERCASE | Tüm karakterlerin çıktıda küçük harfli glifleri kullandığını belirtir. |
TypographicCase.CAPS_AND_SMALL_CAPS | Tüm küçük harfli karakterlerin çıktıda küçük başlık gliflerini kullandığını belirtir. |
| Alt sınıf | Özellik ayarlama etkisi |
|---|---|
GraphicElement | Herhangi bir etkisi yoktur. |
GroupElement | Herhangi bir etkisi yoktur. |
TextElement | Öğedeki metin için kullanılan tipografik durumu belirler. |
Uygulama
public function get typographicCase():String public function set typographicCase(value:String):voidAtar
ArgumentError — TypographicCase öğesinin üyesi olmayan bir değere ayarlanırsa.
| |
IllegalOperationError — ElementFormat nesnesi kilitlendikten sonra (locked true olur) ayarlanırsa.
|
İlgili API Öğeleri
ElementFormat | () | Yapıcı |
public function ElementFormat(fontDescription:FontDescription = null, fontSize:Number = 12.0, color:uint = 0x000000, alpha:Number = 1.0, textRotation:String = "auto", dominantBaseline:String = "roman", alignmentBaseline:String = "useDominantBaseline", baselineShift:Number = 0.0, kerning:String = "on", trackingRight:Number = 0.0, trackingLeft:Number = 0.0, locale:String = "en", breakOpportunity:String = "auto", digitCase:String = "default", digitWidth:String = "default", ligatureLevel:String = "common", typographicCase:String = "default")| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Bir ElementFormat nesnesi oluşturur.
ParametrelerfontDescription:FontDescription (default = null)null şeklindedir. Herhangi bir font açıklaması mevcut değilse, varsayılan bir font açıklaması oluşturulur.
| |
fontSize:Number (default = 12.0) | |
color:uint (default = 0x000000) | |
alpha:Number (default = 1.0)alpha özelliği.
| |
textRotation:String (default = "auto") | |
dominantBaseline:String (default = "roman") | |
alignmentBaseline:String (default = "useDominantBaseline") | |
baselineShift:Number (default = 0.0) | |
kerning:String (default = "on") | |
trackingRight:Number (default = 0.0) | |
trackingLeft:Number (default = 0.0) | |
locale:String (default = "en") | |
breakOpportunity:String (default = "auto") | |
digitCase:String (default = "default") | |
digitWidth:String (default = "default") | |
ligatureLevel:String (default = "common") | |
typographicCase:String (default = "default") |
Atar
ArgumentError — Belirtilen fontSize 0'dan küçüktür.
| |
ArgumentError — Belirtilen textRotation, TextRotation öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen dominantBaseline, TextBaseline öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen alignmentBaseline, TextBaseline öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen kerning, Kerning öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen breakOpportunity, BreakOpportunity öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen digitCase, DigitCase öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen digitWidth, DigitWidth öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen ligatureLevel, LigatureLevel öğesinin bir üyesi değildir.
| |
ArgumentError — Belirtilen typographicCase, TypographicCase öğesinin bir üyesi değildir.
|
clone | () | yöntem |
public function clone():ElementFormat| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
ElementFormat öğesinin kilitlenmemiş, klonlanmış bir kopyasını oluşturur.
DöndürürElementFormat — ElementFormat nesnesinin kilitlenmemiş bir kopyası.
|
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek bir ElementFormat nesnesi oluşturur ve FontSize öğesini ayarlar. TextBlock için içerik olarak ElementFormat (ve böylece kilitlenir) ve TextElement kullanılarak yeni bir TextElement oluşturulur. TextBlock öğesinden bir metin satırı oluşturulur.
ElementFormat nesnesini değiştirmek için öncelikle nesnenin locked özelliğini kontrol edin. Bu özellik true değerindeyse, clone() yöntemini kullanarak ElementFormat öğesinin kilitlenmemiş bir kopyasını oluşturun, bunun özelliklerini değiştirin, daha sonra da ElementFormat öğesini TextBlock öğesine yeniden bağlayın. Satırlar yeniden kesildiğinde, yeni satırlar yeni font ayarlarına sahip olur.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class ElementFormat_cloneExample extends Sprite {
private var ef1:ElementFormat;
private var ef2:ElementFormat;
public function ElementFormat_cloneExample():void {
var fd:FontDescription = new FontDescription();
fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
fd.fontName = "Palatino";
var ef1:ElementFormat = new ElementFormat(fd);
ef1.fontSize=20;
var str:String = "This is flash text 0123456789";
var tb:TextBlock = new TextBlock();
var te1:TextElement = new TextElement(str, ef1);
tb.content = te1;
var line1:TextLine = tb.createTextLine(null, 600);
addChild(line1);
ef2 = (ef1.locked) ? ef1.clone() : ef1;
ef2.fontSize = 32;
tb.content.elementFormat=ef2;
var line2:TextLine = tb.createTextLine(null, 600);
addChild(line2);
}
}
}
getFontMetrics | () | yöntem |
public function getFontMetrics():FontMetrics| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
fontDescription ve fontSize tarafından belirtilen fonta yönelik emBox, üst çizgi konumunu, üst çizgi kalınlığını, alt çizgi konumunu ve alt çizgi kalınlığını açıklayan özelliklere sahip bir FontMetrics nesnesi döndürür.
FontMetrics — fontDescription tarafından belirtilen font özelliklerini açıklayan bir FontMetrics sınıfı.
|
İlgili API Öğeleri
Örnek ( Bu örnek nasıl kullanılır? )
FontDescription içeren bir ElementFormat nesnesi oluşturur ve seçilen fontun ölçümlerini 24 nokta olarak görüntülemek için getFontMetrics yöntemini kullanır.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class FontMetricsExample extends Sprite {
public function FontMetricsExample():void {
var fd:FontDescription = new FontDescription();
fd.fontName = "Garamond";
fd.fontWeight = flash.text.engine.FontWeight.BOLD;
var ef1:ElementFormat = new ElementFormat(fd);
ef1.fontSize = 24;
var fm1:FontMetrics = ef1.getFontMetrics();
trace(fm1.emBox);
trace(fm1.strikethroughOffset);
trace(fm1.strikethroughThickness);
trace(fm1.subscriptScale);
trace(fm1.subscriptOffset);
trace(fm1.superscriptScale);
trace(fm1.superscriptOffset);
trace(fm1.underlineOffset);
trace(fm1.underlineThickness);
}
}
}
Bu örnek iki ElementFormat nesnesi oluşturur ve bunların birçok özelliğini ayarlar. Daha sonra TextBlock öğesinin içeriği olarak atanmış TextElement nesnesine yeni ElementFormats öğesini atar. Bir TextElement öğesinin ElementFormat öğesinin değiştirilmesi, üst TextBlock tarafından önceden oluşturulmuş TextLines öğesini etkilemez.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class ElementFormatExample extends Sprite {
public function ElementFormatExample():void {
var fd:FontDescription = new FontDescription();
fd.fontName = "Garamond";
fd.fontWeight = flash.text.engine.FontWeight.BOLD;
var ef1:ElementFormat = new ElementFormat(fd);
ef1.fontSize = 30;
ef1.color = 0xFF0000;
ef1.alpha = 100;
ef1.kerning = flash.text.engine.Kerning.ON;
ef1.trackingRight = 2;
ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
var ef2:ElementFormat = new ElementFormat(fd);
ef2.fontSize = 30;
ef2.color = 0xFF0000;
ef2.alpha = 0.3;
ef2.kerning = flash.text.engine.Kerning.OFF;
ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
var str:String = "This is flash text 0123456789";
var tb:TextBlock = new TextBlock();
var te1:TextElement = new TextElement(str, ef1);
tb.content = te1;
var line1:TextLine = tb.createTextLine(null, 600);
addChild(line1);
line1.x = 15;
line1.y = 30;
tb.content.elementFormat = ef2;
var line2:TextLine = tb.createTextLine(null, 600);
addChild(line2);
line2.x = 15;
line2.y = 60;
}
}
}
Tue Jun 12 2018, 01:09 PM Z