URLLoader  - AS3

Yükleme sırasında şimdiye kadar gönderilen bayt sayısını gösterir.

İndirilen verideki toplam bayt sayısını gösterir. Yükleme işlemi devam ederken bu özellik 0 değerini içerir ve işlem tamamlandığında doldurulur. Ayrıca, eksik bir Content-Length üstbilgisi bytesTotal öğesinin belirsiz olmasına neden olur.

Yükleme işleminden alınan veriler. Bu özellik yalnızca yükleme işlemi tamamlandığında doldurulur. Verilerin biçimi dataFormat özelliğinin ayarına bağlıdır:

dataFormat özelliği URLLoaderDataFormat.TEXT olursa, alınan veriler, yüklenen dosyanın metnini içeren bir dize olur.

dataFormat özelliği URLLoaderDataFormat.BINARY olursa, alınan veriler, ham ikili verileri içeren bir ByteArray nesnesidir.

dataFormat özelliği URLLoaderDataFormat.VARIABLES olursa, alınan veriler, URL kodlu değişkenleri içeren bir URLVariables nesnesidir.

İlgili API Öğeleri

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

İndirilen verinin metin olarak mı (URLLoaderDataFormat.TEXT), ham ikili veri olarak mı (URLLoaderDataFormat.BINARY) yoksa URL kodlu değişkenler olarak mı (URLLoaderDataFormat.VARIABLES) alınacağını denetler.

dataFormat özelliğinin değeri URLLoaderDataFormat.TEXT olursa, alınan veriler, yüklenen dosyanın metnini içeren bir dize olur.

dataFormat özelliğinin değeri URLLoaderDataFormat.BINARY olursa, alınan veriler, ham ikili verileri içeren bir ByteArray nesnesidir.

dataFormat özelliğinin değeri URLLoaderDataFormat.VARIABLES olursa, alınan veriler, URL tarafından kodlanan değişkenleri içeren bir URLVariables nesnesidir.

Varsayılan değer şudur URLLoaderDataFormat.TEXT.

İlgili API Öğeleri

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Bir URLLoader nesnesi oluşturur.

İlgili API Öğeleri

EventDispatcher nesnesi olan bir olay dinleyici nesnesini, dinleyicinin bir olayın bildirimini alması için kaydeder. Belirli türde bir olay, aşama ve öncelik için görüntüleme listesindeki tüm düğümlere olay dinleyicilerini kaydedebilirsiniz.

Bir olay dinleyicisini başarıyla kaydettikten sonra, addEventListener() öğesine ek çağrılar yaparak önceliğini değiştiremezsiniz. Bir dinleyicinin önceliğini değiştirmek için, ilk olarak removeListener() öğesini çağırmanız gerekir. Daha sonra dinleyiciyi yeni öncelik seviyesiyle kaydedebilirsiniz.

Dinleyici kaydedildikten sonra, farklı bir type veya useCapture değeriyle addEventListener() öğesine yapılan çağrılar, ayrı bir dinleyici kaydının oluşturulmasıyla sonuçlanır. Örneğin, ilk olarak useCapture true değerine ayarlanmış durumdayken bir dinleyiciyi kaydederseniz, dinleyici yalnızca yakalama aşaması boyunca dinleme işlemi yapar. Aynı dinleyici nesnesini kullanarak, ancak useCapture false değerine ayarlanmış durumdayken tekrar addEventListener() öğesini çağırırsanız, iki ayrı dinleyiciniz olur: bunlardan biri yakalama aşamasında dinleme işlemi yapar, diğeri ise hedef ve köpürme aşamasında dinleme işlemi yapar.

Yalnızca hedef aşaması veya köpürme aşaması için bir olay dinleyicisini kaydedemezsiniz. Köpürme yalnızca hedef düğümün alt öğeleri için geçerli olduğundan, bu aşamalar kayıt sırasında birleştirilir.

Artık bir olay dinleyicisine ihtiyacınız olmadığında, removeEventListener() öğesini çağırarak olay dinleyicisini kaldırın, aksi takdirde bellek sorunları oluşabilir. Çöp toplayıcısı, gönderen nesne var olduğu sürece dinleyiciyi kaldırmadığından, (useWeakReference parametresi true olarak ayarlı değilse) olay dinleyicileri otomatik olarak bellekten kaldırılmaz.

Bir EventDispatcher örneği kopyalandığında, o örneğe ekli olan olay dinleyicileri kopyalanmaz. (Yeni oluşturulmuş düğümünüz için bir olay dinleyicisi gerekiyorsa, düğümü oluşturduktan sonra dinleyiciyi eklemeniz gerekir.) Ancak bir EventDispatcher örneğini taşırsanız, örneğe ekli olan olay dinleyicileri de onunla birlikte taşınır.

Bir olay düğümde işlenirken olay dinleyicisi o düğüme kaydediliyorsa, geçerli aşama sırasında olay dinleyicisi tetiklenmez ancak olay akışındaki köpürme aşaması gibi sonraki bir aşamada tetiklenebilir.

Bir olay düğümde işlenirken olay dinleyicisi o düğümden kaldırılırsa, geçerli eylemler tetiklenmeye devam eder. Olay dinleyicisi kaldırıldıktan sonra asla tekrar çağrılmaz (ileride işlenmek üzere tekrar kaydedilmediği sürece).

Parametreler

function(evt:Event):void

Devam etmekte olan yükleme işlemini kapatır. Devam etmekte olan herhangi bir yükleme işlemi hemen sonlandırılır. Herhangi bir URL o anda akıştaysa, geçersiz bir akış hatası verilir.

Belirtilen URL'ye veri gönderir ve buradan veri yükler. Veriler dataFormat özelliği için ayarladığınız değere bağlı olarak metin, ham ikili veriler veya URL kodlu değişkenler şeklinde alınabilir. dataFormat özelliğinin varsayılan ayarının metin olduğunu unutmayın. Verileri belirtilen URL'ye göndermek isterseniz, URLRequest nesnesindeki data özelliğini ayarlayabilirsiniz.

Not: İndirilen bir dosya ASCII olmayan karakterler içeriyorsa (İngilizce dışındaki birçok dilde görüldüğü gibi) dosyayı, ASCII gibi Unicode olmayan bir biçimin aksine UTF-8 veya UTF-16 kodlamasıyla kaydetmeniz önerilir.

Dosya sistemine sahip yerel sanal alandaki bir SWF dosyası, ağ sanal alanındaki bir kaynaktan veya ağ sanal alanındaki bir kaynağa veri yükleyemeyebilir.

Varsayılan olarak, çağıran SWF dosyası ve yüklediğiniz URL tamamen aynı etki alanında olmalıdır. Örneğin www.adobe.com adresindeki bir SWF dosyası yalnızca www.adobe.com adresinde bulunan kaynaklardan veri yükleyebilir. Farklı bir etki alanından veri yüklemek için, verileri barındıran sunucuya bir URL ilke dosyası yerleştirin.

Ortak olarak ayrılmış bağlantı noktalarına bağlanamazsınız. Engellenen bağlantı noktalarının tam listesi için, bkz. "Ağ İletişimi API'lerini Kısıtlama", ActionScript 3.0 Geliştirici Kılavuzu.

Flash Player 10 ve sonrasında, yükleme (POST gövdesi içinde "content-disposition" başlığında "filename" parametresiyle belirtilir) içeren çok bölümlü bir Content-Type (örneğin, "multipart/form-data") kullanırsanız, POST işlemi, yüklemelere uygulanan güvenlik kurallarına tabidir:

• Fare tıklatma veya tuş basışı gibi kullanıcı tarafından başlatılan bir eyleme yanıt olarak POST işleminin gerçekleştirilmesi gerekir.
• POST işlemi etki alanları arasıysa (POST hedefi, POST isteğini gönderen SWF dosyasıyla aynı sunucuda değilse), hedef sunucunun etki alanları arası erişime izin veren bir URL ilke dosyası sağlaması gerekir.

Ayrıca çok bölümlü herhangi bir Content-Type için sözdiziminin geçerli olması gerekir (RFC2046 standartlarına göre). Sözdizimi geçersiz görünüyorsa, POST işlemi, yüklemelere uygulanan güvenlik kurallarına tabi olur.

Güvenlikle ilgili daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

Parametreler

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Alınan tüm verilerin kodu çözüldükten ve URLLoader nesnesinin data özelliğine yerleştirildikten sonra gönderilir. Alınan verilere bu olay gönderildiğinde erişilebilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

load() yöntemine yapılan bir çağrı HTTP üzerinden verilere erişmeye çalışıyorsa ve Adobe AIR, istek için durum kodunu algılayıp döndürebiliyorsa gönderilir.

HTTPStatusEvent.HTTP_RESPONSE_STATUS sabiti, httpResponseStatus olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

URLLoader.load() yöntemine yapılan bir çağrı HTTP üzerinden verilere erişmeye çalışıyorsa gönderilir. Flash Player'da çalışan içerik için, bu olay yalnızca geçerli Flash Player ortamı isteğe ilişkin durum kodunu algılayıp döndürebiliyorsa gönderilir. (Bazı tarayıcı ortamları, bu bilgiyi sağlayamayabilir.) httpStatus olayının (varsa) herhangi bir complete veya error olayından önce (veya buna ek olarak) gönderileceğini unutmayın.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

URLLoader.load() öğesine yapılan bir çağrı, indirme işlemini sonlandıran kritik bir hatayla sonuçlanırsa gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

URLLoader.load() yöntemine yapılan bir çağrıyı izleyen indirme işlemi başladığında gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

İndirme işlemi ilerlerken veri alındığında gönderilir.

Bir URLLoader nesnesi kullanılarak, verilerin tamamı alınana kadar bu verilere erişemeyeceğinizi unutmayın. Bu nedenle, ilerleme olayı yalnızca indirme işleminin ne kadar ilerlediğini gösteren bir bildirim görevi görür. Verilerin tamamı indirilmeden önce verilere erişmek için bir URLStream nesnesi kullanın.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

URLLoader.load() öğesine yapılan bir çağrı, güvenlik sanal alanının dışındaki bir sunucudan veri yüklemeye çalıştığında gönderilir. Ayrıca URLLoader.load() öğesine yapılan bir çağrı, SWZ dosyasını yüklemeye çalıştığında ve sertifika geçersiz olduğunda veya özet dizesi bileşenle eşleşmediğinde gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Not:Bu örneği çalıştırmak için, SWF dosyanızla aynı dizine urlLoaderExample.txt adlı bir dosya koyun. Bu dosya yalnızca şu metin satırını içermelidir: answer=42&question=unknown

Örnek kodu şu işlemleri gerçekleştirir:

1. Yapıcı işlevi bir loader adlı bir URLLoader örneği ve request adlı bir URLRequest örneği oluşturur. Bu örnekler yüklenecek dosyanın konumunu ve adını içerir.
2. loader nesnesi, desteklenen her URLLoader olayı için dinleyiciler ekleyen configureListeners() yöntemine iletilir.
3. Ardından request nesnesi, metin dosyasını yükleyen loader.load() öğesine iletilir.
4. URLLoader, metin dosyasını yüklemeyi tamamladığında Event.COMPLETE olayı tetiklenir ve bu da completeHandler() yöntemini tetikler. completeHandler() yöntemi, dosyadan yüklenen metinden bir URLVariables nesnesi oluşturur. URLVariables nesnesi, yüklenen verileri işlemeyi kolaylaştırmak için URL tarafından kodlanan ad/değer çiftlerini ActionScript özelliklerine dönüştürür.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}