File  - AS3

Uygulamanın yüklü dosyalarını içeren klasör.

Bu nesneye ait url özelliği, app URL şemasını kullanır (file URL şemasını değil). Bu, url dizesinin "app:" ile ("file:" ile değil) başlayacak şekilde belirtildiği anlamına gelir. Ayrıca, File.applicationDirectory diziniyle ilgili bir File nesnesi oluşturursanız (resolvePath() yöntemini kullanarak), File nesnesinin url özelliği de app URL şemasını kullanır.

Not: app: URL şemasını kullanan yollara sahip olan dosya veya dizinlere yazamazsınız. Ayrıca, app: URL şemasını kullanan yollara sahip olan dosya veya klasörleri silemez ya da oluşturamazsınız. Uygulama dizinindeki içeriği değiştirmek, güvenlik nedenlerinden ötürü iyi bir uygulama değildir ve bazı platformlarda işletim sistemi tarafından engellenir. Uygulamaya özel verileri saklamak istiyorsanız, uygulama saklama dizinini (File.applicationStorageDirectory) kullanmayı deneyin. Uygulama saklama dizinindeki herhangi bir içeriğin uygulama ayrıcalıklı işleve (AIR API'leri) erişmesini isterseniz, bir sanal alan köprüsü kullanarak bu işlevi kullanıma açabilirsiniz.

applicationDirectory özelliği, platformlar arası çalışan uygulama dizinine başvurmak için bir yol sağlar. Bir File nesnesini nativePath veya url özelliğini kullanarak uygulama dizinine başvurmak üzere ayarlarsanız, yalnızca bu yolun geçerli olduğu platformda çalışacaktır.

Android üzerinde, uygulama dizinine işaret eden bir File nesnesinin nativePath özelliği boş bir dizedir. Uygulama dosyalarına erişmek için url özelliğini kullanın.

İlgili API Öğeleri

Uygulamanın özel saklama dizini.

Her bir AIR uygulamasının File.applicationStorageDirectory öğesine ilk eriştiğinizde oluşturulan benzersiz, kalıcı bir uygulama saklama dizini vardır. Bu dizin her uygulama ve kullanıcı için benzersizdir. Bu dizin, kullanıcıya özel veya uygulamaya özel verilerin saklanması için uygun bir konumdur.

Bir AIR uygulamasını kaldırdığınızda, kaldırıcının uygulama saklama dizinini ve dosyalarını silip silmeyeceği platforma bağlıdır.

Bu nesneye ait url özelliği, app-storage URL şemasını kullanır (file URL şemasını değil). Bu, url dizesinin "app-storage:" ile ("file:" ile değil) başlayacak şekilde belirtildiği anlamına gelir. Ayrıca, File.applicationStoreDirectory diziniyle ilgili bir File nesnesi oluşturursanız (resolvePath() yöntemini kullanarak), File nesnesinin url öğesi de app-storage URL şemasını kullanır (örnekteki gibi).

applicationStorageDirectory özelliği, platformlar arası çalışan uygulama saklama dizinine başvurmak için bir yol sağlar. Bir File nesnesini nativePath veya url özelliğini kullanarak uygulama saklama dizinine başvurmak üzere ayarlarsanız, yalnızca bu yolun geçerli olduğu platformda çalışacaktır.

Not (Yalnızca Mac OS): Mac App Store gereksinimlerine uymak için bu dizinin fiziksel konumu AIR 3.2 ile AIR 3.3 arasında değişmiştir:

• 3.2 ad alanı veya öncesi: ~/Library/Preferences/appid/Local Store/
• 3.3 ad alanı veya üstü: path/Library/Application Support/appid/Local Store/: Burada path ~/Library/Containers/bundle-id/Data (korumalı ortam) veya ~ (korumalı bir ortamın dışında çalıştırırken) şeklindedir

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

Uygulama önbelleği dizini.

cacheDirectory özelliği, önbellek dizinine başvurma yolu sağlar. Uygulamanız, bir sunucudan indirilen veya farklı şekilde yeniden oluşturulabilen dosyaları depolamak için önbellek dizinini kullanmalıdır. Önbellek dizinine koymanız gereken dosya örneklerine veritabanı önbellek dosyaları ve indirilebilir içerik dahildir (dergi, gazete ve harita uygulamaları tarafından kullanılanlar gibi).

Bir File nesnesini nativePath veya url özelliğini kullanarak önbellek dizinine başvurmak üzere ayarlarsanız, yalnızca bu yolun geçerli olduğu platformlarda çalışacaktır.

Bir işletim sistemi önbellek dizinini desteklemiyorsa, cacheDirectory öğesi null değerindedir

Kullanıcının masaüstü dizini.

desktopDirectory özelliği, platformlar arası çalışan masaüstü dizinine başvurmak için bir yol sağlar. Bir File nesnesini nativePath veya url özelliğini kullanarak masaüstü dizinine başvurmak üzere ayarlarsanız, yalnızca bu yolun geçerli olduğu platformda çalışacaktır.

Bir işletim sistemi masaüstü dizinini desteklemezse, bunun yerine dosya sistemindeki uygun bir dizin kullanılır.

AIR for TV aygıtlarında kullanıcı için bir masaüstü dizini yoktur. Bu yüzden, desktopDirectory özelliği File.userDirectory özelliğiyle aynı dizin konumuna başvurur. Kullanıcı dizini uygulama için benzersizdir.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Kullanıcının belgeler dizini.

Windows'da bu, Belgelerim dizinidir (örneğin, C:\Documents and Settings\kullanıcıAdı\Belgelerim). Mac OS'de, varsayılan konum /Kullanıcılar/kullanıcıAdı/Belgelerim dizinidir. Linux'ta, varsayılan konum /home/userName/Documents (İngilizce sistemde) dizinidir ve özellik xdg-user-dirs ayarını izler.

documentsDirectory özelliği, platformlar arası çalışan belgeler dizinine başvurmak için bir yol sağlar. Bir File nesnesini nativePath veya url özelliğini kullanarak belgeler dizinine başvurmak üzere ayarlarsanız, yalnızca bu yolun geçerli olduğu platformda çalışacaktır.

Bir işletim sistemi belgeler dizinini desteklemezse, bunun yerine dosya sistemindeki uygun bir dizin kullanılır.

AIR for TV aygıtlarında kullanıcı için bir belgeler dizini yoktur. Bu yüzden, documentsDirectory özelliği File.userDirectory özelliğiyle aynı dizin konumuna başvurur. Kullanıcı dizini uygulama için benzersizdir.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Başvurulan dosyanın veya dizinin indirilip indirilmediğini (Internet'ten) belirtir.

Bu özellik yalnızca dosyaların indirildi olarak işaretlenebildiği işletim sistemlerinde mantıklıdır.

• Windows XP servis paketi 2 ve sonrasında ve Windows Vista'da
• Mac OS 10.5 ve sonrasında

Linux gibi, indirilen dosyaları işaretlemeyen sistemlerde bu özellik mantıklı değildir (ve false olarak ayarlanır).

İlgili API Öğeleri

Başvuru yapılan dosyanın veya dizinin mevcut olup olmadığını gösterir. File nesnesi, mevcut bir dosyayı veya dizini işaret ediyorsa değer true, aksi takdirde false olur.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Dosya için tanımlanmış olan simgeleri içeren bir Icon nesnesi. Bir Icon nesnesi, çeşitli simge durumlarına karşılık gelen bir BitmapData nesneleri dizisidir Linux'ta, Icon nesnesi simge içermez. Android üzerinde, icon özelliği null şeklindedir.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Başvurunun bir dizine yapılıp yapılmadığını gösterir. File nesnesi, mevcut bir dosyayı veya dizini işaret ediyorsa değer true, aksi takdirde false olur.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Başvuru yapılan dosyanın veya dizinin “gizli“ olup olmadığını gösterir. Başvuru yapılan dosya veya dizin gizli ise değer true, aksi takdirde false olur.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Başvuru yapılan dizinin bir paket olup olmadığını gösterir.

Başvuru yapılan dizin bir paketse değer true, aksi takdirde false olur. File sınıfının paketleri doğrudan oluşturmaya izin vermediğini unutmayın.

• Mac OS'da dizinler, paket halinde atanabilir ve Finder'da bir dizin yerine tek bir dosya olarak görünür. Başvurulan dizin bir paket olduğunda, bu özellik true olarak, ve dosya bir dizin olmadığında, mevcut olmadığında veya bir paket olmadığında ise false olarak ayarlanır.
• Diğer işletim sistemlerinde bu özellik her zaman false olarak ayarlanmıştır.

Başvurunun sembolik bir bağ olup olmadığını gösterir.

File nesnesi sembolik bir bağsa değertrue, aksi takdirde false olur. File sınıfının sembolik bağları doğrudan oluşturmaya izin vermediğini unutmayın.

Sembolik bağlar, bir dosyanın diskteki başka bir dosyayı veya dizini işaret etmesine olanak tanır. Benzer olmasına rağmen sembolik bağlar, Mac OS'deki takma adlarla ve Windows'taki kısayollarla aynı değildir. Bir takma ad veya kısayol her zaman bir dosya (dizin yerine) olarak bildirilir ve bir takma adın veya kısayolun okunması ya da yazılması, işaret ettiği orijinal dosyayı veya dizini asla etkilemez. Diğer yandan, sembolik bir bağ, genellikle işaret ettiği dosya veya dizin gibi davranır. Bir dosya veya dizin olarak bildirilebilir ve sembolik bağın okunması veya yazılması, sembolik bağın kendisini değil de işaret ettiği dosyayı veya dizini etkiler. Ancak, sembolik bir bağın silinmesi bağı silerken, bağın hedefini silmez.

Mac^® OS^®, Linux ve Windows^® Vista^®, sembolik bağları destekler. Buna ek olarak Windows'da, bir bağlantı noktasına (NTFS dosya sisteminde kullanılır) başvuru yapan bir File nesnesinin isSymbolicLink özelliği true değerine ayarlanmıştır.

Ana bilgisayar işletim sistemi tarafından kullanılan satır sonu karakter sırası.

Bu, Mac OS ve Linux'ta satır besleme karakteridir (karakter kodu 0x0A onaltılık). Windows'da bu, satır başı besleme karakterini (karakter kodu 0x0D onaltılık) izleyen satır besleme karakteridir (karakter kodu 0x0A onaltılık).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Ana bilgisayar işletim sistemi sunumundaki tam yol. Mac OS ve Linux'ta, eğik çizgi (/) karakteri yol ayırıcı olarak kullanılır. Ancak Windows'da, eğik çizgi karakterini veya ters eğik çizgi (\) karakterini yol ayırıcı olarak kullanıp, nativePath özelliğini ayarlayabilirsiniz; AIR, eğik çizgileri uygun ters eğik çizgilerle değiştirir.

Doğrudan nativePath özelliğini ayarlamak için kod yazmadan önce, bunun platforma özgü kodlarla sonuçlanıp sonuçlanmayacağını göz önünde bulundurun. Örneğin, "C:\\Documents and Settings\\bob\\Desktop" gibi yerel yollar yalnızca Windows'ta geçerlidir. Genel olarak kullanılan dizinleri temsil eden ve tüm platformlarda geçerli olan aşağıdaki statik özellikleri kullanmak çok daha iyidir:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Bu dizinlere ilişkin bir yol elde etmek için resolvePath() yöntemini kullanabilirsiniz.

SWFLoader sınıfının source özelliği gibi bazı Flex API'leri, yerel bir yol (nativePath özelliği) değil, bir URL (File nesnesinin url özelliği) kullanır.

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Bu File nesnesi tarafından başvuru yapılan dosyayı veya dizini içeren dizin.

Dosya veya dizin mevcut değilse, o dizin mevcut olmasa bile parent özelliği yine de kapsayıcı dizini işaret eden File nesnesini döndürür.

Bu özellik resolvePath("..") öğesinin döndürme değeriyle aynıdır (kök dizinin üst öğesinin null olması dışında)

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Uygulamaya dosya sistemi erişiminin verilip verilmediğini belirler.

İlgili API Öğeleri

Çalışma zamanının, bu File nesnesinin bulutta yedeklenmesini engelleyip engellemediğini gösterir.

Bu özellik true olarak ayarlanmışsa, bu hizmeti sağlayan platformlarda buluta otomatik olarak yedeklenmez. Bu özelliğin varsayılan değeri false olur.

Ana bilgisayar işletim sisteminin yol bileşeni ayırıcı karakteri.

Bu, Mac OS ve Linux'ta eğik çizgi (/) karakteridir. Windows'da, ters eğik çizgi (\) karakteridir.

Not: Ters eğik çizgi karakterini bir Dize değişmezinde kullanırken, karakteri iki kez yazmayı unutmayın ("directory\\file.ext" içinde olduğu gibi). Bir Dize değişmezi içindeki her ters eğik çizgi çifti, Dize'deki tek bir ters eğik çizgiyi temsil eder.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

Bu File konumundaki kullanılabilir alan (bayt olarak).

File nesnesi bir dizine başvuruyorsa spaceAvailable, dosyaların kullanabileceği dizindeki alanı belirtir. File nesnesi bir dosyaya başvuruyorsa spaceAvailable, dosyanın içinde büyüyebileceği alanı belirtir. Dosya konumu mevcut değilse spaceAvailable 0 değerine ayarlıdır. File nesnesi sembolik bir bağa başvuruyorsa spaceAvailable, sembolik bağın işaret ettiği konumdaki mevcut alanı belirtir.

Genellikle, bir dizin veya dosya için mevcut olan alan dizini veya dosyayı içeren birimdeki alanla aynıdır. Ancak mevcut alan, kotaları ve dizin başına sınırları da hesaba katar.

Bir birime dosya veya dizin eklemek genellikle dosyanın gerçek boyutundan veya dizinin içeriğinin boyutundan daha fazlasını gerektirir. Örneğin işletim sistemi dizin bilgisini saklamak için daha fazla alan gerektirebilir. Veya gereken disk kesimleri ek alan kullanabilir. Ayrıca, kullanılabilir alan dinamik olarak değişir. Bu yüzden, bildirilen alanın tümünün dosya saklama amacıyla ayrılması beklenilemez.

Varsayılan kodlama, ana bilgisayar işletim sistemi tarafından kullanılır.

Olası değerler arasında, "windows-1252" "shift-jis", "cn-gb", "iso-8859-1" ve diğerleri yer alır. Tam liste için, bkz. Desteklenen Karakter Kümeleri.

Bu değeri, FileStream sınıfının readMultiByte() ve writeMultiByte() yöntemlerini kullanırken kullanabilirsiniz.

İlgili API Öğeleri

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

Bu yola ait URL.

Bu, uygulama saklama dizinindeki bir yola yapılan bir başvuruysa, URL şeması "app-storage"; uygulama dizinindeki yola yapılan bir başvuruysa, URL şeması "app" olur; aksi takdirde şema "file" olur.

url özelliğine bir değer atarken boşluk karakteri ("%20" yerine) kullanabilirsiniz; AIR uygulaması dizeleri otomatik olarak kodlar (örneğin, boşlukların "%20"'ye dönüştürülmesi).

İlgili API Öğeleri

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Kullanıcının dizini.

Windows'da bu, Belgelerim dizininin üstüdür (örneğin, C:\Documents and Settings\kullanıcıAdı). Mac OS'de, /Users/userName. Linux'ta, /home/userName.

userDirectory özelliği, platformlar arası çalışan kullanıcı dizinine başvurmak için bir yol sağlar. Bir File nesnesinin nativePath veya url özelliğini doğrudan ayarlarsanız, yalnızca bu yolun geçerli olduğu platformda çalışacaktır.

Bir işletim sistemi kullanıcı dizinini desteklemezse, bunun yerine dosya sistemindeki uygun bir dizin kullanılır.

AIR for TV aygıtlarında, userDirectory özelliği, uygulama için benzersiz olan bir kullanıcı dizinine başvurur.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

File sınıfının yapıcı işlevi.

Bir path argümanını iletirseniz, File nesnesi belirtilen yolu işaret eder ve nativePath özelliği ve url özelliği, o yolu yansıtacak şekilde ayarlanır.

Bir dosya yolu belirlemek için path argümanını iletebilseniz de, bunu yapmanın platforma özgü kodlarla sonuçlanıp sonuçlanmayacağını göz önünde bulundurun. Örneğin, "C:\\Documents and Settings\\bob\\Desktop" gibi yerel bir yol veya "file:///C:/Documents%20and%20Settings/bob/Desktop" gibi bir URL yalnızca Windows'ta geçerlidir. Genel olarak kullanılan dizinleri temsil eden ve tüm platformlarda geçerli olan aşağıdaki statik özellikleri kullanmak çok daha iyidir:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Bu şekilde, bu dizinlere ilişkin bir yol elde etmek için resolvePath() yöntemini kullanabilirsiniz. Örneğin, aşağıdaki kod uygulama saklama dizinindeki settings.xml dosyasını işaret eden bir File nesnesi kurar:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Önemli: path parametresindeki bir URL dizesini iletirseniz, URL dosya yolunu çözümlemek için çözülür. Örneğin, new File("file:///c:/test/demo%20file%201%2e0.txt") ifadesi, "c:\test\demo file 1.0.txt" yerel yoluna sahip bir File nesnesi oluşturur. (URL file:, app: veya app-storage: scheme öneklerini kullanır.) Ancak geçerli URL önekleri çıkarılırsa, yol dizesi yerel bir yol gibi işlem görür ve çözülme gerçekleşmez. Potansiyel olarak güvenilmeyen kaynaklardan türetilen yolları onaylarken bu davranışı dikkate almanız gerekmektedir. Girdi dizesini onaylarsanız, URL'nin kodunun çözülmesi bir saldırganın onay kontrollerinizi atlamasına izin verebilir. Başlatılan File nesnesinin son yolunu her zaman onaylayın:

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

İlgili API Öğeleri

Dizin seçici bir iletişim kutusu görüntüler; buradan kullanıcı bir dizin seçebilir. Kullanıcı dizini seçtiğinde, select olayı gönderilir. select olayının target özelliği, seçili dizini işaret eden File nesnesidir.

Dizin seçici iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (null değerinde olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

Not: Android cihazlarında browseForDirectory() desteklenmez. File nesnesi hemen bir cancel olayı gönderir.

Parametreler

İlgili API Öğeleri

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Dosyayı Aç iletişim kutusunu görüntüler; buradan kullanıcı açacağı dosyayı seçer.

Kullanıcı dosyayı seçtiğinde, select olayı gönderilir. select olayının target özelliği, seçili dosyayı işaret eden File nesnesidir.

Dosyayı Aç iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (boş olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

Not: Android aygıtlarında, dosya iletişim kutusu başlığı ayarlanamaz. title parametresi yok sayılır.

Parametreler

İlgili API Öğeleri

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Dosyayı Aç iletişim kutusunu görüntüler, buradan kullanıcı açacağı bir veya daha fazla dosyayı seçebilir.

Kullanıcı dosyaları seçtiğinde, selectMultiple olayı gönderilir. select olayının target özelliği, bu File dosyasıdır. browseForOpen() yönteminden farklı olarak browseForOpenMultiple() yöntemi ile bu File nesnesi, seçilen dosyalardan herhangi birine başvuru yapmak üzere güncellenmez. Bunun yerine, elde edilen selectMultiple olayı, seçilen dosyaların bir dizinini içerir.

Dosyayı Aç iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (boş olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

Not: Android aygıtlarında, dosya iletişim kutusu başlığı ayarlanamaz. title parametresi yok sayılır.

Parametreler

İlgili API Öğeleri

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Dosyayı Kaydet iletişim kutusunu görüntüler, buradan kullanıcı dosyanın hedefini seçebilir.

Kullanıcı dosyayı seçtiğinde, select olayı gönderilir. select olayının target özelliği, seçili Kaydet konumunu işaret eden File nesnesidir.

Dosyayı Kaydet iletişim kutusu her zaman başka bir pencerenin "sahip olduğu" pencerelerin (null değerinde olmayan bir owner özelliğine sahip pencerelerin) önünde görüntülenmez. Pencere sıralama sorunlarını önlemek için, bu yöntemi çağırmadan önce sahip olunan pencereleri gizleyin.

Not: Android aygıtlarında, dosya iletişim kutusu başlığı ayarlanamaz. title parametresi yok sayılır.

Parametreler

İlgili API Öğeleri

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Bekleyen herhangi bir eşzamansız işlemi iptal eder.

File dizinini kanonlaştırır.

File nesnesi, var olan bir dosyayı veya dizini temsil ediyorsa kanonlaştırma işlemi, yolu gerçek dosya veya dizin adının durumuyla eşleşecek şekilde ayarlar. File nesnesi sembolik bir bağsa, kanonlaştırma işlemi, işaret edilen dosya veya dizinin var olup olmadığına bakılmaksızın, yolu bağın işaret ettiği dosya veya dizinle eşleşecek şekilde ayarlar. Büyük/küçük harfe duyarlı dosya sistemlerinde (Linux gibi), yalnızca büyük/küçük harfle yazım açısından farklı olan adlara sahip birden çok dosya bulunuyorsa, canonicalize() yöntemi, bulunan ilk dosyayla eşleşecek biçimde yolu ayarlar (dosya sistemi tarafından belirlenen düzende).

Ayrıca, kurallaştırma işlemi Windows'ta kısa dosya adlarını uzun dosya adlarına çevirir.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Bu File nesnesinin bir kopyasını döndürür. Olay kayıtları kopyalanmadı.

Not: Bu yöntem, dosyayı kendisi kopyalamaz. Yalnızca ActionScript File nesnesi örneğinin bir kopyasını oluşturur. Bir dosyayı kopyalamak için copyTo() yöntemini kullanın.

Bu File nesnesi tarafından belirtilen konumdaki dosya veya dizini, newLocation parametresi tarafından belirtilen konuma kopyalar. Kopyalama işlemi, gerekli üst dizinleri oluşturur (mümkünse). copyTo() kullanılarak dosyaların üzerine yazılırken, dosya niteliklerinin de üzerine yazılır.

Parametreler

İlgili API Öğeleri

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Bu File nesnesi tarafından belirtilen konumdaki dosya veya dizini, destination parametresi tarafından belirtilen konuma kopyalamaya başlar.

Tamamlandığında, bir complete olayı (başarılı) veya bir ioError olayı (başarısız) gönderilir. Kopyalama işlemi, gerekli üst dizinleri oluşturur (mümkünse).

Parametreler

İlgili API Öğeleri

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Belirtilen dizini ve gerekli üst dizinleri oluşturur. Dizin zaten mevcutsa, hiçbir eylem yapılmaz.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Yeni bir geçici dizine bir başvuru döndürür. Bu, sistemin geçici dizin yolundaki yeni bir dizindir.

Bu yöntem, sistemin dizinin yeni ve benzersiz olup olduğunu sorgulamasını zorunlu kılmadan yeni, benzersiz bir dizin oluşturmanıza olanak tanır.

Bazı cihazlarda otomatik olarak silinmediğinden, uygulamayı kapatmadan önce geçici dizini silmek isteyebilirsiniz.

İlgili API Öğeleri

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Yeni bir geçici dosyaya bir başvuru döndürür. Bu, sistemin geçici dizin yolundaki yeni bir dosyadır.

Bu yöntem, sistemin dosyanın yeni ve benzersiz olup olduğunu sorgulamasını zorunlu kılmadan yeni, benzersiz bir dosya oluşturmanıza olanak tanır.

Otomatik olarak silinmediğinden, uygulamayı kapatmadan önce geçici dosyayı silmek isteyebilirsiniz.

İlgili API Öğeleri

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Dizini siler. Bu Dosya gerçekte bir dizine ilişkin sembolik bir bağsa, dizin değil, bağ kaldırılır.

Parametreler

İlgili API Öğeleri

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Dizini eşzamansız olarak siler. Bu Dosya gerçekte bir dizine ilişkin sembolik bir bağsa, dizin değil, bağ kaldırılır.

Parametreler

İlgili API Öğeleri

Dosyayı siler. Bu Dosya gerçekte sembolik bir bağsa, hedef dosya değil, bağ kaldırılır.

İlgili API Öğeleri

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Dosyayı eşzamansız olarak siler. Bu Dosya gerçekte sembolik bir bağsa, hedef dosya değil, bağ kaldırılır.

İlgili API Öğeleri

Bu File nesnesi tarafından temsil edilen dizindeki dosyalara ve dizinlere karşılık gelen bir File nesneleri dizisi döndürür. Bu yöntem, alt dizinlerin içeriğini araştırmaz.

İlgili API Öğeleri

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Bu File nesnesi tarafından temsil edilen dizinin içeriğine karşılık gelen bir File nesneleri dizisini eşzamansız olarak alır.

İlgili API Öğeleri

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

İki File yolu arasındaki ilgili yolu bulur.

İlgili yol, ikinci (parametre) başvuruyu konumlandırmak için bu başvuruya eklenebilecek (çözülebilecek) bileşenlerin listesindedir. İlgili karakter, "/" ayırıcı karakteri kullanılarak döndürülür.

İsteğe bağlı olarak, ilgili yollar ".." başvurularını içerebilir, ancak bu yollar belirgin hacim sınırlarını geçmez.

Parametreler

Dosya sistemi kök dizinlerini listeleyerek, bir File nesneleri dizisi döndürür.

Örneğin, Windows'da bu, C: sürücüsü ve D: sürücüsü gibi hacimlerin bir listesidir. Hiçbir diskin takılmadığı bir CD veya DVD sürücüsü gibi boş bir sürücü, bu diziye dahil edilmemiştir. Mac OS ve Linux'ta, bu yöntem her zaman bilgisayar için benzersiz bir kök dizini döndürür ("/" dizini)

Android dosya sistemi gibi, kökün okunabilir olmadığı dosya sistemlerinde, döndürülen File nesnesinin özellikleri her zaman doğru değeri yansıtmaz. Örneğin, Android üzerinde spaceAvailable özelliği 0 değerini bildirir.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Bu File nesnesi tarafından belirtilen konumdaki dosya veya dizini, destination parametresi tarafından belirtilen konuma taşır.

Bir dosyayı yeniden adlandırmak için destination parametresini dosyanın dizininde bulunan bir yolu işaret edecek şekilde, ancak farklı bir dosya adıyla ayarlayın.

Taşıma işlemi, gerekli üst dizinleri oluşturur (mümkünse).

Parametreler

İlgili API Öğeleri

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Bu File nesnesi tarafından belirtilen konumdaki dosya veya dizini, newLocation parametresi tarafından belirtilen konuma taşımaya başlar.

Bir dosyayı yeniden adlandırmak için destination parametresini dosyanın dizininde bulunan bir yolu işaret edecek şekilde, ancak farklı bir dosya adıyla ayarlayın.

Taşıma işlemi, gerekli üst dizinleri oluşturur (mümkünse).

Parametreler

İlgili API Öğeleri

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Bir dosyayı veya dizini çöp kutusuna taşır.

Not: Kurtarılabilir bir çöp kutusu klasörünü desteklemeyen işletim sistemlerinde, dosyalar hemen silinir.

İlgili API Öğeleri

Bir dosyayı veya dizini çöp kutusuna eşzamansız olarak taşır.

Not: Kurtarılabilir bir çöp kutusu klasörünü desteklemeyen işletim sistemlerinde, dosyalar hemen silinir.

İlgili API Öğeleri

Bu dosya türünü açmak için işletim sistemi tarafından kaydedilen uygulamada dosyayı açar.

AIR, belirli dosyaları açmak için File.openWithDefaultApplication() yöntemini kullanmanızı önler. Windows'da AIR, belirli dosya türündeki dosyaları (aşağıda listelenen, belirli uzantılara sahip dosyalar) açmanızı önler. Mac OS ve Linux'ta, AIR aşağıda belirtilen belirli uygulamalarda başlatılacak dosyaları açmanıza izin vermez. openWithDefaultApplication() yöntemini kullanarak bu dosyalardan birini açmaya çalışırsanız, bir istisna atılır. Ancak, yerel yükleyici ile yüklenen AIR uygulamaları (genişletilmiş masaüstü profili uygulamaları), bu sınırlamalarla kısıtlanmamıştır, her türde dosyayı açabilir.

Uygulama dizininden belgeleri açamazsınız.

Aşağıdaki tablolarda, Windows'da yasaklanan dosya uzantıları ve Mac OS ve Linux'ta engellenen uygulamalar listelenmektedir:

İlgili API Öğeleri

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Dosya sistemine erişim ister.

path parametresine (bir dize) göre, bu File nesnesinin yoluyla ilgili bir yol ile yeni bir File nesnesi oluşturur.

path parametresine göre mutlak bir yol veya göreceli bir yol kullanabilirsiniz.

Göreceli bir yol belirttiğinizde, söz konusu path, File nesnesinin yoluna “eklenir“. Ancak ".." karakterlerinin kullanımı path içinde kullanılması, File nesnesinin alt öğesi olmayan bir sonuç yolu döndürebilir. Elde edilen başvurunun, gerçek bir sistem konumuna başvurması gerekmez.

Mutlak bir dosya başvurusu belirtirseniz yöntem, o yolu işaret eden File nesnesini döndürür. Mutlak dosya başvurusu, kullanıcının işletim sistemi için geçerli bir yerel yol kullanmalıdır (Windows'ta "C:\\test" gibi). path parametresi olarak URL kullanmayın (örn "file:///c:/test").

Elde edilen tüm yollar şu şekildedir:

• Herhangi bir "." öğesi yok sayılır.
• Herhangi bir ".." öğesi, üst öğesini tüketir.
• Dosya sistemi köküne veya uygulamaya özgü kalıcı depolama köküne ulaşan hiçbir ".." başvurusu o düğümü geçemez; yok sayılır.

Yol ayırıcı olarak her zaman eğik çizgi (/) karakterini kullanmalısınız. Windows'da, ters eğik çizgi (\) karakterini de kullanabilirsiniz, ancak kullanmamanız daha iyidir. Ters eğik çizgi karakteri kullanıldığında, uygulamaların diğer platformlarda çalışmamasına neden olunabilir.

Linux'ta dosya adları ve dizin adları büyük/küçük harfe duyarlıdır.

Parametreler

Bekleyen bir eşzamansız işlem iptal edildiğinde gönderilir.

Bu olay şu özelliklere sahiptir:

Eşzamansız bir dosya işlemi tamamlandığında gönderilir.

Bu olay şu özelliklere sahiptir:

getDirectoryListingAsync() yöntemine yapılan bir çağrının sonucu olarak, bir dizin listesi kullanılabilir hale geldiğinde gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Eşzamansız bir dosya işlemi sırasında hata oluştuğunda gönderilir.

Bu olay şu özelliklere sahiptir:

Uygulama, dosya sistemine erişim izni istediğinde gönderilir. İznin verildiğini veya reddedildiğini belirlemek için status özelliğinin değerini kontrol edin

İlgili API Öğeleri

Bir işlem, bir güvenlik sınırlamasını ihlal ettiğinde gönderilir.

Bu olay şu özelliklere sahiptir:

Kullanıcı, bir dosyayı veya dizini bir dosya veya dizin tarama iletişim kutusundan seçtiğinde gönderilir.

Bu olay şu özelliklere sahiptir:

Kullanıcı, dosyaları browseForOpenMultiple() yöntemine yapılan bir çağrı tarafından açılan iletişim kutusundan seçtiğinde gönderilir.

İlgili API Öğeleri