LoaderInfo  - AS3

Yüklenen SWF dosyasının ActionScript sürümü. Dil sürümü, ActionScriptVersion sınıfı kullanılarak belirtilir, örn. ActionScriptVersion.ACTIONSCRIPT2 ve ActionScriptVersion.ACTIONSCRIPT3.

Not: Bu özellik her zaman ActionScriptVersion.ACTIONSCRIPT2 veya ActionScriptVersion.ACTIONSCRIPT3 değerine sahiptir. ActionScript 1.0 ve 2.0, ActionScriptVersion.ACTIONSCRIPT2 (sürüm 2.0) olarak bildirilir. Bu özellik yalnızca ActionScript 1.0 ve 2.0'ı ActionScript 3.0'dan ayırır.

İlgili API Öğeleri

Harici bir SWF dosyası yüklendiğinde, yüklenen sınıfın içindeki tüm ActionScript 3.0 tanımları applicationDomain özelliğinin içinde saklanır.

Bir SWF dosyasındaki tüm kodlar, bir uygulama etki alanında var olacak şekilde tanımlanmıştır. Geçerli uygulama etki alanı, ana uygulamanızın çalıştığı yerdir. Sistem etki alanları, geçerli etki alanı ve Flash Player veya Adobe AIR tarafından kullanılan tüm sınıflar da dahil olmak üzere, tüm uygulama etki alanlarını içerir.

Sistem etki alanı dışındaki tüm uygulama etki alanları, ilişkilendirilmiş bir üst etki alanına sahiptir. Ana uygulamanızın applicationDomain öğesinin üst etki alanı, sistem etki alanıdır. Yüklenmiş sınıflar yalnızca üst öğeleri tarafından zaten tanımlanmamışsa tanımlanır. Yüklenmiş bir sınıf tanımını, yeni bir tanımla geçersiz kılamazsınız.

Uygulama etki alanlarının kullanım örnekleri için ActionScript 3.0 Geliştirici Kılavuzu'ndaki "Client System Environment" (İstemci Sistem Ortamı) bölümüne bakın.

İlgili API Öğeleri

Bir LoaderInfo nesnesiyle ilişkilendirilmiş baytlar.

Medya için yüklenen bayt sayısı. Bu özellik bytesTotal değerine eşit olduğunda tüm baytlar yüklenir.

Medya dosyasının tamamındaki sıkıştırılmış bayt sayısı.

Bu LoaderInfo nesnesinin karşılık gelen Loader nesnesi tarafından birinci progress olayı gönderilmeden önce, bytesTotal değeri 0'dır. Loader nesnesindeki birinci progress olayından sonra, bytesTotal öğesi, indirilecek gerçek bayt sayısını yansıtır.

Not (yalnızca iOS): iOS'ta bir uygulama çalıştırılırken, döndürülen değer diğer platformlardakiyle aynı değildir.

İlgili API Öğeleri

İçerikten (alt öğe) Loader'a (üst öğe) güven ilişkisini ifade eder. Alt öğe, üst öğe erişimine izin verirse true; aksi takdirde, false. Alt nesne, üst etki alanına izin vermek için allowDomain() yöntemini çağırdıysa veya üst etki alanına izin veren alt etki alanına, bir URL ilkesi yüklenirse, bu özellik true değerine ayarlanır. Alt öğe ve üst öğe aynı etki alanındaysa, bu özellik true değerine ayarlanır.

Güvenlikle ilgili daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

Loader nesnesinin sanal alanındaki kodla erişilebilecek özellikler ve yöntemleri göstermek için yüklenen içeriğin koduyla ayarlanabilen bir nesne. Bu sandbox bridge, uygulama dışı bir sanal alandaki içeriğin uygulama sanal alanındaki komut dosyalarına denetimli erişime sahip olmasını, ve bunun tam tersini sağlar. Sanal alan köprüsü, uygulama ve uygulama dışı güvenlik sanal alanları arasında açık etkileşim sağlayarak sanal alanlar arasında bir ağ geçidi olarak görev yapar.

İlgili API Öğeleri

Bu LoaderInfo nesnesiyle ilişkilendirilen yüklü nesne.

Yüklenen dosyanın MIME türü. Dosyanın türünü belirlemeye yetecek kadar olan kısmı yüklenmediyse, değer null olur. Şu listede olası değerler verilmektedir:

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

Yüklenen SWF dosyasının saniyede kare sayısı olarak nominal kare hızı. Bu sayı genellikle bir tam sayı olsa da her zaman tam sayı olmak zorunda değildir.

Bu değer, kullanılan gerçek kare hızından farklı olabilir. Flash Player veya Adobe AIR, herhangi bir zamanda yüklenen tüm SWF dosyaları için tek bir kare hızı kullanır ve bu kare hızı ana SWF dosyasının nominal kare hızı tarafından belirlenir. Ayrıca, ana kare hızı donanıma, ses senkronizasyonuna ve diğer faktörlere bağlı olarak arşivlenemeyebilir.

Yüklenen dosyanın nominal yüksekliği. Yüklenen içerik veya bunun üst görüntüleme nesneleri ölçeklenebileceğinden, bu değer içeriğin görüntülendiği gerçek yükseklikten farklı olabilir.

LoaderInfo.url özelliğinin kırpıldığını gösterir. isURLInaccessible değeri true olduğunda, LoaderInfo.url değeri yalnızca içeriğin yüklendiği son URL'nin etki alanı olur. Örneğin; içerik, http://www.adobe.com/assets/hello.swf adresinden yüklenmişse ve LoaderInfo.url özeliği http://www.adobe.com değerine sahipse özellik kırpılır. isURLInaccessible değeri yalnızca aşağıdakilerin tümü true olduğunda true olur:

• İçeriği yüklerken bir HTTP yeniden yönlendirmesi oluştu.
• Loader.load() öğesini çağıran SWF dosyası içeriğin son URL'sinden farklı bir etki alanından.
• Loader.load öğesini çağıran SWF dosyasının içeriğe erişim izni yok. İçeriğe verilen izin, BitmapData.draw(): çağrısı Security.allowDomain() öğesinin SWF dosyasına erişim izni ile aynı biçimde verilir. (veya SWF olmayan dosya içeriği, bir ilke dosyası oluşturun ve LoaderContext.checkPolicyFile özelliğini kullanın).

Not: isURLInaccessible özelliği Adobe Flash Player 10.1 ve AIR 2 için eklenmiştir ancak Flash çalışma zamanı desteklediğinde bütün sürümlerin SWF dosyaları için ulaşılabilir kılınmıştır. Bundan dolayı "sıkı mod"da geliştirme araçlarından bazılarını kullanmak derleme hatasına sebep olur. Hatayı geçici olarak düzeltmek için myLoaderInfo["isURLInaccessible"] dolaylı sözdizimini kullanın veya sıkı modu devre dışı bırakın. Flash Professional CS5 veya Flex SDK 4.1 kullanıyorsanız, bu API'yi Flash Player 10.1 ve AIR 2'den önce yayımlanan çalışma zamanları için kullanabilir ve derleyebilirsiniz.

AIR'deki uygulama içeriği için, bu özelliğin değeri her zaman false değeridir.

İlgili API Öğeleri

Bu LoaderInfo nesnesiyle ilişkilendirilen Loader nesnesi. Bu LoaderInfo nesnesi, SWF dosyasının ana sınıfı örneğinin loaderInfo özelliğiyse, herhangi bir Loader nesnesi ilişkilendirilmez.

Bu LoaderInfo nesnesi tarafından açıklanan medyanın yüklemesini başlatan SWF dosyasının URL'si. SWF dosyasının ana sınıfı örneği için bu URL, SWF dosyasının kendi URL'siyle aynıdır.

Yüklenen SWF dosyasında sağlanan parametreleri temsil eden ad-değer çiftlerini içeren bir nesne.

parameters nesnesinden tüm adları ve değerleri çıkarmak için bir for-in döngüsünü kullanabilirsiniz.

İki parametre kaynağı şunlardır: ana SWF dosyasındaki sorgu dizesi ve FlashVars HTML parametresinin değeri. (Bu yalnızca ana SWF dosyasını etkiler.)

parameters özelliği, ana zaman çizelgesi özellikleri olarak SWF dosyası parametrelerini sağlamaya yönelik ActionScript 1.0 ve 2.0 tekniğinin yerini alır.

parameters özelliğinin değeri, ActionScript 1.0 veya 2.0 kullanan SWF dosyalarının yer aldığı Loader nesneleri için null olur. Bu ancak ActionScript 3.0 kullanan SWF dosyalarının yer aldığı Loader nesneleri için null olmaz.

Loader'dan (üst öğe) içeriğe (alt öğe) güven ilişkisini ifade eder. Üst öğe, alt öğe erişimine izin verirse true; aksi takdirde, false. Üst nesne, alt etki alanına izin vermek içinallowDomain() yöntemini çağırdıysa veya alt etki alanına izin veren üst etki alanına, bir URL ilke dosyası yüklenirse, bu özellik true değerine ayarlanır. Alt öğe ve üst öğe aynı etki alanındaysa, bu özellik true değerine ayarlanır.

Güvenlikle ilgili daha fazla bilgi için, bkz. Flash Player Geliştirici Merkezi Konusu: Güvenlik.

Yüklenen içeriğin koduyla erişilebilecek özellikler ve yöntemleri göstermek için Loader nesnesinin sanal alanındaki kod tarafından ayarlanabilen bir nesne. Bu sandbox bridge, uygulama dışı bir sanal alandaki içeriğin uygulama sanal alanındaki komut dosyalarına denetimli erişime sahip olmasını, ve bunun tam tersini sağlar. Sanal alan köprüsü, uygulama ve uygulama dışı güvenlik sanal alanları arasında açık etkileşim sağlayarak sanal alanlar arasında bir ağ geçidi olarak görev yapar.

İlgili API Öğeleri

Yükleyici ve içerik arasındaki etki alanı ilişkisini ifade eder: aynı etki alanından geliyorlarsa true, aksi halde false.

Güvenlik sınırları ötesinde olay alış verişi yapmak için kullanılacak bir EventDispatcher örneği. Loader nesnesi ve yüklenen içerik birbirine güvenmeyen güvenlik etki alanlarından gelse bile, her ikisi de sharedEvents nesnesine erişebilir, bu nesne aracılığıyla olayları gönderebilir ve alabilir.

Yüklenen SWF dosyasının dosya biçimi sürümü. Dosya biçimi, SWFVersion sınıfında numaralandırmalar kullanılarak belirtilir, örn. SWFVersion.FLASH7 ve SWFVersion.FLASH9.

İlgili API Öğeleri

Bu LoaderInfo nesnesinin SWF dosyasındaki kodda işlenmemiş bir hata oluştuğunda bir uncaughtError olayı gönderen nesne. Herhangi bir try..catch bloğunun dışında bir hata atıldığında veya herhangi bir lisanslı dinleyiciye sahip olmayan bir ErrorEvent nesnesi gönderildiğinde yakalanmayan bir hata oluşur.

Örneğin, bir try bloğunda olay işleyicisini çağıran bir olay göndericisi varsa, catch bloğu olay işleyicisinde oluşturulan hatayı yakalamaz. Bundan sonra oluşturulan tüm hatalar LoaderInfo.uncaughtErrorEvents dinlenerek yakalanabilir

Bu özellik, bu LoaderInfo öğesine ilişkin SWF'nin yüklenmesi bittiğinde oluşturulur. O zamana kadar, uncaughtErrorEvents özelliği null kalır. Bir salt ActionScript projesinde, SWF dosyasının ana sınıfının yapıcı işlevinin yürütülmesi sırasında veya işlev yürütüldükten sonra bu özelliğe erişebilirsiniz. Bir Flex projesi için, applicationComplete olayı gönderildikten sonra uncaughtErrorEvents özelliği kullanılabilir.

İlgili API Öğeleri

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

Yüklenmekte olan medyanın URL'si.

LoaderInfo nesnesinin karşılık gelen Loader nesnesi tarafından gönderilen birinci progress olayından önce, url özelliğinin değeri yalnızca Loader nesnesinin load() yöntemine yapılan çağrıda belirtilen ilk URL'yi yansıtabilir. Birinci progress olayından sonra, url özelliği, yeniden yönlendirmelerin ve ilgili URL'lerin çözülmesinin ardından medyanın son URL'sini yansıtır.

Bazı durumlarda url özelliğinin değeri kırpılır. Ayrıntılar için isURLInaccessible özelliğine başvurunuz.

İlgili API Öğeleri

Yüklenen içeriğin nominal genişliği. Yüklenen içerik veya bunun üst görüntüleme nesneleri ölçeklenebileceğinden, bu değer içeriğin görüntülendiği gerçek genişlikten farklı olabilir.

Nesne olarak tanımlanan bir SWF dosyasıyla ilişkilendirilmiş LoaderInfo nesnesini döndürür.

Parametreler

Veriler başarılı şekilde yüklendiğinde gönderilir. Diğer bir deyişle, tüm içerik yüklendiğinde ve yükleme bittiğinde gönderilir. complete olayı her zaman init olayından sonra gönderilir. İçerik hala karşıdan yüklüyor olsa bile nesne erişime hazır olduğunda init olayı gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

HTTP üzerinden bir ağ isteği yapıldığında ve bir HTTP durum kodu algılandığında gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Yüklenen bir SWF dosyasının özellikleri ve yöntemleri erişilebilir ve kullanıma hazır durumdaysa gönderilir. İçerik ise hala karşıdan yüklüyor olabilir. Şu koşullar olduğunda, LoaderInfo nesnesi init olayını gönderir:

• Yüklenen nesneyle ilişkilendirilmiş ve LoaderInfo nesnesiyle ilişkilendirilmiş tüm özelliklere ve yöntemlere erişilebilmesi gerekir.
• Tüm alt nesneler için yapıcılar tamamlanmış olmalıdır.
• Yüklenen SWF'nin ana zaman çizelgesinin ilk karesindeki tüm ActionScript kodu gerçekleştirilmiştir.

Örneğin, bir filmin veya animasyonun ilk karesi yüklendiğinde Event.INIT gönderilir. Ardından film erişilebilir ve görüntüleme listesine eklenebilir. Bütün filmin yüklenmesi ise daha uzun sürebilir. Event.COMPLETE yalnızca bütün film yüklendiğinde gönderilir.

init olayı her zaman complete olayından önce gerçekleşmelidir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Bir yükleme işleminin başarısız olmasına neden olan bir girdi veya çıktı hatası ortaya çıktığında gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Bir yükleme işlemi başladığında gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

İndirme işlemi ilerlerken veri alındığında gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Yüklenen bir nesne, Loader nesnesinin unload() yöntemi kullanılarak her kaldırıldığında veya aynı Loader nesnesi tarafından ikinci bir yükleme gerçekleştirilip yükleme başlamadan önce orijinal içerik kaldırıldığında bir LoaderInfo nesnesi tarafından gönderilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

1. Bir url özelliği oluşturulur; bu, görüntünün konumu ve adıdır.
2. Sınıf yapıcısı, loader adında bir Loader nesnesi oluşturur.
3. loader nesnesi, görüntünün düzgün şekilde yüklenmesini sağlamak için bir olay dinleyicisini başlatır.
4. Yapıcı, dosya adı ve konumunun bilinmesi için url iletilmiş şekilde yeni bir URLRequest nesnesi (request) oluşturur.
5. Daha sonra loader nesnesinin load() yöntemine request nesnesi verilir, böylece görüntüleme listesine görüntü yüklenir.

Önemli: Bu örnek, Image.gif adında bir dosyayı, derlenmiş SWF dosyasıyla aynı dizine eklemenizi gerektirir. Ana SWF dosyasının boyutlarına sığan bir alana sahip bir görüntüyü kullanın.

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}