AccessibilityImplementation  - AS3

Hata kodu belirtir. Hata kodları döndürme değerlerinde değil bant dışı belirtilir. Bir hata belirtmek için errno özelliğini AccessibilityImplementation Sabitleri ekinde belgelenen hata kodlarından birine ayarlayın. Bu, döndürme değerinizin yok sayılmasına sebep olur. AccessibilityImplementation öğesinin errno özelliği her zaman herhangi bir AccessibilityImplementation yöntemi çağırılmadan önce temizlenir (sıfıra ayarlanır)

İlgili API Öğeleri

Bileşen erişilebilirliği kalıntısı oluşturmada kullanılır. Bir bileşen ActionScript erişilebilirlik uygulaması olmadan bırakılırsa, Adobe bileşen erişilebilirliği kalıntısı eklemenizi önerir. Bu kalıntı, erişilebilirlik amaçları için Flash Player'ın bileşenin içindeki düğmelerin, metin alanlarının ve diğerlerinin dahili yapısını göstermek yerine bileşeni basit grafik olarak değerlendirmesine sebep olur.

Bileşen erişilebilirlik kalıntısı oluşturmak için özellik kalıntısını true değeri ile geçersiz kılarak, uygun AccImpl sınıfını alt sınıf yapın.

İlgili API Öğeleri

Statik yapıcı AccessibilityImplementation öğesini yapıcısını çağırarak doğrudan başlatmayın. Bunun yerine her yeni bileşen için mx.accessibility.AccImpl sınıfını genişleterek yeni erişim uygulamaları oluşturun.

İlgili API Öğeleri

AccessibilityImplementation tarafından temsil edilen bileşen ile veya alt öğelerinden biriyle eşleşen varsayılan eylemi uygulayan bir IAccessible yöntemidir.

Bu yöntemi yalnızca AccessibilityImplementation MSAA modeli içinde varsayılan eyleme sahip bir kullanıcı arabirimi öğesi ile eşleşiyorsa uygulayın.

accDoDefaultAction() öğesini yalnızca AccessibilityImplementation veya alt öğeleri için çalıştırıyorsanız, bazı durumlarda söz konusu childID için varsayılan eylemin olmadığını göstermeniz gerekecektir. Bunu errno özelliğini E_MEMBERNOTFOUND şeklinde ayarlayarak yapın.

Parametreler

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

AccessibilityImplementation öğesinde alt öğenin sınırlayıcı kutusunu belirleyen DisplayObject öğesini veya Rectangle öğesini döndürmek için MSAA yöntemidir.

Bu yöntem hiçbir zaman sıfır childID ile çağırılmaz. AccessibilityImplementation öğesi hiçbir zaman alt öğe barındırmayacaksa bu yöntemi uygulamamalısınız. AccessibilityImplementation öğesi alt öğe içerebilirse bu yöntem zorunludur.

Genellikle bu yöntemin gerektirdiklerini alt öğe ile eşleşen bir nesneyi döndürerek karşılayabilirsiniz. Alt öğe DisplayObject olduğu sürece bu yapılabilir. Bunun gibi durumlarda görüntüleme listesindeki görsel nesneyle ilişkili örnek adıyla eşleşen DisplayObject öğesini döndürün.

Alt öğe yukarıda anlatılan teknik için yeterli nitelikte değilse sınırlayıcı kutusu matematiğini siz de yapabilir ve x, y, width ve height özelliklerine sahip bir Rectangle döndürebilirsiniz. x ve y üyeleri sınırlayıcı kutusunun sol-üst köşesini belirlerken, width ve height üyeleri boyutunu belirler. Dört üyenin tamamı Sahne Alanı pikselleri biriminde ve AccessibilityImplementation öğesinin temsil ettiği bileşene göre olmalıdır. DisplayObject öğesinin başlangıç noktası her zaman sol-üst köşesi olmadığından x ve y özellikleri eksi değer alabilir.

childID tarafından belirtilen öğe görünmüyorsa, i(get_accState alt öğesi STATE_SYSTEM_INVISIBLE) öğesini de içeren bir değer döndüreceğinden, accLocation öğesinden null döndürebilirsiniz. Ayrıca alt öğenin görünür halde belireceği koordinatları temsil eden birRectangle da döndürebilirsiniz.

Parametreler

Daha fazla bilgi

İlgili API Öğeleri

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

Bu AccessibilityImplementation öğesinin temsil ettiği bileşendeki seçimi değiştirmeyi sağlayan IAccessible yöntemi.

childID parametresi her zaman sıfırdır. Bu yöntem genel bileşene değil alt öğe için geçerlidir, Flash Player genel bileşenin seçiminin yönetimini kendisi yapar.

selFlag parametresi bir ve daha fazla seçim bayrağı bileşenlerinden oluşan, bir MSAA istemcisinin childID tarafından başvuru yapılan bir öğenin nasıl seçileceği veya odaklanacağını belirtmesini sağlayan bir bit alanıdır. Aşağıda seçim bayrağı bileşenleri ve erişilebilirlik uygulamalarına ne ilettiklerinin hakkında açıklamalar bulunmaktadır. Pratikte, Flex mx.accessibility.ListBaseAccImpl sınıfından devralan bu erişilebilirlik uygulamaları yönteminin çoğu uygulaması selFlag bileşenini yok sayar ve çoklu seçimi işlemek için bileşenin klavye seçim davranışını kullanır.

selFlag parametresi SELFLAG_TAKEFOCUS bayrağını içerebilir veya içermeyebilir. İçermesi durumunda, alt öğe odağını belirtilen childID'ye ayarlamalı ve SELFLAG_EXTENDSELECTION ayrıca bulunmadığı sürece alt öğeyi seçim tutturucusu yapmalısınız. İçermiyorsa alt öğe odağı ve seçim tutturucusu, aşağıda tanımlanan ek bayraklar seçimi değiştirebilecekse de, değiştirilmeden kalmalıdır.

selFlag argümanı aşağıdaki dört bayraktan birini her zaman barındıracaktır. Bu bayraklar hangi tür seçim değişikliğinin istendiğini gösterir.

• SELFLAG_TAKESELECTION: Var olan bütün seçimleri temizle ve seçimi belirli childID'ye ayarlar.

• SELFLAG_EXTENDSELECTION: Seçim tutturucusunun ve belirli childID öğesinin arasındaki ve onların da dahil olduğu alt öğe aralığını hesaplar. SELFLAG_ADDSELECTION varsa, bütün alt öğelerini seçime ekler. SELFLAG_ADDSELECTION varsa, bütün alt öğelerini seçimden çıkarır. Ne SELFLAG_ADDSELECTION ne de SELFLAG_REMOVESELECTION mevcutsa, bütün bu alt öğeler seçim tutturucusunun seçim durumunu almalıdır: seçim tutturucusu seçilirse bu alt öğeleri seçime ekler; seçilmezse seçimden çıkarır.

• SELFLAG_ADDSELECTION (SELFLAG_EXTENDSELECTION hariç): Belirli childID öğesinden seçime ekler.

• SELFLAG_REMOVESELECTION (SELFLAG_EXTENDSELECTION hariç): Belirli childID öğesini seçimden çıkarır.

Çoklu seçilemeyen bileşen için geçerli selFlag parametre değerlerinin yalnızca SELFLAG_TAKEFOCUS ve SELFLAG_TAKESELECTION olduğunu göz önünde bulundurun. Teorik olarak ayrıca çoklu seçilemeyen ve kullanıcının null seçimi zorlamasına olanak veren bir bileşen için SELFLAG_REMOVESELECTION öğesini de desteklemeyi seçebilirdiniz fakat pratikte çoğu çoklu seçilemeyen bileşen bu şekilde çalışmaz ve MSAA istemcileri bu tip işlemler gerçekleştirmez.

Yanlış görünen bayraklarla karşılaşırsanız errno öğesini E_INVALIDARG olarak ayarlayın.

Son olarak,accSelectçağrıldığında Flash Player'ın, host focus (kap uygulamasının pencere odağı) bulundurduğundan ve bileşeninizin Flash Player'ın içinde odağı olduğundan emin olduğunu göz önünde bulundurun.

Parametreler

Daha fazla bilgi

İlgili API Öğeleri

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

Bu AccessibilityImplementation öğesinin temsil ettiği bileşenin veya alt öğelerinden birinin varsayılan eylemini döndürmeyi sağlayan MSAA yöntemi.

Bu yöntemi yalnızca AccessibilityImplementation MSAA modelinde varsayılan eyleme sahip bir kullanıcı arabirimi öğesini temsil ediyorsa uygulayın ve MSAA modelinin belirttiği dizeyi döndürdüğünüzden emin olun. Örneğin, düğme bileşeninin varsayılan eylem dizesi "Bas"'tır.

get_accDefaultAction öğesini yalnızca AccessibilityImplementation veya alt öğeleri için çalıştırıyorsanız, bazı durumlarda söz konusu iletilen childID için varsayılan eylemin olmadığını göstermeniz gerekecektir. Bunu null döndürerek yapın.

Parametreler

Daha fazla bilgi

İlgili API Öğeleri

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

Bileşenin içinde alt öğe odağı olan alt öğenin imzasız tam sayı kimliğini döndürmeyi sağlayan MSAA yöntemi. Hiçbir alt öğenin alt öğe odağı yoksa yöntem sıfır döndürür.

Daha fazla bilgi

İlgili API Öğeleri

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

Bu AccessibilityImplementation öğesinin temsil ettiği bileşenin veya alt öğelerinden birinin adını döndürmeyi sağlayan MSAA yöntemi.

AccessibilityImplementation öğesinde, (childID == 0), bu yöntem uygulanmıyor veya bir değer döndürmüyorsa, Flash Player, varsa, AccessibilityProperties.name özellik değerini kullanır.

Alt öğe alabilen AccessibilityImplementationlar için bu yöntem uygulanmalıdır ve childID sıfırın dışında bir sayı olduğu zaman dize değeri döndürmelidir.

Kullanıcı kimliği öğesinin türüne bağlı olarak MSAA'daki adlar iki farklı anlama gelebilir: geliştirici tarafından atanmış ad veya öğenin gerçek metin içeriği. Genellikle, an AccessibilityImplementation ilk kategoriye girer. name özelliği geliştirici tarafından atanmış bir addır. Alt öğeler her zaman ikinci kategoriye girer. Adları metin içeriklerini gösterir.

AccessibilityImplementation öğesinin name özelliği geliştirici tarafından atanmış bir ad anlamını taşıdığında, bileşenlerin geliştiricilerden ad almasının iki yolu vardır. İlki, bileşenin içinde bulunan adları gerektirir, örneğin, onay kutusu bileşeni adı olarak görev yapan bir metin etiketi bulundurabilir. İkincisi—ilkine destek olarak—kullanıcı arabiriminde belirtilen adları gerektirir ve AccessibilityProperties.name öğesinde son bulur. Bu destek seçeneği kullanıcıların Sprite'a veya Film Klibi'ni adlandırdıkları şekilde ad vermelerini sağlar.

Bu, AccessibilityImplementation için üç olasılık tanır (childID == zero):

• Bileşen içerisinde yazar tarafından atanan ad.get_accName yöntemi uygulanmalı ve childID sıfır olduğunda AccessibilityImplementation adını barındıran bir dize değeri döndürmelidir. childID sıfırsa ancak AccessibilityImplementation adsızsa, get_accName oynatıcının AccessibilityProperties.name özelliğine başvurmasını engellemek üzere boş bir dize döndürmelidir.

• Kullanıcı arabiriminden gelen, yazar tarafından atanan ad. AccessibilityImplementation alt öğe alabiliyorsa, get_accName yöntemi uygulanmalı ancak childID sıfır olduğunda değer döndürmemelidir. AccessibilityImplementation asla alt öğe almayacaksa, get_accName uygulanmamalıdır.

• İçeriği belirten ad.get_accName yöntemi uygulanmalı ve childID sıfır olduğunda uygun dize değeri döndürmelidir. childID sıfırsa ancak AccessibilityImplementation içeriksizse, get_accName, oynatıcının AccessibilityProperties.name özelliğine başvurmasını engellemek üzere boş bir dize döndürmelidir.

Alt öğeler için (AccessibilityImplementation bunları alabiliyorsa), her zaman üçüncü durum geçerlidir. get_accName yöntemi uygulanmalı ve childID sıfır dışında bir sayı olduğunda uygun dize değeri döndürmelidir.

Parametreler

Daha fazla bilgi

İlgili API Öğeleri

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

Bu AccessibilityImplementation öğesinin temsil ettiği bileşenin veya alt öğelerinden birinin sistem rolünü döndürmeyi sağlayan MSAA yöntemi. MSAA'daki bütün bileşenler için sistem rolleri önceden tanımlanmıştır.

Parametreler

Daha fazla bilgi

İlgili API Öğeleri

Seçili olan bütün alt öğelerin kimliklerinin bulunduğu diziyi döndürmeyi sağlayan MSAA yöntemi. Döndürülmüş dizi hepsi imzasız tam sayı olan sıfır, bir veya daha fazla kimlik içerebilir.

Daha fazla bilgi

İlgili API Öğeleri

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

Bu AccessibilityImplementation öğesinin temsil ettiği bileşenin veya alt öğelerinden birinin geçerli çalışma zamanı durumunu döndürmeyi sağlayan IAccessible yöntemi.

Bu yöntem MSAA'daki bileşenler için sıfır, bir veya daha fazla önceden tanımlanmış nesne durumu sabitleri kombinasyonu döndürmelidir. Birden fazla durum geçerli olduğu zaman, |, bitsel OR operatörü kullanılarak durum sabitleri birleştirilerek bir bit alanı oluşturulmalıdır.

Hiçbir durum sabitinin geçerli olmadığını göstermek için bu yöntem sıfır döndürmelidir.

STATE_SYSTEM_FOCUSABLE veya STATE_SYSTEM_FOCUSED durumlarını izleme veya bildirme gereği duymamanız gerekir. Flash Player bu durumları otomatik olarak işler.

Parametreler

Daha fazla bilgi

İlgili API Öğeleri

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

Bu AccessibilityImplementation öğesinin temsil ettiği bileşenin veya alt öğelerinden birinin çalışma zamanı değerini döndürmeyi sağlayan MSAA yöntemi.

Bu yöntemi yalnızca AccessibilityImplementation öğesi, MSAA modeli içinde değere sahip bir kullanıcı arabirimi öğesini temsil ediyorsa uygulayın. Bazı kullanıcı arabirimlerinin görünür 'değer'lere sahip oldukları halde bu değerleri değişik yolardan gösterdiklerini unutmayın. Örneğin; get_accName (örneğin metin), get_accState (örneğin onay kutuları) veya get_accSelection (örneğin liste kutusu).

get_accValue öğesini yalnızca AccessibilityImplementation veya alt öğeleri için çalıştırıyorsanız; bazı durumlarda, iletilen söz konusu childID için değer kavramının olmadığını göstermeniz gerekecektir. Bunu null döndürerek yapın.

Parametreler

Daha fazla bilgi

İlgili API Öğeleri

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

AccessibilityImplementation içerisindeki bütün alt öğelerinin imzasız tam sayı kimliklerini barındıran bir diziyi döndürür.

Dizinin uzunluğu sıfır olabilir. Dizinin içindeki kimlikler temsil ettikleri alt öğeler ile aynı mantık sıralamasında görünmelidir. AccessibilityImplementation öğesi alt öğe barındırabiliyorsa bu yöntem zorunludur; barındıramıyorsa uygulamayın.

Alt öğelerinize alt öğe kimlikleri atarken AccessibilityImplementation öğesindeki her örnekte benzersizliğini koruyan herhangi bir şemayı seçin. Alt öğe kimliklerinin bitişik olmaları ve sıralamalarının alt öğelerin mantıksal sıralamalarıyla eşleşmesi gerekmez. Alt öğe kimliklerini yeniden kullanmamak üzere yerleştirmelisiniz; bir alt öğe silinirse, kimliği o AccessibilityImplementation örneğinin kullanıldığı zaman boyunca hiç tekrar kullanılmamalıdır. Flash Player kodundaki uygulama seçimlerine bağlı olarak, bir milyonu geçen alt öğe kimliğini kullanmanız sonucu istenmeyen davranışlar ortaya çıkabilir.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Bu AccessibilityImplementation öğesinin temsil ettiği bileşen için, x, y, width ve height ile belirlenen bir sınırlama kutusu sahibi metin objesinin etiket olarak değerlendirilip değerlendirilmemesi gerektiğini gösteren true veya false döndürür.

x ve y koordinatları AccessibilityImplementation öğesinin uyguladığı bileşenin üst sol köşesine görecelidir ve eksi değer alabilir. Bütün koordinatlar Sahne alanı pikseli birimindedir.

Bu yöntem erişilebilir bileşenlerin Flash Player'ın otomatik etiketleme ilişkileri aramasına uymasını sağlar. Bu da bir nesnenin dışındaki metnin nesnenin adını sağlamasına izin verir. Bu yöntem, etiket tanınmasındaki kıstasların bileşenden bileşene değişmesi beklendiği için verilmiştir. Bu yöntemi uyguladığınızda, oynatıcının düğmeler ve metin alanları için kullanılan kodunun içindekine benzer geometrik kıstaslar kullanmayı hedeflemelisiniz. Kıstaslar aşağıdaki gibidir:

• Düğmeler için düğmenin içine tam olarak düşen herhangi bir metin etiket kabul edilir.
• Metin alanları için yukarıda yakın konumda ve sola hizalandırılmış veya solun yakınında görülen herhangi bir metin etiket kabul edilir.

AccessibilityImplementation öğesinin temsil ettiği bileşen hiçbir zaman otomatik etiketleme ilişkilerine katılmayacaksa isLabeledBy uygulanmaz. Bu, her zamanfalse dönmesine eş değerdir. isLabeledBy uygulanmaması gereken bir durum da, AccessibilityImplementation öğesinin yukarıda, get_accName altında açıklanan "bileşen içindeki geliştirici tarafından atanmış ad" durumudur

Bu yöntemin hiçbir IAccessible yöntemine dayanmayan Flash'a özgü bir yöntem olduğunu unutmayın.

Parametreler