Loader  - AS3

load() veya loadBytes() yöntemleri kullanılarak yüklenmiş SWF dosyasının veya görüntü (JPG, PNG ya da GIF) dosyasının kök görüntüleme nesnesini içerir.

İlgili API Öğeleri

Yüklenmekte olan nesneye karşılık gelen bir LoaderInfo nesnesi döndürür. Loader nesnesi ile yüklenen content nesnesi arasında paylaşılan LoaderInfo nesneleri. LoaderInfo nesnesi, yükleme ilerleme bilgilerini ve yüklenen dosya hakkında istatistikleri sağlar.

Yüklemeyle ilgili olaylar, Loader nesnesinin contentLoaderInfo özelliğinin başvurduğu LoaderInfo nesnesi tarafından gönderilir. Yükleme öncesinde nesneye olay dinleyicileri ekleyebilmeniz için, içerik daha yüklenmeden önce contentLoaderInfo özelliği geçerli bir LoaderInfo nesnesine ayarlanır.

Yüklü bir SWF'de oluşan yakalanmamış hataları algılamak için, Loader.contentLoaderInfo.uncaughtErrorEvents özelliğine değil, Loader.uncaughtErrorEvents özelliğine bakın.

İlgili API Öğeleri

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

Bu Loader nesnesiyle yüklenen SWF'de işlenmemiş hata oluştuğunda bir uncaughtError olayı gönderen bir nesne. Herhangi bir try..catch bloğunun dışında bir hata atıldığında veya herhangi bir lisanslı dinleyiciye sahip olmayan bir ErrorEvent nesnesi gönderildiğinde yakalanmayan bir hata oluşur.

Bir Loader nesnesinin uncaughtErrorEvents özelliğinin onun doğrudan gönderdiği olayları değil, onun içinden köpüren olayları gönderdiğini unutmayın. O, hiç bir zaman hedef aşamasında bir uncaughtErrorEvent göndermez. Olayı yalnızca yakalama ve köpürme aşamalarında gönderir. Geçerli SWF'de bir yakalanmamış hata algılamak için (Loader nesnesinin içinde tanımlandığı SWF) LoaderInfo.uncaughtErrorEvents özelliğini kullanın.

Loader nesnesi tarafından yüklenen içerik AVM1 (ActionScript 2) SWF dosyası ise, AVM1 SWF dosyasındaki yakalanmayan hatalar uncaughtError olayına sebep olmaz.

İlgili API Öğeleri

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

SWF, JPEG, GIF veya PNG gibi dosyaları yüklemek için kullanabileceğiniz bir Loader nesnesi oluşturur. Loader örneğinin bir alt öğesi olarak varlığı yüklemek için load() yöntemini çağırın. Daha sonra Loader nesnesini görüntüleme listesine ekleyebilirsiniz (örneğin, bir DisplayObjectContainer örneğinin addChild() yöntemini kullanarak). Varlık yüklendiğinde Sahne Alanı üzerinde görüntülenir.

Bir Loader örneğini görüntüleme listesindeki bir görüntüleme nesnesi kabına eklemeden de "liste dışı" şekilde kullanabilirsiniz. Bu modda, bir uygulamanın ek modüllerini içeren bir SWF dosyasını yüklemek için Loader örneği kullanılabilir.

SWF dosyasının yüklemeyi bitirdiği zamanı algılamak için, LoaderInfo nesnesinin, Loader nesnesinin contentLoaderInfo özelliğiyle ilişkili olaylarını kullanabilirsiniz. Bu noktada, SWF dosyasındaki modülde bulunan kod, modülü başlatmak için çalıştırılabilir. Liste dışı modunda, bileşenleri veya medya varlıklarını içeren bir SWF dosyasını yüklemek için bir Loader örneği de kullanılabilir. Tekrar, bileşenlerin yüklenmesinin bittiği zamanı algılamak için LoaderInfo nesnesinin olay bildirimlerini kullanabilirsiniz. Bu noktada uygulama, SWF dosyasının kütüphanesindeki bileşenleri ve medya varlıklarını temsil eden ActionScript 3.0 sınıflarını başlatıp bu bileşenleri ve varlıkları kullanarak başlatılabilir.

Bir Loader nesnesinin durumunu belirlemek için, LoaderInfo nesnesinin Loader nesnesinin contentLoaderInfo özelliğiyle ilişkilendirdiği şu olayları izleyin:

• Yükleme başladığında open olayı gönderilir.
• Dosya yüklenemezse veya yükleme işlemi sırasında bir hata oluşursa, ioError ya da securityError olayı gönderilir.
• Dosya yüklenirken sürekli olarak progress olayı tetiklenir.
• Bir dosyanın indirilmesi tamamlandığında, ancak yüklenen film klibinin yöntemleri ve özellikleri kullanılabilir duruma geçmeden önce complete olayı gönderilir.
• Yüklenen SWF dosyasının özellikleri ve yöntemleri erişilebilir olduktan sonra init olayı gönderilir, böylece yüklenen SWF dosyasını işleyebilirsiniz. complete işleyiciden önce bu olay gönderilir. SWF dosyalarının akışında, complete olayından çok önce init olayı oluşabilir. Birçok amaç için init işleyiciyi kullanın.

Notlar (yalnızca iOS): iOS'ta AIR uygulamalarında, uygulama paketinden yalnızca ActionScirpt içeren bir SWF dosyası yükleyebilirsiniz. Bu kısıtlamaya herhangi bir ActionScript dahildir (örn. ActionScript için dışa aktarılan sınıf adlarına sahip varlıklar gibi). Herhangi bir SWF dosyasını yüklemek için, ana SWF ile aynı uygulama etki alanını kullanan SWF'yi yüklemeniz gerekir.

AIR 3.6'dan önceki sürümlerde, uygulama paketinden ya da bir ağ üzerinden yüklendiğine bakılmaksızın, yalnızca ActionScript bayt kodu içermeyen SWF dosyaları yüklenebilir. ActionScript'e sahip harici bir SWF dosyasını kullanmaya alternatif olarak, bir SWC kütüphanesi oluşturun ve bunu ana SWF'nize bağlayın.

Bu kısıtlamalar, bir uygulama iOS Simulator'da (ipa-test-interpreter-simulator ya da ipa-debug-interpreter-simulator) veya yorumlayıcı modunda (ipa-test-interpreter ya da ipa-debug-interpreter) çalıştığında geçerli değildir.

İlgili API Öğeleri

Loader örneği için devam eden bir load() yöntemi işlemini iptal eder.

İlgili API Öğeleri

Bu Loader nesnesinin alt öğesi olan bir nesneye bir SWF, JPEG, aşamalı JPEG, animasyonsuz GIF veya PNG dosyası yükler. Animasyonlu bir GIF dosyası yüklerseniz, yalnızca birinci kare görüntülenir. Loader nesnesi yalnızca bir alt öğe içerebildiğinden, sonraki load() isteklerinin başlatılması, halen beklemedeyse bir önceki isteği sonlandırır ve yeni bir yükleme başlatır.

Not: AIR 1.5 ve Flash Player 10'da, yüklenen bir görüntü için maksimum boyut genişlik ve yükseklikte 8.191 pikseldir ve toplam piksel sayısı 16.777.215'i geçemez. (Bu nedenle, yüklenen bir görüntü 8.191 piksel genişliğindeyse en fazla 2.048 piksel yüksekliğinde olabilir.) Flash Player 9 ve önceki sürümleri ile AIR 1.1 ve önceki sürümlerinde, sınırlama yükseklikte 2.880 piksel ve genişlikte 2.880 pikseldir.

Loader nesnesine yüklenen bir SWF dosyası veya görüntü, Loader nesnesinin üst görüntüleme nesnelerinin position, rotation ve scale özelliklerini miras alır.

Bu yöntemle yüklenen filmleri veya görüntüleri kaldırmak ya da devam eden bir yükleme işlemini iptal etmek için unload() yöntemini kullanın.

SWF içeriğini barındıran HTML sayfasındaki object veembed etiketlerinin allowNetworking parametresini ayarlayarak bir SWF dosyasının bu yöntemi kullanmasını önleyebilirsiniz.

iOS notları

iOS'ta AIR uygulamalarında, uygulama paketinden yalnızca ActionScript içeren bir SWF dosyası yükleyebilirsiniz. Bu kısıtlamaya herhangi bir ActionScript dahildir (örn. ActionScript için dışa aktarılan sınıf adlarına sahip varlıklar gibi). Herhangi bir SWF dosyasını yüklemek için, ana SWF ile aynı uygulama etki alanını kullanan SWF'yi aşağıdaki örnekte gösterildiği gibi yüklemeniz gerekir:

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

Ayrıca iOS'ta, herhangi bir ActionScript ByteCode (ABC) içeren SWF dosyasını yükleyemez, ardından bunu kaldıramaz ve yeniden yükleyemezsiniz. Bunu yapmaya çalışırsanız çalışma zamanı 3764 hatasını verir.

AIR 3.6'dan önceki sürümlerde, uygulama paketinden ya da bir ağ üzerinden yüklendiğine bakılmaksızın, yalnızca ActionScript bayt kodu içermeyen SWF dosyaları yüklenebilir. ActionScript'e sahip harici bir SWF dosyasını kullanmaya alternatif olarak, bir SWC kütüphanesi oluşturun ve bunu ana SWF'nize bağlayın.

Bu kısıtlamalar, bir uygulama iOS Simulator'da (ipa-test-interpreter-simulator ya da ipa-debug-interpreter-simulator) veya yorumlayıcı modunda (ipa-test-interpreter ya da ipa-debug-interpreter) çalıştığında geçerli değildir.

Yükleyici güvenliği

Bu yöntemi kullanırken, Loader sınıfı açıklamasında açıklanan Flash Player güvenlik modelini aklınızda bulundurun.

Flash Player 10 ve sonrasında, yükleme (POST gövdesi içinde "content-disposition" başlığında "filename" parametresiyle belirtilir) içeren çok bölümlü bir Content-Type (örneğin, "multipart/form-data") kullanırsanız, POST işlemi, yüklemelere uygulanan güvenlik kurallarına tabidir:

• Fare tıklatma veya tuş basışı gibi kullanıcı tarafından başlatılan bir eyleme yanıt olarak POST işleminin gerçekleştirilmesi gerekir.
• POST işlemi etki alanları arasıysa (POST hedefi, POST isteğini gönderen SWF dosyasıyla aynı sunucuda değilse), hedef sunucunun etki alanları arası erişime izin veren bir URL ilke dosyası sağlaması gerekir.

Ayrıca çok bölümlü herhangi bir Content-Type için sözdiziminin geçerli olması gerekir (RFC2046 standardına göre). Sözdizimi geçersiz görünüyorsa, POST işlemi, yüklemelere uygulanan güvenlik kurallarına tabi olur.

Güvenlikle ilgili daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

Parametreler

İlgili API Öğeleri

Bir ByteArray nesnesinde saklanan ikili veriyi yükler.

loadBytes() yöntemi senkronize değildir. Yüklenmiş nesnenin özeliklerine ulaşmadan önce "init" olayını beklemeniz gerekir.

Bu yöntemi kullanırken, Loader sınıfı açıklamasında açıklanan Flash Player güvenlik modelini aklınızda bulundurun.

Not (yalnızca iOS): iOS'ta AIR uygulamalarında, uygulama paketinden yalnızca ActionScript içeren bir SWF dosyası yükleyebilirsiniz. Bu kısıtlamaya herhangi bir ActionScript dahildir (örn. ActionScript için dışa aktarılan sınıf adlarına sahip varlıklar gibi). Herhangi bir SWF dosyasını yüklemek için, ana SWF ile aynı uygulama etki alanını kullanan SWF'yi yüklemeniz gerekir.

AIR 3.6'dan önceki sürümlerde bu yöntemin çağrılmasının iOS üstünde bir etkisi yoktur.

Parametreler

İlgili API Öğeleri

Bir IFilePromise örneği yükler.

loadFilePromise yöntemi bir IFilePromise nesnesini alır ve ikili veriyi yükler. Veri video gibi aşamalı bir akışsa yüklenen nesnenin özelliklerine erişmeden önce "init" öğesini veya progress olaylarını bekleyin. Aksi takdirde, verinin tamamen yüklendiğinden emin olmak için complete olayını bekleyin.

Bu yöntemi kullanırken, Loader sınıfı açıklamasında açıklanan Flash Player güvenlik modelini aklınızda bulundurun.

Parametreler

İlgili API Öğeleri

Bu Loader nesnesinin load() yöntemi kullanılarak yüklenmiş bir alt öğesini kaldırır. İlişkilendirilmiş LoaderInfo nesnesinin property özelliği null değerine sıfırlanır. Diğer nesnelerin alt öğeye başvurusu olduğu için alt öğenin mutlaka yok edilmesi gerekmez; ancak bu artık Loader nesnesinin bir alt öğesi olmaz.

unload() yöntemini çağırdığınızda Loader nesnesinin contentLoaderInfo özelliği null olarak ayarlanır. SWF ile yüklenen görsel varlıklar kaldırılır ve bellekten silinir. Yüklü SWF'deki ActionScript sınıfı tanımları bellekte, kod ise aynı uygulama etki alanında kalır. Bunun nedeni, yüklü SWF'nin söz konusu sınıf örneklerine erişebilmesi ve yeni örnekler oluşturabilmesidir.

Not (yalnızca iOS): AIR 3.6'dan önceki sürümlerde, bu yöntemin iOS üzerinde etkisi yoktur.

En iyi uygulama olarak, alt SWF dosyasını kaldırmadan önce alt SWF dosyasının LocalConnection, NetConnection, NetStream ve Sound gibi nesnelerindeki tüm akışları açıkça kapatmanız gerekir. Aksi takdirde, alt SWF dosyası kaldırıldığı halde alt SWF dosyasındaki ses çalmaya devam edebilir. Alt SWF dosyasındaki akışları kapatmak için, unload olayını dinleyen alt öğeye bir olay dinleyicisi ekleyin. Üst öğe Loader.unload() öğesini çağırdığında, alt öğeye unload olayı gönderir. Şu kod, bunu nasıl yapabileceğinizi gösterir:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

İlgili API Öğeleri

Alt SWF dosyası içeriğini boşaltmaya çalışır ve yüklü SWF dosyalarından komutların gerçekleşmesini durdurur. Bu yöntem, alt SWF dosyasının EventDispatcher, NetConnection, Timer, Sound veya Video nesnelerine verilen başvuruları kaldırarak, Loader.load() veya Loader.loadBytes() kullanılarak yüklenmiş SWF dosyalarını boşaltmayı dener. Sonuç olarak, alt SWF dosyası ve alt SWF dosyasının görüntüleme listesi için şu durum ortaya çıkar:

• Sesler durdurulur.
• Stage olayı dinleyicileri kaldırılır.
• enterFrame, frameConstructed, exitFrame, activate ve deactivate için olay dinleyicileri kaldırılır.
• Zamanlayıcılar durdurulur.
• Camera ve Microphone örnekleri ayrılır.
• Film klipleri durdurulur

unloadAndStop() yöntemini çağırdığınızda Loader nesnesinin contentLoaderInfo özelliği null olarak ayarlanır. SWF ile yüklenen görsel varlıklar kaldırılır ve bellekten silinir. Yüklü SWF'deki ActionScript sınıfı tanımları bellekte, kod ise aynı uygulama etki alanında kalır. Bunun nedeni, yüklü SWF'nin söz konusu sınıf örneklerine erişebilmesi ve yeni örnekler oluşturabilmesidir.

Not (yalnızca iOS): AIR 3.6'dan önceki sürümlerde, bu yöntemin iOS üzerinde etkisi yoktur.

Parametreler

İlgili API Öğeleri

1. Bir url özelliği oluşturulur; bu, görüntü dosyasının konumu ve adıdır.
2. LoaderExample yapıcısında, loader adında yeni bir Loader nesnesi oluşturulur; bu daha sonra 3. adımda açıklanan configureListeners() yöntemine iletilir.
3. Yapıcı, dosya adı ve konumunun bilinmesi için url iletilmiş şekilde yeni bir URLRequest nesnesi (request) oluşturur.
4. request nesnesi, loader nesnesinin load() yöntemine iletilir; bu da görüntüleme listesine görüntüyü yükler.
5. Yükleyicideki click olayı için bir clickHandler olay dinleyicisi kaydedilir. Bir fare tıklatmasından sonra, yüklenen görüntü kaldırılır.
6. configureListeners() yöntemi, şu yöntemleri kullanarak yedi tane olay dinleyicisi ekler:
   • Görüntü yüklemesi bitince completeHandler() yöntemi çalıştırılır.
   • Görüntü yerel olarak yüklenmezse ve yalnızca ağ isteği kullanılabilir hale getirilip Flash Player tarafından algılanabilirse httpStatusHandler() yöntemi çalıştırılır.
   • initHandler() yöntemi, completeHandler() yönteminden önce ve progressHandler() yönteminden sonra çalıştırılır. Genellikle, init olayı SWF dosyalarını yüklerken daha yararlıdır.
   • Görüntü dosyası kullanılamadığında veya erişilemediğinde ioErrorHandler() yöntemi çalıştırılır.
   • Görüntü dosyası ilk açıldığında openHandler() yöntemi çalıştırılır.
   • Görüntü dosyası yüklenmeye başladığında ve bir de görüntü yüklemesi bittiğinde progressHandler() yöntemi çalıştırılır.
   • Kullanıcı görüntüyü tıklatınca unload() yöntemi kullanılarak görüntü kaldırıldığında unLoadHandler() yöntemi çalıştırılır.

Şu gereksinimleri göz önünde bulundurun:

• Bu örnek, Image.gif adında bir dosyayı, derlenmiş SWF dosyasıyla aynı dizine yerleştirmenizi gerektirir. Ana SWF dosyasının boyutlarına sığan bir alana sahip bir görüntüyü kullanın.
• Bu örnek, LoaderInfo nesnesi için kullanılabilir tüm olaylardan yararlansa da, çoğu durum yalnızca bir alt küme gerektirir. Özellikle bir görüntü dosyası yüklenirken, yerel bir görüntünün yüklenmesinde complete olayı (ve belki de ioError olayı) yeterlidir.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}