Date  - AS3

Bir Date nesnesi tarafından yerel saate göre belirtilen ayın günü (1 - 31 arasında bir tam sayı). Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bir Date nesnesinin evrensel saate (UTC) göre ayın günü (1 - 31 arasında bir tam sayı).

İlgili API Öğeleri

Bu Date nesnesi tarafından yerel saate göre belirtilen haftanın günü (Pazar için 0, Pazartesi için 1, vb.). Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bu Date nesnesinin evrensel saate (UTC) göre haftanın günü (Pazar için 0, Pazartesi için 1, vb.).

İlgili API Öğeleri

Bir Date nesnesinin yerel saate göre tam yılı (dört basamaklı bir sayı, örneğin 2000). Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bir Date nesnesinin evrensel saate (UTC) göre dört haneli yılı.

İlgili API Öğeleri

Bir Date nesnesinin gün bölümünün yerel saate göre saati (0 - 23 arasında bir tam sayı). Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bir Date nesnesinin evrensel saate (UTC) göre günün saati (0 - 23 arasında bir tam sayı).

İlgili API Öğeleri

Bir Date nesnesinin yerel saate göre milisaniye (0 - 999 arasında bir tam sayı) bölümü. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bir Date nesnesinin evrensel saate (UTC) göre milisaniye (0 - 999 arasında bir tam sayı) bölümü.

İlgili API Öğeleri

Bir Date nesnesinin yerel saate göre dakika (0 - 59 arasında bir tam sayı) bölümü. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bir Date nesnesinin evrensel saate (UTC) göre dakika (0 - 59 arasında bir tam sayı) bölümü.

İlgili API Öğeleri

Bir Date nesnesinin yerel saate göre ay (Ocak için 0, Şubat için 1, vb.) bölümü. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bir Date nesnesinin evrensel saate (UTC) göre ay (0 [Ocak] - 11 [Aralık]) bölümü.

İlgili API Öğeleri

Bir Date nesnesinin yerel saate göre saniye (0 - 59 arasında bir tam sayı) bölümü. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

Bir Date nesnesinin evrensel saate (UTC) göre saniye (0 - 59 arasında bir tam sayı) bölümü.

İlgili API Öğeleri

Bir Date nesnesi için evrensel saate göre 1 Ocak 1970 gece yarısından bu yana geçen milisaniye sayısı. İki veya daha fazla Date nesnesini karşılaştırırken zamandaki belirli bir örneği temsil etmek için bu yöntemi kullanın.

İlgili API Öğeleri

Evrensel saat (UTC) ve bilgisayarın yerel saati arasındaki dakika cinsinden fark. Özellikle bu değer, UTC'ye denk getirmek için bilgisayarın yerel saatine eklemeniz gereken dakika sayısıdır. Bilgisayarınızın saati UTC'den daha ileriyse, bu değer negatif olur.

İlgili API Öğeleri

Belirtilen tarih ve saati tutan yeni bir Date nesnesi oluşturur.

Date() yapıcısının milisaniye bir tarih ve saat belirtmesi için yedi parametre (year, month, ..., millisecond) gerekir. Yeni oluşturulan Date nesnesinin içerdiği tarih, iletilen argümanların sayısına ve veri türüne bağlıdır.

• Herhangi bir argüman iletmezseniz, Date nesnesi geçerli tarih ve saate atanır.
• Number veri türünde bir argüman iletirseniz, lone argümanının belirttiği gibi 1 Ocak, 1970 0:00:000 GMT zamanından itibaren geçen milisaniye sayısı temel alınarak Date nesnesine bir zaman değeri atanır.
• String veri türünde bir argüman iletirseniz ve dizede geçerli bir tarih bulunursa, Date nesnesi o tarihi temel alan bir zaman değerini içerir.
• İki veya daha fazla argüman iletirseniz; tarihteki yıl, ay, gün, saat, dakika, saniye ve milisaniyeyi temsil eden, iletilen argüman değerleri temel alınarak Date nesnesine bir zaman değeri atanır.

Date sınıfı yapıcısına bir dize iletirseniz, tarih çeşitli biçimlerde olabilir ancak en azından ay, gün ve yılı içermelidir. Örneğin, Feb 1 2005 geçerlidir ancak Feb 2005 geçerli değildir. Şu listede geçerli biçimlerden bazıları gösterilmektedir:

• Gün Ay Günü Tarihi Saat:Dakika:Saniye GMT Yıl (örneğin, "Tue Feb 1 00:00:00 GMT-0800 2005", bu toString() ile eşleşir)
• Gün Ay Günün Tarihi Yıl Saat:Dakika:Saniye AM/PM (örneğin, "Tue Feb 1 2005 12:00:00 AM", bu toLocaleString() ile eşleşir)
• Gün Ay Günün Tarihi Yıl (örneğin, "Tue Feb 1 2005", bu toDateString() ile eşleşir)
• Ay/Gün/Yıl (örneğin, "02/01/2005")
• Ay/Yıl (örneğin, "02/2005")

İlgili API Öğeleri

Bir Date nesnesi tarafından yerel saate göre belirlenmiş olarak ayın gününü (1 - 31 arası bir tam sayı) döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

İlgili API Öğeleri

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

Bu Date nesnesi tarafından yerel saate göre belirlenmiş olarak haftanın gününü döndürür (Pazar için 0, Pazartesi için 1 vb.). Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

Bir Date nesnesinde yerel saate göre tam yılı (2000 gibi dört haneli bir rakam) döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

Bir Date nesnesinde saati (0 - 23 arasında bir tam sayı olarak) yerel saate göre döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num as String;
}

Bir Date nesnesinin milisaniye bölümünü (0 - 999 arası bir tam sayı) yerel saate göre döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

var now:Date = new Date();
trace(now.getMilliseconds());

Bir Date nesnesinin dakika bölümünü (0 - 59 arası bir tam sayı) yerel saate göre döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

Bu Date nesnesinin ay (Ocak için 0, Şubat için 1 vb.) bölümünü yerel saate göre döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

Bir Date nesnesinin saniye (0 - 59 arası bir tam sayı) bölümünü yerel saate göre döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

var now:Date = new Date();
trace(now.getSeconds());

Bir Date nesnesi için evrensel saate göre 1 Ocak 1970 gece yarısından bu yana geçen milisaniye sayısını döndürür. İki veya daha fazla Date nesnesini karşılaştırırken zamandaki belirli bir örneği temsil etmek için bu yöntemi kullanın.

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
     }
 }
 

Evrensel saat (UTC) ve bilgisayarın yerel saati arasındaki farkı dakika cinsinden döndürür.

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

Bir Date nesnesindeki ayın gününü (1 - 31 arasında bir tam sayı) evrensel saate (UTC) göre döndürür.

İlgili API Öğeleri

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

Bu Date nesnesinde haftanın gününü (Pazar için 0, Pazartesi için 1 vb.) evrensel saate (UTC) göre döndürür.

İlgili API Öğeleri

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

Bir Date nesnesinin dört haneli yılını evrensel saate (UTC) göre döndürür.

İlgili API Öğeleri

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

Bir Date nesnesinin saatini (0 - 23 arasında bir tam sayı) evrensel saate (UTC) göre döndürür.

İlgili API Öğeleri

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

Bir Date nesnesinin milisaniye (0 - 999 arası bir tam sayı) bölümünü evrensel saate (UTC) göre döndürür.

var now:Date = new Date();
trace(now.getUTCMilliseconds());

Bir Date nesnesinin dakika (0 - 59 arası bir tam sayı) bölümünü evrensel saate (UTC) göre döndürür.

var now:Date = new Date();
trace(now.getUTCMinutes());

Bir Date nesnesinin ay (0 [Ocak] - 11 [Aralık]) bölümünü evrensel saate (UTC) göre döndürür.

İlgili API Öğeleri

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

Bir Date nesnesinin saniye (0 - 59 arası bir tam sayı) bölümünü evrensel saate (UTC) göre döndürür.

var now:Date = new Date();
trace(now.getUTCSeconds());

Bir tarihi temsil eden bir dizeyi 1 Ocak 1970, UTC tarihinden bu yana geçen milisaniye sayısına eşdeğer bir sayıya çevirir.

Parametreler

     Day Mon DD HH:MM:SS TZD YYYY
     

     Wed Apr 12 15:30:17 GMT-0700 2006
     

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD
     

İlgili API Öğeleri

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

Ayın gününü yerel saate göre ayarlar ve yeni saati milisaniye olarak döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

Parametreler

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

Yılı yerel saate göre ayarlar ve yeni saati milisaniye olarak döndürür. month ve day parametreleri belirtilirse, bunlar yerel saate ayarlanır. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

Bu yöntemin çağrılması, diğer Date alanlarını değiştirmez ancak bu yöntemin çağrılmasının sonucunda haftanın günü değişirse, Date.getUTCDay() ve Date.getDay() yeni bir değer bildirebilir.

Parametreler

İlgili API Öğeleri

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

Saati yerel saate göre ayarlar ve yeni saati milisaniye olarak döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

Parametreler

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

Milisaniyeyi yerel saate göre ayarlar ve yeni saati milisaniye olarak döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

Parametreler

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

Dakikayı yerel saate göre ayarlar ve yeni saati milisaniye olarak döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

Parametreler

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

Ayı ve istenirse ayın gününü yerel saate göre ayarlar ve yeni saati milisaniye olarak döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

Parametreler

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

Saniyeyi yerel saate göre ayarlar ve yeni saati milisaniye olarak döndürür. Yerel saat, Flash çalışma zamanlarının çalıştığı işletim sistemi tarafından belirlenir.

Parametreler

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

Tarihi 1 Ocak 1970 gece yarısından itibaren geçen milisaniyelere ayarlar ve yeni saati milisaniye olarak döndürür.

Parametreler

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

Ayın gününü evrensel saate (UTC) göre ayarlar ve yeni saati milisaniye olarak döndürür. Bu yöntemin çağrılması, diğer Date alanlarını değiştirmez ancak bu yöntemin çağrılmasının sonucunda haftanın günü değişirse, Date.getUTCDay() ve Date.getDay() yöntemleri yeni bir değer bildirebilir.

Parametreler

İlgili API Öğeleri

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

Yılı evrensel saate (UTC) göre ayarlar ve yeni saati milisaniye olarak döndürür.

İsteğe bağlı olarak bu yöntem de ayı ve ayın gününü ayarlayabilir. Bu yöntemin çağrılması, diğer alanları değiştirmez, ancak bu yöntemin çağrılmasının sonucunda haftanın günü değişirse, Date.getUTCDay() ve Date.getDay() yöntemleri yeni bir değer bildirebilir.

Parametreler

İlgili API Öğeleri

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

Saati evrensel saate (UTC) göre ayarlar ve yeni saati milisaniye olarak döndürür. İsteğe bağlı olarak dakika, saniye ve milisaniye belirtilebilir.

Parametreler

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

Milisaniyeyi evrensel saate (UTC) göre ayarlar ve yeni saati milisaniye olarak döndürür.

Parametreler

var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

Dakikayı evrensel saate (UTC) göre ayarlar ve yeni saati milisaniye olarak döndürür. İsteğe bağlı olarak saniyeleri ve milisaniyeleri belirtebilirsiniz.

Parametreler

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

Ayı ve istenirse günü evrensel saate (UTC) göre ayarlar ve yeni saati milisaniye olarak döndürür. Bu yöntemin çağrılması, diğer alanları değiştirmez, ancak bu yöntemin çağrılmasının sonucunda haftanın günü değişirse, Date.getUTCDay() ve Date.getDay() yöntemleri yeni bir değer bildirebilir.

Parametreler

İlgili API Öğeleri

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

Saniyeyi ve istenirse milisaniyeyi evrensel saate (UTC) göre ayarlar ve yeni saati milisaniye olarak döndürür.

Parametreler

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

Yalnızca gün ve tarihin dize ile temsil edilen halini döndürür ve saati veya saat dilimini içermez. Şu yöntemlerin tersidir:

• Yalnızca saat ve saat dilimini döndüren Date.toTimeString()
• Gün ve tarihin yanı sıra saat ve saat dilimini de döndüren Date.toString().

İlgili API Öğeleri

var now:Date = new Date();
trace(now);
trace(now.toDateString());

Bir Date nesnesindeki değerlerin JSON kodlamasını özelleştirmek için geçersiz kılınabilir bir yöntem sağlar.

JSON.stringify() yöntemi, geçtiği her nesnede bir toJSON() yöntemi arar. toJSON() yöntemi bulunursa JSON.stringify() yöntemi, karşılaştığı her bir değer için onu çağırır ve değerle eşleşen tuşu iletir.

Date; toJSON() yönteminin Date.toString() çıktısını döndüren bir varsayılan uygulamasını sağlar. Date nesnelerini JSON sınıfına herhangi başka bir biçimde dışa aktarmak isteyen istemciler kendi uygulamalarını sağlayabilir. toJSON() yöntemini sınıf prototipinde yeniden tanımlayarak bunu gerçekleştirebilirsiniz.

toJSON() yöntemi herhangi bir türde değer döndürebilir. Bir nesne döndürürse, stringify() o nesne içinde kendi kendini yineler. toJSON() bir dize döndürürse, stringify() kendi kendini yinelemez ve geçişine devam eder.

Parametreler

İlgili API Öğeleri

Yalnızca gün ve tarihin dize ile temsil edilen halini döndürür ve saati veya saat dilimini içermez. Bu yöntem, Date.toDateString ile aynı değeri döndürür. Şu yöntemlerin tersidir:

• Yalnızca saat ve saat dilimini döndüren Date.toTimeString()
• Gün ve tarihin yanı sıra saat ve saat dilimini de döndüren Date.toString().

İlgili API Öğeleri

Gün, tarih ve saatin, yerel saat olarak dize ile temsil edilen halini döndürür. Dizenin sonunda listelenen yıl ile aynı bilgileri (artı saat dilimini) döndüren Date.toString() yönteminin tersi.

Yalnızca saatin dize ile temsil edilen halini döndürür, gün, tarih, yıl veya saat dilimi içermez. Saat ve saat dilimini döndüren Date.toTimeString() yönteminin tersi.

İlgili API Öğeleri

Gün, tarih, saat ve saat diliminin dize ile temsil edilen halini döndürür. Çıktının tarih biçimi şudur:

     Day Mon Date HH:MM:SS TZD YYYY
     

Örneğin:

     Wed Apr 12 15:30:17 GMT-0700 2006
     

var now:Date = new Date();
trace(now);

Yalnızca saat ve saat diliminin dize ile temsil edilen halini döndürür, gün ve tarihi içermez. Yalnızca gün ve tarihi döndüren Date.toDateString() yönteminin tersi.

İlgili API Öğeleri

Gün, tarih ve saatin evrensel saat (UTC) biçiminde bir dize ile temsil edilen halini döndürür. Örneğin, 1 Şubat 2005 tarihi, Tue Feb 1 00:00:00 2005 UTC olarak döndürülür..

İlgili API Öğeleri

01 Ocak 1970 gece yarısı evrensel saat ile parametrelerde belirtilen saat arasındaki milisaniye sayısını döndürür. Date yapıcısı yerel saati kullanırken, bu yöntem evrensel saati kullanır.

Date sınıfı yapıcısına UTC tarihi iletmek isterseniz bu yöntem yararlıdır. Date sınıfı yapıcısı parametre olarak milisaniye uzaklığını kabul ettiğinden, UTC tarihini, karşılık gelen milisaniye uzaklığına dönüştürmek ve bu uzaklığı argüman olarak Date sınıfı yapıcısına göndermek için Date.UTC() yöntemini kullanabilirsiniz.

Parametreler

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

Bir Date nesnesi için evrensel saate göre 1 Ocak 1970 gece yarısından bu yana geçen milisaniye sayısını döndürür.

var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());

• myDate1 parametre olmadan Date() öğesini çağırır, bu da şu anki tarih ve saate myDate1 öğesini ayarlar (geçerli sisteminizin tarih ve saatine göre).
• myDate2, year (2000), month (0 = January) ve day (1) parametreleri iletilmiş şekilde Date() öğesini çağırır.
• myDate3, parametre olarak year (65 = 1965), month (2 = March), day (6), hour (9), minute (30), second (15) ve millisecond-+ (0) iletilmiş şekilde Date() öğesini çağırır.
• myDate4, 0:00:00 GMT 1 Ocak 1970 öncesindeki milisaniye sayısını temsil eden zaman değeriyle (değer negatif olduğundan) Date() öğesini çağırır.

package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}