MovieClip  - AS3

Oynatma kafasının MovieClip örneğinin zaman çizelgesinde bulunduğu karenin sayısını belirtir. Film klibinin birden çok karesi varsa, bu değer geçerli sahnedeki kare sayısıdır.

mc1.gotoAndStop(mc1.currentFrame + 5);

MoviClip örneğinin zaman çizelgesindeki geçerli karede bulunan etiket. Geçerli karede hiç etiket yoksa, currentLabel, null olur.

Oynatma kafasının MovieClip örneği zaman çizelgesinde bulunduğu geçerli etiket. Geçerli karenin etiketi yoksa, currentLabel öğesi, bir etiket içeren önceki karenin adına ayarlanır. Geçerli kare ve önceki kareler bir etiket içermiyorsa, currentLabel öğesi null değerini döndürür.

trace(mc1.currentLabel);

Geçerli sahneden bir FrameLabel nesneleri dizisi döndürür. MovieClip örneği sahneleri kullanmıyorsa, bu dizi MovieClip örneğinin tamamındaki tüm kare etiketlerini içerir.

İlgili API Öğeleri

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

Oynatma kafasının MovieClip örneğinin zaman çizelgesinde bulunduğu geçerli sahne.

İlgili API Öğeleri

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Bir film klibinin etkinleştirilip etkinleştirilmediğini gösteren Booelan değeri. enabled öğesinin varsayılan değeri true olur. enabled öğesi false değerine ayarlanırsa, film klibinin Over, Down ve Up kareleri devre dışı bırakılır. Film klibi olayları almaya devam eder (örneğin, mouseDown, mouseUp, keyDown ve keyUp).

enabled özelliği bir film klibinin yalnızca düğmeye benzer özelliklerini yönetir. enabled özelliğini istediğiniz zaman değiştirebilirsiniz; değiştirilen film klibi hemen etkinleştirilir veya devre dışı bırakılır. enabled öğesi false değerine ayarlanırsa, nesne otomatik sekme sıralamasına dahil edilmez.

mc1.enabled = false;

Bir SWF akış dosyasından yüklenen kare sayısı. Belirli bir karenin veya tüm karelerin içeriklerinin yüklenmeden önce tarayıcıda yerel olarak kullanılabilir olup olmayacağını belirlemek için framesLoaded özelliğini kullanabilirsiniz. Ayrıca büyük SWF dosyalarının indirilmesini izlemek için de bunu kullanabilirsiniz. Örneğin, SWF dosyasındaki belirtilen bir karenin yüklenmesi sona erinceye kadar SWF dosyasının yüklenmekte olduğunu belirten bir mesajı kullanıcılara görüntülemek isteyebilirsiniz.

Film klibinde birden çok sahne yer alıyorsa, framesLoaded özelliği, film klibindeki allsahneleri için yüklenen kare sayısını döndürür.

İlgili API Öğeleri

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Bir film klibinin geçerli olarak oynatılıp oynatılmadığını gösteren Boolean değeri.

Her biri, MovieClip örneğindeki bir sahnenin adını, kare sayısını ve kare etiketlerini listeleyen Scene nesnelerinin bir dizisi.

İlgili API Öğeleri

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

MovieClip örneğindeki toplam kare sayısı.

Film klibinde birden çok sahne yer alıyorsa, totalFrames özelliği, film klibindeki all sahnelerinin toplam kare sayısını döndürür.

 trace(mc1.totalFrames);

SimpleButton veya MovieClip nesneleri olan diğer görüntüleme nesnelerinin, fare bırakma olaylarını veya diğer kullanıcı girdisi bırakma olaylarını alıp alamadığını belirtir. trackAsMenu özelliği, menüler oluşturmanızı sağlar. Herhangi bir SimpleButton veya MovieClip nesnesinde trackAsMenu özelliğini ayarlayabilirsiniz. trackAsMenu özelliğinin varsayılan değeri false olur.

trackAsMenu özelliğini istediğiniz zaman değiştirebilirsiniz; değiştirilen film klibi hemen yeni davranışı kullanır.

 mc1.trackAsMenu = true;

Yeni bir MovieClip örneği oluşturur. MovieClip öğesini oluşturduktan sonra, sahne alanı üzerindeki bir görüntüleme nesnesi kabının addChild() veya addChildAt() yöntemini çağırır.

SWF dosyasını belirtilen karede oynatmaya başlar. Karedeki kalan tüm eylemlerin çalışması sona erdikten sonra bu gerçekleşir. Bir karenin yanı sıra bir sahne belirtmek üzere scene parametresi için bir değer belirtin.

Parametreler

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Oynatma kafasını film klibinin belirtilen karesine getirir ve orada durdurur. Karedeki kalan tüm eylemlerin çalışması sona erdikten sonra bu gerçekleşir. Kareye ek olarak bir sahne belirtmek isterseniz, bir scene parametresini belirtin.

Parametreler

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Oynatma kafasını bir sonraki kareye gönderir ve durdurur. Karedeki kalan tüm eylemlerin çalışması sona erdikten sonra bu gerçekleşir.

İlgili API Öğeleri

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Oynatma kafasını MovieClip örneğinin bir sonraki sahnesine taşır. Karedeki kalan tüm eylemlerin çalışması sona erdikten sonra bu gerçekleşir.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Oynatma kafasını film klibinin zaman çizelgesinde taşır.

İlgili API Öğeleri

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Oynatma kafasını bir önceki kareye gönderir ve durdurur. Karedeki kalan tüm eylemlerin çalışması sona erdikten sonra bu gerçekleşir.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Oynatma kafasını MovieClip örneğinin bir önceki sahnesine taşır. Karedeki kalan tüm eylemlerin çalışması sona erdikten sonra bu gerçekleşir.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Film klibindeki oynatma kafasını durdurur.

1. Yapıcı işlevi, MovieClipExample nesnesinin özelliklerinin değerlerini (MovieClip öğesini genişleten) görüntülemek için kullanılan metin alanını tanımlar.
2. getPropertiesString() yönteminin dönüş değeri, outputText metin alanının metni olarak kullanılır. getPropertiesString() yöntemi, film klibinin şu özelliklerinin değerleriyle doldurulmuş bir dize döndürür: currentFrame, currentLabel, currentScene, framesLoaded, totalFrames ve trackAsMenu.
3. Yapıcı işlevindeki iki kod satırı, outputText metin alanının width ve height özelliklerini ayarlar.
4. Yapıcı işlevinin son satırı, outputText metin alanını görüntüleme listesine ekler.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}