URLRequest  - AS3

Bu istek için kimlik doğrulama isteklerinin işlenip (true) işlenmeyeceğini (false) belirtir. Değer false ise, kimlik doğrulama sorunları bir HTTP hatası döndürür.

Desteklenen kimlik doğrulama yöntemleri şunlardır:

• Windows—HTTP Temel/Özet, Tümleşik Windows Kimlik Doğrulaması (NTLM ve Kerberos dahil), SSL Sertifikası Kimlik Doğrulama.
• Mac—HTTP Temel/Özet, NTLM, SSL Sertifikası Kimlik Doğrulama.

Not:FileReference.upload(), FileReference.download() ve HTMLLoader.load() yöntemleri URLRequest.authenticate özelliğini desteklemez.

Varsayılan değer şudur true.

İlgili API Öğeleri

Bu istek için başarılı yanıt verilerinin önbelleğe alınıp alınmayacağını belirtir. true değerine ayarlandığında, AIR uygulaması, işletim sisteminin HTTP önbelleğini kullanır.

Not:HTMLLoader.load() yöntemi URLRequest.cacheResponse özelliğini desteklemez.

Varsayılan değer şudur true.

İlgili API Öğeleri

data özelliğinde içeriğin MIME içerik türü.

Varsayılan değer application/x-www-form-urlencoded şeklindedir.

Not:FileReference.upload(), FileReference.download() ve HTMLLoader.load() yöntemleri URLRequest.contentType özelliğini desteklemez.

Bir POST isteği gönderilirken, contentType ve data özelliklerinin değerleri düzgün bir şekilde eşleşmelidir. contentType özelliğinin değeri sunuculara data özelliğinin nasıl yorumlanacağını gösterir.

• data özelliğinin değeri bir URLVariables nesnesiyse, contentType değeri application/x-www-form-urlencoded şeklinde olmalıdır.
• data özelliğinin değeri başka bir türse, contentType öğesinin değeri, gönderilecek olan POST verilerinin türünü (data özelliğine dahil edilmiş ikili veriler veya dize verileri) göstermelidir.
• FileReference.upload() öğesinde, isteğin Content-Type öğesi otomatik şekilde multipart/form-data olarak ayarlanır ve contentType özelliğinin değeri yok sayılır.

Flash Player 10 ve sonrasında, yükleme (POST gövdesi içinde "content-disposition" başlığında "filename" parametresiyle belirtilir) içeren çok bölümlü bir Content-Type (örneğin, "multipart/form-data") kullanırsanız, POST işlemi, yüklemelere uygulanan güvenlik kurallarına tabidir:

• Fare tıklatma veya tuş basışı gibi kullanıcı tarafından başlatılan bir eyleme yanıt olarak POST işleminin gerçekleştirilmesi gerekir.
• POST işlemi etki alanları arasıysa (POST hedefi, POST isteğini gönderen SWF dosyasıyla aynı sunucuda değilse), hedef sunucunun etki alanları arası erişime izin veren bir URL ilke dosyası sağlaması gerekir.

Ayrıca çok bölümlü herhangi bir Content-Type için sözdiziminin geçerli olması gerekir (RFC2046 standartlarına göre). Sözdizimi geçersiz görünüyorsa, POST işlemi, yüklemelere uygulanan güvenlik kurallarına tabi olur.

İlgili API Öğeleri

URL isteği ile iletilecek olan verileri içeren bir nesne.

Bu özellik method özelliğiyle birlikte kullanılır. method değeri GET olduğunda, HTTP sorgu dizesi sözdizimi kullanılarak data değeri, URLRequest.url değerinin sonuna eklenir. method değeri POST (veya GET dışında bir değer) olduğunda, data değeri HTTP isteğinin gövdesinde iletilir.

URLRequest API ikili POST desteği ve URL kodlu değişken desteğinin yanı sıra dizeler için destek sağlar. Veri nesnesi bir ByteArray, URLVariables veya String nesnesi olabilir.

Verilerin kullanılma yöntemi kullanılan nesne türüne bağlıdır:

• Nesne bir ByteArray nesnesiyse, ByteArray nesnesinin ikili verileri POST verileri olarak kullanılır. GET öğesi için, ByteArray türündeki veriler desteklenmez. Ayrıca, ByteArray türündeki veriler FileReference.upload() ve FileReference.download() için desteklenmez.
• Nesne bir URLVariables nesnesiyse ve yöntem POST ise, değişkenler x-www-form-urlencoded biçimi kullanılarak kodlanır ve sonuç olarak ortaya çıkan dize POST verisi olarak kullanılır. Değişkenlerin bir multipart/form-data gönderiminde ayrı alanlar olarak gönderildiği FileReference.upload() çağrısı bir istisnadır.
• Nesne bir URLVariables nesnesiyse ve yöntem GET ise, URLVariables nesnesi, URLRequest nesnesiyle birlikte gönderilecek değişkenleri tanımlar.
• Aksi takdirde, nesne bir dizeye dönüştürülür ve bu dize POST veya GET verisi olarak kullanılır.

Bu veri, navigateToURL() veya FileReference.upload() gibi bir yöntem URLRequest nesnesini kullanıncaya kadar gönderilmez.

Not: contentType değerinin, data özelliğindeki veri türüne karşılık gelmesi gerekir. contentType özelliğinin açıklamasındaki nota bakın.

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Flash Player önbelleğine saklanacak (veya buradan alınacak) imzalanmış Adobe platformu bileşenini benzersiz şekilde tanımlayan bir dize. Adobe platformu bileşeni, kullanıcının makinesinde kalıcı olarak önbelleğe alınan SWF içeriğini barındıran imzalanmış bir dosyadır (bir SWZ dosyası). Tüm SWZ dosyaları Adobe tarafından imzalanır. Özet, önbelleğe alınan tek bir dosyaya karşılık gelir; herhangi bir şekilde dosyayı değiştirirseniz, dosyanın özeti beklenmedik şekilde değişir. Bir özet kullanarak, önbelleğe alınan dosyayı birden çok etki alanında doğrulayabilirsiniz. Aynı özete sahip iki dosya aynı dosyadır ve farklı özetlere sahip iki dosya aynı dosya değildir. Bir dosya, özeti "aldatmak" için oluşturulamaz (pratik olarak) ve başka bir özetmiş gibi davranamaz.

Özet, SHA-256 mesaj özeti algoritmasını esas alır (onaltılık biçimde 64 karakter uzunluğu).

Örneğin, Flex SDK, Flex karesi için bir SWZ içerir (ve bu SWZ dosyası için özet dize sağlar). Bu SWZ dosyasını web sunucunuzda gönderebilir ve SWF dosyanıza yükleyebilirsini (URLLoader nesnesinin load() yöntemini kullanarak). Son kullanıcının makinesinde, eşleşen SWZ dosyası önceden önbelleğe alınmışsa, uygulama önbelleğe alınan SWZ dosyasını kullanır. (SWZ dosyasının digest öğesi sizin sağladığınızla eşleşiyorsa, o SWZ dosyası eşleşir.) Aksi takdirde, uygulama belirttiğiniz URL'den SWZ dosyasını indirir.

Yalnızca SWZ dosyası yüklemek için URLLoader.load() yöntemine yapılan bir çağrıda kullanılan URLRequest nesnesinde digest parametresini ayarlayın. URLRequest nesnesinin digest özelliği, bu nesne başka yöntemlerde kullanılırken ayarlı durumdaysa, uygulama bir IOError istisnası atar.

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

Yeniden yönlendirmelerin izlenip (true) izlenmeyeceğini (false) belirtir.

Not:FileReference.upload(), FileReference.download() ve HTMLLoader.load() yöntemleri URLRequest.followRedirects özelliğini desteklemez.

Varsayılan değer şudur true.

İlgili API Öğeleri

Bu isteğe ilişkin boşta kalma zaman aşımı değerini (milisaniye cinsinden) belirtir.

Boşta kalma zaman aşımı, istemcinin bağlantı kurulduktan sonra ve istekten vazgeçilmeden önce sunucudan bir yanıt beklediği süre miktarıdır.

Not: HTMLLoader.load() yöntemi URLRequest.idleTimeout özelliğini desteklemez. HTMLLoader sınıfı kendi idleTimeout özelliğini tanımlar.

Varsayılan değer şudur initialized from the URLRequestDefaults.idleTimeout property.

İlgili API Öğeleri

HTTP protokol yığınının, bu isteğe yönelik tanımlama bilgilerini yönetip yönetmeyeceğini belirtir. Değer true olduğunda, tanımlama bilgileri isteğe eklenir ve yanıt tanımlama bilgileri hatırlanır. Değer false olduğunda, tanımlama bilgileri isteğe eklenmez ve yanıt tanımlama bilgileri hatırlanmaz, ancak kullanıcılar doğrudan üstbilgiyi işleyerek tanımlama bilgilerini kendileri de yönetebilir. Not: Windows'ta, manageCookies öğesi true olarak ayarlandığında, tanımlama bilgilerini bir URL isteğine el ile ekleyemezsiniz. Diğer işletim sistemlerinde, manageCookies öğesinin true olarak mı yoksa false olarak mı ayarlandığına bakılmaksızın, bir isteğe tanımlama bilgisi eklenmesine izin verilir. İzin verildiğinde, tanımlama bilgisi verilerini içeren bir URLRequestHeader nesnesini requestHeaders dizisine ekleyerek bir isteğe manuel olarak tanımlama bilgileri ekleyebilirsiniz.

Mac OS'da tanımlama bilgileri Safari ile paylaşılır. Mac OS'da tanımlama bilgilerini temizlemek için:

1. Safari'yi açın.
2. Safari > Preferences (Tercihler) seçeneğini belirleyin ve Security (Güvenlik) panelini tıklatın.
3. Show Cookies (Tanımlama Bilgilerini Göster) düğmesini tıklatın.
4. Remove All (Tümünü Kaldır) düğmesini tıklatın.

Windows'da tanımlama bilgilerini temizlemek için:

1. Internet Özellikleri denetim panosunu açın ve Genel sekmesini tıklatın.
2. Tanımlama Bilgilerini Sil düğmesini tıklatın.

Varsayılan değer şudur true.

İlgili API Öğeleri

HTTP form teslim yöntemini denetler.

Flash Player'da (tarayıcıda) çalışan SWF içeriği için bu özellik GET veya POST işlemleriyle sınırlıdır ve geçerli değerler URLRequestMethod.GET veya URLRequestMethod.POST olur.

İçerik, uygulama güvenlik sanal alanında bulunduğu sürece, Adobe AIR'de çalışan içerik için herhangi bir dize değeri kullanabilirsiniz. Aksi takdirde Flash Player'da çalışan içerikte olduğu gibi, GET veya POST işlemlerini kullanmakla sınırlandırılırsınız.

Adobe AIR'de çalışan içerik için, navigateToURL() işlevinin kullanılması sırasında, GET yöntemini kullandığı gibi POST yöntemini kullanan URLRequest öğesi (method özelliği URLRequestMethod.POST olarak ayarlanmış olan).

Not: Flash Player'da çalışılıyorsa ve başvurulan formun gövdesi yoksa, yöntem URLRequestMethod.POST olarak ayarlanmış olsa da Flash Player otomatik olarak bir GET işlemi kullanır. Bu nedenle, doğru yöntemin kullanıldığından emin olmak için her zaman bir "taklit" gövde dahil etmeniz önerilir.

Varsayılan değer şudur URLRequestMethod.GET.

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

HTTP isteğine eklenecek HTTP istek üstbilgileri dizisi. Dizi URLRequestHeader nesnelerinden oluşur. Dizideki her nesne, şu şekilde bir ad dizesi ve bir değer dizesi içeren bir URLRequestHeader nesnesi olmalıdır:

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

Flash Player ve AIR çalışma zamanı, istek üstbilgilerine belirli kısıtlamalar getirir; daha fazla bilgi için URLRequestHeader sınıfının açıklamasına bakın.

URLRequest parametrelerini kabul eden tüm yöntemler requestHeaders özelliğini desteklemez, bu konuda bilgi almak için çağırdığınız yöntemin belgelerine başvurun. Örneğin, FileReference.upload() ve FileReference.download() yöntemleri URLRequest.requestHeaders özelliğini desteklemez.

Tarayıcı sınırlamaları nedeniyle, özel HTTP isteği üstbilgileri yalnızca POST istekleri için desteklenip GET istekleri için desteklenmez.

İlgili API Öğeleri

İstenecek URL.

Tekdüzen Kaynak Tanımlayıcısı belirtiminde (bkz. http://www.faqs.org/rfcs/rfc1738.html) güvenilir olmayan niteliğiyle açıklanan veya URLRequest nesnesinin URL şemasında saklanan (saklanma amaçlarıyla kullanılmadıklarında) karakterleri kodladığınızdan emin olun. Örneğin, "http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25" adresindeki gibi yüzde (%) sembolü için "%25" öğesini ve sayı işareti (#) için "%23" öğesini kullanın.

İçerik Adobe AIR uygulama güvenlik sanal alanında çalışmadığı sürece, varsayılan olarak, URL ile çağıran dosyanın aynı etki alanında olması gerekir. Farklı bir etki alanından veri yüklemeniz gerekiyorsa, verileri barındıran sunucuya bir URL ilke dosyası yerleştirin. Daha fazla bilgi için, URLRequest sınıfının açıklamasına bakın.

Adobe AIR'da çalışan içerik için uygulama güvenlik sanal alanındaki dosyalar (AIR uygulamasıyla yüklenen dosyalar) şu URL şemalarından herhangi birini kullanarak URL'lere erişebilir:

• http ve https
• file
• app-storage
• app

Not: IPv6 (Internet Protokolü sürüm 6), AIR ve Flash Player 9.0.115.0 ve sonraki sürümlerde desteklenir. IPv6, 128 bit adresleri destekleyen bir Internet Protokolü sürümüdür (32 bit adresleri destekleyen önceki IPv4 protokolündeki bir geliştirme). Ağ arabirimleriniz üzerinde IPv6'yı etkinleştirmeniz gerekebilir. Daha fazla bilgi için verileri barındıran işletim sisteminin Yardım bölümüne bakın. IPv6, barındıran sistem üzerinde destekleniyorsa, köşeli ayraç ([]) içindeki URL'lerde şu şekilde sayısal IPv6 adresleri belirtebilirsiniz.

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

Bu URLRequest veriyi getirmeden önce yerel önbelleğe başvurulup başvurulmayacağını belirtir.

Not:HTMLLoader.load() yöntemi URLRequest.useCache özelliğini desteklemez.

Varsayılan değer şudur true.

İlgili API Öğeleri

HTTP isteğinde kullanılacak kullanıcı-aracı dizesini belirtir.

Varsayılan değer, Flash Player tarafından kullanılan kullanıcı aracısı dizesiyle aynı olup Mac, Linux ve Windows'ta farklıdır.

Not: URLRequest nesnesi HTMLLoader nesnesinin load() yöntemiyle kullanıldığında bu özellik kullanıcı aracı dizesini etkilemez. HTMLLoader nesnesine kullanıcı aracı dizesi ayarlamak için, HTMLLoader nesnesinin userAgent özelliğini ayarlayın veya statik URLRequestDefaults.userAgent özelliğini ayarlayın.

İlgili API Öğeleri

Bir URLRequest nesnesi oluşturur. System.useCodePage öğesi true değerindeyse istek, Unicode yerine sistem kod sayfası kullanılarak kodlanır. System.useCodePage öğesi false değerindeyse, istek, sistem kod sayfası yerine Unicode kullanılarak kodlanır.

İlgili API Öğeleri

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

URLRequest kaynağından yeniden yönlendirilen bir URL'nin yeni bir URLRequest dahilindeki URL'nin bir kısmının yerine geçmesine izin verir. Bu, ilk isteğin yeniden yönlendirilmesinin ardından ondan sonra gelen isteklerin doğrudan yeniden yönlendirilen sunucu konumuna gönderilmesine olanak tanır.

İlk URLRequest tamamlandıktan sonra HTTPStatusEvent.redirected öğesi true ise, bu yöntem ilk istek sourceRequest olarak kullanılarak çağırılabilir. Varsayılan olarak, yeniden yönlendirilen URL'deki etki alanı bu URLRequest'e ait URL'deki etki alanının yerine kullanılır. Bu yöntem çağrılmadan önce URLRequest.url ayarlanmalıdır. Bu URLRequest yüklenmeden önce yöntem çağrılmalıdır. İsteğe bağlı olarak, wholeURL parametresi true ise, URLRequest kaynağındaki url'nin tamamı (dosya adı hariç), bu URLRequest dahilindeki URL'nin tamamının (son dosya adı hariç) yerine geçer. Arayan, pattern parametresinde isteğe bağlı olarak bir dize ya da normal ifade sağlayabilir. Desen aranır ve replace parametresindeki dize ile değiştirilir. Bu arama ve değiştirme işlemi, URL'nin değişiminden sonra gerçekleşir.

Parametreler

İlgili API Öğeleri

Bu örneği çalıştırmak için, SWF dosyanızla aynı dizine XMLFile.xml adlı bir dosya yerleştirin.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}