DisplayObject  - AS3

Bu görüntüleme nesnesi için geçerli erişilebilirlik seçenekleri. accessibilityProperties özelliğini veya accessibilityProperties içindeki alanlardan herhangi birini değiştirirseniz, değişikliklerinizin etkili olması için Accessibility.updateProperties() yöntemini çağırmanız gerekir.

Not: Flash geliştirme ortamında oluşturulan bir nesne için, accessibilityProperties öğesi, Accessibility paneline o nesneyle ilgili girdiğiniz tüm bilgilerle önceden doldurulur.

İlgili API Öğeleri

import flash.text.TextField;
import flash.accessibility.AccessibilityProperties;
import flash.accessibility.Accessibility;
import flash.system.Capabilities;

var tf:TextField = new TextField();
tf.text = "hello";

var accessProps:AccessibilityProperties = new AccessibilityProperties();
accessProps.name = "Greeting";

tf.accessibilityProperties = accessProps;

if (Capabilities.hasAccessibility) {
    Accessibility.updateProperties();
}

trace(tf.accessibilityProperties.name); // Greeting

Belirtilen nesnenin alfa saydamlık değerini gösterir. Geçerli değerler 0 (tam saydam) ile 1 (tam opak) şeklindedir. Varsayılan değer 1'dir. alpha özelliği 0 olarak ayarlanmış görüntüleme nesneleri görünmez olsa da etkindir.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFF0000);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_OVER, dimObject);
circle.addEventListener(MouseEvent.MOUSE_OUT, restoreObject);

function dimObject(event:MouseEvent):void {
    event.target.alpha = 0.5;
}

function restoreObject(event:MouseEvent):void {
    event.target.alpha = 1.0;
}

Hangi karışım modunun kullanılacağını belirten bir BlendMode sınıfı değeri. Bir bitmap dahili olarak iki şekilde çizilebilir. Etkin bir karışım modu veya harici bir kırpma maskesi varsa, vektör oluşturucuya bitmap dolgulu bir kare şekli eklenerek bitmap çizilir. Bu özelliği geçersiz bir değere ayarlamaya çalışırsanız, Flash çalışma zamanları bu değeri BlendMode.NORMAL olarak ayarlar.

blendMode özelliği, görüntüleme nesnesinin her pikselini etkiler. Her piksel üç renkten (kırmızı, yeşil ve mavi) oluşur ve pikseli oluşturan her renk 0x00 ile 0xFF arasında bir değere sahiptir. Flash Player veya Adobe AIR, film klibindeki bir pikseli oluşturan her bir rengi arka plandaki pikselin karşılık gelen rengiyle karşılaştırır. Örneğin, blendMode öğesi BlendMode.LIGHTEN olarak ayarlanırsa, Flash Player veya Adobe AIR, görüntüleme nesnesinin kırmızı değerini arka planın kırmızı değeriyle karşılaştırır ve bunlardan daha açık renkli olanını görüntülenen rengin kırmızı bileşeninin değeri olarak kullanır.

Şu tablo blendMode ayarlarını açıklar. BlendMode sınıfı, kullanabileceğiniz dize değerlerini tanımlar. Tablodaki resimler, bir görüntüleme nesnesinin (1) üzerine eklenmiş dairesel bir görüntüleme nesnesine (2) uygulanan blendMode değerlerini gösterir.

BlendMode Sabiti	Resim	Açıklama
BlendMode.NORMAL		Görüntüleme nesnesi arka planın önünde görüntülenir. Görüntüleme nesnesinin piksel değerleri, arka planın piksel değerlerini geçersiz kılar. Görüntüleme nesnesi saydam olduğunda arka plan görünebilir.
BlendMode.LAYER		Görüntüleme nesnesi için bir saydamlık grubu oluşturmaya zorlar. Başka bir deyişle, görüntüleme nesnesi, daha fazla işlenmeden önce geçici bir arabellekte önceden oluşturulur. Bitmap önbelleğe alma yoluyla görüntüleme nesnesi önceden önbelleğe alınırsa veya görüntüleme nesnesi, BlendMode.NORMAL dışında bir blendMode ayarına sahip en az bir alt nesne içeren bir görüntüleme nesnesi kabıysa, bu işlem otomatik olarak yapılır. GPU görüntü oluşturma altında desteklenmez.
BlendMode.MULTIPLY		Görüntüleme nesnesini oluşturan renkleri arka plan rengini oluşturan renkler ile çarpar ve 0xFF ile bölerek normalleştirir, sonuçta daha koyu renkler elde eder. Bu ayar, gölgeler ve derinlik efektleri için yaygın olarak kullanılır. Örneğin görüntüleme nesnesinde bir pikseli oluşturan renk (örn. kırmızı) ile arka plandaki pikselin karşılık gelen rengin ikisi de 0x88 değerine sahipse, çarpma sonucu 0x4840 olur. 0xFF ile bölünmesi, o oluşturan renk için 0x48 değerini verir ve bu da görüntüleme nesnesinin renginden veya arka plan renginden daha koyu bir gölge sağlar.
BlendMode.SCREEN		Görüntüleme nesnesi renginin tamlayanını (tersini) arka plan renginin tamlayanı ile çarpar, sonuçta bir renk açma efekti elde edilir. Bu ayar, vurgular için veya görüntüleme nesnesinin siyah alanlarını kaldırmak için yaygın olarak kullanılır.
BlendMode.LIGHTEN		Görüntüleme nesnesini oluşturan renklerden ve arka plan renginden daha açık olanını (daha büyük değerli renkler) seçer. Bu ayar, yaygın olarak üzerine ekleme türü için kullanılır. Örneğin görüntüleme nesnesinin 0xFFCC33 RGB değerine sahip bir pikseli ve 0xDDF800 RGB değerine sahip arka plan pikseli varsa, görüntülenen pikselin sonuç RGB değeri, 0xFFF833 olur (0xFF > 0xDD, 0xCC < 0xF8 ve 0x33 > 0x00 = 33 olması nedeniyle). GPU görüntü oluşturma altında desteklenmez.
BlendMode.DARKEN		Görüntüleme nesnesini oluşturan renklerden ve arka plan renklerinden daha koyu olanını (daha küçük değerli renkler) seçer. Bu ayar, yaygın olarak üzerine ekleme türü için kullanılır. Örneğin görüntüleme nesnesinin 0xFFCC33 RGB değerine sahip bir pikseli ve 0xDDF800 RGB değerine sahip arka plan pikseli varsa, görüntülenen pikselin sonuç RGB değeri, 0xDDCC00 olur (0xFF > 0xDD, 0xCC < 0xF8 ve 0x33 > 0x00 = 33 olması nedeniyle). GPU görüntü oluşturma altında desteklenmez.
BlendMode.DIFFERENCE		Görüntüleme nesnesini oluşturan renkleri arka planının renkleri ile karşılaştırır ve oluşturan iki renkten daha koyu olanın değerlerini daha açık olanın değerinden çıkarır. Bu ayar yaygın olarak daha canlı renkler için kullanılır. Örneğin görüntüleme nesnesinin 0xFFCC33 RGB değerine sahip bir pikseli ve 0xDDF800 RGB değerine sahip arka plan pikseli varsa, görüntülenen pikselin sonuç RGB değeri, 0x222C33 olur (0xFF - 0xDD = 0x22, 0xF8 - 0xCC = 0x2C ve 0x33 - 0x00 = 0x33 olması nedeniyle).
BlendMode.ADD		Görüntüleme nesnesini oluşturan renklerin değerlerini, 0xFF düzeyinde bir tavan uygulayarak arka planının renklerine ekler. Bu ayar, yaygın olarak iki nesne arasında bir açıklaştırma erimesi animasyonu için kullanılır. Örneğin görüntüleme nesnesinin 0xAAA633 RGB değerine sahip bir pikseli ve 0xDD2200 RGB değerine sahip arka plan pikseli varsa, görüntülenen pikselin sonuç RGB değeri, 0xFFC833 olur (0xAA + 0xDD > 0xFF, 0xA6 + 0x22 = 0xC8 ve 0x33 + 0x00 = 0x33 olması nedeniyle).
BlendMode.SUBTRACT		Görüntüleme nesnesini oluşturan renklerin değerlerini arka plan renginin değerinden çıkarır ve 0 tabanını uygular. Bu ayar, yaygın olarak iki nesne arasında bir koyulaştırma erimesi animasyonu için kullanılır. Örneğin görüntüleme nesnesinin 0xAA2233 RGB değerine sahip bir pikseli ve 0xDDA600 RGB değerine sahip arka plan pikseli varsa, görüntülenen pikselin sonuç RGB değeri, 0x338400 olur (0xDD - 0xAA = 0x33, 0xA6 - 0x22 = 0x84 ve 0x00 - 0x33 < 0x00 olması nedeniyle).
BlendMode.INVERT		Arka planı ters çevirir.
BlendMode.ALPHA		Ekran nesnesinin her pikselinin alfa değerini arka plana uygular. Bunun için, üst görüntüleme nesnesinin blendMode ayarının BlendMode.LAYER olarak ayarlanması gerekir. Örneğin, resimde, beyaz arka plan olan üst görüntüleme nesnesi blendMode = BlendMode.LAYER öğesine sahiptir. GPU görüntü oluşturma altında desteklenmez.
BlendMode.ERASE		Arka planı, ekran nesnesinin alfa değerini esas alarak siler. Bunun için, üst görüntüleme nesnesinin blendMode öğesinin BlendMode.LAYER olarak ayarlanması gerekir. Örneğin, resimde, beyaz arka plan olan üst görüntüleme nesnesi blendMode = BlendMode.LAYER öğesine sahiptir. GPU görüntü oluşturma altında desteklenmez.
BlendMode.OVERLAY		Arka planın koyuluğunu esas alarak her pikselin rengini ayarlar. Arka plan, %50 griden daha açıksa, görüntüleme nesnesi ve arka plan renkleri taranır ve sonucunda daha açık renk elde edilir. Arka plan %50 griden daha koyuysa, renkler çarpılır ve sonucunda daha koyu renk elde edilir. Bu ayar, yaygın olarak gölgelendirme efektleri için kullanılır. GPU görüntü oluşturma altında desteklenmez.
BlendMode.HARDLIGHT		Görüntüleme nesnesinin koyuluğunu esas alarak her pikselin rengini ayarlar. Görüntüleme nesnesi %50 griden daha açıksa, görüntüleme nesnesi ve arka plan renkleri taranır ve sonucunda daha açık renk elde edilir. Görüntüleme nesnesi %50 griden daha koyuysa, renkler çarpılır ve sonucunda daha koyu renk elde edilir. Bu ayar, yaygın olarak gölgelendirme efektleri için kullanılır. GPU görüntü oluşturma altında desteklenmez.
BlendMode.SHADER	Yok	Özel bir gölgelendirici yordamı kullanarak rengi ayarlar. Kullanılan gölgelendirici, blendShader özelliğine atanan Shader örneği olarak belirtilir. Görüntüleme nesnesinin blendShader özelliğinin bir Shader örneğine ayarlanması, görüntüleme nesnesinin blendMode özelliğini otomatik olarak BlendMode.SHADER değerine ayarlar. İlk önce blendShader özelliği ayarlanmadan blendMode özelliği BlendMode.SHADER olarak ayarlanırsa, bunun yerine blendMode özelliği BlendMode.NORMAL olarak ayarlanır. GPU görüntü oluşturma altında desteklenmez.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.display.BlendMode;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFF88CC);
square.graphics.drawRect(0, 0, 80, 80);
addChild(square);

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xAA0022);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_OVER, dimObject);
circle.addEventListener(MouseEvent.MOUSE_OUT, restoreObject);

function dimObject(event:MouseEvent):void {
    event.target.blendMode = BlendMode.SUBTRACT;
}

function restoreObject(event:MouseEvent):void {
    event.target.blendMode = BlendMode.NORMAL;
}

Ön planı ve arka planı karıştırmak için kullanılacak bir gölgelendirici ayarlar. blendMode özelliği BlendMode.SHADER olarak ayarlandığında, görüntüleme nesnesi için karışım modu oluşturmak üzere belirtilen Shader kullanılır.

Görüntüleme nesnesinin blendShader özelliğinin bir Shader örneğine ayarlanması, görüntüleme nesnesinin blendMode özelliğini otomatik olarak BlendMode.SHADER değerine ayarlar. blendShader özelliği ayarlanırsa (blendMode özelliğini BlendMode.SHADER olarak ayarlar), daha sonra blendMode özelliğinin değeri değiştirilir, karışım gölgelendiricisini kullanmak için yalnızca blendMode özelliği BlendMode.SHADER değerine ayarlanarak karışım modu sıfırlanabilir. Karışım modu için kullanılan gölgelendiriciyi değiştirme durumu dışında blendShader özelliğinin tekrar ayarlanması gerekmez.

blendShader özelliğine atanan Shader öğesinin en az iki image4 girdisi belirtmesi gerekir. İlişkilendirilmiş ShaderInput nesnesinin input özellikleri kullanılarak girdilerin kodda belirtilmesi gerekmez. Arka plan görüntüleme nesnesi otomatik olarak birinci girdi olarak kullanılır (index 0 değerine sahip girdi). Ön plan görüntüleme nesnesi ikinci girdi olarak kullanılır (index 1 değerine sahip girdi). Karışım gölgelendiricisi olarak kullanılan bir gölgelendirici, ikiden çok girdi belirtebilir. Bu durumda ShaderInput örneğinin input özelliği ayarlanarak ek girdinin belirtilmesi gerekir.

Bu özelliğe bir Shader örneği atadığınızda, gölgelendirici dahili olarak kopyalanır. Karışım işlemi, orijinal gölgelendiricinin başvurusunu değil, bu dahili kopyayı kullanır. Gölgelendiriciye yapılan değişiklikler (örn. parametre değerini, girdiyi veya bayt kodunu değiştirme) karışım modu için kullanılan kopyalanmış gölgelendiriciye uygulanmaz.

İlgili API Öğeleri

true olarak ayarlanırsa, Flash çalışma zamanları, görüntüleme nesnesinin dahili bir bitmap temsilini önbelleğe alır. Bu önbelleğe alma işlemi, karmaşık vektör içeriği barındıran görüntüleme nesnelerinin performansını artırabilir.

Önbelleğe alınan bitmap'i olan bir görüntüleme nesnesinin tüm vektör verisi, ana görüntü yerine bitmap'e çizilir. cacheAsBitmapMatrix null değerindeyse veya desteklenmiyorsa, bitmap en yakın piksel sınırlarıyla kırpılmış uzatılmamış ve döndürülmemiş pikseller olarak ana ekrana kopyalanır. Pikseller üst nesneyle bire bir eşleştirilir. Bitmap'in sınırları değişirse, bitmap uzatılmak yerine yeniden oluşturulur.

cacheAsBitmapMatrix null değilse ve destekleniyorsa, nesne bu matris kullanılarak ekran dışı bitmap'e çekilir ve bu oluşumun uzatılan ve/veya döndürülen sonuçları, nesnenin ana ekrana çekilmesi için kullanılır.

cacheAsBitmap özelliği true değerine ayarlanmazsa, herhangi bir dahili bitmap oluşturulmaz.

Siz cacheAsBitmap özelliğini true değerine ayarladıktan sonra, oluşturma değişmez ancak görüntüleme nesnesi otomatik olarak piksel bitiştirme işlemini gerçekleştirir. Vektör içeriğinin karmaşıklığına bağlı olarak, animasyon hızı çok daha yüksek olabilir.

Bir görüntüleme nesnesine her filtre uyguladığınızda (filter dizisi boş olmadığında) cacheAsBitmap özelliği otomatik olarak true değerine ayarlanır ve bu görüntüleme nesnesine bir filtre uygulanmışsa, özelliği false değerine ayarlasanız da o görüntüleme nesnesi için cacheAsBitmap true olarak bildirilir. Görüntüleme nesnesinin tüm filtrelerini temizlerseniz, cacheAsBitmap ayarı en son ayarlandığı değere geçer.

cacheAsBitmap özelliği true değerine ayarlansa da, görüntüleme nesnesi bir bitmap kullanmaz ve bunun yerine şu durumlarda vektör verilerinden bitmap oluşturur:

• Bitmap çok büyük. AIR 1.5 ve Flash Player 10'da, bir bitmap görüntüsü için maksimum boyut genişlik ve yükseklikte 8.191 pikseldir ve toplam piksel sayısı 16.777.215'i geçemez. (Bu nedenle, bir bitmap görüntüsü 8.191 piksel genişliğindeyse en fazla 2.048 piksel yüksekliğinde olabilir.) Flash Player 9 ve daha önceki sürümlerde, sınırlama yükseklikte ve genişlikte 2880 pikseldir.
• Bitmap bellek ayırmayı başaramazsa (yetersiz bellek hatası).

cacheAsBitmap özelliği, daha çok statik içeriğe sahip olan ve sık sık ölçeklenmeyen ve döndürülmeyen film klipleriyle en iyi şekilde kullanılır. Böyle film kliplerinde cacheAsBitmap, film klibi çevrildiğinde (x ve y konumu değiştiğinde) performans artışı sağlar.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.filters.DropShadowFilter

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xAA0022);
circle.graphics.drawCircle(40, 40, 40);

addChild(circle);

trace(circle.cacheAsBitmap); // false

var filter:DropShadowFilter = new DropShadowFilter();
circle.filters = [filter];

trace(circle.cacheAsBitmap); // true

Bu Matrix nesnesi null olmazsa, görüntüleme nesnesinin cacheAsBitmap true olarak ayarlandığı zaman nasıl oluşturacağını tanımlar. Uygulama bu matrisi, görüntüleme nesnesinin bitmap sürümü oluşturulurken başvurulan bir dönüşüm matrisi olarak kullanır.

AIR profil desteği: Bu özellik mobil aygıtlarda desteklenir ancak masaüstü işletim sistemlerinde desteklenmez. Ayrıca AIR for TV aygıtlarında sınırlı desteğe sahiptir. Özellikle AIR for TV aygıtlarında, desteklenen dönüştürmeler ölçeklemeyi ve çeviriyi içerir ancak döndürmeyi ve eğriltmeyi içermez. Birden fazla profilde API desteği ile ilgili daha fazla bilgi için bkz. AIR Profil Desteği.

cacheAsBitmapMatrix ayarlı iken uygulama; çeviri, döndürme ve ölçekleme dahil olmak üzere çeşitli 2B dönüşümler üzerinden önbelleğe alınmış bir bitmap görüntüyü korur. Uygulama donanım hızlandırma kullanıyorsa, nesne bir video bellekte doku olarak saklanacaktır. Bu GPU'nun, desteklenen dönüşümleri nesneye uygulamasını sağlar. GPU bu dönüşümleri CPU'dan daha hızlı yapabilir.

Donanım hızlandırma kullanmak için, Flash Professional CS5'in içindeki iPhone Ayarları iletişim kutusunun Genel sekmesinde Oluşturma'yı GPU'ya ayarlayın. Veya renderMode özelliğini uygulama açıklaması dosyasında gpu olarak ayarlayın. AIR for TV aygıtlarının, mevcut olması halinde otomatik olarak donanım hızlandırma kullandığını unutmayın.

Örneğin, aşağıdaki kod görüntüleme nesnesinin dönüştürülmemiş bitmap temsilini GPU'ya yollar.

matrix:Matrix = new Matrix(); // creates an identity matrix 
     mySprite.cacheAsBitmapMatrix = matrix; 
     mySprite.cacheAsBitmap = true;

Genellikle kimlik matrisi (new Matrix()) yeterlidir. Bunun yanı sıra GPU'ya değişik bir bitmap yüklemek için küçültülerek ölçeklenmiş matris gibi başka bir matrisi de kullanabilirsiniz. Örneğin, aşağıdaki örnek x ve y eksenleri boyunca 0.5 olarak ölçeklendirilmiş bir cacheAsBitmapMatrix uygular. GPU'nun kullandığı bitmap nesnesi daha küçüktür ancak GPU bu nesnenin boyutunu görüntüleme nesnesinin matris özelliğiyle eşleşecek şekilde ayarlar.

matrix:Matrix = new Matrix(); // creates an identity matrix 
     matrix.scale(0.5, 0.5); // scales the matrix 
     mySprite.cacheAsBitmapMatrix = matrix; 
     mySprite.cacheAsBitmap = true;

Genel olarak görüntüleme nesnesinin uygulamada görüneceği boyuta dönüştürecek bir matris seçmelisiniz. Örneğin, uygulamanız sprite nesnesinin bitmap halini 1/2 oranında ölçeklendiriyorsa 1/2 oranında ölçeklendiren bir matris seçin. Uygulamanız sprite nesnesini geçerli boyutlarından daha büyük olarak görüntüleyecekse, o oranda büyüterek ölçeklendiren bir matris kullanın.

Not: cacheAsBitmapMatrix özelliği, 2B dönüşümler için uygundur. Dönüşümleri 3B olarak uygulamanız gerekiyorsa, bunu nesnenin 3B özelliğini ayarlayarak ve transform.matrix3D özelliğini işleyerek yapabilirsiniz. Uygulama GPU modu kullanarak paketlenmişse, 3B dönüşümler GPU tarafından nesneye uygulanabilir. cacheAsBitmapMatrix 3B nesneler için yok sayılır.

İlgili API Öğeleri

import flash.geom.Matrix;
import flash.display.*;
import flash.utils.Timer;

var my_shape:MovieClip = new MovieClip();
my_shape.graphics.beginFill(0xCCFF00);
my_shape.graphics.drawRect(200, 0, 100, 100);
addChild(my_shape);

var my_timer:Timer = new Timer(250);
my_timer.start();
my_timer.addEventListener(TimerEvent.TIMER, timerHandler);

// make sure this Display Object remains cached for all 2D transforms
my_shape.cacheAsBitmap = true;
my_shape.cacheAsBitmapMatrix = new Matrix();

// rotation variables
const initAngle:Number = 0;
const pi:Number = 3.142;
const incrAngle:Number = pi/10;

// scaling variables
const initScale:Number = 0.25;
const incrScale: Number = 1.1;
var initHeight : Number = my_shape.height;
var initWidth : Number = my_shape.width;

// translation variables
var incrX : Number = root.width / 20;
var incrY : Number = root.height / 10;

// do some initial transforms
var tempMat : Matrix = my_shape.transform.matrix;
tempMat.rotate(initAngle);
tempMat.scale(initScale, initScale);

my_shape.transform.matrix = tempMat;

function timerHandler(evt:TimerEvent):void {

    tempMat = my_shape.transform.matrix;
    
    tempMat.rotate(incrAngle);
    tempMat.translate(incrX, incrY);
    tempMat.scale(incrScale, incrScale);
    
    my_shape.transform.matrix = tempMat;
    
    // ensure we are still in a reasonable state or reset 
    if(my_shape.height > stage.stageHeight/2)
    {
        my_shape.height = initHeight;
    }
    
    if(my_shape.width > stage.stageWidth/2)
    {
        my_shape.width = initWidth;
    }
                              
    if(my_shape.x > stage.stageWidth)
    {
        my_shape.x = 0;
    }
    else if (my_shape.x < 0)
    {
        my_shape.x = stage.stageWidth;
    }

    
    if(my_shape.y > stage.stageHeight)
    {
        my_shape.y = 0;
    }
    else if (my_shape.y < 0)
    {
        my_shape.y = stage.stageHeight;
    }
    
}

Geçerli olarak görüntüleme nesnesiyle ilişkilendirilmiş her filtre nesnesini içeren dizinli bir dizi. flash.filters paketi, kullanabileceğiniz belirli filtreleri tanımlayan birçok sınıfı içerir.

Filtreler, ActionScript kodu kullanılarak tasarım süresinde veya çalışma zamanında Flash Professional'da uygulanabilir. ActionScript kullanarak bir filtre uygulamak için, tüm filters dizisinin geçici bir kopyasını yapmanız, geçici diziyi değiştirmeniz ve sonra geçici dizinin değerini geri filters dizisine atamanız gerekir. filters dizisine yeni bir filtre nesnesini doğrudan ekleyemezsiniz.

ActionScript kullanarak bir filtre eklemek için şu adımları uygulayın (hedef görüntüleme nesnesinin myDisplayObject adında olduğu varsayılarak):

1. Seçtiğiniz filter sınıfının yapıcı yöntemini kullanarak yeni bir filtre nesnesi oluşturun.
2. myFilters adındaki gibi geçici bir diziye myDisplayObject.filters dizisinin değerini atayın.
3. Yeni filtre nesnesini myFilters geçici dizisine ekleyin.
4. Geçici dizinin değerini myDisplayObject.filters dizisine atayın.

filters dizisi tanımsızsa, geçici bir dizi kullanmanız gerekmez. Bunun yerine, oluşturduğunuz bir veya birkaç filtre nesnesini içeren bir değişmez diziyi doğrudan atayabilirsiniz. Örnekler bölümündeki birinci örnek, hem tanımlı hem de tanımsız filters dizilerini işleyen kodu kullanarak bir gölge filtresi ekler.

Mevcut bir filtre nesnesini değiştirmek için, filters dizisinin bir kopyasını değiştirme tekniğini kullanmanız gerekir:

1. myFilters adındaki gibi geçici bir diziye filters dizisinin değerini atayın.
2. Geçici diziyi (myFilters) kullanarak özelliği değiştirin. Örneğin, dizideki birinci filtrenin quality özelliğini ayarlamak için şu kodu kullanabilirsiniz: myFilters[0].quality = 1;
3. Geçici dizinin değerini filters dizisine atayın.

Yükleme süresinde, bir görüntüleme nesnesinin ilişkilendirilmiş bir filtresi varsa, bu, saydam bir bitmap olarak önbelleğe alınması için işaretlenir. Bu noktadan sonra, görüntüleme nesnesinin geçerli bir filtre listesi olduğu sürece oynatıcı, görüntüleme nesnesini bir bitmap olarak önbelleğe alır. Bu kaynak bitmap'i, filtre efektleri için kaynak görüntü olarak kullanılır. Genellikle her görüntüleme nesnesinin iki bitmap'i vardır: biri orijinal filtrelenmemiş kaynak görüntüleme nesnesi ve diğeri filtrelemeden sonraki görüntü içindir. Oluşturma sırasında kullanılan son görüntü. Görüntüleme nesnesi değişmediği sürece, son görüntünün güncellenmesi gerekmez.

flash.filters paketi, filtreler için sınırları içerir. Örneğin, bir DropShadow filtresi oluşturmak için şu yazılır:

     import flash.filters.DropShadowFilter
     var myFilter:DropShadowFilter = new DropShadowFilter (distance, angle, color, alpha, blurX, blurY, quality, inner, knockout)
     

filter dizisindeki her dizin konumuna atanan filtre türünü belirlemek için is operatörünü kullanabilirsiniz. Örneğin, şu kod, bir DropShadowFilter olan filters dizisinde birinci filtrenin konumunun nasıl belirleneceğini gösterir:

     import flash.text.TextField;
     import flash.filters.*;
     var tf:TextField = new TextField();
     var filter1:DropShadowFilter = new DropShadowFilter();
     var filter2:GradientGlowFilter = new GradientGlowFilter();
     tf.filters = [filter1, filter2];
     
     tf.text = "DropShadow index: " + filterPosition(tf, DropShadowFilter).toString(); // 0
     addChild(tf)
     
     function filterPosition(displayObject:DisplayObject, filterClass:Class):int {
         for (var i:uint = 0; i < displayObject.filters.length; i++) {
             if (displayObject.filters[i] is filterClass) {
                 return i;
             }
         }
         return -1;
     }
     

Not: DisplayObject.filters dizisine doğrudan yeni bir filtre ekleyemeyeceğiniz için, şu kodun myDisplayObject adındaki hedef görüntüleme nesnesi üzerinde herhangi bir etkisi yoktur:

     myDisplayObject.filters.push(myDropShadow);
     

İlgili API Öğeleri

Görüntüleme nesnesinin yüksekliğini, piksel cinsinden belirtir. Yükseklik, görüntüleme nesnesi içeriğinin sınırları esas alınarak hesaplanır. height özelliğini ayarladığınızda, şu kodda gösterildiği gibi scaleY özelliği de uygun şekilde ayarlanır:

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleY) // 1;
    rect.height = 200;
    trace(rect.scaleY) // 2;

TextField ve Video nesneleri dışında, içeriği olmayan bir görüntüleme nesnesinin (örn. boş bir hareketli grafik) height öğesini farklı bir değere ayarlasanız da, bu nesnenin yüksekliği 0 olur.

import flash.text.TextField;

var tf1:TextField = new TextField();
tf1.text = "Text Field 1";
tf1.border = true;
tf1.wordWrap = true;
tf1.width = 40;
tf1.height = tf1.textHeight + 5;
addChild(tf1);

var tf2:TextField = new TextField();
tf2.text = "Text Field 2";
tf2.border = true;
tf2.wordWrap = true;
tf2.width = 40;
tf2.height = tf2.textHeight + 5;
tf2.y = tf1.y + tf1.height + 5;
addChild(tf2);

Bu görüntüleme nesnesinin ait olduğu dosyayı yükleme hakkında bilgi içeren bir LoaderInfo nesnesi döndürür. loaderInfo özelliği yalnızca bir SWF dosyasının kök görüntüleme nesnesi için veya yüklü bir Bitmap için (ActionScript ile çizilen bir Bitmap için değil) tanımlanır. myDisplayObject adındaki bir görüntüleme nesnesini içeren SWF dosyasıyla ilişkilendirilmiş loaderInfo nesnesini bulmak için, myDisplayObject.root.loaderInfo öğesini kullanın.

Büyük bir SWF dosyası, this.root.loaderInfo.addEventListener(Event.COMPLETE, func) öğesini çağırarak indirme işlemini izleyebilir.

İlgili API Öğeleri

 trace (this.loaderInfo.url);
 

Çağıran görüntüleme nesnesi belirtilen mask nesnesiyle maskelenir. Sahne Alanı ölçeklendiğinde maskelemenin çalışmasını sağlamak için, mask görüntüleme nesnesi, görüntüleme listesinin etkin bir bölümünde olmalıdır. mask nesnesi çizilmez. Maskeyi kaldırmak için mask öğesini null değerine ayarlayın.

Bir mask nesnesinin ölçeklenebilmesi için görüntüleme listesinde olması gerekir. Bir mask Sprite nesnesinin sürüklenebilmesi için (startDrag() yöntemi çağrılarak) görüntüleme listesinde olması gerekir. Hareketli grafiğin göndermekte olduğu mouseDown olayı esas alınarak bir maske hareketli grafiği için startDrag() yöntemini çağırmak üzere hareketli grafiğin buttonMode özelliğini true değerine ayarlayın.

Görüntüleme nesneleri cacheAsBitmap özelliği true olarak ve cacheAsBitmapMatrix özelliği Matrix nesnesi olarak ayarlanarak önbelleğe alındıklarında, maskelenen maske ve görüntüleme nesnesi önbelleğe alınan aynı bitmap'in parçası olmalıdır. Bu nedenle, görüntüleme nesnesi önbelleğe alınırsa, maske görüntüleme nesnesinin alt öğesi olmalıdır. Görüntüleme nesnesinin üst öğesi görüntüleme listesinde önbelleğe alınırsa, maske bu üst öğenin veya bu öğenin alt öğelerinden birinin alt öğesi olmalıdır. Maskelenen nesnenin birden fazla üst öğesi önbelleğe alınırsa, maske, görüntüleme listesindeki maskelenmiş nesneye en yakın olan önbelleğe alınmış kabın alt öğesi olmalıdır.

Not: Birden çok çağıran görüntüleme nesnesini maskelemek için tek bir mask nesnesi kullanılamaz. mask ikinci bir görüntüleme nesnesine atandığında, birinci nesnenin maskesi olarak kaldırılır ve o nesnenin mask özelliği null olur.

import flash.text.TextField;
import flash.display.Sprite;
import flash.events.MouseEvent;

var tf:TextField = new TextField();
tf.text = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, " 
            + "sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. "
tf.selectable = false;
tf.wordWrap = true;
tf.width = 150;
addChild(tf);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFF0000);
square.graphics.drawRect(0, 0, 40, 40);
addChild(square);

tf.mask = square;

tf.addEventListener(MouseEvent.MOUSE_DOWN, drag);
tf.addEventListener(MouseEvent.MOUSE_UP, noDrag);

function drag(event:MouseEvent):void {
    square.startDrag();
}
function noDrag(event:MouseEvent):void {
    square.stopDrag();
}

Meta veri SWF dosyasında PlaceObject4 aracılığıyla söz konusu DisplayObject örneğinin yanında depolanmışsa, DisplayObject örneğinin meta veri nesnesini alır.

Farenin veya kullanıcı girdi aygıtı konumunun x koordinatını piksel olarak belirtir.

Not: Döndürülmüş bir DisplayObject için, döndürülmüş x koordinatı, döndürülmemiş nesneyi yansıtır.

import flash.display.Sprite;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFF0000);
square.graphics.drawRect(0, 0, 200, 200);
addChild(square);

square.addEventListener(MouseEvent.CLICK, traceCoordinates);

function traceCoordinates(event:MouseEvent):void {
    trace(square.mouseX, square.mouseY);
}

Farenin veya kullanıcı girdi aygıtı konumunun y koordinatını piksel olarak belirtir.

Not: Döndürülmüş bir DisplayObject için, döndürülmüş y koordinatı, döndürülmemiş nesneyi yansıtır.

import flash.display.Sprite;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFF0000);
square.graphics.drawRect(0, 0, 200, 200);
addChild(square);

square.addEventListener(MouseEvent.CLICK, traceCoordinates);

function traceCoordinates(event:MouseEvent):void {
    trace(square.mouseX, square.mouseY);
}

DisplayObject öğesinin örnek adını belirtir. Görüntüleme nesnesi kabının getChildByName() yöntemi çağrılarak nesne, üst görüntüleme nesnesi kabının alt öğe listesinde tanımlanabilir.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.name = "circle1";
addChild(circle1);
circle1.addEventListener(MouseEvent.CLICK, traceName);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x0000FF);
circle2.graphics.drawCircle(140, 40, 40);
circle2.name = "circle2";
addChild(circle2);
circle2.addEventListener(MouseEvent.CLICK, traceName);

function traceName(event:MouseEvent):void {
    trace(event.target.name);
}

Görüntüleme nesnesinin belirli bir arka plan rengiyle opak olup olmadığını belirtir. Saydam bir bitmap, alfa kanalı verilerini içerir ve saydam şekilde çizilir. Opak bir bitmap, alfa kanalı içermez (ve saydam bir bitmap'ten daha hızlı oluşturur). Bitmap opaksa, kullanmak için kendi arka plan rengini belirtirsiniz.

Bir sayı değerine ayarlanırsa, yüzey sayının belirttiği RGB arka plan rengiyle opak olur (saydam değil). null değerine (varsayılan değer) ayarlanırsa, görüntüleme nesnesinin saydam arka planı olur.

opaqueBackground özelliği, oluşturma işlemini en iyileştirmek için daha çok cacheAsBitmap özelliğiyle kullanılmak üzere tasarlanmıştır. cacheAsBitmap özelliğinin true değerine ayarlandığı görüntüleme nesneleri için, opaqueBackground öğesinin ayarlanması, oluşturma performansını artırabilir.

shapeFlag parametresi true değerine ayarlanmış durumdayken hitTestPoint() yöntemi çağrıldığında, opak arka plan bölgesi eşleşmez.

Opak arka plan bölgesi, mouse olaylarına tepki vermez.

İlgili API Öğeleri

import flash.display.Shape;

var circle:Shape = new Shape();
circle.graphics.beginFill(0x0000FF);
circle.graphics.drawCircle(40, 40, 40);
circle.opaqueBackground = 0xFF0000;
addChild(circle);

Bu görüntüleme nesnesini içeren DisplayObjectContainer nesnesini belirtir. Görüntüleme listesi hiyerarşisinde geçerli görüntüleme nesnesinin yukarısındaki görüntüleme nesnelerine göre bir yol belirtmek için parent özelliğini kullanın.

Aşağıda belirtildiği gibi görüntüleme listesinde birden çok düzey yukarı çıkmak için parent öğesini kullanabilirsiniz:

     this.parent.parent.alpha = 20;
     

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite2.parent.name); // sprite1
trace(sprite3.parent.name); // sprite2
trace(sprite3.parent.parent.name); // sprite1

Yüklü bir SWF dosyasındaki bir görüntüleme nesnesi için root özelliği, görüntüleme listesi ağaç yapısının o SWF dosyası tarafından temsil edilen kısmındaki en üst görüntüleme nesnesidir. Yüklü bir görüntüyü temsil eden bir Bitmap nesnesi için root özelliği, Bitmap nesnesinin kendisidir. Yüklü birinci SWF dosyasının ana sınıfı örneği için, root özelliği, görüntüleme nesnesinin kendisidir. Stage nesnesinin root özelliği, Stage nesnesinin kendisidir. Görüntüleme listesine eklenmemiş bir görüntüleme nesnesi, görüntüleme listesi dışında olan ancak yüklü bir SWF dosyasındaki en üst görüntüleme nesnesinin alt öğesi olan bir görüntüleme nesnesi kabına eklenmediyse, o görüntüleme nesnesi için root özelliği null değerine ayarlanır.

Örneğin, Sprite() yapıcı yöntemini çağırarak yeni bir Sprite nesnesi oluşturursanız, siz nesneyi görüntüleme listesine (veya görüntüleme listesi dışında olan ancak yüklü bir SWF dosyasındaki en üst görüntüleme nesnesinin alt öğesi olan bir görüntüleme nesnesi kabına) ekleyinceye kadar bu nesnenin root özelliği null olur.

Yüklü bir SWF dosyası söz konusu olduğunda, dosyayı yüklemek için kullanılan Loader nesnesi görüntüleme listesinde olmayabilse de, SWF dosyasındaki en üst görüntüleme nesnesinin root özelliği kendisine ayarlıdır. Loader nesnesi root özelliğinin ayarlandığı görüntüleme nesnesinin bir alt öğesi olarak ekleninceye kadar, Loader nesnesinin root özelliği ayarlanmaz.

import flash.display.Loader;
import flash.net.URLRequest;
import flash.events.Event;

trace(stage.root); // [object Stage]

var ldr:Loader = new Loader();
trace (ldr.root); // null

addChild(ldr); 
trace (ldr.root); // [object ...]

var urlReq:URLRequest = new URLRequest("example.jpg");
ldr.load(urlReq);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);

function loaded(event:Event):void {
    trace(ldr.content.root); // [object Bitmap]
}

DisplayObject örneğinin başlangıç yönlendirmesinden itibaren döndürülmesini derece olarak belirtir. 0 ile 180 arasındaki değerler saat yönünde dönüşü temsil eder; 0 ile -180 arasındaki değerler saatin ters yönünde dönüşü temsil eder. Aralık içinde bir değer elde etmek için, bu aralık dışındaki değerler, 360'a eklenir veya 360'tan çıkarılır. Örneğin, my_video.rotation = 450 deyimi my_video.rotation = 90 ile aynıdır.

import flash.display.Sprite;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFFCC00);
square.graphics.drawRect(-50, -50, 100, 100);
square.x = 150;
square.y = 150;
addChild(square);

square.addEventListener(MouseEvent.CLICK, rotate);

function rotate(event:MouseEvent):void {
        square.rotation += 15;
}

DisplayObject örneğinin, 3B üst kabına göre başlangıç yönlendirmesinden itibaren x ekseninde döndürülmesini derece olarak belirtir. 0 ile 180 arasındaki değerler saat yönünde dönüşü temsil eder; 0 ile -180 arasındaki değerler saatin ters yönünde dönüşü temsil eder. Aralık içinde bir değer elde etmek için, bu aralık dışındaki değerler, 360'a eklenir veya 360'tan çıkarılır.

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.geom.*;
    import flash.display.Graphics;
    import flash.events.TimerEvent;
    import flash.utils.Timer;

    public class RotationExample1 extends MovieClip {
        private var ellipse:Shape = new Shape();
        private var speed:int = 10;
        private var ellipse1:Shape;
        private var ellipse2:Shape;
        
        public function RotationExample1():void {

            ellipse1 = drawEllipse(-50, -40, (this.stage.stageWidth / 2), 
                                    (this.stage.stageHeight / 2));
            
            ellipse2 = drawEllipse(30, 40, (this.stage.stageWidth / 2), 
                                          (this.stage.stageHeight / 2));

            this.addChild(ellipse1);
            this.addChild(ellipse2);

            var t:Timer = new Timer(50);
            t.addEventListener(TimerEvent.TIMER, timerHandler);
            t.start();
        }

        private function drawEllipse(x1, y1, x2, y2):Shape {
        
            var e:Shape = new Shape();
            e.graphics.beginFill(0xFF0000);
            e.graphics.lineStyle(2);
            e.graphics.drawEllipse(x1, y1, 100, 80);
            e.graphics.endFill();

            e.x  = x2;  
            e.y  = y2;
            e.z = 1;
            return e;
        }

        private function timerHandler(event:TimerEvent):void {
            ellipse1.rotationY += speed;    
            ellipse1.rotationX -= speed;

            ellipse2.rotationY += speed;    
            ellipse2.rotationX -= speed;
        }
    }
}

//Requires:
//  - Slider control UI component in Flash library.
//  - Publish for Flash Player 10.
//
 
[SWF(width="400", height="300")]
 
import fl.controls.Slider;
import fl.controls.SliderDirection;
import fl.events.SliderEvent;
 
var slider:Slider = new Slider();
slider.direction = SliderDirection.HORIZONTAL;
slider.minimum = 0;
slider.maximum = 360;
slider.value = 45;
slider.tickInterval = 45;
slider.snapInterval = 1;
slider.liveDragging = true;
slider.addEventListener(SliderEvent.CHANGE, slider_change);
slider.move(10, 10);
addChild(slider);
 
var spr:Sprite = new Sprite();
spr.graphics.lineStyle(2, 0xFF0000);
spr.graphics.drawRect(0, 0, 100, 80);
spr.x = Math.round((stage.stageWidth - spr.width)/2);
spr.y = Math.round((stage.stageHeight - spr.height)/2);
spr.rotationX = 45;
addChild(spr);
 
function slider_change(evt:SliderEvent):void {
    spr.rotationX = evt.value;
}

DisplayObject örneğinin, 3B üst kabına göre başlangıç yönlendirmesinden itibaren y ekseninde döndürülmesini derece olarak belirtir. 0 ile 180 arasındaki değerler saat yönünde dönüşü temsil eder; 0 ile -180 arasındaki değerler saatin ters yönünde dönüşü temsil eder. Aralık içinde bir değer elde etmek için, bu aralık dışındaki değerler, 360'a eklenir veya 360'tan çıkarılır.

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.geom.*;
    import flash.display.Graphics;
    import flash.events.TimerEvent;
    import flash.utils.Timer;

    public class RotationExample1 extends MovieClip {
        private var ellipse:Shape = new Shape();
        private var speed:int = 10;
        private var ellipse1:Shape;
        private var ellipse2:Shape;
        
        public function RotationExample1():void {

            ellipse1 = drawEllipse(-50, -40, (this.stage.stageWidth / 2), 
                                    (this.stage.stageHeight / 2));
            
            ellipse2 = drawEllipse(30, 40, (this.stage.stageWidth / 2), 
                                          (this.stage.stageHeight / 2));

            this.addChild(ellipse1);
            this.addChild(ellipse2);

            var t:Timer = new Timer(50);
            t.addEventListener(TimerEvent.TIMER, timerHandler);
            t.start();
        }

        private function drawEllipse(x1, y1, x2, y2):Shape {
        
            var e:Shape = new Shape();
            e.graphics.beginFill(0xFF0000);
            e.graphics.lineStyle(2);
            e.graphics.drawEllipse(x1, y1, 100, 80);
            e.graphics.endFill();

            e.x  = x2;  
            e.y  = y2;
            e.z = 1;
            return e;
        }

        private function timerHandler(event:TimerEvent):void {
            ellipse1.rotationY += speed;    
            ellipse1.rotationX -= speed;

            ellipse2.rotationY += speed;    
            ellipse2.rotationX -= speed;
        }
    }
}

DisplayObject örneğinin, 3B üst kabına göre başlangıç yönlendirmesinden itibaren z ekseninde döndürülmesini derece olarak belirtir. 0 ile 180 arasındaki değerler saat yönünde dönüşü temsil eder; 0 ile -180 arasındaki değerler saatin ters yönünde dönüşü temsil eder. Aralık içinde bir değer elde etmek için, bu aralık dışındaki değerler, 360'a eklenir veya 360'tan çıkarılır.

Etkin durumdaki geçerli ölçekleme ızgarası. null değerine ayarlanırsa, herhangi bir ölçek dönüşümü uygulandığında görüntüleme nesnesinin tamamı normal şekilde ölçeklenir.

scale9Grid özelliğini tanımladığınızda, görüntüleme nesnesi, ızgaranın merkez bölgesini tanımlayan scale9Grid dikdörtgenini esas alarak dokuz bölgeli bir ızgaraya bölünür. Izgaranın diğer sekiz bölgesini şu alanlar oluşturur:

• Dikdörtgenin sol üst köşesinin dış kısmı
• Dikdörtgenin yukarısındaki alan
• Dikdörtgenin sağ üst köşesinin dış kısmı
• Dikdörtgenin solundaki alan
• Dikdörtgenin sağındaki alan
• Dikdörtgenin sol alt köşesinin dış kısmı
• Dikdörtgenin aşağısındaki alan
• Dikdörtgenin sağ alt köşesinin dış kısmı

Merkez bölgenin (dikdörtgenin tanımladığı) dışındaki sekiz bölgeyi, ölçeklendiğinde özel kurallar uygulanan bir resim gibi düşünebilirsiniz.

scale9Grid özelliği ayarlandığında ve bir görüntüleme nesnesi ölçeklendiğinde, tüm metin ve degradeler normal şekilde ölçeklenir; ancak başka nesne türleri için şu kurallar geçerlidir:

• Merkezdeki içerik normal şekilde ölçeklenir.
• Köşelerdeki içerik ölçeklenmez.
• Üst ve alt bölgelerdeki içerik yalnızca yatay olarak ölçeklenir. Sol ve sağ bölgelerdeki içerik yalnızca dikey olarak ölçeklenir.
• Tüm dolgular (bitmap'ler, video ve degradeler), şekillerine sığacak şekilde uzatılır.

Bir görüntüleme nesnesi döndürülürse, sonraki tüm ölçeklemeler normaldir (ve scale9Grid özelliği yok sayılır).

Örneğin, şu görüntüleme nesnesini ve görüntüleme nesnesinin scale9Grid öğesi olarak uygulanan bir dikdörtgeni göz önünde bulundurun:

Görüntüleme nesnesi.

Kırmızı dikdörtgen scale9Grid öğesini gösterir.

Görüntüleme nesnesi ölçeklendiğinde veya uzatıldığında, dikdörtgenin içindeki nesneler normal şekilde ölçeklenir ancak dikdörtgenin dışındaki nesneler scale9Grid kurallarına göre ölçeklenir:

%75 değerine ölçekli:
%50 değerine ölçekli:
%25 değerine ölçekli:
Yatay olarak %150 uzatılmış:

scale9Grid öğesinin ayarlanması yaygın olarak, ölçeklendiğinde kenar bölgeleri aynı genişlikte kalacak ve bileşen olarak kullanılacak bir görüntüleme nesnesini kurmakta kullanılır.

İlgili API Öğeleri

import flash.display.Shape;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.geom.Matrix;
import flash.geom.Rectangle;
import flash.utils.Timer;
import flash.events.TimerEvent;

var square:Shape = new Shape();
square.graphics.lineStyle(20, 0xFFCC00);
var gradientMatrix:Matrix = new Matrix();
gradientMatrix.createGradientBox(15, 15, Math.PI, 10, 10);
square.graphics.beginGradientFill(GradientType.RADIAL, 
            [0xffff00, 0x0000ff], 
            [100, 100], 
            [0, 0xFF], 
            gradientMatrix, 
            SpreadMethod.REFLECT, 
            InterpolationMethod.RGB, 
            0.9);
square.graphics.drawRect(0, 0, 100, 100);

var grid:Rectangle = new Rectangle(20, 20, 60, 60);
square.scale9Grid = grid ;

addChild(square);

var tim:Timer = new Timer(100);
tim.start();
tim.addEventListener(TimerEvent.TIMER, scale);

var scaleFactor:Number = 1.01;

function scale(event:TimerEvent):void {
    square.scaleX *= scaleFactor;
    square.scaleY *= scaleFactor;
    
    if (square.scaleX > 2.0) {
        scaleFactor = 0.99;
    }
    if (square.scaleX < 1.0) {
        scaleFactor = 1.01;
    }
}

Nesnenin, kayıt noktasından itibaren uygulandığı haliyle yatay ölçeğini (percentage) belirtir. Varsayılan kayıt noktası (0,0) olur. 1,0, %100 ölçeğe eşittir.

Yerel koordinat sisteminin ölçeklemesi, bütün pikseller olarak tanımlanan x ve y özelliği değerlerini değiştirir.

import flash.display.Sprite;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFFCC00);
square.graphics.drawRect(0, 0, 100, 100);
addChild(square);

square.addEventListener(MouseEvent.CLICK, scale);

function scale(event:MouseEvent):void {
    square.scaleX *= 1.10;
    square.scaleY *= 1.10;
}

Nesnenin kayıt noktasından itibaren uygulandığı haliyle nesnenin dikey ölçeğini (percentage) belirtir. Varsayılan kayıt noktası (0,0) olur. 1,0; %100 ölçektir.

Yerel koordinat sisteminin ölçeklemesi, bütün pikseller olarak tanımlanan x ve y özelliği değerlerini değiştirir.

import flash.display.Sprite;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFFCC00);
square.graphics.drawRect(0, 0, 100, 100);
addChild(square);

square.addEventListener(MouseEvent.CLICK, scale);

function scale(event:MouseEvent):void {
    square.scaleX *= 1.10;
    square.scaleY *= 1.10;
}

Nesnenin kayıt noktasından itibaren uygulandığı haliyle nesnenin derinlik ölçeğini (percentage) belirtir. Varsayılan kayıt noktası (0,0) olur. 1,0; %100 ölçektir.

Yerel koordinat sisteminin ölçeklemesi, bütün pikseller olarak tanımlanan x, y ve z özellik değerlerini değiştirir.

İlgili API Öğeleri

Görüntüleme nesnesinin kaydırma dikdörtgeni sınırları. scrollRect nesnesinin x ve y özelliklerini değiştirdiğinizde, görüntüleme nesnesi, dikdörtgenin tanımladığı boyuta kırpılır ve dikdörtgen içinde gezinir.

scrollRect Rectangle nesnesinin özellikleri, görüntüleme nesnesinin koordinat alanını kullanır ve genel görüntüleme nesnesi gibi ölçeklenir. Kaydırma görüntüleme nesnesindeki kırpılan pencerenin köşe sınırları, görüntüleme nesnesinin başlangıç konumu (0,0) ve dikdörtgenin genişlik ve yüksekliğiyle tanımlanan noktadır. Bunlar başlangıç noktasında ortalanmaz ancak alanın sol üst köşesini tanımlamak için başlangıç noktasını kullanır. Kaydırılan bir görüntüleme nesnesi her zaman bütün piksellik artışlarda kaydırılır.

scrollRect Rectangle nesnesinin x özelliğini ayarlayarak bir nesneyi sola ve sağa kaydırabilirsiniz. scrollRect Rectangle nesnesinin y özelliğini ayarlayarak bir nesneyi yukarı ve aşağı kaydırabilirsiniz. Görüntüleme nesnesi 90° döndürülür ve bu nesneyi sola ve sağa kaydırırsanız, görüntüleme nesnesi gerçekten yukarı ve aşağı kaydırılır.

scrollRect özelliğinde yapılan değişikliklerin yalnızca nesne oluşturulduğunda işlendiğini unutmayın. Bu nedenle, localToGlobal gibi yöntemler, scrollRect değiştirildikten hemen sonra çağrıldığında beklenen sonucu vermeyebilir.

Not: Flash Player 11.4/AIR 3.4'ten itibaren, dikdörtgenin genişliğinin veya yüksekliğinin negatif değerleri 0 olarak değiştirildi.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.geom.Rectangle;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(200, 200, 200);
circle.scrollRect = new Rectangle(0, 0, 200, 200);
addChild(circle);

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    var rect:Rectangle = event.target.scrollRect;
    rect.y -= 5;
    event.target.scrollRect = rect;
}

Görüntüleme nesnesinin Sahne Alanı. Bir Flash çalışma zamanı uygulamasının yalnızca bir Stage nesnesi vardır. Örneğin, birden çok görüntüleme nesnesi oluşturup görüntüleme listesine ekleyebilirsiniz ve her görüntüleme nesnesinin stage özelliği aynı Stage nesnesini ifade eder (görüntüleme nesnesi yüklü bir SWF dosyasına ait olsa da).

Bir görüntüleme nesnesi görüntüleme listesine eklenmezse, o nesnenin stage özelliği null değerine ayarlanır.

import flash.text.TextField;

var tf1:TextField = new TextField();
tf1.text = "Text Field 1";
tf1.border = true;
tf1.x = 10;
addChild(tf1);
tf1.width = tf1.stage.stageWidth / 2 - 10;

var tf2:TextField = new TextField();
tf2.text = "Text Field 2";
tf2.border = true;
tf2.x = tf1.x + tf1.width + 5;
addChild(tf2);
tf2.width = tf2.stage.stageWidth / 2 - 10;

trace(stage.stageWidth);

Bir görüntüleme nesnesinin matrisi, renk dönüşümü ve piksel sınırları ile ilgili özellikleri olan bir nesne. Belirli özellikler — matrix, colorTransform ve üç salt okunur özellikler (concatenatedMatrix, concatenatedColorTransform ve pixelBounds) — Transform sınıfının girişinde açıklanır.

transform nesnesinin özelliklerinin her biri nesnedir. matrix veya colorTransform nesneleri için yeni değerler ayarlamanın tek yolu yeni bir nesne oluşturup o nesneyi transform.matrix ya da transform.colorTransform özelliğine kopyalamak olduğu için bu kavram önemlidir.

Örneğin, bir görüntüleme nesnesi matrisinin tx değerini artırmak için, matris nesnesinin tamamının bir kopyasını yapmanız ve sonra yeni nesneyi transform nesnesinin matrix özelliğine kopyalamanız gerekir:

    var myMatrix:Matrix = myDisplayObject.transform.matrix;  
    myMatrix.tx += 10; 
    myDisplayObject.transform.matrix = myMatrix;  
    

tx özelliğini doğrudan ayarlayamazsınız. Şu kodun myDisplayObject üzerinde herhangi bir etkisi yoktur:

    myDisplayObject.transform.matrix.tx += 10;
    

Bir transform nesnesinin tamamını kopyalayıp başka bir görüntüleme nesnesinin transform özelliğine de atayabilirsiniz. Örneğin, şu kod myOldDisplayObj öğesindeki transform nesnesinin tamamını myNewDisplayObj öğesine kopyalar:

Sonuçta elde edilen görüntüleme nesnesi (myNewDisplayObj) şimdi eski görüntüleme nesnesiyle (myOldDisplayObj) aynı matris, renk dönüşümü ve piksel sınırları değerlerine sahip olur.

AIR for TV aygıtlarının, renk dönüştürmeleri için, mevcut olması halinde otomatik olarak donanım hızlandırma kullandığını unutmayın.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.geom.ColorTransform;
import flash.geom.Matrix;
import flash.geom.Transform;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.lineStyle(20, 0xFF2200);
square.graphics.beginFill(0x0000DD);
square.graphics.drawRect(0, 0, 100, 100);
addChild(square);

var resultColorTransform:ColorTransform = new ColorTransform();
resultColorTransform.alphaMultiplier = 0.5;
resultColorTransform.redOffset = 155;
resultColorTransform.greenMultiplier = 0.5;

var skewMatrix:Matrix = new Matrix(1, 1, 0, 1);

square.addEventListener(MouseEvent.CLICK, transformer);

function transformer(event:MouseEvent):void {
    var transformation:Transform = square.transform;
    var tempMatrix:Matrix = square.transform.matrix;
    tempMatrix.concat(skewMatrix);
    square.transform.colorTransform = resultColorTransform;
    
    square.transform.matrix = tempMatrix;
}

Görüntüleme nesnesinin görünür olup olmadığı. Görünür olmayan görüntüleme nesneleri devre dışı bırakılır. Örneğin, bir InteractiveObject örneği için visible=false olursa, bu nesne tıklatılamaz.

import flash.text.TextField;
import flash.utils.Timer;
import flash.events.TimerEvent;

var tf:TextField = new TextField();
tf.text = "Hello.";
addChild(tf);

var tim:Timer = new Timer(250);
tim.start();
tim.addEventListener(TimerEvent.TIMER, blinker);

function blinker(event:TimerEvent):void {
    tf.visible = !tf.visible;
}

Görüntüleme nesnesinin genişliğini, piksel cinsinden belirtir. Genişlik, görüntüleme nesnesi içeriğinin sınırları esas alınarak hesaplanır. width özelliğini ayarladığınızda, şu kodda gösterildiği gibi scaleX özelliği de uygun şekilde ayarlanır:

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleX) // 1;
    rect.width = 200;
    trace(rect.scaleX) // 2;

TextField ve Video nesneleri dışında, içeriği olmayan bir görüntüleme nesnesinin (örn. boş bir hareketli grafik) width öğesini farklı bir değere ayarlasanız da, bu nesnenin genişliği 0 olur.

import flash.display.Sprite;
import flash.events.MouseEvent;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFF0000);
square.graphics.drawRect(0, 0, 100, 100);
addChild(square);

square.addEventListener(MouseEvent.CLICK, widen);

function widen(event:MouseEvent):void {
    square.width += 10;
}

DisplayObject örneğinin DisplayObjectContainer üst öğesinin yerel koordinatlarına göre x koordinatını belirtir. Nesne, dönüşümler içeren bir DisplayObjectContainer içindeyse, çevreleyen DisplayObjectContainer öğesinin yerel koordinat sistemi içindedir. Böylece, 90° saatin ters yönünde döndürülmüş bir DisplayObjectContainer için, DisplayObjectContainer'ın alt öğeleri, 90° saatin ters yönünde döndürülmüş bir koordinat sistemini miras alır. Nesnenin koordinatları, kayıt noktası konumunu ifade eder.

import flash.display.Sprite;
import flash.utils.Timer;
import flash.events.TimerEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFF0000);
circle.graphics.drawCircle(100, 100, 100);
addChild(circle);

var tim:Timer = new Timer(50);
tim.start();
tim.addEventListener(TimerEvent.TIMER, bounce);

var xInc:Number = 2;

function bounce(event:TimerEvent):void {
    circle.x += xInc;
    if (circle.x > circle.width) {
        xInc = -2;
    }
    if (circle.x < 0) {
        xInc = 2;
    }
}

DisplayObject örneğinin DisplayObjectContainer üst öğesinin yerel koordinatlarına göre y koordinatını belirtir. Nesne, dönüşümler içeren bir DisplayObjectContainer içindeyse, çevreleyen DisplayObjectContainer öğesinin yerel koordinat sistemi içindedir. Böylece, 90° saatin ters yönünde döndürülmüş bir DisplayObjectContainer için, DisplayObjectContainer'ın alt öğeleri, 90° saatin ters yönünde döndürülmüş bir koordinat sistemini miras alır. Nesnenin koordinatları, kayıt noktası konumunu ifade eder.

import flash.text.TextField;

var tf1:TextField = new TextField();
tf1.text = "Text Field 1";
tf1.border = true;
tf1.wordWrap = true;
tf1.width = 40;
tf1.height = tf1.textHeight + 5;
addChild(tf1);

var tf2:TextField = new TextField();
tf2.text = "Text Field 2";
tf2.border = true;
tf2.wordWrap = true;
tf2.width = 40;
tf2.height = tf2.textHeight + 5;
tf2.y = tf1.y + tf1.height + 5;
addChild(tf2);

3B üst kabına göre DisplayObject örneğinin z ekseni boyunca z koordinatı konumunu belirtir. z özelliği, ekran veya piksel koordinatlarıyla değil, 3B koordinatlarla çalışmak içindir.

Bir görüntüleme nesnesi için z özelliğini 0 varsayılan değeri dışında bir değer olarak ayarladığınızda, karşılık gelen Matrix3D nesnesi otomatik olarak oluşturulur. bir görüntüleme nesnesi konumunu ve yönlendirmesini üç boyutlu olarak ayarlamak için. z ekseniyle çalışırken, x ve y özelliklerinin mevcut davranışı, ekran veya piksel koordinatlarından, 3B üst kabına göre konumlara geçer.

Örneğin, x = 100, y = 100, z = 200 konumunda bir _root alt öğesi, piksel konumunda (100,100) çizilmez. Alt öğe, 3B projeksiyon hesaplamasının koyduğu yere çizilir. Hesaplama şu şekildedir:

(x*cameraFocalLength/cameraRelativeZPosition, y*cameraFocalLength/cameraRelativeZPosition)

İlgili API Öğeleri

package {
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.geom.*;

    public class ZAxisExample1 extends MovieClip {
        private var ellipse1Back:int = 1;
        private var ellipse2Back:int = 1;
        private var depth:int = 1000;
        
        public function ZAxisExample1():void {
            
            var ellipse1 = drawEllipse((this.stage.stageWidth / 2) - 100, 
                                      (this.stage.stageHeight / 2), 100, 80, 10);
            var ellipse2 = drawEllipse((this.stage.stageWidth / 2) + 100, 
                                      (this.stage.stageHeight / 2), 100, 80, 300);

            this.addChild(ellipse1);
            this.addChild(ellipse2);
            
            ellipse1.addEventListener(Event.ENTER_FRAME, ellipse1FrameHandler);
            ellipse2.addEventListener(Event.ENTER_FRAME, ellipse2FrameHandler);
        }

        private function drawEllipse(x:Number, y:Number, w:Number, h:Number, z:Number):Shape {
            var s:Shape = new Shape();                            
            s.z = z;
            s.graphics.beginFill(0xFF0000);
            s.graphics.lineStyle(2);
            s.graphics.drawEllipse(x, y, w, h);
            s.graphics.endFill();
            return s;
        }

        private function ellipse1FrameHandler(e:Event):void {
            ellipse1Back = setDepth(e, ellipse1Back);
            e.currentTarget.z += ellipse1Back * 10;
        }

        private function ellipse2FrameHandler(e:Event):void {
            ellipse2Back = setDepth(e, ellipse2Back);
            e.currentTarget.z += ellipse2Back * 20;
        }

        private function setDepth(e:Event, d:int):int {
            if(e.currentTarget.z > depth) {
                e.currentTarget.z = depth; 
                d = -1;
            }else if (e.currentTarget.z <  0) {
                e.currentTarget.z = 0;
                d = 1;
            }
            return d;
        }
    }
}

Görüntüleme nesnesinin alanını targetCoordinateSpace nesnesinin koordinat sistemine göre tanımlayan bir dikdörtgen döndürür. Döndürülen dikdörtgenin, yönteme ilettiğiniz targetCoordinateSpace parametresine bağlı olarak nasıl değişebileceğini gösteren şu kodu göz önünde bulundurun:

     var container:Sprite = new Sprite();
     container.x = 100;
     container.y = 100;
     this.addChild(container);
     var contents:Shape = new Shape();
     contents.graphics.drawCircle(0,0,100);
     container.addChild(contents);
     trace(contents.getBounds(container));
      // (x=-100, y=-100, w=200, h=200)
     trace(contents.getBounds(this));
      // (x=0, y=0, w=200, h=200)
     

Not: Görüntüleme nesnesinin yerel koordinatlarını görüntüleme koordinatlarına dönüştürmek için localToGlobal() yöntemini veya görüntüleme koordinatlarını yerel koordinatlara dönüştürmek için globalToLocal() yöntemini kullanın.

getBounds() yöntemi getRect() yöntemine benzer; ancak getBounds() yönteminin döndürdüğü Rectangle içindeki şekillerde konturlar bulunurken, getRect() yönteminin döndürdüğü Rectangle içindeki şekillerde konturlar bulunmaz. Bir örnek için, getRect() yönteminin açıklamasına bakın.

Parametreler

İlgili API Öğeleri

targetCoordinateSpace parametresince tanımlanan koordinat sistemini esas alarak ve her tür çizgi ve şekli dışarıda bırakarak görüntüleme nesnesinin sınırlarını tanımlayan bir dikdörtgen döndürür. getRect() yönteminin döndürdüğü değerler, getBounds() yönteminin döndürdüğü değerlerle aynı veya bu değerlerden daha düşüktür.

Not: Görüntüleme nesnesinin yerel koordinatlarını Sahne Alanı koordinatlarına dönüştürmek için localToGlobal() yöntemini veya Sahne Alanı koordinatlarını yerel koordinatlara dönüştürmek için globalToLocal() yöntemini kullanın.

Parametreler

İlgili API Öğeleri

import flash.display.CapsStyle;
import flash.display.JointStyle;
import flash.display.LineScaleMode;
import flash.display.Sprite;
import flash.geom.Rectangle;

var triangle:Sprite = new Sprite();
var color:uint = 0xFF0044;
var width:Number = 20;
var alpha:Number = 1.0;
var pixelHinting:Boolean = true;
var scaleMode:String = LineScaleMode.NORMAL;
var caps:String = CapsStyle.SQUARE;
var joints:String = JointStyle.MITER;
triangle.graphics.lineStyle(width, color, alpha, pixelHinting, scaleMode, caps, joints);

var triangleSide:Number = 100;
triangle.graphics.moveTo(0, 0);
triangle.graphics.lineTo(0, triangleSide);
triangle.graphics.lineTo(triangleSide, triangleSide);
triangle.graphics.lineTo(0, 0);

addChild(triangle);

trace(triangle.getBounds(this)); // (x=-10, y=-24.1, w=134.10000000000002, h=134.1)
trace(triangle.getRect(this));     // (x=0, y=0, w=100, h=100)

point nesnesini, Sahne Alanı (global) koordinatlarından görüntüleme nesnesinin (yerel) koordinatlarına dönüştürür.

Bu yöntemi kullanmak için ilk olarak Point sınıfının bir örneğini oluşturun. Atadığınız x ve y değerleri, ana görüntüleme alanının başlangıç konumuna (0,0) göre olduğundan, global koordinatları temsil ederler. Daha sonra Point örneğini parametre olarak globalToLocal() yöntemine iletin. Yöntem, Stage öğesinin başlangıç konumu yerine görüntüleme nesnesinin başlangıç konumuna göre x ve y değerleriyle yeni bir Point nesnesi döndürür.

Parametreler

İlgili API Öğeleri

import flash.display.Shape;
import flash.geom.Point;

var circle:Shape = new Shape();
circle.graphics.beginFill(0x0000FF);
circle.graphics.drawCircle(40, 40, 40);
circle.x = 10;
addChild(circle);

var point1:Point = new Point(0, 0);
trace(circle.hitTestPoint(point1.x, point1.y, true)); // false
trace(circle.hitTestPoint(point1.x, point1.y, false)); // false
trace(circle.globalToLocal(point1)); // [x=-10, y=0]

var point2:Point = new Point(10, 1);
trace(circle.hitTestPoint(point2.x, point2.y, true)); // false
trace(circle.hitTestPoint(point2.x, point2.y, false)); // true
trace(circle.globalToLocal(point2)); // [x=0, y=1]

var point3:Point = new Point(30, 20);
trace(circle.hitTestPoint(point3.x, point3.y, true)); // true
trace(circle.hitTestPoint(point3.x, point3.y, false)); // true
trace(circle.globalToLocal(point3)); // [x=20, y=20]

Sahne Alanı (global) koordinatlarından iki boyutlu noktayı üç boyutlu görüntüleme nesnesinin (yerel) koordinatlarına dönüştürür.

Bu yöntemi kullanmak için ilk olarak Point sınıfının bir örneğini oluşturun. Point nesnesine atadığınız x ve y değerleri, ana görüntüleme alanının başlangıç konumuna (0,0) göre olduğu için global koordinatları temsil eder. Ardından Point nesnesiniglobalToLocal3D() yöntemiyle point parametresi olarak iletin. Yöntem, üç boyutlu koordinatları, üç boyutlu görüntüleme nesnesinin başlangıç konumuna göre x, y ve z değerlerini içeren Vector3D nesnesi olarak döndürür.

Parametreler

obj görüntüleme nesnesinin sınırlayıcı kutusuyla örtüşüp örtüşmediğini veya kesişip kesişmediğini görmek için görüntüleme nesnesinin sınırlayıcı kutusunu değerlendirir.

Parametreler

import flash.display.Shape;

var circle1:Shape = new Shape();
circle1.graphics.beginFill(0x0000FF);
circle1.graphics.drawCircle(40, 40, 40);
addChild(circle1);

var circle2:Shape = new Shape();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(40, 40, 40);
circle2.x = 50;
addChild(circle2);

var circle3:Shape = new Shape();
circle3.graphics.beginFill(0xFF0000);
circle3.graphics.drawCircle(40, 40, 40);
circle3.x = 100;
circle3.y = 67;
addChild(circle3);

trace(circle1.hitTestObject(circle2)); // true
trace(circle1.hitTestObject(circle3)); // false
trace(circle2.hitTestObject(circle3)); // true

Görüntüleme nesnesinin x ve y ile belirtilen bir noktayla örtüştüğünü veya kesiştiğini görmek için görüntüleme nesnesini değerlendirir. x ve y parametreleri, görüntüleme nesnesini içeren görüntüleme nesnesi kabının değil, Sahne Alanı'nın koordinat alanında bir noktayı belirtir (o görüntüleme nesnesi kabı Sahne Alanı olmadığı sürece).

Parametreler

İlgili API Öğeleri

import flash.display.Shape;
import flash.geom.Point;

var circle:Shape = new Shape();
circle.graphics.beginFill(0x0000FF);
circle.graphics.drawCircle(40, 40, 40);
circle.x = 10;
addChild(circle);

var point1:Point = new Point(0, 0);
trace(circle.hitTestPoint(point1.x, point1.y, true)); // false
trace(circle.hitTestPoint(point1.x, point1.y, false)); // false
trace(circle.globalToLocal(point1)); // [x=-10, y=0]

var point2:Point = new Point(10, 1);
trace(circle.hitTestPoint(point2.x, point2.y, true)); // false
trace(circle.hitTestPoint(point2.x, point2.y, false)); // true
trace(circle.globalToLocal(point2)); // [x=0, y=1]

var point3:Point = new Point(30, 20);
trace(circle.hitTestPoint(point3.x, point3.y, true)); // true
trace(circle.hitTestPoint(point3.x, point3.y, false)); // true
trace(circle.globalToLocal(point3)); // [x=20, y=20]

Üç boyutlu görüntüleme nesnesinin (yerel) koordinatlarının üç boyutlu noktasını, Sahne Alanı (global) koordinatlarındaki iki boyutlu noktaya dönüştürür.

Örneğin, display.Graphics yöntemleriyle çizim yapmak için yalnızca iki boyutlu koordinatlar (x,y) kullanabilirsiniz. Üç boyutlu nesne çizmek için, görüntüleme nesnesinin üç boyutlu koordinatlarını iki boyutlu koordinatlara eşlemeniz gerekir. İlk önce, üç boyutlu görüntüleme nesnesinin x-, y- ve z- koordinatlarını bulunduran Vector3D sınıfının bir örneğini oluşturun. Ardından, Vector3D nesnesinilocal3DToGlobal() yöntemiyle point3d parametresi olarak iletin. Yöntem, üç boyutlu nesne çizmek için Graphics API ile kullanılan iki boyutlu Point nesnesini döndürür.

Parametreler

package {
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.geom.*;

    public class Local3DToGlobalExample extends MovieClip {
        private var myCube:Sprite = new Sprite();
        private var v8:Vector.<Vector3D> = new Vector.<Vector3D>(8);

        public function Local3DToGlobalExample():void {
            this.x = -(this.stage.stageWidth / 2);
            this.y = -(this.stage.stageWidth / 2);

            v8[0] = new Vector3D(-40,-40,-40);
            v8[1] = new Vector3D(40,-40,-40);
            v8[2] = new Vector3D(40,-40,40);
            v8[3] = new Vector3D(-40,-40,40);
            v8[4] = new Vector3D(-40,100,-40);
            v8[5] = new Vector3D(40,100,-40);
            v8[6] = new Vector3D(40,100,40);
            v8[7] = new Vector3D(-40,100,40);

            myCube.x = (this.stage.stageWidth / 2);
            myCube.y = (this.stage.stageWidth / 2);
            myCube.z = 1;
            addChild(myCube);

            Cube();         
        }

        private function Cube():void {
            var ps:Point = new Point(0,0);

            myCube.graphics.lineStyle(2,0xFF0000);

            ps = myCube.local3DToGlobal(v8[0]);
            myCube.graphics.moveTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[1]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[2]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[3]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[0]);
            myCube.graphics.lineTo(ps.x, ps.y);

            ps = myCube.local3DToGlobal(v8[4]);
            myCube.graphics.moveTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[5]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[6]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[7]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[4]);
            myCube.graphics.lineTo(ps.x, ps.y);

            ps = myCube.local3DToGlobal(v8[0]);
            myCube.graphics.moveTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[4]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[1]);
            myCube.graphics.moveTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[5]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[2]);
            myCube.graphics.moveTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[6]);
            myCube.graphics.lineTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[3]);
            myCube.graphics.moveTo(ps.x, ps.y);
            ps = myCube.local3DToGlobal(v8[7]);
            myCube.graphics.lineTo(ps.x, ps.y);
        }
    }
}

point nesnesini, görüntüleme nesnesinin (yerel) koordinatlarından Sahne Alanı (global) koordinatlarına dönüştürür.

Bu yöntem herhangi bir x ve y koordinatını, belirli bir görüntüleme nesnesinin başlangıç noktasına (0,0) (yerel koordinatlar) göre olan değerlerden, Sahne Alanı'nın başlangıç noktasına (global koordinatlar) göre olan değerlere dönüştürmenizi sağlar.

Bu yöntemi kullanmak için ilk olarak Point sınıfının bir örneğini oluşturun. Atadığınız x ve y değerleri, görüntüleme nesnesinin başlangıç konumuna göre olduğundan, yerel koordinatları temsil ederler.

Daha sonra, parametre olarak oluşturduğunuz Point örneğini localToGlobal() yöntemine verirsiniz. Yöntem, görüntüleme nesnesinin başlangıç konumu yerine Sahne Alanı'nın başlangıç konumuna göre x ve y değerleriyle yeni bir Point nesnesi döndürür.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.geom.Point;

var square:Sprite = new Sprite();
square.graphics.beginFill(0xFFCC00);
square.graphics.drawRect(0, 0, 100, 100);
square.x = 100;
square.y = 200;

addChild(square);

square.addEventListener(MouseEvent.CLICK, traceCoordinates)

function traceCoordinates(event:MouseEvent):void {
    var clickPoint:Point = new Point(square.mouseX, square.mouseY);
    trace("display object coordinates:", clickPoint);
    trace("stage coordinates:", square.localToGlobal(clickPoint));
}

Görüntüleme listesine bir ekran nesnesi eklendiğinde gönderilir. Şu yöntemler bu olayı tetikler: DisplayObjectContainer.addChild(), DisplayObjectContainer.addChildAt().

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Ya doğrudan ya da ekran nesnesini içeren alt ağaca ekleme yaparak, sahne görüntüleme listesine bir ekran nesnesi eklendiğinde gönderilir. Şu yöntemler bu olayı tetikler: DisplayObjectContainer.addChild(), DisplayObjectContainer.addChildAt().

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

[broadcast olayı] Oynatma kafası yeni bir kareye girerken gönderilir. Oynatma kafası hareket etmiyorsa veya yalnızca bir kare varsa, kare hızıyla bağlantılı şekilde bu olay sürekli olarak gönderilir. Bu olay bir broadcast olayıdır; yani, bu olay kendisi için kaydedilmiş bir dinleyiciye sahip tüm görüntüleme nesneleri tarafından gönderilir.

Not: Bu olayda “yakalama aşaması“ veya “köpürme aşaması“ bulunmaz; başka bir deyişle, olay dinleyicileri her türlü potansiyel hedefe, hedefler görüntüleme listesinde olsun veya olmasın, doğrudan eklenmelidir.

Bu olay şu özelliklere sahiptir:

[broadcast olayı] Oynatma kafası geçerli kareden çıkarken gönderilir. Tüm kare komut dosyaları çalıştırılmıştır. Oynatma kafası hareket etmiyorsa veya yalnızca bir kare varsa, kare hızıyla bağlantılı şekilde bu olay sürekli olarak gönderilir. Bu olay bir broadcast olayıdır; yani, bu olay kendisi için kaydedilmiş bir dinleyiciye sahip tüm görüntüleme nesneleri tarafından gönderilir.

Not: Bu olayda “yakalama aşaması“ veya “köpürme aşaması“ bulunmaz; başka bir deyişle, olay dinleyicileri her türlü potansiyel hedefe, hedefler görüntüleme listesinde olsun veya olmasın, doğrudan eklenmelidir.

Bu olay şu özelliklere sahiptir:

[broadcast olayı] Kare görüntüleme nesnelerinin yapıcıları çalıştırıldıktan sonra ancak kare komut dosyaları çalıştırılmadan önce gönderilir. Oynatma kafası hareket etmiyorsa veya yalnızca bir kare varsa, kare hızıyla bağlantılı şekilde bu olay sürekli olarak gönderilir. Bu olay bir broadcast olayıdır; yani, bu olay kendisi için kaydedilmiş bir dinleyiciye sahip tüm görüntüleme nesneleri tarafından gönderilir.

Not: Bu olayda “yakalama aşaması“ veya “köpürme aşaması“ bulunmaz; başka bir deyişle, olay dinleyicileri her türlü potansiyel hedefe, hedefler görüntüleme listesinde olsun veya olmasın, doğrudan eklenmelidir.

Bu olay şu özelliklere sahiptir:

Görüntüleme listesinden bir ekran nesnesi kaldırılmak üzereyken gönderilir. DisplayObjectContainer sınıfının iki yöntemi bu olayı üretir: removeChild() ve removeChildAt().

Bir DisplayObjectContainer nesnesinin şu yöntemleri de, yeni nesne için yer açmak üzere bir nesnenin kaldırılması gerektiğinde bu olayı gerçekleştirir: addChild(), addChildAt() ve setChildIndex().

Bu olay şu özelliklere sahiptir:

Ya doğrudan ya da ekran nesnesini içeren alt ağacın kaldırılmasıyla, sahne görüntüleme listesinden bir ekran nesnesi kaldırılmak üzereyken gönderilir. DisplayObjectContainer sınıfının iki yöntemi bu olayı üretir: removeChild() ve removeChildAt().

Bir DisplayObjectContainer nesnesinin şu yöntemleri de, yeni nesne için yer açmak üzere bir nesnenin kaldırılması gerektiğinde bu olayı gerçekleştirir: addChild(), addChildAt() ve setChildIndex().

Bu olay şu özelliklere sahiptir:

[broadcast olayı] Ekran güncellenmek ve oluşturulmak üzereyken gönderilir. Bu olay, bu olayı dinleyen nesnelere görüntüleme listesi oluşturulmadan önce değişiklik yapmaları için son fırsatı sağlar. render olayının gönderilmesini her istediğinizde Stage nesnesinin invalidate() yöntemini çağırmalısınız. Render olayları yalnızca bir nesne ile Stage.invalidate() öğesini çağıran nesne arasında karşılıklı güven varsa o nesneye gönderilir. Bu olay bir broadcast olayıdır; yani, bu olay kendisi için kaydedilmiş bir dinleyiciye sahip tüm görüntüleme nesneleri tarafından gönderilir.

Not: Görüntü oluşturulmadığında bu olay gönderilmez. İçerik simge durumuna getirildiğinde veya gizlendiğinde bu durum gerçekleşir.

Not: Bu olayda “yakalama aşaması“ veya “köpürme aşaması“ bulunmaz; başka bir deyişle, olay dinleyicileri her türlü potansiyel hedefe, hedefler görüntüleme listesinde olsun veya olmasın, doğrudan eklenmelidir.

Bu olay şu özelliklere sahiptir:

1. Karenin rengi ve boyutu için Class özellikleri bildirilir.
2. Yapıcı, Stage öğesinde varsayılan x = 0, y = 0 koordinatlarında turuncu bir kare çizen draw() yöntemini çağırır.
3. Şu olay dinleyicisi yöntemleri, kareye eklenir:
   • addedHandler(), görüntüleme listesine kare eklendiğinde gönderilen added olaylarını dinler.
   • enterFrameHandler(), bu örnekte gerçek bir anlamı olmayan enterFrame olaylarını dinler.
   • removedHandler(), kare tıklatılıp görüntüleme listesinden kaldırıldığında gönderilen removed olaylarını dinler.
   • clickHandler(), turuncu kare tıklatıldığında gönderilen click olaylarını dinler.
   • renderHandler(), görüntüleme listesi güncellendikten sonra gönderilen render olaylarını dinler.

package {
    import flash.display.Sprite;

    public class DisplayObjectExample extends Sprite {
        public function DisplayObjectExample() {
            var child:CustomDisplayObject = new CustomDisplayObject();
            addChild(child);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.*;

class CustomDisplayObject extends Sprite {
    private var bgColor:uint = 0xFFCC00;
    private var size:uint    = 80;

    public function CustomDisplayObject() {
        draw();
        addEventListener(Event.ADDED, addedHandler);
        addEventListener(Event.ENTER_FRAME, enterFrameHandler);
        addEventListener(Event.REMOVED, removedHandler);
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(Event.RENDER, renderHandler);
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler: " + event);
        parent.removeChild(this);
    }

    private function addedHandler(event:Event):void {
        trace("addedHandler: " + event);
        stage.scaleMode = StageScaleMode.NO_SCALE;
        stage.align = StageAlign.TOP_LEFT;
        stage.addEventListener("resize", resizeHandler);
    }

    private function enterFrameHandler(event:Event):void {
        trace("enterFrameHandler: " + event);
        removeEventListener("enterFrame", enterFrameHandler);
    }

    private function removedHandler(event:Event):void {
        trace("removedHandler: " + event);
        stage.removeEventListener("resize", resizeHandler);
    }

    private function renderHandler(event:Event):void {
        trace("renderHandler: " + event);
    }

    private function resizeHandler(event:Event):void {
        trace("resizeHandler: " + event);
    }
}