FileReference  - AS3

Yerel diskteki dosyanın oluşturulma tarihi. Nesne doldurulmadıysa, bu özelliğin değerini almak için yapılan bir çağrı null değerini döndürür.

Not: Bir işletim sisteminde özellik olarak creationDate yoksa, böyle durumlarda CreationDate ile lastModifiedDate değeri eşittir.

İlgili API Öğeleri

Yalnızca Mac OS X öncesindeki Mac OS sürümlerinde kullanılan dosyanın Macintosh oluşturan türü. Windows ve Linux'ta bu null değerindedir. FileReference nesnesi doldurulmadıysa, bu özelliğin değerini almak için yapılan bir çağrı null değerini döndürür.

İlgili API Öğeleri

load() yöntemine yapılan başarılı bir çağrıdan sonra yüklenen dosyada bulunan verileri temsil eden ByreArray nesnesi.

İlgili API Öğeleri

Dosya adı uzantısı.

Dosyanın uzantısı, ismin en sondaki noktadan (".") sonra gelen (son nokta hariç) bölümüdür. Dosya adında nokta yoksa, uzantı null değerindedir.

Not: Dosyanın türünü belirlemek için extension özelliğini kullanmanız gerekir; creator veya type özelliklerini kullanmayın. creator ve type özelliklerinin onaylanmadığını unutmamalısınız. Bunlar eski Mac OS sürümleri için geçerlidir.

Yerel diskteki dosyanın son değiştirilme tarihi. FileReference nesnesi doldurulmadıysa, bu özelliğin değerini almak için yapılan bir çağrı null değerini döndürür.

İlgili API Öğeleri

Yerel diskteki dosyanın adı. FileReference nesnesi doldurulmamışsa (FileReference.download() veya FileReference.browse() öğesine yapılan geçerli bir çağrıyla), bu özelliğin değerini almaya çalıştığınızda Flash Player bir hata atar.

Bir FileReference nesnesinin tüm özellikleri browse() yöntemi çağrılarak doldurulur. Diğer FileReference özelliklerinin aksine download() yöntemini çağırırsanız, select olayı gönderildiğinde name özelliği doldurulur.

İlgili API Öğeleri

Uygulamaya dosya sistemi erişiminin verilip verilmediğini belirler.

İlgili API Öğeleri

Yerel diskteki dosyanın bayt olarak boyutu.

Not: İlk ActionScript 3.0 sürümünde size özelliği, 4 GB'a kadar boyuta sahip dosyaları destekleyen bir uint nesnesi olarak tanımlanmıştı. Şimdi ise daha büyük dosyaları desteklemek için bir Number nesnesi olarak uygulanır.

İlgili API Öğeleri

Dosya türü.

Windows veya Linux'ta, bu özellik dosya uzantısıdır. Macintosh'ta bu özellik yalnızca Mac OS X öncesindeki Mac OS sürümlerinde kullanılan dört karakterli dosya türüdür. FileReference nesnesi doldurulmazsa, bu özelliğin değerini almak için yapılan bir çağrı null değerini döndürür.

Windows, Linux ve Mac OS X için dosya uzantısı — noktanın (.) en son bulunduğu yerden sonra gelen name özelliği karakter — dosya türünü tanımlar.

İlgili API Öğeleri

Yeni bir FileReference nesnesi oluşturur. Bir FileReference nesnesi doldurulduğunda, kullanıcının yerel diski üzerindeki bir dosyayı temsil eder.

İlgili API Öğeleri

Kullanıcının yüklenecek bir dosya seçmesini sağlayan bir dosya gözatma iletişim kutusu görüntüler. İletişim kutusu, kullanıcının işletim sistemi için yereldir. Kullanıcı yerel bilgisayar üzerinden veya Windows'daki bir UNC yaması gibi başka sistemler üzerinden bir dosya seçebilir.

Not: Adobe AIR'de kullanılabilen File sınıfı, daha belirli sistem dosyası seçim iletişim kutularına erişme yöntemleri içerir. Bu yöntemler şunlardır: File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() ve File.browseForSave().

Bu yöntemi çağırdığınızda ve kullanıcı başarılı bir şekilde dosya seçtiğinde, bu FileReference nesnesinin özellikleri o dosyanın özellikleriyle doldurulur. FileReference.browse() yöntemi daha sonra her çağrıldığında, FileReference nesnesinin özellikleri, kullanıcının iletişim kutusunda seçtiği dosyanın özelliklerine sıfırlanır. Aynı anda yalnızca bir browse() veya download() oturumu gerçekleştirilebilir (aynı anda yalnızca bir iletişim kutusu çağrılabildiğinden).

typeFilter parametresini kullanarak iletişim kutusunda hangi dosyaların görüntüleneceğini belirleyebilirsiniz.

Flash Player 10 ve Flash Player 9 Güncelleme 5'te, bir kullanıcı olayına (örneğin, fare tıklatması veya tuş basışı olayı için bir olay işleyicisinde) yanıt olarak bu yöntemi başarıyla çağırabilirsiniz. Aksi halde, bu yöntemin çağrılması Flash Player'ın bir Error istisnası atmasına neden olur.

Flash Player'a eklenen yeni işlevler nedeniyle, Flash Player 10'a yayın yapılırken aynı anda şu işlemlerden yalnızca birinin etkin olacağını unutmayın: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Aksi takdirde, Flash Player bir çalışma zamanı hatası (kod 2174) atar. Devam eden bir işlemi durdurmak için FileReference.cancel() öğesini kullanın. Bu kısıtlama yalnızca Flash Player 10 için geçerlidir. Önceki Flash Player sürümleri, eşzamanlı birden çok işlem üzerindeki bu kısıtlamadan etkilenmez.

Adobe AIR uygulamasında dosyaya göz atma iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (null değerinde olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

Parametreler

İlgili API Öğeleri

Bu FileReference nesnesi üzerinde devam eden yükleme veya indirme işlemlerini iptal eder. Bu yöntemi çağırırsanız cancel olayı gönderilmez; bu olay yalnızca kullanıcı, dosya yükleme veya indirme iletişim kutusunu kapatarak işlemi iptal ederse gönderilir.

Kullanıcının uzak bir sunucudan bir dosya indirmesini sağlayan bir iletişim kutusu açar. Flash Player, yükleyebileceğiniz veya indirebileceğiniz dosyaların boyutuna yönelik bir kısıtlama getirmese de, resmi olarak 100 MB'a kadar olan yükleme ya da indirmeleri destekler.

download() yöntemi ilk olarak, kullanıcıdan bir dosya adı girmesini ve dosyayı kaydetmek için yerel bilgisayar üzerinde bir konum seçmesini isteyen bir işletim sistemi iletişim kutusu açar. Kullanıcı bir konum seçtiğinde ve indirme işlemini onayladığında (örneğin Kaydet'i tıklatarak), uzak sunucundan indirme işlemi başlar. Dinleyiciler, indirme işleminin ilerlemesini, başarılı veya başarısız olduğunu gösteren olaylar alır. download() öğesini çağırdıktan sonra iletişim kutusunun ve indirme işleminin durumunu kesinleştirmek için, kodunuz cancel, open, progress ve complete gibi olayları dinlemelidir.

FileReference.upload() ve FileReference.download() işlevleri tıkanmasızdır. Bu işlevler çağrıldıktan sonra, dosya iletimi tamamlanmadan önce döndürülür. Ayrıca, FileReference nesnesi kapsam dışına çıkarsa, bu nesne üzerindeki henüz tamamlanmamış olan herhangi bir yükleme veya indirme işlemi, kapsam dışına çıkıldığında iptal edilir. Yükleme ve indirme işleminin devam etmesi beklenen süre boyunca FileReference nesnesinin kapsam içinde kaldığından emin olun.

Dosya başarıyla indirildiğinde, FileReference nesnesinin özellikleri, yerel dosyanın özellikleriyle doldurulur. İndirme başarılı olursa complete olayı gönderilir.

Aynı anda yalnızca bir browse() veya download() oturumu gerçekleştirilebilir (aynı anda yalnızca bir iletişim kutusu çağrılabildiğinden).

Bu dosya HTTP veya HTTPS ile olmak üzere herhangi bir dosya türünün indirilmesini destekler.

Ortak olarak ayrılmış bağlantı noktalarına bağlanamazsınız. Engellenen bağlantı noktalarının tam listesi için, bkz. "Ağ İletişimi API'lerini Kısıtlama", ActionScript 3.0 Geliştirici Kılavuzu.

Not: Sunucunuz kimlik doğrulama gerektiriyorsa, yalnızca bir tarayıcıda çalışan SWF dosyaları, yani, tarayıcı eklentisini veya ActiveX denetimini kullanan dosyalar, kimlik doğrulama ve yalnızca indirmeler için kullanıcıdan bir kullanıcı adı ve şifre isteyen bir iletişim kutusu sağlar. Eklenti veya ActiveX denetimini kullanan yüklemelerde veya tek başına çalışabilen ya da harici oynatıcıyı kullanan yüklemelerde ve indirmelerde, dosya aktarımı başarısız olur.

Bu yöntemi kullanırken Flash Player güvenlik modelini göz önünde bulundurun:

• Çağıran SWF dosyası güvenilmeyen bir yerel sanal alandaysa yükleme işlemlerine izin verilmez.
• Varsayılan davranış, sanal alanlar arasında erişimi reddetmektir. Bir web sitesi, URL ilke dosyası eklenerek bir kaynağa erişilmesini sağlayabilir.
• SWF içeriğini barındıran HTML sayfasındaki object veembed etiketlerinin allowNetworking parametresini ayarlayarak bir SWF dosyasının bu yöntemi kullanmasını önleyebilirsiniz.
• Flash Player 10 ve Flash Player 9 Güncelleme 5'te, bir kullanıcı olayına (örneğin, fare tıklatması veya tuş basışı olayı için bir olay işleyicisinde) yanıt olarak bu yöntemi başarıyla çağırabilirsiniz. Aksi halde, bu yöntemin çağrılması Flash Player'ın bir Error istisnası atmasına neden olur.

Ancak Adobe AIR'de, uygulama güvenlik sanal alanındaki içerik (AIR uygulamasıyla yüklenen içerik) bu güvenlik sınırlamalarıyla kısıtlanmaz.

Güvenlikle ilgili daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

Bu yöntemi kullanarak bir dosyayı indirmenizin ardından, indirilen dosyaları bayrakla işaretleyen işletim sistemlerinde dosya, indirildiğinin belirtilmesi için bayrakla işaretlenir:

• Windows XP servis paketi 2 ve sonrasında ve Windows Vista'da
• Mac OS 10.5 ve sonrasında

Linux gibi bazı işletim sistemleri, indirilen dosyaları bayrakla işaretlemez.

Flash Player'a eklenen yeni işlevler nedeniyle, Flash Player 10'a yayın yapılırken aynı anda şu işlemlerden yalnızca birinin etkin olacağını unutmayın: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Aksi takdirde, Flash Player bir çalışma zamanı hatası (kod 2174) atar. Devam eden bir işlemi durdurmak için FileReference.cancel() öğesini kullanın. Bu kısıtlama yalnızca Flash Player 10 için geçerlidir. Önceki Flash Player sürümleri, eşzamanlı birden çok işlem üzerindeki bu kısıtlamadan etkilenmez.

Adobe AIR uygulamasında, indirme iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (null değerinde olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

Parametreler

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Kullanıcı tarafından seçilen yerel dosyanın yüklenmesini başlatır. Flash Player, karşıya yükleyebileceğiniz, indirebileceğiniz, yükleyebileceğiniz veya kaydedebileceğiniz dosyaların boyutu konusunda bir kısıtlama getirmese de, resmi olarak 100 MB'a kadar olan boyutları destekler. Flash Player'da çalışan içerik için, load() yöntemini çağırmadan önce FileReference.browse() veya FileReferenceList.browse() yöntemini çağırmalısınız. Ancak, AIR'da uygulama sanal alanında çalışan içerik, önce browse() yöntemini çağırmadan da bir File nesnesinin load() yöntemini çağırabilir. (AIR File sınıfı, FileReference sınıfını genişletir.)

Dinleyiciler, yükleme işleminin ilerlemesini, başarılı veya başarısız olduğunu gösteren olaylar alır. Kullanıcıların yükleme için birden çok dosya seçmesine izin vermek için FileReferenceList nesnesini kullanabiliyor olsanız da, bu dosyaları birer birer yüklemelisiniz. Dosyaları birer birer yüklemek için, FileReference nesnesinin FileReferenceList.fileList dizisini yineleyin.

Adobe AIR, ayrıca daha fazla dosya okuma seçeneği sağlayan FileStream sınıfını da içerir.

FileReference.upload(), FileReference.download(), FileReference.load() ve FileReference.save() işlevleri tıkanmasızdır. Bu işlevler çağrıldıktan sonra, dosya iletimi tamamlanmadan önce döndürülür. Ayrıca, FileReference nesnesi kapsam dışına çıkarsa, bu nesne üzerindeki henüz tamamlanmamış olan herhangi bir işlem, kapsam dışına çıkıldığında iptal edilir. Karşıya yükleme, indirme, yükleme veya kaydetme işleminin devam etmesi beklenen süre boyunca FileReference nesnesinin kapsam içinde kaldığından emin olun.

Dosyanın yüklenmesi başarıyla tamamlanırsa, içeriği FileReference nesnesinin data özelliğinde bir bayt dizisi olarak saklanır.

Şu güvenlik önlemleri uygulanır:

• Çağıran SWF dosyası güvenilmeyen bir yerel sanal alandaysa yükleme işlemlerine izin verilmez.
• Varsayılan davranış, sanal alanlar arasında erişimi reddetmektir. Bir web sitesi, etki alanları arası ilke dosyası ekleyerek bir kaynağa erişim sağlayabilir.
• SWF içeriğini kapsayan HTML sayfasındaki object ve embed etiketlerinin allowNetworking parametresini ayarlayarak bir SWF dosyasının bu yöntemi kullanmasını önleyebilirsiniz.

Ancak, bu önlemler uygulama sanal alanındaki AIR içeriğine uygulanmaz.

Flash Player 10 veya AIR 1.5'te yayınlarken, bir defada bu işlemlerden yalnızca birinin etkin olabileceğini göz önünde bulundurun: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Aksi halde, uygulama bir çalışma zamanı hatası (kod 2174) atar. Devam eden bir işlemi durdurmak için FileReference.cancel() öğesini kullanın. Bu sınırlamalar yalnızca Flash Player 10 ve AIR 1.5 için uygulanır. Önceki Flash Player veya AIR sürümleri eşzamanlı çoklu işlemlere ilişkin bu sınırlamalardan etkilenmez.

Adobe AIR uygulamasında dosyaya göz atma iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (null değerinde olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

İlgili API Öğeleri

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Dosya sistemine erişim ister.

Kullanıcının dosyayı yerel dosya sistemine kaydetmesini sağlayan bir iletişim kutusu açar. Flash Player, karşıya yükleyebileceğiniz, indirebileceğiniz, yükleyebileceğiniz veya kaydedebileceğiniz dosyaların boyutu konusunda bir kısıtlama getirmese de, resmi olarak 100 MB'a kadar olan boyutları destekler.

save() yöntemi ilk olarak, kullanıcıdan bir dosya adı girmesini ve dosyayı kaydetmek için yerel bilgisayar üzerinde bir konum seçmesini isteyen bir işletim sistemi iletişim kutusu açar. Kullanıcı bir konum seçtiğinde ve kaydetme işlemini onayladığında (örneğin Kaydet'i tıklatarak), kaydetme işlemi başlar. Dinleyiciler, kaydetme işleminin ilerlemesini, başarılı veya başarısız olduğunu gösteren olaylar alır. save() öğesini çağırdıktan sonra iletişim kutusunun ve kaydetme işleminin durumunu kesinleştirmek için, kodunuz cancel, open, progress ve complete gibi olayları dinlemelidir.

Adobe AIR, ayrıca daha fazla dosyaları yerel olarak kaydetme seçeneği sağlayan FileStream sınıfını da içerir.

FileReference.upload(), FileReference.download(), FileReference.load() ve FileReference.save() işlevleri tıkanmasızdır. Bu işlevler çağrıldıktan sonra, dosya iletimi tamamlanmadan önce döndürülür. Ayrıca, FileReference nesnesi kapsam dışına çıkarsa, bu nesne üzerindeki henüz tamamlanmamış olan herhangi bir işlem, kapsam dışına çıkıldığında iptal edilir. Karşıya yükleme, indirme, yükleme veya kaydetme işleminin devam etmesi beklenen süre boyunca FileReference nesnesinin kapsam içinde kaldığından emin olun.

Dosya başarıyla kaydedildiğinde, FileReference nesnesinin özellikleri, yerel dosyanın özellikleriyle doldurulur. Kaydetme başarılı olursa complete olayı gönderilir.

Aynı anda yalnızca bir browse() veya save() oturumu gerçekleştirilebilir (aynı anda yalnızca bir iletişim kutusu çağrılabildiğinden).

Flash Player'da, bu yöntemi yalnızca bir kullanıcı olayına yanıt olarak başarıyla çağırabilirsiniz (örneğin, fare tıklatması veya keypress olayı için bir olay işleyicisinde). Aksi halde, bu yöntemin çağrılması Flash Player'ın bir Error istisnası atmasına neden olur. Bu sınırlama, uygulama sanal alanındaki AIR içeriğine uygulanmaz.

Adobe AIR uygulamasında, kaydetme iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (null değerinde olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

Parametreler

İlgili API Öğeleri

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Dosyanın uzak bir sunucuya yüklenme işlemini başlatır. Flash Player, yükleyebileceğiniz veya indirebileceğiniz dosyaların boyutuna yönelik bir kısıtlama getirmese de, resmi olarak 100 MB'a kadar olan yükleme ya da indirmeleri destekler. Bu yöntemi çağırmadan önce FileReference.browse() veya FileReferenceList.browse() yöntemini çağırmalısınız.

FileReference sınıfını genişleten Adobe AIR File sınıfı için, herhangi bir dosyayı yüklemek için upload() yöntemini kullanabilirsiniz. FileReference sınıfı için (Flash Player'da kullanılan), kullanıcı ilk olarak bir dosya seçmelidir.

Dinleyiciler, yükleme işleminin ilerlemesini, başarılı veya başarısız olduğunu gösteren olaylar alır. Kullanıcıların yükleme için birden çok dosya seçmesini sağlamak için FileReferenceList nesnesini kullanabilseniz de dosyaları teker teker yüklemelisiniz; bunun için, FileReference nesnelerinin FileReferenceList.fileList dizisini yineleyin.

FileReference.upload() ve FileReference.download() işlevleri tıkanmasızdır. Bu işlevler çağrıldıktan sonra, dosya iletimi tamamlanmadan önce döndürülür. Ayrıca, FileReference nesnesi kapsam dışına çıkarsa, bu nesne üzerindeki henüz tamamlanmamış olan herhangi bir yükleme veya indirme işlemi, kapsam dışına çıkıldığında iptal edilir. Yükleme ve indirme işleminin devam etmesi beklenen süre boyunca FileReference nesnesinin kapsam içinde kaldığından emin olun.

Dosya, url parametresine iletilen URL'ye yüklenir. URL, yüklemeleri kabul edecek şekilde konfigüre edilmiş bir sunucu komut dosyası olmalıdır. Flash Player, HTTP POST yöntemini kullanarak dosyaları yükler. Yüklemeyi işleyen sunucu komut dosyası aşağıdaki öğelere sahip bir POST isteği beklemelidir:

• multipart/form-data öğesinin Content-Type öğesi
• Bir name niteliği varsayılan olarak "Filedata" şeklinde ayarlanmış ve bir filename niteliği orijinal dosyanın adı şeklinde ayarlanmış Content-Disposition öğesi.
• Dosyanın ikili içeriği

Ortak olarak ayrılmış bağlantı noktalarına bağlanamazsınız. Engellenen bağlantı noktalarının tam listesi için, bkz. "Ağ İletişimi API'lerini Kısıtlama", ActionScript 3.0 Geliştirici Kılavuzu.

Örnek bir POST isteği için, uploadDataFieldName parametresinin açıklamasına bakın. upload() yöntemini kullanarak POST veya GET parametrelerini sunucuya gönderebilirsiniz; request parametresinin açıklamasına bakın.

testUpload parametresi true değerindeyse ve yüklenecek dosya yaklaşık 10 KB'tan büyükse, Windows'daki Flash Player ilk olarak, iletimin başarılı olabileceğini doğrulamak için gerçek dosyayı yüklemeden önce sıfır içerikli bir test yüklemesi POST işlemi gönderir. Ardından Flash Player, gerçek dosya içeriğine sahip ikinci bir POST işlemi gönderir. 10 KB'tan küçük dosyalar için, Flash Player yüklenecek olan gerçek dosya içeriğiyle birlikte tek bir yükleme POST işlemi gerçekleştirir. Macintosh'taki Flash Player test yüklemesi POST işlemleri gerçekleştirmez.

Not: Sunucunuz kimlik doğrulama gerektiriyorsa, yalnızca bir tarayıcıda çalışan SWF dosyaları, yani, tarayıcı eklentisini veya ActiveX denetimini kullanan dosyalar, kimlik doğrulama ve yalnızca indirmeler için kullanıcıdan bir kullanıcı adı ve şifre isteyen bir iletişim kutusu sağlar. Eklenti veya ActiveX denetimini kullanan yüklemelerde veya tek başına çalışabilen ya da harici oynatıcıyı kullanan yüklemelerde ve indirmelerde, dosya aktarımı başarısız olur.

Bu yöntemi kullanırken Flash Player güvenlik modelini göz önünde bulundurun:

• Çağıran SWF dosyası güvenilmeyen bir yerel sanal alandaysa yükleme işlemlerine izin verilmez.
• Varsayılan davranış, sanal alanlar arasında erişimi reddetmektir. Bir web sitesi, URL ilke dosyası eklenerek bir kaynağa erişilmesini sağlayabilir.
• SWF içeriğini barındıran HTML sayfasındaki object veembed etiketlerinin allowNetworking parametresini ayarlayarak bir SWF dosyasının bu yöntemi kullanmasını önleyebilirsiniz.

Ancak Adobe AIR'de, application güvenlik sanal alanındaki içerik (AIR uygulamasıyla yüklenen içerik) bu güvenlik sınırlamalarıyla kısıtlanmaz.

Güvenlikle ilgili daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

Flash Player'a eklenen yeni işlevler nedeniyle, Flash Player 10'a yayın yapılırken aynı anda şu işlemlerden yalnızca birinin etkin olacağını unutmayın: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Aksi takdirde, Flash Player bir çalışma zamanı hatası (kod 2174) atar. Devam eden bir işlemi durdurmak için FileReference.cancel() öğesini kullanın. Bu kısıtlama yalnızca Flash Player 10 için geçerlidir. Önceki Flash Player sürümleri, eşzamanlı birden çok işlem üzerindeki bu kısıtlamadan etkilenmez.

Parametreler

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

İlgili API Öğeleri

Kodlama olmadan bir URL'ye dosya yüklemesini başlatır. upload() yöntemi dosyayı biçim-veri zarfında kodlarken, uploadUnencoded() yöntemi dosya içeriklerini HTTP istek gövdesinde olduğu gibi iletir. Göndermek istediğiniz veriler zaten alıcı sunucunun anlayabileceği bir biçimde kodlanmışsa uploadUnencoded() yöntemini kullanın.Genellikle HTTP/WebDAV PUT yöntemiyle uploadeUnencoded() yöntemi kullanılır.

Parametreler

İlgili API Öğeleri

Dosya yükleme veya indirme işlemi, kullanıcı tarafından dosya gözatma iletişim kutusu üzerinden iptal edildiğinde gönderilir. Kullanıcı yükleme veya indirme işlemini başka yollarla iptal ederse (tarayıcıyı kapatarak veya geçerli uygulamayı durdurarak), Flash Player bu olayı göndermez.

Bu olay şu özelliklere sahiptir:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

İndirme tamamlandığında veya sunucuya yükleme işlemi HTTP durum kodu 200 verdiğinde gönderilir. Dosya indirme işleminde, Flash Player veya Adobe AIR dosyanın tamamını diske indirmeyi bitirdiğinde bu olay gönderilir. Dosya yükleme işleminde, Flash Player veya Adobe AIR, iletimi alan sunucudan bir HTTP durum kodu 200 aldıktan sonra bu olay gönderilir.

Bu olay şu özelliklere sahiptir:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

İlgili API Öğeleri

upload() veya uploadUnencoded() yöntemine yapılan bir çağrı HTTP üzerinden verilere erişmeye çalışıyorsa ve Adobe AIR, istek için durum kodunu algılayıp döndürebiliyorsa gönderilir.

HTTPStatusEvent.HTTP_RESPONSE_STATUS sabiti, httpResponseStatus olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Sunucuya yükleme işlemi başarısız olduğunda ve hatayı tanımlayan bir HTTP durum kodu bulunduğunda gönderilir. Bir ioError olayı tarafından izlenen httpStatus olayı gönderilir.

httpStatus yalnızca yüklemelerin başarısız olma durumunda gönderilir. Flash Player'da çalışan içeriklerde bu olay, indirme hatası için geçerli değildir. İndirme bir HTTP hatası nedeniyle başarısız olursa, hata bir G/Ç hatası olarak bildirilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Sunucuya yükleme veya sunucudan indirme işlemi başarısız olduğunda gönderilir. Dosya aktarımı şu nedenlerin birinden ötürü başarısız olabilir:

• Oynatıcı dosyayı okurken, yazarken veya iletirken bir girdi/çıktı hatası oluşur.
• SWF dosyası, kimlik doğrulama (örn. kullanıcı adı ve şifre) gerektiren bir sunucuya dosya yüklemeyi dener. Flash Player veya Adobe AIR, yükleme sırasında kullanıcıların şifre girmesi için herhangi bir araç sağlamaz. Bir SWF dosyası kimlik doğrulama gerektiren bir sunucuya dosya yüklemeyi denerse, yükleme başarısız olur.
• SWF dosyası, kimlik doğrulama gerektiren bir sunucudan, tek başına çalışabilen veya harici oynatıcı içerisine dosya indirmeyi dener. Bağımsız ve harici oynatıcılar, indirme sırasında kullanıcıların şifre girmesi için herhangi bir araç sağlamaz. Bu oynatıcılardaki bir SWF dosyası, kimlik doğrulama gerektiren bir sunucudan dosya indirmeyi denerse, indirme başarısız olur. Dosya indirme işlemi yalnızca ActiveX denetiminde, tarayıcı eklentisi Player'larında ve Adobe AIR çalışma zamanında başarılı olabilir.
• upload() yöntemindeki url parametresine iletilen değer geçersiz bir protokol içeriyor. Geçerli protokoller HTTP ve HTTPS'dir.

Önemli: Yalnızca bir tarayıcıda çalışan — yani, tarayıcı eklentisi veya ActiveX denetimi kullanan — uygulamalar ve Adobe AIR'de çalışan içerik, kullanıcılara kimlik doğrulama için ve sonra da yalnızca indirme işlemleri için bir kullanıcı adı ve şifre girmelerini isteyen bir iletişim kutusu sağlayabilir. Flash Player'ın eklenti veya ActiveX denetimi sürümünü kullanılarak yapılan yüklemeler için veya tek başına çalışabilen ya da harici Player kullanarak yapılan yüklemeler için dosya aktarımı başarısız olur.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Sunucuya yükleme veya sunucudan indirme işlemi başladığında gönderilir.

Bu olay şu özelliklere sahiptir:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

İlgili API Öğeleri

Uygulama, dosya sistemine erişim izni istediğinde gönderilir. İznin verildiğini veya reddedildiğini belirlemek için status özelliğinin değerini kontrol edin

İlgili API Öğeleri

Sunucuya dosya yükleme veya sunucudan dosya indirme işlemi sırasında düzenli aralıklarla gönderilir. progress olayı Flash Player sunucuya bayt iletirken iletilir ve en sonunda iletim başarısız olsa da iletim sırasında belirli aralıklarla gönderilir. Dosya iletiminin başarılı bir şekilde tamamlanıp tamamlanmadığını ve ne zaman tamamlandığını belirlemek için complete olayını dinleyin.

Bazı durumlarda, progress olayları alınmaz. Örneğin, iletilmekte olan dosya çok küçükse ve yükleme ve indirme işlemi çok hızlı gerçekleşiyorsa bir progress olayı gönderilmeyebilir.

Dosya yükleme ilerlemesi, OS X 10.3'ten daha önceki Macintosh platformlarında belirlenemez. Yükleme işlemi sırasında progress olayı çağrılır ancak ilerleme olayının bytesLoaded özelliğinin değeri -1'dir ve ilerlemenin belirlenemeyeceğini gösterir.

Bu olay şu özelliklere sahiptir:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

İlgili API Öğeleri

FileReference.upload() veya FileReference.download() yöntemine yapılan bir çağrı sunucuya bir dosya yüklemeye çalıştığında veya çağıranın güvenlik sanal alanının dışındaki bir dosyayı sunucudan almaya çalıştığında gönderilir. Meydana gelen belirli hatayı açıklayan metin özelliğinin değeri normalde "securitySandboxError" şeklindedir. Çağıran SWF dosyası, kendi etki alanının dışındaki bir SWF dosyasına erişmeye çalışmış olabilir ve bunun için izne sahip olmayabilir. Bir URL like dosyası kullanarak bu hatayı gidermeyi deneyebilirsiniz.

Adobe AIR'de bu güvenlik kısıtlamaları, uygulama güvenlik sanal alanındaki içerik için geçerli değildir.

Adobe AIR'de bu güvenlik kısıtlamaları, uygulama güvenlik sanal alanındaki içerik için geçerli değildir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Kullanıcı, sunucuya yüklemek veya sunucudan indirmek için, dosyaya gözatma iletişim kutusundan dosya seçtiğinde gönderilir. (Bu iletişim kutusu, FileReference.browse(), FileReferenceList.browse() veya FileReference.download() yöntemini çağırdığınızda açılır.) Kullanıcı bir dosya seçtiğinde ve işlemi onayladığında (örneğin Tamam'ı tıklatarak), FileReference nesnesinin özellikleri doldurulur.

Flash Player'da veya Adobe AIR çalışma zamanındaki uygulama güvenlik sanal alanı dışında çalışan içerik için, select olayı kendisini çağıran yönteme bağlı olarak biraz farklı davranır. browse() çağrısından sonra select olayı gönderildiğinde, kullanıcı tarafından seçilen dosya yerel dosya sistemi üzerinde olduğundan Flash Player veya AIR uygulaması, FileReference nesnesinin tüm özelliklerini okuyabilir. download() çağrısından sonra select olayı oluştuğunda, select olayı gönderildiği zaman dosya henüz yerel dosya sistemine indirilmemiş olduğundan Flash Player veya AIR uygulaması yalnızca name özelliğini okuyabilir. Dosya indirildiğinde ve complete olayı gönderildiğinde, Flash Player veya AIR uygulaması, FileReference nesnesinin diğer tüm özelliklerini okuyabilir.

Bu olay şu özelliklere sahiptir:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Sunucuya yapılan başarılı bir yükleme işleminin ardından veri alındığında gönderilir. Veriler sunucudan döndürülmezse bu olay gönderilmez.

Bu olay şu özelliklere sahiptir:

Not: Bu örneği çalıştırmak için, uploadURL.url özelliğini, örnekteki kurgusal bir URL yerine gerçek bir URL'ye işaret edecek şekilde değiştirin. URL, belirtilen URL'nin kök web dizinindeki yourUploadHandlerScript.cfm adlı bir dosyaya işaret etmelidir. Konfigürasyonunuza bağlı olarak, SWF dosyasını Yerel Oynatma Güvenliği, Yalnızca Ağa Erişim şeklinde ayarlanmış biçimde derlemeniz veya Flash Player güvenlik ayarlarını bu dosyanın ağa erişmesine izin verecek şekilde güncellemeniz gerekebilir.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}