DisplayObjectContainer  - AS3

Nesnenin alt öğelerinin, fare veya kullanıcı girdi aygıtı etkin olduğunu belirtir. Bir nesne etkinleştirilmişse, kullanıcı, fare veya kullanıcı girdi aygıtı kullanarak o nesneyle etkileşim kurabilir. Varsayılan değer true şeklindedir.

Bir Sprite sınıfı örneğiyle (SimpleButton sınıfını kullanmak yerine) düğme oluşturduğunuzda, bu özellik yararlıdır. Düğme oluşturmak için bir Sprite örneğini kullandığınızda, ek Sprite örnekleri eklemek için addChild() yöntemini kullanarak düğmeyi süslemeyi seçebilirsiniz. Üst örneğin hedef nesne olmasını beklediğinizde, alt öğe olarak eklediğiniz Sprite örnekleri mouse olayının hedef nesnesi olabildiğinden, bu işlem beklenmeyen bir davranışa yol açabilir. Üst örneğin, fare olaylarının hedef nesneleri görevini görmesini sağlamak için, üst örneğin mouseChildren özelliğini false değerine ayarlayabilirsiniz.

Bu özelliğin ayarlanmasıyla herhangi bir olay gönderilmez. Etkileşimli işlevler oluşturmak için addEventListener() yöntemini kullanmanız gerekir.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Bu nesnenin alt öğelerinin sayısını döndürür.

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Nesnenin alt öğelerinin sekme tuşuna tepki verip vermediğini belirler. Nesnenin alt öğeleri için sekme işlemini etkinleştirir veya devre dışı bırakır. Varsayılan değer true şeklindedir.

Not: tabChildren özelliğini Flex ile kullanmayın. Onun yerine, mx.core.UIComponent.hasFocusableChildren özelliğini kullanın.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Bu DisplayObjectContainer örneği için bir TextSnapshot nesnesi döndürür.

İlgili API Öğeleri

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

new DisplayObjectContainer() yapıcısının çağrılması, bir ArgumentError istisnası atar. Ancak DisplayObjectContainer öğesinin şu alt sınıfları için yapıcıları çağırabilirsiniz:

• new Loader()
• new Sprite()
• new MovieClip()

Bu DisplayObjectContainer örneğine bir alt DisplayObject örneği ekler. Alt öğe, bu DisplayObjectContainer örneğindeki diğer tüm alt öğelerin önüne (üstüne) eklenir. (Belirli bir dizin konumuna bir alt öğe eklemek için, addChildAt() yöntemini kullanın.)

Zaten üst öğe olarak farklı bir görüntüleme nesnesi kabı olan bir alt nesne eklerseniz, nesne diğer görüntüleme nesnesi kabının alt öğe listesinden kaldırılır.

Not: stage.addChild() komutu bir yayınlanmış SWF dosyasıyla sorun yaratabilir. Buna güvenlik sorunları ve diğer yüklü SWF dosyalarıyla çakışmalar dahildir. Çalışma zamanına ne kadar çok SWF dosyası yüklerseniz yükleyin, bir Flash çalışma zamanı örneğinde yalnızca bir Sahne Alanı vardır. Bu yüzden, genellikle nesneler asla doğrudan Sahne Alanına eklenmemelidir. Sahne Alanının içermesi gereken tek nesne kök nesnesidir. Görüntüleme listesindeki tüm öğeleri içermesi için bir DisplayObjectContainer oluşturun. Sonra, gerekiyorsa, o DisplayObjectContainer örneğini Sahne Alanı'na ekleyin.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Bu DisplayObjectContainer örneğine bir alt DisplayObject örneği ekler. Alt öğe belirtilen dizin konumuna eklenir. Bir 0 dizini, bu DisplayObjectContainer nesnesinin görüntüleme listesinin arkasını (altını) temsil eder.

Örneğin, şu örnek sırayla 0, 2 ve 1 dizin konumlarında, a, b ve c etiketli üç görüntüleme nesnesini gösterir:

Zaten üst öğe olarak farklı bir görüntüleme nesnesi kabı olan bir alt nesne eklerseniz, nesne diğer görüntüleme nesnesi kabının alt öğe listesinden kaldırılır.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Güvenlik kısıtlamalarının, DisplayObjectContainer.getObjectsUnderPoint() yönteminin belirtilen point noktası ile çağrılması sonucunda döndürülen listeden görüntüleme nesnelerinin çıkarılmasına neden olup olmayacağını belirtir. Varsayılan olarak, bir etki alanındaki içerik, Security.allowDomain() yöntemine yapılan bir çağrı ile erişimine izin verilmediği sürece başka bir etki alanındaki nesnelere erişemez. Güvenlikle ilgili daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

point parametresi, Sahne Alanı'nın koordinat alanındadır; bu koordinat alanı, görüntüleme nesnesi kabının koordinat alanından farklı olabilir (görüntüleme nesnesi kabı Sahne Alanı olmadığı sürece). Bu koordinat alanları arasındaki noktaları dönüştürmek için globalToLocal() ve localToGlobal() yöntemlerini kullanabilirsiniz.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Belirtilen görüntüleme nesnesinin, DisplayObjectContainer örneğinin alt öğesi mi, yoksa örneğin kendisi mi olduğunu belirler. Arama, bu DisplayObjectContainer örneği dahil olmak üzere, görüntüleme listesinin tamamını içerir. Her bir alt alt öğe, vb. true değerini döndürür.

Parametreler

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Belirtilen dizinde bulunan alt görüntüleme nesnesi örneğini döndürür.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Belirtilen ad ile var olan alt görüntüleme nesnesini döndürür. Birden çok alt görüntüleme nesnesi belirtilen ada sahipse, yöntem alt öğe nesnesindeki birinci nesneyi döndürür.

getChildAt() yöntemi, getChildByName() yönteminden daha hızlıdır. getChildAt() yöntemi, önbelleğe alınmış dizideki bir alt öğeye erişirken, getChildByName() yönteminin bir alt öğeye erişmesi için bağlı bir listeyi geçmesi gerekir.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Bir child DisplayObject örneğinin dizin sayısını döndürür.

Parametreler

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Belirtilen noktanın altında olan ve bu DisplayObjectContainer örneğinin alt öğesi (veya alt alt öğesi vb.) olan nesnelerin bir dizisini döndürür. Güvenlik nedenleriyle erişilemeyen tüm alt nesneler döndürülen diziden atlanır. Bu güvenlik kısıtlamasının döndürülen diziyi etkileyip etkilemediğini belirlemek için areInaccessibleObjectsUnderPoint() yöntemini çağırın.

point parametresi, Sahne Alanı'nın koordinat alanındadır; bu koordinat alanı, görüntüleme nesnesi kabının koordinat alanından farklı olabilir (görüntüleme nesnesi kabı Sahne Alanı olmadığı sürece). Bu koordinat alanları arasındaki noktaları dönüştürmek için globalToLocal() ve localToGlobal() yöntemlerini kullanabilirsiniz.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Belirtilen child DisplayObject örneğini DisplayObjectContainer örneğinin alt öğe listesinden kaldırır. Kaldırılan alt öğenin parent özelliği null değerine ayarlanır ve alt öğeye başka başvuru yoksa, nesne çöp toplama işlemine tabi tutulur. DisplayObjectContainer içinde alt öğenin yukarısında bulunan görüntüleme nesnelerinin dizin konumları 1 azaltılır.

Çöp toplayıcısı, kullanılmayan bellek alanını yeniden ayırır. Bir değişken veya nesneye artık etkin olarak başvurulmuyorsa veya bunlar başka yerde saklanmıyorsa, çöp toplayıcısı, başka başvuru olmadığında kaplamak için kullandığı bellek alanını tarayıp siler.

Parametreler

 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

DisplayObjectContainer nesnesinin alt öğe listesinde belirtilen index konumundan bir alt DisplayObject öğesini kaldırır. Kaldırılan alt öğenin parent özelliği null değerine ayarlanır ve alt öğeye başka başvuru yoksa, nesnede çöp toplama işlemine tabi tutulur. DisplayObjectContainer içinde alt öğenin yukarısında bulunan görüntüleme nesnelerinin dizin konumları 1 azaltılır.

Çöp toplayıcısı, kullanılmayan bellek alanını yeniden ayırır. Bir değişken veya nesneye artık etkin olarak başvurulmuyorsa veya bunlar başka yerde saklanmıyorsa, çöp toplayıcısı, başka başvuru olmadığında kaplamak için kullandığı bellek alanını tarayıp siler.

Parametreler

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Tüm child DisplayObject örneklerini DisplayObjectContainer örneğinin alt öğe listesinden kaldırır. Kaldırılan alt öğenin parent özelliği null olarak ayarlanır ve alt öğeye başka bir başvuru bulunmuyorsa çöp olan nesneler toplanır.

Çöp toplayıcısı, kullanılmayan bellek alanını yeniden ayırır. Bir değişken veya nesneye artık etkin olarak başvurulmuyorsa veya bunlar başka yerde saklanmıyorsa, çöp toplayıcısı, başka başvuru olmadığında kaplamak için kullandığı bellek alanını tarayıp siler.

Parametreler

Mevcut bir alt öğenin görüntüleme nesnesi kabındaki konumunu değiştirir. Bu, alt nesnelerin katmanlarını etkiler. Örneğin, şu örnek sırayla 0, 1 ve 2 dizin konumlarında, a, b ve c etiketli üç görüntüleme nesnesini gösterir:

setChildIndex() yöntemini kullanıp zaten kaplanmış bir dizin konumunu belirttiğinizde, yalnızca görüntüleme nesnesinin birinci ve yeni konumu arasındaki konumlar değişir. Diğerlerinin tümü aynı kalır. Bir alt öğe geçerli dizininden DAHA DÜŞÜK bir dizine taşınırsa, aradaki tüm alt öğeler dizin başvuruları için 1 değer ARTIŞ GÖSTERİR. Bir alt öğe geçerli dizininden DAHA YÜKSEK bir dizine taşınırsa, aradaki tüm alt öğeler dizin başvuruları için 1 değer DÜŞÜŞ GÖSTERİR. Örneğin, bir önceki örnekte görüntüleme nesnesi kabı container olarak adlandırılırsa, şu kodu çağırarak a ve b etiketli görüntüleme nesnelerinin konumunu takas edebilirsiniz:

container.setChildIndex(container.getChildAt(1), 0);

Bu kod, nesnelerin şu şekilde düzenlenmesiyle sonuçlanır:

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Kökü bu nesnede bulunan tüm MovieClip öğelerinin zaman çizelgesinde yürütülmesini özyinelemeli olarak durdurur.

Yürütme kodunun erişime sahip olmadığı sanal alana ait olan alt görüntüleme nesneleri yoksayılır.

Not: NetStream nesnesiyle kontrol edilen medya oynatma akışının oluşturulması durdurulmaz.

Belirtilen iki alt nesnenin z sırasını (önden arkaya sıra) takas eder. Görüntüleme nesnesi kabındaki diğer alt nesnelerin tümü aynı dizin konumunda kalır.

Parametreler

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Alt öğe listesinde belirtilen iki dizin konumundaki alt öğe nesnelerinin z sırasını (önden arkaya sıra) takas eder. Görüntüleme nesnesi kabındaki diğer alt nesnelerin tümü aynı dizin konumunda kalır.

Parametreler

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. Yapıcı configureAssets() yöntemini çağırır.
2. configureAssets() yöntemi, child ve lastChild Sprite nesnelerini oluşturur.
3. for döngüsü, beş adet turuncu kare oluşturur ve bunları art arda konumlandırır.
4. Her CustomSprite nesnesi oluşturulduğunda, bu nesnenin yapıcısı CustomSprite nesnesinin draw() yöntemini çağırır; böylece Graphics sınıfının beginFill(), drawRect() ve endFill() yöntemleri çağrılarak 50 x 50 piksel bir kare oluşturulur. addChild() yöntemi, her kareyi görüntüleme listesine ekler.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}