TextLine  - AS3

Taban çizgisinden satırdaki en uzun karakterlerin en üstüne kadar piksel sayısını belirtir. Yalnızca bir grafik öğesini içeren bir TextLine için, ascent öğesi 0 değerine ayarlanır.

Boşluklar ve grafik öğeleri dahil olmak üzere, bölünemez öğelerin sayısını belirten, satırdaki atom sayısı.

Taban çizgisinden satırdaki en düşük azalan karakterlerin en altına kadar piksel sayısını belirtir. Yalnızca bir grafik öğesini içeren bir TextLine için, descent öğesi 0 değerine ayarlanır.

Metin satırının grafik öğeleri içerip içermediğini belirtir.

İlgili API Öğeleri

Metin satırının herhangi bir sekme içerip içermediğini belirtir.

Satırla ilişkilendirilmiş TextLineMirrorRegion nesnelerini içeren bir Vector veya herhangi bir şey yoksa null değeri.

İlgili API Öğeleri

TextBlock içinde bulunan bir sonraki TextLine veya bloktaki son satır geçerli satırsa ya da satırın geçerliliği TextLineValidity.STATIC ise null değeri.

İlgili API Öğeleri

TextBlock içinde bulunan bir önceki TextLine veya satır bloktaki ilk satırsa ya da satırın geçerliliği TextLineValidity.STATIC ise null değeri.

İlgili API Öğeleri

Satırın bir parçası olduğu halde görüntülenmeyen grafik öğelerini ve sona eklenen boşlukları temsil eden U+FDEF karakterleri dahil olmak üzere, satır olan metin bloğundaki ham metnin uzunluğu.

İlgili API Öğeleri

Satırı oluşturduğunda TextBlock.createTextLine() yöntemine belirtilen genişlik. Bir değişikliğin satırın yeniden kesilmesini gerektirip gerektirmediğini belirlerken bu değer kullanışlıdır.

İlgili API Öğeleri

Bu metin satırını içeren TextBlock veya satırın geçerliliği TextLineValidity.STATIC olup satır ile TextBlock arasındaki bağlantının kesildiği anlamına gelirse, null.

İlgili API Öğeleri

Metin bloğunun ham metnindeki satırın birinci karakterinin dizini.

İlgili API Öğeleri

ascent + descent değerine eşit olan, metin satırının mantıksal yüksekliği. Mürekkep yüksekliğini almak için, miras alınan height özelliğine erişin.

Bu değer, satırı sınırlayan taban çizgileri (TextBlock.baselineZero öğesinin ideo olup olmamasına bağlı olarak ideo top/bottom veya ascent/descent) arasındaki fark esas alınarak hesaplanır. Bu taban çizgileri hesaplanırken grafik öğeleri göz önünde bulundurulmaz.

İlgili API Öğeleri

Metin satırının mantıksal genişliği; bu, metin motorunun satırı düzenlemek için kullandığı genişliktir. Tüm çizilmiş piksellerin sınırlayan kutusunun gerçek genişliğini almak için, miras alınan width özelliğine erişin.

İlgili API Öğeleri

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Satır taban çizgisinden satırdaki en uzun karakter veya grafiğin en üstüne kadar piksel sayısını belirtir.

Satır taban çizgisinden satırdaki en düşük azalan karakter veya grafiğin en altına kadar piksel sayısını belirtir.

totalAscent + totalDescent değerine eşit olan, metin satırının toplam mantıksal yüksekliği.

Yaslanmamışsa, satırın genişliği. Yaslanmamış metin için bu değer textWidth ile aynıdır. Yaslanmış metin için bu değer, yaslama olmadan ölçülen uzunluk değeridir ve textWidth gerçek satır genişliğini temsil eder. Örneğin, şu String yaslanıp 500 genişliğiyle TextBlock.createTextLine() öğesine gönderildiğinde, 500 gerçek genişlik değerine ve 268,9921875 yaslanmamış genişlik değerine sahip olur.

İlgili API Öğeleri

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Uygulamaya, rastgele verileri metin satırıyla ilişkilendirme yolu sağlar.

Metin satırının şu anki geçerliliğini belirtir. Bu özelliğin değerleri, TextLineValidity sınıfının üyelerinde bulunur. Bu özelliğin ayarlanmasına yönelik kurallar şunlardır:

Geçerlilik, TextLineValidity üyesi olmayan bir dizeye ayarlanırsa, satır USER_INVALID olarak değerlendirilir. USER_INVALID, böyle bir değeri temsil etmek için burada kullanılan bir özettir.

TextBlock öğesinin içerikleri değiştirildiğinde, Flash çalışma zamanı etkilenen metin satırlarını, önceki satırı ve sonraki tüm satırları INVALID olarak işaretler. Bir değişiklik, önceki satırın, başlangıçta ilk etkilenen satırda olan içeriğin bölümünü kapsamına almasına izin verdiğinde, bir önceki satır geçersiz olarak işaretlenmelidir.

Yeni kesilmiş satırlar her zaman VALID olur. Flash çalışma zamanı, takip eden satırları VALID değerinden POSSIBLY_INVALID veya INVALID değeriyle değiştirebilir. Satır kesmeleri eşleşirse POSSIBLY_INVALID satırlarını VALID değeriyle veya eşleşmezse INVALID değeriyle değiştirir.

Uygulama kodu, VALID satırları INVALID veya USER_INVALID olarak ve USER_INVALID satırları VALID olarak işaretleyebilir. Uygulama kodu, satırları POSSIBLY_INVALID olarak işaretleyemez.

Uygulama kodu herhangi bir satırı STATIC olarak işaretleyebilir. Bu, block üyesinin null olmasına neden olur. STATIC metin satırındaki herhangi bir grafik öğesi, STATIC metin satırının başlangıçta türetildiği metin bloğundan kesilen yeni metin satırının parçasıysa, kaldırılır ve bu grafik öğesi yeniden üst öğeye sahip olur.

İlgili API Öğeleri

TextLine öğesinin temel içeriğini bir XML dizesi olarak atar. Bu durum otomatik test işleminde fayda sağlayabilir ve metin, biçimlendirme ve mizanpaj bilgilerini içerir.

Aşağıda, çıktı açıklanmaktadır:

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Not: Bu yöntemden gelen çıktının içeriği ve biçimi gelecekte değişebilir. Adobe, bu yöntemin geriye dönük uyumluluğunu garantilemez.

İlgili API Öğeleri

Bu yöntem onaylanmamıştır ve bir etkiye sahip değildir. Atom verileri sıkıştırılır ve bellek verimliliğinin yönetiminde bir faktör değildir.

İlgili API Öğeleri

Belirtilen dizindeki atomun iki yönlü düzeyini alır. Satırı oluşturan karakterlerin Unicode iki yönlü özellikleri ile TextBlock.bidiLevel öğesinin birleşimiyle belirlenir.

Örneğin, İbranice bir metinle metin bloğunu başlatırsanız, TextBlock.bidiLevel öğesini 1 değerine ayarlayarak sağdan sola varsayılanını oluşturursunuz. Metin içinde İngilizce bir alıntınız (soldan sağa) varsa, bu metin 2 değerine sahip AtomBidiLevel öğesi içerir. İngilizce içinde Arapça bir bit (sağdan sola) varsa bunun AtomBidiLevel öğesi 3 değerine gider. Arapça içinde bir sayı (soldan sağa) oluşursa, sayının AtomBidiLevel ayarı 4 olur. Atomların hangi satırda bittiğinin önemi yoktur; İbranizce atomlar AtomBidiLevel 1, İngilizce atomlar AtomBidiLevel 2, Arapça atomlar AtomBidiLevel 3 ve sayı atomları AtomBidiLevel 4'tür.

Parametreler

İlgili API Öğeleri

Metin satırına göre belirtilen dizindeki atom sınırlarını alır. Belirtilen atomun sınırları, satırdaki yatay konumu (x), satırdaki dikey konumu (y), genişliği (w) ve yüksekliği (h) içerir. Tüm değerler piksel cinsindendir.

Parametreler

Belirtilen dizindeki satır taban çizgisi boyunca ölçülen atom merkezini alır.

Parametreler

Belirtilen dizindeki atomun grafik öğesini veya atom bir karakterse null değerini alır.

Parametreler

charIndex parametresi tarafından belirtilen karakteri içeren atomun dizinini veya karakter satır içerisindeki herhangi bir atoma katkıda bulunmuyorsa -1 değerini döndürür. charIndex, satırı içeren metin bloğunun tüm içeriğiyle ilişkilidir.

Parametreler

x ve y parametreleri tarafından belirtilen noktadaki atomun dizinini döndürür veya o noktada bir atom yoksa -1 olur.

Bu yöntem, MouseEvent.stageX ve MouseEvent.stageY özellikleriyle kolayca kullanabilmeniz için global koordinatları alır.

Parametreler

Belirtilen dizindeki atomun metin bloğu başlangıç dizinini alır.

Parametreler

Belirtilen dizindeki atomun metin bloğu bitiş dizinini alır.

Parametreler

Belirtilen dizindeki atomun döndürme değerini alır. Bu özellik için TextRotation sabitleri kullanılır. Atomun dönüşü, öğenin ve satırın toplam dönüşüdür. Birincil olarak, TextLine ile etkileşim kurulurken düzeltme karakterinin (imleç) yönlendirmesinin ayarlanması için kullanılır.

Parametreler

İlgili API Öğeleri

Belirtilen dizindeki atomun sol tarafına doğru bir kelime sınırı olup olmadığını belirtir. Satıra katkıda bulunmuş olan karakterlerin Unicode özellikleri esas alınarak kelime sınırları belirlenir.

Parametreler

Belirtilen taban çizgisinin TextBlock.baselineZero öğesine göre konumunu alır.

Parametreler

İlgili API Öğeleri

mirror özelliği, mirror parametresi tarafından belirtilen değerle eşleşen, satır üzerindeki ilk TextLineMirrorRegion öğesini döndürür veya herhangi bir eşleşme yoksa null olur.

Tek bir TextElement öğesi bile, iki yönlü düzeye ve satır kesmesine bağlı olarak bir veya daha fazla satır üzerinde birden çok TextLineMirrorRegion nesnesi oluşturabilir. nextRegion ve previousRegion özellikleri, bir metin öğesinden oluşturulan tüm yansıtma bölgelerini bağlar.

Parametreler

İlgili API Öğeleri

Bir metin satırının piksel cinsinden istenen maksimum genişliği. Bir değer belirtmezseniz, TextBlock.createTextLine() yöntemi, width parametresi için varsayılan değer olarak bu sabiti kullanır.

İlgili API Öğeleri

1. NumericStepper bileşenini kütüphaneye ekleyin.
2. Bu kodu FLA dosyanızla aynı dizine TextLineExample.as olarak kaydedin.
3. FLA'nın Özellikler penceresindeki Sınıf öğesini TextLineExample olarak ayarlayın.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}