Sprite  - AS3

Bu hareketli grafiğin düğme modunu belirtir. true olursa, bu hareketli grafik bir düğme olarak hareket eder, başka bir deyişle, işaretçi hareketli grafiğin üzerinden geçtiğinde el imlecinin görüntülenmesini tetikler ve odak hareketli grafikteyken enter ya da space tuşlarına basıldığında bir click olayı alabilir. useHandCursor özelliğini false değerine ayarlayarak (bu durumda işaretçi görüntülenir) el imlecinin görüntülenmesini engelleyebilirsiniz.

Düğme oluşturmak için SimpleButton sınıfının kullanılması daha iyi olsa da, hareketli grafiğe düğmeye benzer bir işlev vermek için buttonMode özelliğini kullanabilirsiniz. Bir hareketli grafiği sekme sırasına eklemek için, tabEnabled özelliğini (InteractiveObject sınıfından miras alınır varsayılan olarak false değerindedir) true değerine ayarlayın. Ayrıca, hareketli grafiğinizin alt öğelerinin kullanıcı girdisi etkin olmasını isteyip istemediğinizi göz önünde bulundurun. Çoğu düğme, olay akışını karıştırdığından, alt nesneler için kullanıcı girdisi etkileşimini etkinleştirmez. Tüm alt nesnelerin kullanıcı girdisi etkileşimini devre dışı bırakmak için, mouseChildren özelliğini (DisplayObjectContainer sınıfından miras alınır) false değerine ayarlamanız gerekir.

MovieClip sınıfıyla (Sprite sınıfının bir alt sınıfıdır) buttonMode özelliğini kullanırsanız, düğmenize bazı işlevler eklenebilir. labeled _up, _over ve _down karelerini eklerseniz, Flash Player, otomatik durum değişiklikleri (önceki ActionScript sürümlerinde film klipleri için düğmeler olarak sağlanan işleve benzer) sağlar. Bu otomatik durum değişiklikleri, zaman çizelgesi olmayan hareketli grafikler için kullanılamaz, bu nedenle etiketlenecek kare yoktur.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Hareketli grafiğin üzerine sürüklenmekte olduğu veya hareketli grafiğin üzerine bırakıldığı görüntüleme nesnesini belirtir.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Vektör çizimi komutlarının gerçekleşebileceği, bu hareketli grafiğe ait Graphics nesnesini belirtir.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Bir hareketli görüntü için vuruş alanı olarak başka bir hareketli görüntüyü atar. hitArea özelliği yoksa veya değer null ya da undefined ise, hareketli grafiğin kendisi tıklatma alanı olarak kullanılır. hitArea özelliğinin değeri, Sprite nesnesinin bir başvurusu olabilir.

hitArea özelliğini istediğiniz zaman değiştirebilirsiniz; değiştirilen hareketli grafik hemen yeni tıklatma alanı davranışını kullanır. Tıklatma alanı olarak atanan hareketli grafiğin görünebilir olması gerekmez; görünmese de, grafiksel şekli tıklatma alanı olarak algılanmaya devam eder.

Not: Tıklatma alanı olarak atanan hareketli grafiğin mouseEnabled özelliğini false değerine ayarlamanız gerekir. Aksi takdirde, tıklatma alanı olarak atanan hareketli grafik, hareketli grafik düğmesi yerine kullanıcı girdisi olaylarını aldığından, hareketli grafik düğmeniz çalışmayabilir.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Bu hareketli grafikteki sesi denetler.

Not: Bu özellik bir HTMLControl nesnesindeki HTML içeriğini etkilemez (Adobe AIR'de).

İlgili API Öğeleri

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

İşaret eden elin (el imleci), buttonMode özelliği true değerine ayarlanmış bir hareketli grafiğin üzerinde işaretçi gezinirken görüntülenip görüntülenmeyeceğini belirten Boolean değeri. useHandCursor özelliğinin varsayılan değeri true olur. useHandCursor öğesi true değerine ayarlanırsa, işaretçi bir düğme hareketli grafiğinin üzerinde gezinirken düğmeler için kullanılan işaret eden el görüntülenir. useHandCursor öğesi false değerine ayarlanırsa, bunun yerine ok işaretçisi kullanılır.

useHandCursor özelliğini istediğiniz zaman değiştirebilirsiniz; değiştirilen hareketli grafik hemen yeni imleç görünümünü alır.

Not:Flex veya Flash Builder'da hareketli grafiğiniz alt hareketli grafik öğeleri içeriyorsa, mouseChildren özelliğini false olarak ayarlamanız gerekebilir. Örneğin, bir el imlecinin Flex <mx:Label> denetimi üzerinde görüntülenmesini istiyorsanız, useHandCursor ve buttonMode özelliklerini true değerine ve mouseChildren özelliğini de false değerine ayarlayın.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Yeni bir Sprite örneği oluşturur. Sprite örneğini oluşturduktan sonra, Sprite öğesini üst DisplayObjectContainer öğesine eklemek için DisplayObjectContainer.addChild() veya DisplayObjectContainer.addChildAt() yöntemini çağırın.

Kullanıcının belirtilen hareketli grafiği sürüklemesini sağlar. Hareketli grafik, Sprite.stopDrag() yöntemine yapılan bir çağrıyla açıkça durduruluncaya kadar veya başka bir hareketli grafik sürüklenebilir duruma getirilinceye kadar sürüklenebilir olmaya devam eder. Bir kerede yalnızca tek bir hareketli grafik sürüklenebilir.

Görüntüleme nesnesi tarafından tanımlanan üç boyutlu düzlemde üç boyutlu görüntüleme nesneleri işaretçiyi takip eder ve Sprite.startDrag() öğesi nesneyi hareket ettirir. Veya görüntüleme nesnesi iki boyutlu bir nesneyse ve üç boyutlu nesnenin alt öğesiyse, iki boyutlu nesne, üç boyutlu üst nesne tarafından tanımlanan üç boyutlu düzlemde hareket eder.

Parametreler

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Kullanıcının dokunmatik etkin bir aygıtta belirli hareketli grafiği sürüklemesine izin verir. Hareketli grafik, Sprite.stopTouchDrag() yöntemine yapılan bir çağrıyla açıkça durduruluncaya kadar veya başka bir hareketli grafik sürüklenebilir duruma getirilinceye kadar sürüklenebilir olmaya devam eder. Bir kerede yalnızca tek bir hareketli grafik sürüklenebilir.

Görüntüleme nesnesi tarafından tanımlanan üç boyutlu düzlemde üç boyutlu görüntüleme nesneleri işaretçiyi takip eder ve Sprite.startTouchDrag() öğesi nesneyi hareket ettirir. Veya görüntüleme nesnesi iki boyutlu bir nesneyse ve üç boyutlu nesnenin alt öğesiyse, iki boyutlu nesne, üç boyutlu üst nesne tarafından tanımlanan üç boyutlu düzlemde hareket eder.

Parametreler

İlgili API Öğeleri

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

startDrag() yöntemini bitirir. startDrag() yöntemiyle sürüklenebilir duruma getirilen hareketli bir grafik, bir stopDrag() yöntemi ekleninceye kadar veya başka bir hareketli grafik sürüklenebilir duruma gelinceye kadar sürüklenebilir olmaya devam eder. Bir kerede yalnızca tek bir hareketli grafik sürüklenebilir.

İlgili API Öğeleri

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Dokunma etkin aygıtlarla kullanım için startTouchDrag() yöntemini sonlandırır. startTouchDrag() yöntemiyle sürüklenebilir duruma getirilen hareketli bir grafik, bir stopTouchDrag() yöntemi ekleninceye kadar veya başka bir hareketli grafik sürüklenebilir duruma gelinceye kadar sürüklenebilir olmaya devam eder. Bir kerede yalnızca tek bir hareketli grafik sürüklenebilir.

Parametreler

İlgili API Öğeleri

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. İleride kare çiziminde kullanmak üzere size özelliğini (100 x 100 piksel) ve arka plan rengini (turuncu) bildirin.
2. Böylece yapıcı yeni bir child Sprite nesnesi oluşturur ve iki olay dinleyicisi ve bunların ilişkilendirilmiş yöntemlerini eklemek için bu nesneyi kullanır: mouseDownHandler() ve mouseUpHandler().
3. Ardından child Sprite nesnesi draw() yöntemine iletilerek turuncu kare çizilir.
4. Sonra da addChild() yöntemi çağrılarak görüntüleme listesine alt öğe yerleştirilir.
5. Olay dinleyicileri şu şekilde çalışır:
   • mouseDownHandler(): kullanıcı Sprite nesnesini tıklattığında, bu yöntem bir mouseMove olay dinleyicisini ve fare hareketlerini işleyen mouseMoveHandler() yöntemini ekler. Daha sonra startDrag() yöntemi çağrılır, bu çağrı Sprite nesnesinin sürüklenmesini sağlar.
   • mouseUpHandler(): fare düğmesi serbest bırakıldığında, mouseMove olay dinleyicisi kaldırılır ve turuncu kareyi yerinde donduran stopDrag() yöntemi çağrılır.
   • mouseMoveHandler: sol fare düğmesi basılı tutulduğu sürece, bu yöntem oynatıcıyı sürekli olarak turuncu kareyi yeniden çizmesi için yönlendirir.

Not: Event listener yöntemlerinin her biri, olayın target özelliğine atanan yerel bir sprite değişkenini bildirir.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}