Graphics  - AS3

Çizim alanını bitmap görüntüsüyle doldurur. Alanı doldurmak için bitmap yinelenebilir veya döşenebilir. Siz beginFill(), beginBitmapFill(), beginGradientFill() veya beginShaderFill() yöntemini çağırana kadar dolgu etkin kalır. clear() yönteminin çağrılması dolguyu temizler.

Üç veya daha çok nokta çizildiğinde veya endFill() yöntemi çağrıldığında, uygulama dolguyu oluşturur.

Parametreler

     matrix = new flash.geom.Matrix(); 
     matrix.rotate(Math.PI / 4);
     

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.geom.Matrix;

    public class Graphics_beginBitmapFillExample extends Sprite {
 
        private var url:String = "image1.jpg";
        private var loader:Loader = new Loader();

        public function Graphics_beginBitmapFillExample() {

            var request:URLRequest = new URLRequest(url);
            
            loader.load(request);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, drawImage);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function drawImage(event:Event):void {

            var mySprite:Sprite = new Sprite();
            var myBitmap:BitmapData = new BitmapData(loader.width, loader.height, false);
  
            myBitmap.draw(loader, new Matrix());
            
            var matrix:Matrix = new Matrix();
            matrix.rotate(Math.PI/4);
            
            mySprite.graphics.beginBitmapFill(myBitmap, matrix, true);
            mySprite.graphics.drawRect(100, 50, 200, 90);
            mySprite.graphics.endFill();
            
            addChild(mySprite);
        }
 
         private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }   
}

Diğer Graphics yöntemlerine yapılan sonraki çağrıların (lineTo() veya drawCircle() gibi) çizim sırasında kullandığı basit bir tek renkli dolguyu belirtir. Siz beginFill(), beginBitmapFill(), beginGradientFill() veya beginShaderFill() yöntemini çağırana kadar dolgu etkin kalır. clear() yönteminin çağrılması dolguyu temizler.

Üç veya daha çok nokta çizildiğinde veya endFill() yöntemi çağrıldığında, uygulama dolguyu oluşturur.

Parametreler

İlgili API Öğeleri

Nesne için (lineTo() veya drawCircle() gibi) diğer Graphics yöntemlerine yapılan sonraki çağrılar tarafından kullanılacak bir degrade dolguyu belirtir. Siz beginFill(), beginBitmapFill(), beginGradientFill() veya beginShaderFill() yöntemini çağırana kadar dolgu etkin kalır. clear() yönteminin çağrılması dolguyu temizler.

Üç veya daha çok nokta çizildiğinde veya endFill() yöntemi çağrıldığında, uygulama dolguyu oluşturur.

Parametreler

	type:String — Hangi degrade türünün kullanılacağını belirten GradientType sınıfı değeri: GradientType.LINEAR veya GradientType.RADIAL.
	colors:Array — Degradede kullanılacak RGB onaltılık renk değerleri dizisi; örneğin, kırmızı 0xFF0000, mavi 0x0000FF vb. olur. En fazla 15 renk belirtebilirsiniz. Her renk için, alphas ve ratios parametrelerinde karşılık gelen bir değer belirttiğinizden emin olun.
	alphas:Array — Renkler dizisinde karşılık gelen renkler için alfa değerleri dizisi; geçerli değerler 0 - 1 arasındadır. Değer 0'dan düşükse, varsayılan 0'dır. Değer 1'den büyükse, varsayılan 1'dir.
	ratios:Array — Bir renk dağıtım oranları dizisi; geçerli değerler 0 - 255 arasındadır. Bu değer, rengin %100 oranında örneklendiği yerdeki genişlik yüzdesini tanımlar. 0 değeri, degrade kutusundaki sol konumu temsil ederken, 255 değeri de degrade kutusundaki sağ konumu temsil eder. Not: Bu değer, son degradenin koordinat alanını (bu, degrade kutusundan daha geniş veya daha ince olabilir) değil, degrade kutusundaki konumları temsil eder. colors parametresinde her değer için bir değer belirtin. Örneğin, mavi ve yeşil olmak üzere iki renk içeren doğrusal bir degrade için, şu örnek ratios dizisindeki farklı değerler esas alınarak renklerin degradede yerleşimini gösterir. ratios Degrade [0, 127] [0, 255] [127, 255] Dizideki değerlerin birbirini izleyerek artması gerekir; örneğin, [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — flash.geom.Matrix sınıfının tanımladığı gibi dönüştürme matrisi. flash.geom.Matrix sınıfı, matrisi beginGradientFill() yöntemiyle rahatça kullanmanız için ayarlamanızı sağlayan bir createGradientBox() yöntemini içerir.
	spreadMethod:String (default = "pad") — Hangi spread yönteminin kullanılacağını belirten SpreadMethod sınıfı değeri, şunlardan biri olabilir: SpreadMethod.PAD, SpreadMethod.REFLECT veya SpreadMethod.REPEAT. Örneğin, iki renk arasında basit bir doğrusal degrade olduğunu düşünün: import flash.geom.* import flash.display.* var fillType:String = GradientType.LINEAR; var colors:Array = [0xFF0000, 0x0000FF]; var alphas:Array = [1, 1]; var ratios:Array = [0x00, 0xFF]; var matr:Matrix = new Matrix(); matr.createGradientBox(20, 20, 0, 0, 0); var spreadMethod:String = SpreadMethod.PAD; this.graphics.beginGradientFill(fillType, colors, alphas, ratios, matr, spreadMethod); this.graphics.drawRect(0,0,100,100); Bu örnek, spread yöntemi için SpreadMethod.PAD öğesini kullanır ve degrade dolgu şöyle görünür: Spread yöntemi için SpreadMethod.REFLECTöğesini kullanırsanız, degrade dolgu şöyle görünür: Spread yöntemi için SpreadMethod.REPEATöğesini kullanırsanız, degrade dolgu şöyle görünür:
	interpolationMethod:String (default = "rgb") — Hangi değerin kullanılacağını belirten bir InterpolationMethod sınıfı değeri: InterpolationMethod.LINEAR_RGB veya InterpolationMethod.RGB Örneğin iki renk arasındaki basit bir doğrusal degradeyi düşünün (spreadMethod parametresi SpreadMethod.REFLECT olarak ayarlanmış şekilde). Farklı enterpolasyon yöntemleri, görünümü şöyle etkiler: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Degradenin odak noktası konumunu denetleyen bir sayı. 0, odak noktasının ortada olduğu anlamına gelir. 1, odak noktasının degrade dairesinin bir kenarında olduğu anlamına gelir. -1, odak noktasının degrade dairesinin diğer kenarında olduğu anlamına gelir. -1'den düşük veya 1'den büyük bir değer, sırayla -1'e ya da 1'e yuvarlanır. Örneğin şu örnek 0,75'e ayarlı bir focalPointRatio öğesini gösterir:

İlgili API Öğeleri

Nesne için diğer Graphics yöntemlerine (lineTo() veya drawCircle() gibi) yapılan sonraki çağrılar tarafından kullanılan bir gölgelendirici dolgusunu belirtir. Siz beginFill(), beginBitmapFill(), beginGradientFill() veya beginShaderFill() yöntemini çağırana kadar dolgu etkin kalır. clear() yönteminin çağrılması dolguyu temizler.

Üç veya daha çok nokta çizildiğinde veya endFill() yöntemi çağrıldığında, uygulama dolguyu oluşturur.

GPU görüntü oluşturmada gölgelendirici dolguları desteklenmez; doldurulan alanlar cam göbeği rengine boyanır.

Parametreler

     matrix = new flash.geom.Matrix(); 
     matrix.rotate(Math.PI / 4);
     

İlgili API Öğeleri

Bu Graphics nesnesine çizilmiş grafikleri temizler ve dolgu ve çizgi stili ayarlarını sıfırlar.

Kaynak Graphics nesnesindeki tüm çizim komutlarını, çağıran Graphics nesnesine kopyalar.

Parametreler

Geçerli çizim konumundan, belirtilen bağlantı noktasına kübik bir Bezier eğrisi çizer. Kübik Bezier eğrileri iki tutturma noktasından ve iki denetim noktasından oluşur. Eğri, iki tutturma noktasını ve eğrileri iki denetim noktasına doğru ekler.

cubicCurveTo() yöntemi ile kübik bir Bezier eğrisi çizmek için kullandığınız dört nokta aşağıda verilmiştir:

• Geçerli çizim konumu, ilk tutturma noktasıdır.
• anchorX ve anchorY parametreleri ikinci tutturma noktasını belirtir.
• controlX1 ve controlY1 parametreleri ilk denetim noktasını belirtir.
• controlX2 ve controlY2 parametreleri ikinci denetim noktasını belirtir.

moveTo() yöntemini çağırmadan önce cubicCurveTo() yöntemini çağırırsanız eğriniz (0, 0) konumundan başlar.

cubicCurveTo() yöntemi başarılı olursa Flash çalışma zamanı, geçerli çizim konumunu (anchorX, anchorY) parametrelerine ayarlar. cubicCurveTo() yöntemi başarısız olursa geçerli çizim konumu aynı kalır.

Film klibiniz Flash çizim araçlarıyla oluşturulan içerik barındırıyorsa cubicCurveTo() yöntemine yapılan çağrılar bu içeriğin altında çizilir.

Parametreler

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    
    public class Graphics_cubicCurveToExample extends Sprite
    {
        public function Graphics_cubicCurveToExample():void
        {
            var rounderObject:Shape = new Shape();

            rounderObject.graphics.beginFill(0x0000FF);
            rounderObject.graphics.moveTo(250, 0);
            rounderObject.graphics.cubicCurveTo(275, 0, 300, 25, 300, 50);
            rounderObject.graphics.cubicCurveTo(300, 75, 275, 100, 250, 100);
            rounderObject.graphics.cubicCurveTo(225, 100, 200, 75, 200, 50);
            rounderObject.graphics.cubicCurveTo(200, 25, 225, 0, 250, 0);
            rounderObject.graphics.endFill();
            
            this.addChild(rounderObject);
        }
    }
}

Geçerli çizim konumundan (anchorX, anchorY) konumuna geçerli çizgi stilini kullanarak ve (controlX, controlY) öğesinin belirttiği denetim noktasını kullanarak kuadratik bir Bezier eğrisi çizer. Geçerli çizim konumu daha sonra (anchorX, anchorY) olarak ayarlanır. İçinde çizim yaptığınız film klibi, Flash çizim araçlarıyla oluşturulmuş içerik içeriyorsa, curveTo() yöntemine yapılan çağrılar, bu içeriğin altında çizilir. moveTo() yöntemine çağrı yapmadan önce curveTo() yöntemini çağırırsanız, geçerli çizim konumunun varsayılan değeri (0, 0) olur. Parametrelerden herhangi biri eksikse, bu yöntem başarısız olur ve geçerli çizim konumu değişmez.

Çizilen eğri kuadratik bir Bezier eğrisidir. Kuadratik Bezier eğrileri iki tutturma noktasından ve bir denetim noktasından oluşur. Eğri, iki tutturma noktasını ve eğrileri denetim noktasına doğru ekler.

Parametreler

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    
    public class Graphics_curveToExample1 extends Sprite
    {
        public function Graphics_curveToExample1():void
        {
            var roundObject:Shape = new Shape();

            roundObject.graphics.beginFill(0x00FF00);
            roundObject.graphics.moveTo(250, 0);
            roundObject.graphics.curveTo(300, 0, 300, 50);
            roundObject.graphics.curveTo(300, 100, 250, 100);
            roundObject.graphics.curveTo(200, 100, 200, 50);
            roundObject.graphics.curveTo(200, 0, 250, 0);
            roundObject.graphics.endFill();
            
            this.addChild(roundObject);
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_curveToExample2 extends Sprite
    {
        public function Graphics_curveToExample2() {
            var newMoon:Shape = new Shape();
            
            newMoon.graphics.lineStyle(1, 0);
            newMoon.graphics.beginFill(0xFFFFFF);
            newMoon.graphics.moveTo(100, 100); 
            newMoon.graphics.curveTo(30, 150, 100, 200);    
            newMoon.graphics.curveTo(50, 150, 100, 100);
            graphics.endFill();
            
            this.addChild(newMoon);
        }
    }
}

Bir daire çizer. drawCircle() yöntemini çağırmadan önce, linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() veya beginBitmapFill() yöntemini çağırarak çizgi stilini, dolguyu veya her ikisini ayarlayın.

Parametreler

İlgili API Öğeleri

Bir elips çizer. drawEllipse() yöntemini çağırmadan önce, linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() veya beginBitmapFill() yöntemini çağırarak çizgi stilini, dolguyu veya her ikisini ayarlayın.

Parametreler

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_drawEllipseExample extends Sprite
    {
        public static const SMALL:uint = 0;
        public static const MEDIUM:uint = 1;
        public static const LARGE:uint = 2;

        public function Graphics_drawEllipseExample()
        {
            drawEgg(SMALL, 0, 100);
            drawEgg(MEDIUM, 100, 60);
            drawEgg(LARGE, 250, 35);    
        }

        public function drawEgg(eggSize:uint, x:Number, y:Number):void  {
            
            var myEgg:Shape = new Shape();
            
            myEgg.graphics.beginFill(0xFFFFFF);
            myEgg.graphics.lineStyle(1);

            switch(eggSize) {
                case SMALL:
                    myEgg.graphics.drawEllipse(x, y, 60, 70);
                    break;
                case MEDIUM:
                    myEgg.graphics.drawEllipse(x, y, 120, 150);    
                    break;
                case LARGE:
                    myEgg.graphics.drawEllipse(x, y, 150, 200);
                    break;
                default:
                    trace ("Wrong size! There is no egg.");
                break;            
            }
            
            myEgg.graphics.endFill();
    
            this.addChild(myEgg);
        }
    }
}

Çizim için bir IGraphicsData örnekleri serisi gönderir. Bu yöntem, IGraphicsData arabirimini uygulayan ve yol, dolgu ve kontur gibi nesneleri içeren bir Vector öğesini kabul eder. IGraphicsData örnekleri Vector'u, bütün bir şekli oluşturmak için şeklin bir kısmını veya karmaşık ve tam tanımlı bir veriler kümesine başvurabilir.

Grafik yolları başka grafik yollarını da içerebilir. graphicsData Vector öğesi bir yol içeriyorsa, bu işlem sırasında o yol ve o yolun alt yolları oluşturulur.

Parametreler

İlgili API Öğeleri

package
{
    import flash.display.*;
    import flash.geom.*;

    public class DrawGraphicsDataExample extends Sprite
    {
        public function DrawGraphicsDataExample()
        {
            // establish the fill properties
            var myFill:GraphicsGradientFill = new GraphicsGradientFill();
            myFill.colors = [0xEEFFEE, 0x0000FF];
            myFill.matrix = new Matrix();
            myFill.matrix.createGradientBox(100, 100, 0);
            
            // establish the stroke properties
            var myStroke:GraphicsStroke = new GraphicsStroke(2);
            myStroke.fill = new GraphicsSolidFill(0x000000);
            
            // establish the path properties
            var pathCommands = new Vector.<int>(5, true);
            pathCommands[0] = GraphicsPathCommand.MOVE_TO;
            pathCommands[1] = GraphicsPathCommand.LINE_TO;
            pathCommands[2] = GraphicsPathCommand.LINE_TO;
            pathCommands[3] = GraphicsPathCommand.LINE_TO;
            pathCommands[4] = GraphicsPathCommand.LINE_TO;
            
            var pathCoordinates:Vector.<Number> = new Vector.<Number>(10, true);
            pathCoordinates.push(10,10, 10,100, 100,100, 100,10, 10,10);
            
            var myPath:GraphicsPath = new GraphicsPath(pathCommands, pathCoordinates);
            
            // populate the IGraphicsData Vector array
            var myDrawing:Vector.<IGraphicsData> = new Vector.<IGraphicsData>(3, true);
            myDrawing[0] = myFill;
            myDrawing[1] = myStroke;
            myDrawing[2] = myPath;
            
            // render the drawing
            graphics.drawGraphicsData(myDrawing);
        }
    }
}

Çizim için bir komutlar serisi gönderir. drawPath() yöntemi, moveTo() lineTo() ve curveTo() çizim komutları Vektörünü ayrı ayrı kabul eder ve bunları tek bir çağrıda birleştirir. drawPath() yöntemi parametreleri, x ve y koordinatları değer çiftleri olan çizim komutlarını bir çizim yönü ile birleştirir. Çizim komutları, GraphicsPathCommand sınıfında tanımlanan sabitler olarak temsil edilen tamsayılardır. x ve y koordinatları değer çiftleri, her çiftin bir koordinat konumunu tanımladığı bir dizideki Numbers öğeleridir. Çizim yönü, GraphicsPathWinding sınıfına ait bir değerdir.

Çizimler, drawPath() ile, tek tek lineTo() ve curveTo() yöntemi çağrı serisinden genellikle daha hızlı oluşturulur.

drawPath() yöntemi kayar hesaplama kullanır, böylece şekillerin dönmesi ve ölçeklendirilmesi daha doğru bir şekilde gerçekleşir ve daha iyi sonuçlar verir. Ancak, drawPath() yöntemiyle gönderilen eğrilerin, lineTo() ve curveTo() yöntemleriyle bağlantılı kullanıldığında küçük alt piksel hizalama hataları olabileceği anlamına da gelir.

drawPath() yöntemi ayrıca dolgu yapmak ve çizgi çizmek için biraz daha farklı kurallar kullanır. Bu kurallar şunlardır:

• Yol oluşturulurken bir dolgu uygulandığında:
  • 3 noktadan düşük bir alt yol oluşturulmaz. (Ancak aşağıdaki kontur kurallarıyla tutarlı şekilde, kontur oluşturmanın yine de oluşacağını unutmayın.)
  • Kapalı olmayan bir alt yol (son noktası başlangıç noktasına eşit değildir) örtülü bir şekilde kapalıdır.
• Yol oluşturulurken bir kontur uygulandığında:
  • Alt yollar herhangi bir sayıda noktadan oluşabilir.
  • Alt yol asla örtülü bir şekilde kapalı değildir.

Parametreler

İlgili API Öğeleri

package
{
    import flash.display.*;
        
    public class DrawPathExample extends Sprite
    {
        public function DrawPathExample()
        {
            var star_commands:Vector.<int> = new Vector.<int>(5, true);
            
            star_commands[0] = GraphicsPathCommand.MOVE_TO;
            star_commands[1] = GraphicsPathCommand.LINE_TO;
            star_commands[2] = GraphicsPathCommand.LINE_TO;
            star_commands[3] = GraphicsPathCommand.LINE_TO;
            star_commands[4] = GraphicsPathCommand.LINE_TO;
            
            var star_coord:Vector.<Number> = new Vector.<Number>(10, true);
            star_coord[0] = 66; //x
            star_coord[1] = 10; //y 
            star_coord[2] = 23; 
            star_coord[3] = 127; 
            star_coord[4] = 122; 
            star_coord[5] = 50; 
            star_coord[6] = 10; 
            star_coord[7] = 49; 
            star_coord[8] = 109; 
            star_coord[9] = 127;
            
            graphics.beginFill(0x003366);
            graphics.drawPath(star_commands, star_coord);
        }
    }
}

 graphics.drawPath(star_commands, star_coord, GraphicsPathWinding.NON_ZERO);
 

Bir dikdörtgen çizer. drawRect() yöntemini çağırmadan önce, linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() veya beginBitmapFill() yöntemini çağırarak çizgi stilini, dolguyu veya her ikisini ayarlayın.

Parametreler

İlgili API Öğeleri

var movieClip:MovieClip = new MovieClip();
movieClip.graphics.beginFill(0xFF0000);
movieClip.graphics.drawRect(0, 0, 100, 80);
movieClip.graphics.endFill();
movieClip.x = 10;
movieClip.y = 10;
addChild(movieClip);

Yuvarlak köşeli bir dikdörtgen çizer. drawRoundRect() yöntemini çağırmadan önce, linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() veya beginBitmapFill() yöntemini çağırarak çizgi stilini, dolguyu veya her ikisini ayarlayın.

Parametreler

İlgili API Öğeleri

Genellikle bitmap'leri bozmak ve onlara üç boyutlu görünüm kazandırmak için bir üçgen kümesi oluşturur. drawTriangles() yöntemi, (u, v) koordinatları kümesini kullanarak geçerli dolguyu veya bitmap dolgusunu, üçgen yüzlerine eşler.

Herhangi bir dolgu türü kullanılabilir ancak dolgunun bir dönüştürme matrisi varsa, bu matris yok sayılır.

Bitmap dolgu kullanıldığında uvtData parametresi doku eşlemesini iyileştirir.

Parametreler

İlgili API Öğeleri

beginFill(), beginGradientFill() veya beginBitmapFill() yöntemine yapılan son çağrıdan bu yana eklenmiş olan çizgi ve eğrilere dolgu uygular. Flash, beginFill(), beginGradientFill() veya beginBitmapFill() yöntemine yapılan önceki çağrıda belirtilmiş dolguyu kullanır. Geçerli çizim konumu, bir moveTo() yönteminde belirtilen önceki konuma eşit olmazsa ve bir dolgu tanımlanırsa, yol bir çizgiyle kapatılır ve sonra doldurulur.

İlgili API Öğeleri

Çizgi çizilirken satır konturu için kullanılacak bir degradeyi belirtir.

Bitmap çizgi stili, lineTo() yöntemi veya drawCircle() yöntemi gibi Graphics yöntemlerine yapılan sonraki çağrılar için kullanılır. Siz farklı parametrelerle lineStyle() veya lineGradientStyle() yöntemlerini ya da lineBitmapStyle() yöntemini tekrar çağırıncaya kadar çizgi stili etkili olur.

Bir yol içindeki farklı çizgi parçaları için farklı stiller belirtmek üzere bir yol çiziminin ortasında lineBitmapStyle() yöntemini çağırabilirsiniz.

Bir konturu etkinleştirmek için lineBitmapStyle() yöntemini çağırmadan önce lineStyle() yöntemini çağırın, aksi takdirde çizgi stilinin değeri undefined olur.

clear() yöntemine yapılan çağrılar, çizgi stilini geri undefined değerine ayarlar.

Parametreler

İlgili API Öğeleri

Çizgi çizilirken kontur için kullanılacak bir degradeyi belirtir.

Bu degrade çizgi stili, lineTo() yöntemleri veya drawCircle() yöntemi gibi Graphics yöntemlerine yapılan sonraki çağrılar için kullanılır. Siz farklı parametrelerle lineStyle() veya lineBitmapStyle() yöntemlerini veya lineGradientStyle() yöntemini tekrar çağırıncaya kadar çizgi stili etkili olur.

Bir yol içindeki farklı çizgi parçaları için farklı stiller belirtmek üzere bir yol çiziminin ortasında lineGradientStyle() yöntemini çağırabilirsiniz.

Bir konturu etkinleştirmek için lineGradientStyle() yöntemini çağırmadan önce lineStyle() yöntemini çağırın, aksi takdirde çizgi stilinin değeri undefined olur.

clear() yöntemine yapılan çağrılar, çizgi stilini geri undefined değerine ayarlar.

Parametreler

	type:String — Hangi degrade türünün kullanılacağını belirten GradientType sınıfı değeri: GradientType.LINEAR veya GradientType.RADIAL.
	colors:Array — Degradede kullanılacak RGB onaltılık renk değerleri dizisi; örneğin, kırmızı 0xFF0000, mavi 0x0000FF, vb. olur.
	alphas:Array — Renkler dizisinde karşılık gelen renkler için alfa değerleri dizisi; geçerli değerler 0 - 1 arasındadır. Değer 0'dan düşükse, varsayılan 0'dır. Değer 1'den büyükse, varsayılan 1'dir.
	ratios:Array — Bir renk dağıtım oranları dizisi; geçerli değerler 0 - 255 arasındadır. Bu değer, rengin %100 oranında örneklendiği yerdeki genişlik yüzdesini tanımlar. 0 değeri, degrade kutusundaki sol konumu temsil ederken, 255 değeri de degrade kutusundaki sağ konumu temsil eder. Bu değer, son degradenin koordinat alanını (bu, degrade kutusundan daha geniş veya daha ince olabilir) değil, degrade kutusundaki konumları temsil eder. colors parametresinde her değer için bir değer belirtin. Örneğin, mavi ve yeşil olmak üzere iki renk içeren doğrusal bir degrade için, şu şekil ratios dizisindeki farklı değerler esas alınarak renklerin degradede yerleşimini gösterir. ratios Degrade [0, 127] [0, 255] [127, 255] Dizideki değerlerin birbirini izleyerek artması gerekir; örneğin, [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — flash.geom.Matrix sınıfının tanımladığı gibi dönüştürme matrisi. flash.geom.Matrix sınıfı, matrisi lineGradientStyle() yöntemiyle rahatça kullanmanız için ayarlamanızı sağlayan bir createGradientBox() yöntemini içerir.
	spreadMethod:String (default = "pad") — Hangi spread yönteminin kullanılacağını belirten bir SpreadMethod değeri: SpreadMethod.PAD SpreadMethod.REFLECT SpreadMethod.REPEAT
	interpolationMethod:String (default = "rgb") — Hangi değerin kullanılacağını belirten bir InterpolationMethod değeri. Örneğin iki renk arasındaki basit bir doğrusal degradeyi düşünün (spreadMethod parametresi SpreadMethod.REFLECT olarak ayarlanmış şekilde). Farklı enterpolasyon yöntemleri, görünümü şöyle etkiler: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Degradenin odak noktası konumunu denetleyen bir sayı. 0 değeri, odak noktasının ortada olduğu anlamına gelir. 1 değeri, odak noktasının degrade dairesinin bir kenarında olduğu anlamına gelir. -1 değeri, odak noktasının degrade dairesinin diğer kenarında olduğu anlamına gelir. -1'den düşük veya 1'den büyük değerler sırayla -1'e ya da 1'e yuvarlanır. Şu görüntü, -0,75 focalPointRatio içeren bir degradeyi gösterir:

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.geom.Matrix; 
    import flash.display.GradientType;
    
    public class Graphics_lineGradientStyleExample extends Sprite
    {
        public function Graphics_lineGradientStyleExample()
        {
            var myShape:Shape = new Shape();
            var gradientBoxMatrix:Matrix = new Matrix();
  
            gradientBoxMatrix.createGradientBox(200, 40, 0, 0, 0);  
            
            myShape.graphics.lineStyle(5);
  
            myShape.graphics.lineGradientStyle(GradientType.LINEAR, [0xFF0000,
            0x00FF00, 0x0000FF], [1, 1, 1], [0, 128, 255], gradientBoxMatrix);
            
            myShape.graphics.drawRect(0, 0, 200, 40);
            myShape.graphics.drawCircle(100, 120, 50);  
             
            this.addChild(myShape);
    
        }
    }
}

Çizgi çizilirken satır konturu için kullanılacak gölgelendiriciyi belirtir.

Gölgelendirici çizgi stili, lineTo() yöntemi veya drawCircle() yöntemi gibi Graphics yöntemlerine yapılan sonraki çağrılar için kullanılır. Siz farklı parametrelerle lineStyle() veya lineGradientStyle() yöntemlerini ya da lineBitmapStyle() yöntemini tekrar çağırıncaya kadar çizgi stili etkili olur.

Bir yol içindeki farklı çizgi parçaları için farklı stiller belirtmek üzere bir yol çiziminin ortasında lineShaderStyle() yöntemini çağırabilirsiniz.

Bir konturu etkinleştirmek için lineShaderStyle() yöntemini çağırmadan önce lineStyle() yöntemini çağırın, aksi takdirde çizgi stilinin değeri undefined olur.

clear() yöntemine yapılan çağrılar, çizgi stilini geri undefined değerine ayarlar.

Parametreler

İlgili API Öğeleri

lineTo() yöntemi veya drawCircle() yöntemi gibi Graphics yöntemlerine yapılan sonraki çağrılar için kullanılacak bir çizgi stilini belirtir. Siz farklı parametrelerle lineGradientStyle(), yöntemini, lineBitmapStyle() yöntemini veya lineStyle() yöntemini çağırıncaya kadar çizgi stili etkili olur.

Yol içindeki farklı çizgi parçaları için farklı stiller belirtmek üzere bir yol çiziminin ortasında lineStyle() yöntemini çağırabilirsiniz.

Not: clear() öğesine yapılan çağrılar, çizgi stilini geri undefined değerine ayarlar.

Not: Flash 4 yalnızca ilk 3 parametreyi destekler (kalınlık, renk ve alfa).

Parametreler

İlgili API Öğeleri

Geçerli çizim konumundan (x, y) konumuna geçerli çizgi stilini kullanarak bir çizgi çizer; geçerli çizim konumu sonradan (x, y) konumuna ayarlanır. İçinde çizim yaptığınız görüntüleme nesnesi, Flash çizim araçlarıyla oluşturulmuş içerik barındırıyorsa, lineTo() yöntemine yapılan çağrılar, içeriğin altında çizilir. moveTo() yöntemine herhangi bir çağrı yapmadan önce lineTo() öğesini çağırırsanız, geçerli çizimin varsayılan konumu (0, 0) olur. Parametrelerden herhangi biri eksikse, bu yöntem başarısız olur ve geçerli çizim konumu değişmez.

Parametreler

package {
    import flash.display.Sprite;
    import flash.display.LineScaleMode;
    import flash.display.CapsStyle;
    import flash.display.JointStyle;
    import flash.display.Shape;


    public class Graphics_lineToExample extends Sprite {

        public function Graphics_lineToExample() {

            var trapezoid:Shape = new Shape();    

            trapezoid.graphics.lineStyle(10, 0xFFD700, 1, false, LineScaleMode.VERTICAL,
                               CapsStyle.NONE, JointStyle.MITER, 10);

            trapezoid.graphics.moveTo(100, 100);
 
            trapezoid.graphics.lineTo(120, 50);
            trapezoid.graphics.lineTo(200, 50);
            trapezoid.graphics.lineTo(220, 100);
            trapezoid.graphics.lineTo(100, 100); 

            this.addChild(trapezoid);
        }
    }
}

Geçerli çizim konumunu (x, y) konumuna taşır. Parametrelerden herhangi biri eksikse, bu yöntem başarısız olur ve geçerli çizim konumu değişmez.

Parametreler

package {
    import flash.display.Sprite;
    import flash.display.CapsStyle;
    import flash.display.LineScaleMode;

    public class Graphics_moveToExample extends Sprite
    {
        public function Graphics_moveToExample() {
            
            graphics.lineStyle(3, 0x990000, 0.25, false, 
                            LineScaleMode.NONE, CapsStyle.SQUARE);

            graphics.moveTo(10, 20);
            graphics.lineTo(20, 20);
            graphics.moveTo(30, 20);
            graphics.lineTo(50, 20);
            graphics.moveTo(60, 20);
            graphics.lineTo(80, 20);
            graphics.moveTo(90, 20);
            graphics.lineTo(110, 20);            
            graphics.moveTo(120, 20);
            graphics.lineTo(130, 20);           
        }
    }
}

Sprite veya Shape nesnesini (ve isteğe bağlı olarak alt öğelerini) vektör grafiği içeriği açısından sorgular. Sonuç, IGraphicsData nesneleri Vektörüdür. Dönüşümler, görüntüleme nesnesine sorgudan önce uygulanır. Böylece döndürülen yolların tamamı aynı koordinat alanında olur. Sonuç verileri kümesindeki koordinatlar sahne alanı ile alakalıdır, örneği oluşturulan görüntüleme nesnesi ile değil.

Sonuca aşağıdaki nesne türleri ile belirtilen sınırlamalar dahildir:

• GraphicsSolidFill
• GraphicsGradientFill
  • Degrade dolgunun tüm özellikleri readGraphicsData() ile döndürülür.
  • Döndürülen matris benzer, ancak giriş matrisi ile tamamen aynı değil.
• GraphicsEndFill
• GraphicsBitmapFill
  • Döndürülen matris benzer, ancak giriş matrisi ile tamamen aynı değil.
  • repeat her zaman true değerindedir.
  • smooth her zaman false değerindedir.
• GraphicsStroke
  • thickness desteklenir.
  • fill, önceden açıklandığı gibi GraphicsSolidFill, GraphicsGradientFill ve GraphicsBitmapFill öğesini destekler
  • Diğer tüm özellikler varsayılan değerlere sahiptir.
• GraphicsPath
  • Yalnızca MOVE_TO, CURVE_TO ve LINE_TO komutları desteklenir.

Aşağıdaki görsel öğeler ve dönüşümler temsil edilemez ve sonuca dahil edilmez:

• Maskeler
• Bir istisnası olan metin: "animasyon için kenar yumuşatma" kenar yumuşatma türü ile tanımlanan statik metin, sonuca dahil edilecek şekilde vektör şekilleri olarak oluşturulur.
• Gölgelendirici dolguları
• Karışım modları
• 9 dilimli ölçekleme
• Üçgenler (drawTriangles() yöntemi ile oluşturulan)
• Opak arka plan
• scrollrect ayarları
• 2.5D dönüşümleri
• Görünmeyen nesneler (visible özelliği false olan nesneler)

Parametreler

İlgili API Öğeleri

package
{
    import flash.display.GraphicsPathCommand;
    import flash.display.IGraphicsData;
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    
    public class ReadGraphicsDataExample extends Sprite
    {
        private var original:Shape;
        private var copy:Shape;
        
        public function ReadGraphicsDataExample()
        {
            original = new Shape();
            original.x = 50;
            original.y = 100;
            addChild(original);
            
            drawSquare();
            
            copy = new Shape();
            copy.x = 250;
            copy.y = 100;
            addChild(copy);
            
            stage.addEventListener(MouseEvent.CLICK, drawCopyOnClick);
        }
        
        private function drawCopyOnClick(event:MouseEvent):void
        {
            // reset
            copy.graphics.clear();
            
            // Sample the vector data. Move the original to 0,0
            // before sampling so that the coordinates match the 
            // relative coordinates of the original.
            var xPos:Number = original.x;
            var yPos:Number = original.y;
            original.x = 0;
            original.y = 0;
            var result:Vector.<IGraphicsData> = original.graphics.readGraphicsData(false);
            original.x = xPos;
            original.y = yPos;
            
            // re-draw
            copy.graphics.drawGraphicsData(result);
        }
        
        private function drawSquare():void
        {
            var squareCommands:Vector.<int> = new Vector.<int>(5, true);
            
            squareCommands[0] = GraphicsPathCommand.MOVE_TO;
            squareCommands[1] = GraphicsPathCommand.LINE_TO;
            squareCommands[2] = GraphicsPathCommand.LINE_TO;
            squareCommands[3] = GraphicsPathCommand.LINE_TO;
            
            var squareCoordinates:Vector.<Number> = new Vector.<Number>(8, true);
            squareCoordinates[0] = 0;
            squareCoordinates[1] = 0; 
            squareCoordinates[2] = 50; 
            squareCoordinates[3] = 0; 
            squareCoordinates[4] = 50; 
            squareCoordinates[5] = 50; 
            squareCoordinates[6] = 0; 
            squareCoordinates[7] = 50; 
            
            original.graphics.beginFill(0x003366);
            original.graphics.drawPath(squareCommands, squareCoordinates);
        }
    }
}

1. Her şeklin boyutunu belirlerken ileride kullanmak üzere size özelliğini bildirin.
2. Arka plan rengini turuncu, kenarlık rengini koyu gri, kenarlık boyutunu 0 piksel, köşe yarıçapını 9 piksel ve sahne kenarı ile diğer nesneler arasındaki alanı 5 piksel olarak ayarlayan özellikleri bildirin.
3. x = 0, y = 0 koordinatlarında daire, yuvarlak köşeli dikdörtgen ve kare çizmek için Graphics sınıfının yerleşik yöntemlerinin yanı sıra önceki adımlarda bildirilen özellikleri de kullanın.
4. Şekiller arasında 5 piksel boşluk bırakarak, x = 5, y = 5 koordinatlarından başlayıp sahnenin üst kenarı boyunca şekillerin her birini yeniden çizin.

package {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class GraphicsExample extends Sprite {
        private var size:uint         = 80;
        private var bgColor:uint      = 0xFFCC00;
        private var borderColor:uint  = 0x666666;
        private var borderSize:uint   = 0;
        private var cornerRadius:uint = 9;
        private var gutter:uint       = 5;

        public function GraphicsExample() {
            doDrawCircle();
            doDrawRoundRect();
            doDrawRect();
            refreshLayout();
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = gutter;
            lastChild.y = gutter;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = gutter;
                lastChild = child;
            }
        }

        private function doDrawCircle():void {
            var child:Shape = new Shape();
            var halfSize:uint = Math.round(size / 2);
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawCircle(halfSize, halfSize, halfSize);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRoundRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRoundRect(0, 0, size, size, cornerRadius);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRect(0, 0, size, size);
            child.graphics.endFill();
            addChild(child);
        }
    }
}