Adobe® Flash® Platform için ActionScript® 3.0 Başvurusu
Ana Sayfa  |  Paket ve Sınıf Listesini Gizle |  Paketler  |  Sınıflar  |  Yenilikler  |  Dizin  |  Ekler  |  Niçin İngilizce?
Filtreler: AIR 30.0 ve öncesi, Flash Player 30.0 ve öncesi, Flash Lite 4
Flex 4.6 ve öncesi, Flash Pro CS6 ve öncesi
Filtreleri Gizle
flash.geom 

Matrix  - AS3

Paketlerx

Üst Düzey
adobe.utils
air.desktop
air.net
air.update
air.update.events
coldfusion.air
coldfusion.air.errors
coldfusion.air.events
coldfusion.service
coldfusion.service.events
coldfusion.service.mxml
com.adobe.acm.solutions.authoring.domain.extensions
com.adobe.acm.solutions.ccr.domain.extensions
com.adobe.consulting.pst.vo
com.adobe.dct.component
com.adobe.dct.component.datadictionary
com.adobe.dct.component.datadictionaryElement
com.adobe.dct.component.dataElementsPanel
com.adobe.dct.component.toolbars
com.adobe.dct.event
com.adobe.dct.exp
com.adobe.dct.model
com.adobe.dct.service
com.adobe.dct.service.provider
com.adobe.dct.transfer
com.adobe.dct.util
com.adobe.dct.view
com.adobe.ep.taskmanagement.domain
com.adobe.ep.taskmanagement.event
com.adobe.ep.taskmanagement.filter
com.adobe.ep.taskmanagement.services
com.adobe.ep.taskmanagement.util
com.adobe.ep.ux.attachmentlist.component
com.adobe.ep.ux.attachmentlist.domain
com.adobe.ep.ux.attachmentlist.domain.events
com.adobe.ep.ux.attachmentlist.domain.renderers
com.adobe.ep.ux.attachmentlist.skin
com.adobe.ep.ux.attachmentlist.skin.renderers
com.adobe.ep.ux.content.event
com.adobe.ep.ux.content.factory
com.adobe.ep.ux.content.handlers
com.adobe.ep.ux.content.managers
com.adobe.ep.ux.content.model.asset
com.adobe.ep.ux.content.model.preview
com.adobe.ep.ux.content.model.relation
com.adobe.ep.ux.content.model.search
com.adobe.ep.ux.content.model.toolbar
com.adobe.ep.ux.content.search
com.adobe.ep.ux.content.services
com.adobe.ep.ux.content.services.load
com.adobe.ep.ux.content.services.permissions
com.adobe.ep.ux.content.services.preview
com.adobe.ep.ux.content.services.providers
com.adobe.ep.ux.content.services.query
com.adobe.ep.ux.content.services.relationships
com.adobe.ep.ux.content.services.search.lccontent
com.adobe.ep.ux.content.services.version
com.adobe.ep.ux.content.view
com.adobe.ep.ux.content.view.components.activate
com.adobe.ep.ux.content.view.components.grid
com.adobe.ep.ux.content.view.components.grid.hover
com.adobe.ep.ux.content.view.components.grid.hover.component
com.adobe.ep.ux.content.view.components.grid.renderers
com.adobe.ep.ux.content.view.components.relationships
com.adobe.ep.ux.content.view.components.review
com.adobe.ep.ux.content.view.components.search.renderers
com.adobe.ep.ux.content.view.components.searchpod
com.adobe.ep.ux.content.view.components.toolbar
com.adobe.ep.ux.content.view.components.toolbar.controlRenderers
com.adobe.ep.ux.content.view.components.version
com.adobe.ep.ux.documentsubmit.component
com.adobe.ep.ux.documentsubmit.domain
com.adobe.ep.ux.documentsubmit.skin
com.adobe.ep.ux.taskaction.component
com.adobe.ep.ux.taskaction.domain
com.adobe.ep.ux.taskaction.domain.events
com.adobe.ep.ux.taskaction.skin
com.adobe.ep.ux.taskdetails.component
com.adobe.ep.ux.taskdetails.domain
com.adobe.ep.ux.taskdetails.skin
com.adobe.ep.ux.tasklist.component
com.adobe.ep.ux.tasklist.domain
com.adobe.ep.ux.tasklist.skin
com.adobe.ep.ux.webdocumentviewer.domain
com.adobe.exm.expression
com.adobe.exm.expression.error
com.adobe.exm.expression.event
com.adobe.exm.expression.impl
com.adobe.fiber.runtime.lib
com.adobe.fiber.services
com.adobe.fiber.services.wrapper
com.adobe.fiber.styles
com.adobe.fiber.util
com.adobe.fiber.valueobjects
com.adobe.gravity.binding
com.adobe.gravity.context
com.adobe.gravity.flex.bundleloader
com.adobe.gravity.flex.progress
com.adobe.gravity.flex.serviceloader
com.adobe.gravity.framework
com.adobe.gravity.init
com.adobe.gravity.service.bundleloader
com.adobe.gravity.service.logging
com.adobe.gravity.service.manifest
com.adobe.gravity.service.progress
com.adobe.gravity.tracker
com.adobe.gravity.ui
com.adobe.gravity.utility
com.adobe.gravity.utility.async
com.adobe.gravity.utility.error
com.adobe.gravity.utility.events
com.adobe.gravity.utility.factory
com.adobe.gravity.utility.flex.async
com.adobe.gravity.utility.logging
com.adobe.gravity.utility.message
com.adobe.gravity.utility.sequence
com.adobe.gravity.utility.url
com.adobe.guides.control
com.adobe.guides.domain
com.adobe.guides.i18n
com.adobe.guides.spark.components.skins
com.adobe.guides.spark.components.skins.mx
com.adobe.guides.spark.headers.components
com.adobe.guides.spark.headers.skins
com.adobe.guides.spark.layouts.components
com.adobe.guides.spark.layouts.skins
com.adobe.guides.spark.navigators.components
com.adobe.guides.spark.navigators.renderers
com.adobe.guides.spark.navigators.skins
com.adobe.guides.spark.util
com.adobe.guides.spark.wrappers.components
com.adobe.guides.spark.wrappers.skins
com.adobe.guides.submit
com.adobe.icc.dc.domain
com.adobe.icc.dc.domain.factory
com.adobe.icc.editors.events
com.adobe.icc.editors.handlers
com.adobe.icc.editors.managers
com.adobe.icc.editors.model
com.adobe.icc.editors.model.config
com.adobe.icc.editors.model.el
com.adobe.icc.editors.model.el.operands
com.adobe.icc.editors.model.el.operators
com.adobe.icc.enum
com.adobe.icc.external.dc
com.adobe.icc.obj
com.adobe.icc.services
com.adobe.icc.services.category
com.adobe.icc.services.config
com.adobe.icc.services.download
com.adobe.icc.services.export
com.adobe.icc.services.external
com.adobe.icc.services.formbridge
com.adobe.icc.services.fragmentlayout
com.adobe.icc.services.layout
com.adobe.icc.services.letter
com.adobe.icc.services.locator
com.adobe.icc.services.module
com.adobe.icc.services.render
com.adobe.icc.services.submit
com.adobe.icc.services.user
com.adobe.icc.token
com.adobe.icc.vo
com.adobe.icc.vo.render
com.adobe.icomm.assetplacement.controller
com.adobe.icomm.assetplacement.controller.utils
com.adobe.icomm.assetplacement.data
com.adobe.icomm.assetplacement.model
com.adobe.livecycle.assetmanager.client
com.adobe.livecycle.assetmanager.client.event
com.adobe.livecycle.assetmanager.client.handler
com.adobe.livecycle.assetmanager.client.managers
com.adobe.livecycle.assetmanager.client.model
com.adobe.livecycle.assetmanager.client.model.cms
com.adobe.livecycle.assetmanager.client.service
com.adobe.livecycle.assetmanager.client.service.search
com.adobe.livecycle.assetmanager.client.service.search.cms
com.adobe.livecycle.assetmanager.client.utils
com.adobe.livecycle.content
com.adobe.livecycle.rca.model
com.adobe.livecycle.rca.model.constant
com.adobe.livecycle.rca.model.document
com.adobe.livecycle.rca.model.participant
com.adobe.livecycle.rca.model.reminder
com.adobe.livecycle.rca.model.stage
com.adobe.livecycle.rca.service
com.adobe.livecycle.rca.service.core
com.adobe.livecycle.rca.service.core.delegate
com.adobe.livecycle.rca.service.process
com.adobe.livecycle.rca.service.process.delegate
com.adobe.livecycle.rca.token
com.adobe.livecycle.ria.security.api
com.adobe.livecycle.ria.security.service
com.adobe.mosaic.layouts
com.adobe.mosaic.layouts.dragAndDrop
com.adobe.mosaic.layouts.interfaces
com.adobe.mosaic.mxml
com.adobe.mosaic.om.constants
com.adobe.mosaic.om.events
com.adobe.mosaic.om.impl
com.adobe.mosaic.om.interfaces
com.adobe.mosaic.skinning
com.adobe.mosaic.sparklib.editors
com.adobe.mosaic.sparklib.optionMenu
com.adobe.mosaic.sparklib.scrollableMenu
com.adobe.mosaic.sparklib.scrollableMenu.skins
com.adobe.mosaic.sparklib.tabLayout
com.adobe.mosaic.sparklib.tabLayout.events
com.adobe.mosaic.sparklib.tabLayout.layouts
com.adobe.mosaic.sparklib.tabLayout.skins
com.adobe.mosaic.sparklib.text
com.adobe.mosaic.sparklib.util
com.adobe.solutions.acm.authoring.presentation
com.adobe.solutions.acm.authoring.presentation.actionbar
com.adobe.solutions.acm.authoring.presentation.common
com.adobe.solutions.acm.authoring.presentation.events
com.adobe.solutions.acm.authoring.presentation.fragment
com.adobe.solutions.acm.authoring.presentation.letter
com.adobe.solutions.acm.authoring.presentation.letter.data
com.adobe.solutions.acm.authoring.presentation.preview
com.adobe.solutions.acm.authoring.presentation.rte
com.adobe.solutions.acm.ccr.presentation
com.adobe.solutions.acm.ccr.presentation.contentcapture
com.adobe.solutions.acm.ccr.presentation.contentcapture.events
com.adobe.solutions.acm.ccr.presentation.contentcapture.preview
com.adobe.solutions.acm.ccr.presentation.datacapture
com.adobe.solutions.acm.ccr.presentation.datacapture.renderers
com.adobe.solutions.acm.ccr.presentation.pdf
com.adobe.solutions.exm
com.adobe.solutions.exm.authoring
com.adobe.solutions.exm.authoring.components.controls
com.adobe.solutions.exm.authoring.components.toolbars
com.adobe.solutions.exm.authoring.domain
com.adobe.solutions.exm.authoring.domain.expression
com.adobe.solutions.exm.authoring.domain.impl
com.adobe.solutions.exm.authoring.domain.method
com.adobe.solutions.exm.authoring.domain.variable
com.adobe.solutions.exm.authoring.enum
com.adobe.solutions.exm.authoring.events
com.adobe.solutions.exm.authoring.model
com.adobe.solutions.exm.authoring.renderer
com.adobe.solutions.exm.authoring.view
com.adobe.solutions.exm.expression
com.adobe.solutions.exm.impl
com.adobe.solutions.exm.impl.method
com.adobe.solutions.exm.method
com.adobe.solutions.exm.mock
com.adobe.solutions.exm.mock.method
com.adobe.solutions.exm.runtime
com.adobe.solutions.exm.runtime.impl
com.adobe.solutions.exm.variable
com.adobe.solutions.prm.constant
com.adobe.solutions.prm.domain
com.adobe.solutions.prm.domain.factory
com.adobe.solutions.prm.domain.impl
com.adobe.solutions.prm.domain.manager
com.adobe.solutions.prm.presentation.asset
com.adobe.solutions.prm.presentation.constant
com.adobe.solutions.prm.presentation.document
com.adobe.solutions.prm.presentation.event
com.adobe.solutions.prm.presentation.file
com.adobe.solutions.prm.presentation.project
com.adobe.solutions.prm.presentation.team
com.adobe.solutions.prm.presentation.util
com.adobe.solutions.prm.service
com.adobe.solutions.prm.services.impl
com.adobe.solutions.prm.vo
com.adobe.solutions.rca.constant
com.adobe.solutions.rca.domain
com.adobe.solutions.rca.domain.common
com.adobe.solutions.rca.domain.factory
com.adobe.solutions.rca.domain.impl
com.adobe.solutions.rca.domain.impl.manager
com.adobe.solutions.rca.domain.manager
com.adobe.solutions.rca.presentation
com.adobe.solutions.rca.presentation.comment
com.adobe.solutions.rca.presentation.constant
com.adobe.solutions.rca.presentation.event
com.adobe.solutions.rca.presentation.gantt
com.adobe.solutions.rca.presentation.gantt.ruler
com.adobe.solutions.rca.presentation.template
com.adobe.solutions.rca.presentation.template.audit
com.adobe.solutions.rca.presentation.template.definition
com.adobe.solutions.rca.presentation.template.documents
com.adobe.solutions.rca.presentation.template.stages
com.adobe.solutions.rca.presentation.util
com.adobe.solutions.rca.service
com.adobe.solutions.rca.services.impl
com.adobe.solutions.rca.vo
com.adobe.solutions.rca.vo.um
com.adobe.viewsource
fl.accessibility
fl.containers
fl.controls
fl.controls.dataGridClasses
fl.controls.listClasses
fl.controls.progressBarClasses
fl.core
fl.data
fl.display
fl.events
fl.ik
fl.lang
fl.livepreview
fl.managers
fl.motion
fl.motion.easing
fl.rsl
fl.text
fl.transitions
fl.transitions.easing
fl.video
flash.accessibility
flash.concurrent
flash.crypto
flash.data
flash.desktop
flash.display
flash.display3D
flash.display3D.textures
flash.errors
flash.events
flash.external
flash.filesystem
flash.filters
flash.geom
flash.globalization
flash.html
flash.media
flash.net
flash.net.dns
flash.net.drm
flash.notifications
flash.permissions
flash.printing
flash.profiler
flash.sampler
flash.security
flash.sensors
flash.system
flash.text
flash.text.engine
flash.text.ime
flash.ui
flash.utils
flash.xml
flashx.textLayout
flashx.textLayout.compose
flashx.textLayout.container
flashx.textLayout.conversion
flashx.textLayout.edit
flashx.textLayout.elements
flashx.textLayout.events
flashx.textLayout.factory
flashx.textLayout.formats
flashx.textLayout.operations
flashx.textLayout.utils
flashx.undo
ga.controls
ga.layouts
ga.model
ga.uiComponents
ga.util
ga.views
ga.wrappers
lc.foundation
lc.foundation.domain
lc.foundation.events
lc.foundation.ui
lc.foundation.util
lc.preloader
lc.procmgmt
lc.procmgmt.commands
lc.procmgmt.domain
lc.procmgmt.events
lc.procmgmt.formbridge
lc.procmgmt.impl
lc.procmgmt.ui.attachments
lc.procmgmt.ui.controls
lc.procmgmt.ui.controls.card
lc.procmgmt.ui.controls.renderer
lc.procmgmt.ui.help
lc.procmgmt.ui.layout
lc.procmgmt.ui.presentationmodel
lc.procmgmt.ui.process
lc.procmgmt.ui.search
lc.procmgmt.ui.startpoint
lc.procmgmt.ui.task
lc.procmgmt.ui.task.form
lc.procmgmt.ui.task.form.commands
lc.procmgmt.ui.tracking
mx.accessibility
mx.automation
mx.automation.air
mx.automation.delegates
mx.automation.delegates.advancedDataGrid
mx.automation.delegates.charts
mx.automation.delegates.containers
mx.automation.delegates.controls
mx.automation.delegates.controls.dataGridClasses
mx.automation.delegates.controls.fileSystemClasses
mx.automation.delegates.core
mx.automation.delegates.flashflexkit
mx.automation.events
mx.binding
mx.binding.utils
mx.charts
mx.charts.chartClasses
mx.charts.effects
mx.charts.effects.effectClasses
mx.charts.events
mx.charts.renderers
mx.charts.series
mx.charts.series.items
mx.charts.series.renderData
mx.charts.styles
mx.collections
mx.collections.errors
mx.containers
mx.containers.accordionClasses
mx.containers.dividedBoxClasses
mx.containers.errors
mx.containers.utilityClasses
mx.controls
mx.controls.advancedDataGridClasses
mx.controls.dataGridClasses
mx.controls.listClasses
mx.controls.menuClasses
mx.controls.olapDataGridClasses
mx.controls.scrollClasses
mx.controls.sliderClasses
mx.controls.textClasses
mx.controls.treeClasses
mx.controls.videoClasses
mx.core
mx.core.windowClasses
mx.data
mx.data.crypto
mx.data.errors
mx.data.events
mx.data.messages
mx.data.mxml
mx.data.offline.errors
mx.data.utils
mx.effects
mx.effects.easing
mx.effects.effectClasses
mx.events
mx.filters
mx.flash
mx.formatters
mx.geom
mx.graphics
mx.graphics.codec
mx.graphics.shaderClasses
mx.logging
mx.logging.errors
mx.logging.targets
mx.managers
mx.messaging
mx.messaging.channels
mx.messaging.config
mx.messaging.errors
mx.messaging.events
mx.messaging.management
mx.messaging.messages
mx.modules
mx.netmon
mx.olap
mx.olap.aggregators
mx.preloaders
mx.printing
mx.resources
mx.rpc
mx.rpc.events
mx.rpc.http
mx.rpc.http.mxml
mx.rpc.livecycle
mx.rpc.mxml
mx.rpc.remoting
mx.rpc.remoting.mxml
mx.rpc.soap
mx.rpc.soap.mxml
mx.rpc.wsdl
mx.rpc.xml
mx.skins
mx.skins.halo
mx.skins.spark
mx.skins.wireframe
mx.skins.wireframe.windowChrome
mx.states
mx.styles
mx.utils
mx.validators
org.osmf.containers
org.osmf.display
org.osmf.elements
org.osmf.events
org.osmf.layout
org.osmf.logging
org.osmf.media
org.osmf.metadata
org.osmf.net
org.osmf.net.dvr
org.osmf.net.httpstreaming
org.osmf.net.metrics
org.osmf.net.qos
org.osmf.net.rtmpstreaming
org.osmf.net.rules
org.osmf.traits
org.osmf.utils
spark.accessibility
spark.automation.delegates
spark.automation.delegates.components
spark.automation.delegates.components.gridClasses
spark.automation.delegates.components.mediaClasses
spark.automation.delegates.components.supportClasses
spark.automation.delegates.skins.spark
spark.automation.events
spark.collections
spark.components
spark.components.calendarClasses
spark.components.gridClasses
spark.components.mediaClasses
spark.components.supportClasses
spark.components.windowClasses
spark.core
spark.effects
spark.effects.animation
spark.effects.easing
spark.effects.interpolation
spark.effects.supportClasses
spark.events
spark.filters
spark.formatters
spark.formatters.supportClasses
spark.globalization
spark.globalization.supportClasses
spark.layouts
spark.layouts.supportClasses
spark.managers
spark.modules
spark.preloaders
spark.primitives
spark.primitives.supportClasses
spark.skins
spark.skins.mobile
spark.skins.mobile.supportClasses
spark.skins.spark
spark.skins.spark.mediaClasses.fullScreen
spark.skins.spark.mediaClasses.normal
spark.skins.spark.windowChrome
spark.skins.wireframe
spark.skins.wireframe.mediaClasses
spark.skins.wireframe.mediaClasses.fullScreen
spark.transitions
spark.utils
spark.validators
spark.validators.supportClasses
xd.core.axm.enterprise.view.components
xd.core.axm.enterprise.view.skins
xd.core.axm.view.components
xd.core.axm.view.components.support

Dil Öğeleri

Global Sabitler
Global İşlevler
Operatörler
İfadeler, Anahtar Kelimeler ve Direktifler
Özel Türler

Ekler

Yenilikler
Derleyici Hataları
Derleyici Uyarıları
Çalışma Zamanı Hataları
ActionScript 3'e Geçiş Yapma
Desteklenen Karakter Kümeleri
Yalnızca MXML Etiketleri
Motion XML Öğeleri
Timed Text Etiketleri
Onaylanmamış öğelerin listesi
Erişilebilirlik Uygulaması Sabitleri
ActionScript Örnekleri Nasıl Kullanılır?
Yasal uyarılar
Paketflash.geom
Sınıfpublic class Matrix
Miras AlmaMatrix Inheritance Object

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Matrix sınıfı bir koordinat alanından diğerine noktaların nasıl eşleneceğini belirleyen bir dönüştürme matrisini temsil eder. Bir Matrix nesnesinin özelliklerini ayarlayarak bir görüntüleme nesnesi üzerinde çeşitli grafik dönüşümler gerçekleştirebilirsiniz. Bunu yapmak için söz konusu Matrix nesnesini Transform nesnesinin matrix özelliğine uygulamanız ve ardından bu Transform nesnesini görüntüleme nesnesinin transform özelliği olarak uygulamanız gerekir. Bu dönüşüm işlevleri çevirmeyi (x ve y yeniden konumlandırması), döndürmeyi, ölçeklemeyi ve eğmeyi içerir.

Bu tür dönüşümlere toplu olarak afin dönüşümler adı verilir. Afin dönüşümler, paralel çizgilerin paralel kalmasını sağlayacak şekilde dönüşüm sırasında çizgilerin düzlüğünü korur.

Bir görüntüleme nesnesine dönüşüm matrisi uygulamak için, bir Transform nesnesi oluşturmanız, matrix özelliğini dönüşüm matrisine ayarlamanız ve ardından görüntüleme nesnesinin transform özelliğini Transform nesnesine ayarlamanız gerekir. Matrix nesneleri, şunları da içeren bazı yöntemlerin parametreleri olarak da kullanılır:

  • BitmapData nesnesinin draw() yöntemi
  • Graphics nesnesinin beginBitmapFill() yöntemi, beginGradientFill() yöntemi veya lineGradientStyle() yöntemi

Bir dönüşüm matris nesnesi, şunları içeren 3 x 3'lük bir matristir:

Matris notasyonundaki Matrix sınıfı özellikleri

Geleneksel dönüşüm matrislerinde, u, v ve w özellikleri ek yetenekler sağlar. Matrix sınıfı yalnızca iki boyutlu alanda çalışabilir, bu nedenle u ve v özellik değerlerinin 0,0 olduğunu ve w özellik değerinin 1,0 olduğunu varsayar. Matrisin etkili değerleri şunlardır:

Matris notasyonunda u, v ve w için varsayılan değerleri gösteren Matrix sınıfı özellikleri

Matrix nesnesindeki diğer altı özelliğin tümünün değerlerini alabilir ve ayarlayabilirsiniz: a, b, c, d, tx ve ty.

Matrix sınıfı dört ana dönüşüm türünü destekler: çevirme, ölçekleme, döndürme ve eğme. Bu dönüşümlerin üçünü, şu tabloda açıklandığı gibi özel yöntemler kullanarak ayarlayabilirsiniz:

DönüşümYöntemMatris değerleriGörüntülenen sonuçAçıklama
Çevirme (yer değiştirme) translate(tx, ty) Translate yöntemi parametrelerinin matris notasyonu Translate yöntemi efektlerinin şekli Görüntüyü sağa doğru tx piksel, aşağı doğru ty piksel taşır.
Ölçekleme scale(sx, sy) Scale yöntemi parametrelerinin matris notasyonu Scale yöntemi efektlerinin şekli Her pikselin konumunu x ekseni üzerinde sx ile, y ekseni üzerinde sy ile çarparak görüntüyü yeniden boyutlandırır.
Dönüş rotate(q) Rotate yöntemi parametrelerinin matris notasyonu Rotate yöntemi efektlerinin şekli Görüntüyü radyan olarak ölçülen bir açı q değeriyle döndürür.
Eğme veya makaslama Yok; b ve c özellikleri ayarlanmalı skew işlevi özelliklerinin matris notasyonu skew işlevi efektlerinin şekli Görüntüyü x veya y eksenine paralel doğrultuda aşamalı olarak kaydırır. Matrix nesnesinin b özelliği, y ekseni boyunca uzanan eğim açısının tanjantını temsil eder. Matrix nesnesinin c özelliği x ekseni boyunca uzanan eğme açısı tanjantını temsil eder.

Her dönüşüm işlevi geçerli matris özelliklerini, birden çok dönüşümü etkin şekilde birleştirmenize olanak tanıyacak biçimde değiştirir. Bunu yapmak için, matrisi görüntüleme nesnesi hedefine uygulamadan önce birden çok dönüşüm işlevi çağırmanız gerekir (söz konusu görüntüleme nesnesinin transform özelliğini kullanarak).

Matrix nesnesinin yöntemlerini çağırabilmek için Matrix nesnesi oluşturmak üzere new Matrix() yapıcısını kullanın.

Örnekleri görüntüle

İlgili API Öğeleri



Genel Özellikler
 ÖzellikTanımlayan:
  a : Number
Görüntüyü ölçeklerken veya döndürürken piksellerin x ekseni boyunca konumlandırmasını etkileyen değer.
Matrix
  b : Number
Görüntüyü döndürürken veya eğerken piksellerin y ekseni boyunca konumlandırmasını etkileyen değer.
Matrix
  c : Number
Görüntüyü döndürürken veya eğerken piksellerin x ekseni boyunca konumlandırmasını etkileyen değer.
Matrix
 Inheritedconstructor : Object
Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.
Object
  d : Number
Görüntüyü ölçeklerken veya döndürürken piksellerin y ekseni boyunca konumlandırmasını etkileyen değer.
Matrix
  tx : Number
Her noktanın x ekseni boyunca çevrileceği mesafe.
Matrix
  ty : Number
Her noktanın y ekseni boyunca çevrileceği mesafe.
Matrix
Genel Yöntemler
 YöntemTanımlayan:
  
Matrix(a:Number = 1, b:Number = 0, c:Number = 0, d:Number = 1, tx:Number = 0, ty:Number = 0)
Belirtilen parametrelerle yeni bir Matrix nesnesi oluşturur.
Matrix
  
İçerilen nesnenin tam kopyasıyla bu matrisin bir klonu olan yeni bir Matrix nesnesi döndürür.
Matrix
  
Geometrik efektlerini etkili bir şekilde bir araya getirerek bir matrisi ve geçerli matrisi birleştirir.
Matrix
  
copyColumnFrom(column:uint, vector3D:Vector3D):void
Çağrı yapan Matrix3D nesnesinin belirli sütununa bir Vector3D nesnesi kopyalar.
Matrix
  
copyColumnTo(column:uint, vector3D:Vector3D):void
Çağrı yapan Matrix nesnesinin belirli sütununu Vector3D nesnesine kopyalar.
Matrix
  
copyFrom(sourceMatrix:Matrix):void
Kaynak Point nesnesindeki tüm matris verisini çağrı yapan Matrix nesnesine kopyalar.
Matrix
  
copyRowFrom(row:uint, vector3D:Vector3D):void
Çağrı yapan Matrix nesnesinin belirli satırına bir Vector3D nesnesi kopyalar.
Matrix
  
copyRowTo(row:uint, vector3D:Vector3D):void
Çağrı yapan Matrix nesnesinin belirli satırını Vector3D nesnesine kopyalar.
Matrix
  
createBox(scaleX:Number, scaleY:Number, rotation:Number = 0, tx:Number = 0, ty:Number = 0):void
Ölçekleme, döndürme ve çevirme için parametreler içerir.
Matrix
  
createGradientBox(width:Number, height:Number, rotation:Number = 0, tx:Number = 0, ty:Number = 0):void
Graphics sınıfının beginGradientFill() ve lineGradientStyle() yöntemlerinin beklediği özel stilde bir matris oluşturur.
Matrix
  
Dönüştürme öncesi koordinat alanındaki belirli bir noktanın dönüştürme sonrasındaki koordinatlarını döndürür.
Matrix
 Inherited
Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.
Object
  
Her matris özelliğini boş bir dönüşüme neden olan bir değere ayarlar.
Matrix
  
Orijinal matrisin zıt dönüşümünü gerçekleştirir.
Matrix
 Inherited
Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.
Object
 Inherited
Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.
Object
  
Matrix nesnesine bir döndürme dönüşümü uygular.
Matrix
  
Matrise bir ölçekleme dönüşümü uygular.
Matrix
 Inherited
Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.
Object
  
setTo(aa:Number, ba:Number, ca:Number, da:Number, txa:Number, tya:Number):void
Matrix öğesinin üyelerini belirtilen değerlere ayarlar
Matrix
 Inherited
Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.
Object
  
Matrix nesnesinin özelliklerini listeleyen metin değerini döndürür.
Matrix
  
Matrix nesnesinin temsil ettiği geometrik dönüşümün belirtilen noktaya uygulanmasıyla elde edilen sonucu döndürür.
Matrix
  
Matrisi, dx ve dy parametreleri tarafından belirtildiği gibi x ve y eksenleri boyunca çevirir.
Matrix
 Inherited
Belirtilen nesnenin temel değerini döndürür.
Object
Özellik Ayrıntısı

a

özellik
public var a:Number

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Görüntüyü ölçeklerken veya döndürürken piksellerin x ekseni boyunca konumlandırmasını etkileyen değer.


Örnek  ( Bu örnek nasıl kullanılır? )
Şu örnekte, myMatrix Matrix nesnesi oluşturulmakta ve a değeri ayarlanmaktadır.
import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.a);  // 1

myMatrix.a = 2;
trace(myMatrix.a);  // 2

b

özellik 
public var b:Number

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Görüntüyü döndürürken veya eğerken piksellerin y ekseni boyunca konumlandırmasını etkileyen değer.


Örnek  ( Bu örnek nasıl kullanılır? )
Şu örnekte myMatrix Matrix nesnesi oluşturulmakta ve b değeri ayarlanmaktadır.
import flash.geom.Matrix;
 
var myMatrix:Matrix = new Matrix();
trace(myMatrix.b);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.b = Math.tan(radians);
trace(myMatrix.b);  // 0.5773502691896257

c

özellik 
public var c:Number

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Görüntüyü döndürürken veya eğerken piksellerin x ekseni boyunca konumlandırmasını etkileyen değer.


Örnek  ( Bu örnek nasıl kullanılır? )
Şu örnekte, myMatrix Matrix nesnesi oluşturulmakta ve c değeri ayarlanmaktadır.
import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.c);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.c = Math.tan(radians);
trace(myMatrix.c);  // 0.5773502691896257

d

özellik 
public var d:Number

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Görüntüyü ölçeklerken veya döndürürken piksellerin y ekseni boyunca konumlandırmasını etkileyen değer.


Örnek  ( Bu örnek nasıl kullanılır? )
Şu örnekte, myMatrix Matrix nesnesi oluşturulmakta ve d değeri ayarlanmaktadır.
import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.d);  // 1

myMatrix.d = 2;
trace(myMatrix.d);  // 2

tx

özellik 
public var tx:Number

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Her noktanın x ekseni boyunca çevrileceği mesafe.


Örnek  ( Bu örnek nasıl kullanılır? )
Şu örnekte, myMatrix Matrix nesnesi oluşturulmakta ve tx değeri ayarlanmaktadır.
import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.tx);  // 0

myMatrix.tx = 50;  // 50
trace(myMatrix.tx);

ty

özellik 
public var ty:Number

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Her noktanın y ekseni boyunca çevrileceği mesafe.


Örnek  ( Bu örnek nasıl kullanılır? )
Şu örnekte, myMatrix Matrix nesnesi oluşturulmakta ve ty değeri ayarlanmaktadır.
import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.ty);  // 0

myMatrix.ty = 50;
trace(myMatrix.ty);  // 50
Yapıcı Ayrıntı

Matrix

()Yapıcı
public function Matrix(a:Number = 1, b:Number = 0, c:Number = 0, d:Number = 1, tx:Number = 0, ty:Number = 0)

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Belirtilen parametrelerle yeni bir Matrix nesnesi oluşturur. Matris notasyonunda özellikler şu şekilde organize edilir:

Matris notasyonunda u, v ve w için varsayılan değerleri gösteren Matrix sınıfı özellikleri

new Matrix() yapıcısına hiçbir parametre sağlamazsanız, yapıcı şu değerlerle bir kimlik matrisi oluşturur:

a = 1
b = 0
c = 0
d = 1
tx = 0
ty = 0

Matris notasyonunda kimlik matrisi şu şekilde görünür:

Matris notasyonundaki Matrix sınıfı özellikleri

Parametreler
a:Number (default = 1) — Görüntüyü ölçeklerken veya döndürürken piksellerin x ekseni boyunca konumlandırmasını etkileyen değer.
 
b:Number (default = 0) — Görüntüyü döndürürken veya eğerken piksellerin y ekseni boyunca konumlandırmasını etkileyen değer.
 
c:Number (default = 0) — Görüntüyü döndürürken veya eğerken piksellerin x ekseni boyunca konumlandırmasını etkileyen değer.
 
d:Number (default = 1) — Görüntüyü ölçeklerken veya döndürürken piksellerin y ekseni boyunca konumlandırmasını etkileyen değer.
 
tx:Number (default = 0) — Her noktanın x ekseni boyunca çevrileceği mesafe.
 
ty:Number (default = 0) — Her noktanın y ekseni boyunca çevrileceği mesafe.

Örnek  ( Bu örnek nasıl kullanılır? )

Şu örnek, Matrix() yapıcısına hiçbir parametre göndermeden matris_1 öğesini, parametre göndererek matris_2 öğesini oluşturur. Parametre kullanılmadan oluşturulan matris_1 öğesinin, a=1, b=0, c=0, d=1, tx=0, ty=0 değerlerine sahip bir kimlik matrisi sonucunu verdiğine dikkat edin.
import flash.geom.Matrix;

var matrix_1:Matrix = new Matrix();
trace(matrix_1);  // (a=1, b=0, c=0, d=1, tx=0, ty=0)

var matrix_2:Matrix = new Matrix(1, 2, 3, 4, 5, 6);
trace(matrix_2);  // (a=1, b=2, c=3, d=4, tx=5, ty=6)
Yöntem Ayrıntısı

clone

()yöntem
public function clone():Matrix

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

İçerilen nesnenin tam kopyasıyla bu matrisin bir klonu olan yeni bir Matrix nesnesi döndürür.

Döndürür
Matrix — Bir Matrix nesnesi.

concat

()yöntem 
public function concat(m:Matrix):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Geometrik efektlerini etkili bir şekilde bir araya getirerek bir matrisi ve geçerli matrisi birleştirir. Matematiksel olarak, iki matrisin birleştirilmesi matris çarpımı kullanılarak birleştirilmesiyle aynıdır.

Örneğin, matris m1 bir nesneyi dördün katlarıyla ölçeklerse ve matris m2 bir nesneyi 1,5707963267949 radyanıyla döndürürse (Math.PI/2); bu durumda m1.concat(m2), m1 öğesini bir nesneyi dördün katlarıyla ölçekleyen bir matrise dönüştürür ve nesneyi Math.PI/2 radyanıyla döndürür.

Bu yöntem kaynak matrisi birleştirilmiş matrisle değiştirir. İki kaynak matristen herhangi birini değiştirmeden iki matrisi birleştirmek istiyorsanız, Sınıf Örnekleri bölümünde gösterildiği şekilde ilk olarak clone() yöntemini kullanarak kaynak matrisi kopyalayın.

Parametreler

m:Matrix — Kaynak matris ile birleştirilecek olan matris.

copyColumnFrom

()yöntem 
public function copyColumnFrom(column:uint, vector3D:Vector3D):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: Flash Player 11, AIR 3.0, Flash Lite 4

Çağrı yapan Matrix3D nesnesinin belirli sütununa bir Vector3D nesnesi kopyalar.

Parametreler

column:uint — Verilerin kopyalanacağı kaynak sütun.
 
vector3D:Vector3D — Verinin kopyalanacağı kaynak Vector3D nesnesi.

copyColumnTo

()yöntem 
public function copyColumnTo(column:uint, vector3D:Vector3D):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: Flash Player 11, AIR 3.0, Flash Lite 4

Çağrı yapan Matrix nesnesinin belirli sütununu Vector3D nesnesine kopyalar. Vector3D nesnesini w öğesi değiştirilmez.

Parametreler

column:uint — Verilerin kopyalanacağı kaynak sütun.
 
vector3D:Vector3D — Verinin kopyalanacağı kaynak Vector3D nesnesi.

copyFrom

()yöntem 
public function copyFrom(sourceMatrix:Matrix):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: Flash Player 11, AIR 3.0, Flash Lite 4

Kaynak Point nesnesindeki tüm matris verisini çağrı yapan Matrix nesnesine kopyalar.

Parametreler

sourceMatrix:Matrix — Verilerin kopyalanacağı kaynak Matrix nesnesi.

copyRowFrom

()yöntem 
public function copyRowFrom(row:uint, vector3D:Vector3D):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: Flash Player 11, AIR 3.0, Flash Lite 4

Çağrı yapan Matrix nesnesinin belirli satırına bir Vector3D nesnesi kopyalar.

Parametreler

row:uint — Verilerin kopyalanacağı kaynak satır.
 
vector3D:Vector3D — Verinin kopyalanacağı kaynak Vector3D nesnesi.

copyRowTo

()yöntem 
public function copyRowTo(row:uint, vector3D:Vector3D):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: Flash Player 11, AIR 3.0, Flash Lite 4

Çağrı yapan Matrix nesnesinin belirli satırını Vector3D nesnesine kopyalar. Vector3D nesnesini w öğesi değiştirilmez.

Parametreler

row:uint — Verilerin kopyalanacağı kaynak satır.
 
vector3D:Vector3D — Verinin kopyalanacağı kaynak Vector3D nesnesi.

createBox

()yöntem 
public function createBox(scaleX:Number, scaleY:Number, rotation:Number = 0, tx:Number = 0, ty:Number = 0):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Ölçekleme, döndürme ve çevirme için parametreler içerir. Bir matrise uygulandığında, matrisin değerlerini söz konusu parametreleri temel alarak ayarlar.

createBox() yönteminin kullanılması, identity(), rotate(), scale() ve translate() yöntemlerinin art arda uygulanmasıyla aynı matrisin elde edilmesine olanak tanır. Örneğin, mat1.createBox(2,2, Math.PI/4, 100, 100) ile şunun sonucu aynıdır:

     import flash.geom.Matrix;
     
     var mat1:Matrix = new Matrix();
     mat1.identity();
     mat1.rotate(Math.PI/4);
     mat1.scale(2,2);
     mat1.translate(10,20);
     

Parametreler

scaleX:Number — Yatay ölçeklemede kullanılacak faktör.
 
scaleY:Number — Dikey ölçeklemede kullanılacak faktör.
 
rotation:Number (default = 0) — Radyan olarak, döndürülecek miktar.
 
tx:Number (default = 0)x ekseni boyunca sağa doğru çevrilecek (taşınacak) piksel sayısı.
 
ty:Number (default = 0)y ekseni boyunca aşağı doğru çevrilecek (taşınacak) piksel sayısı.

İlgili API Öğeleri


Örnek  ( Bu örnek nasıl kullanılır? )

Şu örnekte createBox() yöntemi çağrılarak myMatrix öğesinin x ölçeği, y ölçeği, x konumu ve y konumu ayarlanmaktadır.
package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_createBox extends Sprite
    {
        public function Matrix_createBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createBox(1, 2, Math.PI/4, 50, 100);
             trace(myMatrix.toString());  
             // (a=0.7071067811865476, b=1.414213562373095, c=-0.7071067811865475, 
             //  d=1.4142135623730951, tx=50, ty=100)
             
             var rectangleShape:Shape = createRectangle(20, 80, 0xFF0000);   
             addChild(rectangleShape);
              
             var rectangleTrans:Transform = new Transform(rectangleShape);
             rectangleTrans.matrix = myMatrix;
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

createGradientBox

()yöntem 
public function createGradientBox(width:Number, height:Number, rotation:Number = 0, tx:Number = 0, ty:Number = 0):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Graphics sınıfının beginGradientFill() ve lineGradientStyle() yöntemlerinin beklediği özel stilde bir matris oluşturur. Genişlik ve yükseklik bir scaleX/scaleY çiftine ölçeklenir ve tx/ty değerleri, genişlik ve yüksekliğin yarısı kadar kaydırılır.

Örneğin, aşağıdaki özelliklere sahip bir degrade olduğunu düşünelim:

  • GradientType.LINEAR
  • İki renk, yeşil ve mavi, oranlar dizisi [0, 255] olarak ayarlanmış durumda
  • SpreadMethod.PAD
  • InterpolationMethod.LINEAR_RGB

Aşağıdaki şekiller matrisin, createGradientBox() yöntemi farklı parametre ayarlarıyla kullanılarak tanımlandığı degradeleri gösterir:

createGradientBox() ayarlarıElde edilen degrade
width = 25;
     height = 25; 
     rotation = 0; 
     tx = 0; 
     ty = 0;
elde edilen doğrusal degrade
width = 25; 
     height = 25; 
     rotation = 0; 
     tx = 25; 
     ty = 0;
elde edilen doğrusal degrade
width = 50; 
     height = 50; 
     rotation = 0; 
     tx = 0; 
     ty = 0;
elde edilen doğrusal degrade
width = 50;
     height = 50; 
     rotation = Math.PI / 4; // 45 degrees
     tx = 0; 
     ty = 0;
elde edilen doğrusal degrade

Parametreler

width:Number — Degrade kutunun genişliği.
 
height:Number — Degrade kutunun yüksekliği.
 
rotation:Number (default = 0) — Radyan olarak, döndürülecek miktar.
 
tx:Number (default = 0) — Piksel olarak, x ekseni boyunca sağa doğru çevrilecek mesafe. Bu değer, width parametresinin yarısına denk gelen değer kadar kaydırılır.
 
ty:Number (default = 0) — Piksel olarak, y ekseni boyunca aşağı doğru çevrilecek mesafe. Bu değer, height parametresinin yarısına denk gelen değer kadar kaydırılır.

İlgili API Öğeleri


Örnek  ( Bu örnek nasıl kullanılır? )

Şu örnekte createBox() yöntemi çağrılarak myMatrix öğesinin x ölçeği, y ölçeği, x konumu ve y konumu ayarlanmaktadır.
package
{
    import flash.display.GradientType;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    
    public class Matrix_createGradientBox extends Sprite
    {
        public function Matrix_createGradientBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());          // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createGradientBox(200, 200, 0, 50, 50);
             trace(myMatrix.toString());          // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)
             
             var colors:Array = [0xFF0000, 0x0000FF];
             var alphas:Array = [100, 100];
             var ratios:Array = [0, 0xFF];
             
             this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
             this.graphics.drawRect(0, 0, 300, 200);
        }
    }
}

deltaTransformPoint

()yöntem 
public function deltaTransformPoint(point:Point):Point

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Dönüştürme öncesi koordinat alanındaki belirli bir noktanın dönüştürme sonrasındaki koordinatlarını döndürür. transformPoint() yöntemi kullanılarak uygulanan standart dönüşümün aksine deltaTransformPoint() yönteminin dönüşümü, tx ve ty çeviri parametrelerini göz önüne almaz.

Parametreler

point:Point — Matris dönüşümünün sonucunu almak istediğiniz nokta.

Döndürür
Point — Matris dönüşümünün uygulanmasıyla elde edilen nokta.

identity

()yöntem 
public function identity():void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Her matris özelliğini boş bir dönüşüme neden olan bir değere ayarlar. Kimlik matrisi uygulanarak dönüştürülen bir nesne, orijinal ile aynı olur.

identity() yöntemi çağrıldıktan sonra, elde edilen matris şu özelliklere sahip olur: a=1, b=0, c=0, d=1, tx=0, ty=0.

Matris notasyonunda kimlik matrisi şu şekilde görünür:

Matris notasyonundaki Matrix sınıfı özellikleri

invert

()yöntem 
public function invert():void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Orijinal matrisin zıt dönüşümünü gerçekleştirir. Orijinal matrisi uygularken gerçekleştirilen dönüşümü geri almak için bir nesneye ters çevrilmiş bir matris uygulayabilirsiniz.


Örnek  ( Bu örnek nasıl kullanılır? )

Şu örnekte, doubleScaleMatrix öğesinin invert() yöntemi çağrılarak bir halfScaleMatrix oluşturulmaktadır. Ardından noScaleMatrix öğesine eşit olan originalAndInverseMatrix öğesini oluşturarak; bu iki öğenin birbirinin Matrix tersi, başka bir deyişle diğeri tarafından gerçekleştirilen tüm dönüşümleri geri alan birer matris olduğunu gösterir.
package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_invert extends Sprite
    {
        public function Matrix_invert()
        {
            var rect0:Shape = createRectangle(20, 80, 0xFF0000);   
            var rect1:Shape = createRectangle(20, 80, 0x00FF00);   
            var rect2:Shape = createRectangle(20, 80, 0x0000FF);
            var rect3:Shape = createRectangle(20, 80, 0x000000);
            
            var trans0:Transform = new Transform(rect0);
            var trans1:Transform = new Transform(rect1);
            var trans2:Transform = new Transform(rect2);
            var trans3:Transform = new Transform(rect3);
             
            var doubleScaleMatrix:Matrix = new Matrix(2, 0, 0, 2, 0, 0);
            trans0.matrix = doubleScaleMatrix;
            trace(doubleScaleMatrix.toString());  // (a=2, b=0, c=0, d=2, tx=0, ty=0)
             
            var noScaleMatrix:Matrix = new Matrix(1, 0, 0, 1, 0, 0);
            trans1.matrix = noScaleMatrix;
            rect1.x = 50;
            trace(noScaleMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
            var halfScaleMatrix:Matrix = doubleScaleMatrix.clone();
            halfScaleMatrix.invert();
            trans2.matrix = halfScaleMatrix;
            rect2.x = 100;
            trace(halfScaleMatrix.toString());  // (a=0.5, b=0, c=0, d=0.5, tx=0, ty=0)
             
            var originalAndInverseMatrix:Matrix = doubleScaleMatrix.clone();
            originalAndInverseMatrix.concat(halfScaleMatrix);
            trans3.matrix = originalAndInverseMatrix;
            rect3.x = 150;
            trace(originalAndInverseMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)            
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

rotate

()yöntem 
public function rotate(angle:Number):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Matrix nesnesine bir döndürme dönüşümü uygular.

rotate() yöntemi, Matrix nesnesinin a, b, c ve d özelliklerini değiştirir. Matris notasyonunda bu, geçerli matrisi şununla birleştirmekle aynıdır:

Scale yöntemi parametrelerinin matris notasyonu

Parametreler

angle:Number — Radyan olarak, döndürme açısı.

scale

()yöntem 
public function scale(sx:Number, sy:Number):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Matrise bir ölçekleme dönüşümü uygular. x ekseni sx ile çarpılır ve y ekseni sy ile çarpılır.

scale() yöntemi, Matrix nesnesinin a ve d özelliklerini değiştirir. Matris notasyonunda bu, geçerli matrisi şu matrisle birleştirmekle aynıdır:

Scale yöntemi parametrelerinin matris notasyonu

Parametreler

sx:Number — Nesneyi x ekseni boyunca ölçeklemek için kullanılan bir çarpan.
 
sy:Number — Nesneyi y ekseni boyunca ölçeklemek için kullanılan bir çarpan.

setTo

()yöntem 
public function setTo(aa:Number, ba:Number, ca:Number, da:Number, txa:Number, tya:Number):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: Flash Player 11, AIR 3.0, Flash Lite 4

Matrix öğesinin üyelerini belirtilen değerlere ayarlar

Parametreler

aa:Number — matrisin ayarlanacağı değerler.
 
ba:Number
 
ca:Number
 
da:Number
 
txa:Number
 
tya:Number

toString

()yöntem 
public function toString():String

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Matrix nesnesinin özelliklerini listeleyen metin değerini döndürür.

Döndürür
String — Matrix nesnesinin özelliklerinin değerlerini içeren bir dize: a, b, c, d, tx ve ty.

transformPoint

()yöntem 
public function transformPoint(point:Point):Point

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Matrix nesnesinin temsil ettiği geometrik dönüşümün belirtilen noktaya uygulanmasıyla elde edilen sonucu döndürür.

Parametreler

point:Point — Matris dönüştürme işleminin sonucunu almak istediğiniz nokta.

Döndürür
Point — Matris dönüşümünün uygulanmasıyla elde edilen nokta.

translate

()yöntem 
public function translate(dx:Number, dy:Number):void

Dil Sürümü: ActionScript 3.0
Çalışma Zamanı Sürümleri: AIR 1.0, Flash Player 9, Flash Lite 4

Matrisi,dx ve dy parametreleri tarafından belirtildiği gibi x ve y eksenleri boyunca çevirir.

Parametreler

dx:Number — Piksel olarak, x ekseni boyunca sağa doğru hareket miktarı.
 
dy:Number — Piksel olarak, y ekseni boyunca aşağı doğru hareket miktarı.

MatrixExample.as

Şu örnek, bir degrade ile doldurulmuş karenin ne kadar büyük olduğunu göstermek için MatrixExample sınıfını kullanır. Bu işlem, aşağıdaki adımlar uygulanarak gerçekleştirilir:
  1. Uygulama yeni bir Matrix nesnesi myMatrix öğesi oluşturur ve myMatrix nesnesinin varsayılan özellik değerlerini vermek için trace() yöntemini kullanır.
  2. Uygulama, width ve height parametreleri 200 piksele ayarlanmış durumdayken, döndürme yokken ve x ile y eksenleri boyunca çevrilecek mesafe 50 piksele ayarlanmış durumdayken createGradientBox() öğesini çağırır.
  3. Uygulama, createGradientBox() öğesi çağrıldıktan sonraki değişikliği göstermek için myMatrix nesnesini yeniden yazdırır.
  4. Uygulama, degrade kutunun nasıl doldurulacağını kontrol etmek için üç değişken oluşturur:
    • renkler: Degrade renkleri düz kırmızı ve düz mavi arasında değişecek şekilde ayarlar.
    • alfalar: Opaklığı düze ayarlar.
    • oranlar: Renklerin dağılımını hem kırmızı hem mavi için eşit olacak şekilde ayarlar.
  5. Uygulama, myMatrixnesnesinde çalışan beginGradientFill() grafik yöntemini çağırır ve lineTo() yöntemini çağırır; bunun sonucu olarak degrade ile doldurulmuş kutu oluşturulur.
package {
    import flash.geom.Matrix;
    import flash.display.Sprite;
    import flash.display.GradientType;

    public class MatrixExample extends Sprite {

        public function MatrixExample() {
            var myMatrix:Matrix = new Matrix();
            trace(myMatrix.toString());    // (a=1, b=0, c=0, d=1, tx=0, ty=0)

            myMatrix.createGradientBox(200, 200, 0, 50, 50);
            trace(myMatrix.toString());    // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)

            var colors:Array = [0xFF0000, 0x0000FF];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 0xFF];
            graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
            graphics.lineTo(0, 300);
            graphics.lineTo(300, 300);
            graphics.lineTo(300, 0);
            graphics.lineTo(0, 0);
        }
    }
}




[ X ]Niçin İngilizce?
ActionScript 3.0 Başvurusu'ndaki içerik İngilizce görünür

ActionScript 3.0 Başvurusu'nun tüm bölümleri tüm dillere çevrilmemiştir. Bir dil öğesi çevrilmediğinde İngilizce görünür. Örneğin, ga.controls.HelpBox sınıfı hiçbir dile çevrilmez. Bu nedenle, başvurunun Türkçe versiyonunda ga.controls.HelpBox sınıfı İngilizce görünür.